git.cworth.org Git - tar/blob - m4/time_r.m4

   1 dnl Reentrant time functions: localtime_r, gmtime_r.
   2
   3 dnl Copyright (C) 2003, 2006-2010 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl Written by Paul Eggert.
   9
  10 AC_DEFUN([gl_TIME_R],
  11 [
  12   dnl Persuade glibc and Solaris <time.h> to declare localtime_r.
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14
  15   AC_REQUIRE([gl_HEADER_TIME_H_DEFAULTS])
  16   AC_REQUIRE([AC_C_RESTRICT])
  17
  18   AC_CHECK_FUNCS_ONCE([localtime_r])
  19   if test $ac_cv_func_localtime_r = yes; then
  20     AC_CACHE_CHECK([whether localtime_r is compatible with its POSIX signature],
  21       [gl_cv_time_r_posix],
  22       [AC_COMPILE_IFELSE(
  23          [AC_LANG_PROGRAM(
  24             [[#include <time.h>]],
  25             [[/* We don't need to append 'restrict's to the argument types,
  26                  even though the POSIX signature has the 'restrict's,
  27                  since C99 says they can't affect type compatibility.  */
  28               struct tm * (*ptr) (time_t const *, struct tm *) = localtime_r;
  29               if (ptr) return 0;
  30               /* Check the return type is a pointer.
  31                  On HP-UX 10 it is 'int'.  */
  32               *localtime_r (0, 0);]])
  33          ],
  34          [gl_cv_time_r_posix=yes],
  35          [gl_cv_time_r_posix=no])
  36       ])
  37     if test $gl_cv_time_r_posix = yes; then
  38       REPLACE_LOCALTIME_R=0
  39     else
  40       REPLACE_LOCALTIME_R=1
  41     fi
  42   else
  43     HAVE_LOCALTIME_R=0
  44   fi
  45   if test $HAVE_LOCALTIME_R = 0 || test $REPLACE_LOCALTIME_R = 1; then
  46     AC_LIBOBJ([time_r])
  47     gl_PREREQ_TIME_R
  48   fi
  49 ])
  50
  51 # Prerequisites of lib/time_r.c.
  52 AC_DEFUN([gl_PREREQ_TIME_R], [
  53   :
  54 ])