git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
   6
   7 # Set default built type
   8 if (NOT CMAKE_BUILD_TYPE)
   9     set (CMAKE_BUILD_TYPE Debug
  10         CACHE
  11         STRING "Choose the build type, options are: None, Debug, Release, RelWithDebInfo, or MinSizeRel."
  12         FORCE)
  13 endif (NOT CMAKE_BUILD_TYPE)
  14
  15 set (CMAKE_USE_PYTHON_VERSION 2.6)
  16
  17 find_package (PythonInterp REQUIRED)
  18 find_package (OpenGL REQUIRED)
  19 find_package (Qt4 COMPONENTS QtCore QtGui QtWebKit)
  20 find_package (QJSON)
  21
  22 if (NOT WIN32)
  23     # Always use the bundled zlib and libpng sources on Windows to make it easy
  24     # to deploy the wrappers DLLs
  25     find_package (ZLIB)
  26     find_package (PNG)
  27     find_package (X11 REQUIRED)
  28
  29     # We use GLX on MacOSX, which is in a separate library
  30     if (APPLE)
  31         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  32         set(X11_LIBRARIES ${X11_LIBRARIES} ${X11_GL_LIB})
  33     endif (APPLE)
  34 else (NOT WIN32)
  35     find_package (DirectX)
  36 endif (NOT WIN32)
  37
  38 if (WIN32)
  39     # MSVC & MinGW only define & use APIENTRY
  40     add_definitions (-DGLAPIENTRY=__stdcall)
  41 endif (WIN32)
  42
  43 if (MSVC)
  44     # C99 includes for msvc
  45     include_directories (msvc)
  46
  47     # Enable math constants defines
  48     add_definitions (-D_USE_MATH_DEFINES)
  49
  50     # No min/max macros
  51     add_definitions (-DNOMINMAX)
  52
  53     # Adjust warnings
  54     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  55     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  56     add_definitions (-W4)
  57     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  58     add_definitions (-wd4505) # unreferenced local function has been removed
  59     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  60     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  61     add_definitions (-wd4018) # signed/unsigned mismatch
  62
  63     # Use static runtime
  64     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  65     foreach (flag_var
  66         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  67         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  68     )
  69         if (${flag_var} MATCHES "/MD")
  70             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  71         endif (${flag_var} MATCHES "/MD")
  72     endforeach (flag_var)
  73 else ()
  74     # Adjust warnings
  75     add_definitions (-Wall)
  76     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  77     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
  78 endif ()
  79
  80 # Use bundled ZLIB if system one can't be found
  81 if (ZLIB_FOUND)
  82     include_directories (${ZLIB_INCLUDE_DIRS})
  83     link_libraries (${ZLIB_LIBRARIES})
  84 else (ZLIB_FOUND)
  85     add_library (zlib STATIC
  86         zlib/adler32.c
  87         zlib/compress.c
  88         zlib/crc32.c
  89         zlib/gzio.c
  90         zlib/uncompr.c
  91         zlib/deflate.c
  92         zlib/trees.c
  93         zlib/zutil.c
  94         zlib/inflate.c
  95         zlib/infback.c
  96         zlib/inftrees.c
  97         zlib/inffast.c
  98     )
  99     include_directories (zlib)
 100     link_libraries (zlib)
 101 endif (ZLIB_FOUND)
 102
 103 # Use bundled LIBPNG if system one can't be found
 104 if (PNG_FOUND)
 105     include_directories (${PNG_INCLUDE_DIR})
 106     add_definitions (${PNG_DEFINITIONS})
 107     link_libraries (${PNG_LIBRARIES})
 108 else (PNG_FOUND)
 109     add_library (png STATIC
 110         libpng/png.c
 111         libpng/pngerror.c
 112         libpng/pngget.c
 113         libpng/pngmem.c
 114         libpng/pngpread.c
 115         libpng/pngread.c
 116         libpng/pngrio.c
 117         libpng/pngrtran.c
 118         libpng/pngrutil.c
 119         libpng/pngset.c
 120         libpng/pngtrans.c
 121         libpng/pngwio.c
 122         libpng/pngwrite.c
 123         libpng/pngwtran.c
 124         libpng/pngwutil.c
 125     )
 126     include_directories (libpng)
 127     link_libraries (png)
 128 endif (PNG_FOUND)
 129
 130 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 131
 132 add_custom_command (
 133     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 134     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 135     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py glapi.py glenum.py stdapi.py
 136 )
 137
 138 if (WIN32)
 139     # Put wrappers in a separate directory
 140     set (LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/wrappers)
 141
 142     # d3d8.dll
 143     #if (DirectX_D3D8_FOUND)
 144     #    include_directories (${DirectX_D3D8_INCLUDE_DIR})
 145     #    add_custom_command (
 146     #        OUTPUT d3d8.cpp
 147     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 148     #        DEPENDS d3d8.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 149     #    )
 150     #    add_library (d3d8 SHARED d3d8.def d3d8.cpp trace_write.cpp os_win32.cpp)
 151     #    set_target_properties (d3d8 PROPERTIES PREFIX "")
 152     #endif (DirectX_D3D8_FOUND)
 153
 154     # d3d9.dll
 155     if (DirectX_D3DX9_FOUND)
 156         include_directories (${DirectX_D3DX9_INCLUDE_DIR})
 157         add_custom_command (
 158             OUTPUT d3d9.cpp
 159             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 160             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py d3dshader.py winapi.py stdapi.py
 161         )
 162         add_library (d3d9 SHARED d3d9.def d3d9.cpp trace_write.cpp os_win32.cpp)
 163         set_target_properties (d3d9 PROPERTIES PREFIX "")
 164     endif (DirectX_D3DX9_FOUND)
 165
 166     # d3d10.dll
 167     #if (DirectX_D3D10_FOUND)
 168     #    include_directories (${DirectX_D3D10_INCLUDE_DIR})
 169     #    add_custom_command (
 170     #        OUTPUT d3d10.cpp
 171     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 172     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 173     #    )
 174     #    add_library (d3d10 SHARED d3d10.def d3d10.cpp trace_write.cpp os_win32.cpp)
 175     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 176     #endif (DirectX_D3D10_FOUND)
 177
 178     # opengl32.dll
 179     add_custom_command (
 180         OUTPUT wgltrace.cpp
 181         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 182         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glenum.py winapi.py stdapi.py
 183     )
 184     add_library (opengl SHARED opengl32.def wgltrace.cpp trace_write.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 185     set_target_properties (opengl PROPERTIES
 186         PREFIX ""
 187         OUTPUT_NAME opengl32)
 188     if (MINGW)
 189         set_target_properties(opengl PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 190     endif (MINGW)
 191
 192 else ()
 193     include_directories (${X11_INCLUDE_DIR})
 194
 195     # libGL.so
 196     add_custom_command (
 197         OUTPUT glxtrace.cpp
 198         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 199         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glenum.py stdapi.py
 200     )
 201
 202     add_library (glxtrace SHARED glxtrace.cpp trace_write.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 203
 204     set_target_properties (glxtrace PROPERTIES
 205         PREFIX ""
 206     )
 207
 208     target_link_libraries (glxtrace dl)
 209 endif ()
 210
 211 if (WIN32)
 212     set (os os_win32.cpp)
 213     set (glws glws_wgl.cpp)
 214 else (WIN32)
 215     set (os os_posix.cpp)
 216     set (glws glws_glx.cpp)
 217 endif (WIN32)
 218
 219 add_library (trace trace_model.cpp trace_parser.cpp trace_write.cpp ${os})
 220
 221 add_executable (tracedump tracedump.cpp)
 222 target_link_libraries (tracedump trace)
 223
 224 add_custom_command (
 225     OUTPUT glretrace_gl.cpp
 226     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 227     DEPENDS glretrace.py retrace.py codegen.py glapi.py glenum.py stdapi.py
 228 )
 229
 230 add_custom_command (
 231     OUTPUT glretrace_state.cpp
 232     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_state.cpp
 233     DEPENDS glstate.py glapi.py glenum.py stdapi.py
 234 )
 235
 236 include_directories (
 237     ${CMAKE_CURRENT_BINARY_DIR}
 238     ${OPENGL_INCLUDE_PATH}
 239 )
 240
 241 add_executable (glretrace
 242     glretrace_gl.cpp
 243     glretrace_main.cpp
 244     glretrace_state.cpp
 245     retrace.cpp
 246     ${glws}
 247     image.cpp
 248     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 249 )
 250
 251 set_property (
 252     TARGET glretrace
 253     APPEND
 254     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 255 )
 256
 257 target_link_libraries (glretrace
 258     trace
 259     ${OPENGL_gl_LIBRARY}
 260     ${OPENGL_glu_LIBRARY}
 261     ${X11_LIBRARIES}
 262 )
 263
 264 if (NOT WIN32)
 265     target_link_libraries (glretrace ${X11_LIBRARIES})
 266 endif (NOT WIN32)
 267
 268 if (QT4_FOUND AND QJSON_FOUND)
 269     add_subdirectory(gui)
 270 endif (QT4_FOUND AND QJSON_FOUND)