git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
   6
   7 # Set default built type
   8 if (NOT CMAKE_BUILD_TYPE)
   9     set (CMAKE_BUILD_TYPE Debug
  10         CACHE
  11         STRING "Choose the build type, options are: None, Debug, Release, RelWithDebInfo, or MinSizeRel."
  12         FORCE)
  13 endif (NOT CMAKE_BUILD_TYPE)
  14
  15 set (CMAKE_USE_PYTHON_VERSION 2.6)
  16
  17 find_package (PythonInterp REQUIRED)
  18 find_package (OpenGL REQUIRED)
  19 find_package (Qt4)
  20
  21 if (NOT WIN32)
  22     # Always use the bundled zlib and libpng sources on Windows to make it easy
  23     # to deploy the wrappers DLLs
  24     find_package (ZLIB)
  25     find_package (PNG)
  26 else (NOT WIN32)
  27     find_package (DirectX)
  28 endif (NOT WIN32)
  29
  30 find_package (GLUT)
  31
  32 if (WIN32)
  33     # MSVC & MinGW only define & use APIENTRY
  34     add_definitions (-DGLAPIENTRY=__stdcall)
  35 endif (WIN32)
  36
  37 if (MSVC)
  38     # Enable math constants defines
  39     add_definitions (-D_USE_MATH_DEFINES)
  40
  41     # Adjust warnings
  42     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  43     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  44     add_definitions (-W4)
  45     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  46     add_definitions (-wd4505) # unreferenced local function has been removed
  47     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  48     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  49     add_definitions (-wd4018) # signed/unsigned mismatch
  50
  51     # Use static runtime
  52     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  53     foreach (flag_var
  54         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  55         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  56     )
  57         if (${flag_var} MATCHES "/MD")
  58             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  59         endif (${flag_var} MATCHES "/MD")
  60     endforeach (flag_var)
  61 else ()
  62     # Adjust warnings
  63     add_definitions (-Wall)
  64     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  65     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
  66 endif ()
  67
  68 # Use bundled ZLIB if system one can't be found
  69 if (ZLIB_FOUND)
  70     include_directories (${ZLIB_INCLUDE_DIRS})
  71     link_libraries (${ZLIB_LIBRARIES})
  72 else (ZLIB_FOUND)
  73     add_library (zlib STATIC
  74         zlib/adler32.c
  75         zlib/compress.c
  76         zlib/crc32.c
  77         zlib/gzio.c
  78         zlib/uncompr.c
  79         zlib/deflate.c
  80         zlib/trees.c
  81         zlib/zutil.c
  82         zlib/inflate.c
  83         zlib/infback.c
  84         zlib/inftrees.c
  85         zlib/inffast.c
  86     )
  87     include_directories (zlib)
  88     link_libraries (zlib)
  89 endif (ZLIB_FOUND)
  90
  91 # Use bundled LIBPNG if system one can't be found
  92 if (PNG_FOUND)
  93     include_directories (${PNG_INCLUDE_DIR})
  94     add_definitions (${PNG_DEFINITIONS})
  95     link_libraries (${PNG_LIBRARIES})
  96 else (PNG_FOUND)
  97     add_library (png STATIC
  98         libpng/png.c
  99         libpng/pngerror.c
 100         libpng/pngget.c
 101         libpng/pngmem.c
 102         libpng/pngpread.c
 103         libpng/pngread.c
 104         libpng/pngrio.c
 105         libpng/pngrtran.c
 106         libpng/pngrutil.c
 107         libpng/pngset.c
 108         libpng/pngtrans.c
 109         libpng/pngwio.c
 110         libpng/pngwrite.c
 111         libpng/pngwtran.c
 112         libpng/pngwutil.c
 113     )
 114     include_directories (libpng)
 115     link_libraries (png)
 116 endif (PNG_FOUND)
 117
 118 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 119
 120 add_custom_command (
 121     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 122     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 123     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py glapi.py glenum.py stdapi.py
 124 )
 125
 126 if (WIN32)
 127     # Put wrappers in a separate directory
 128     set (LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/wrappers)
 129
 130     # d3d8.dll
 131     #if (DirectX_D3D8_FOUND)
 132     #    include_directories (${DirectX_D3D8_INCLUDE_DIR})
 133     #    add_custom_command (
 134     #        OUTPUT d3d8.cpp
 135     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 136     #        DEPENDS d3d8.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 137     #    )
 138     #    add_library (d3d8 SHARED d3d8.def d3d8.cpp trace_write.cpp os_win32.cpp)
 139     #    set_target_properties (d3d8 PROPERTIES PREFIX "")
 140     #endif (DirectX_D3D8_FOUND)
 141
 142     # d3d9.dll
 143     if (DirectX_D3DX9_FOUND)
 144         include_directories (${DirectX_D3DX9_INCLUDE_DIR})
 145         add_custom_command (
 146             OUTPUT d3d9.cpp
 147             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 148             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py d3dshader.py winapi.py stdapi.py
 149         )
 150         add_library (d3d9 SHARED d3d9.def d3d9.cpp trace_write.cpp os_win32.cpp)
 151         set_target_properties (d3d9 PROPERTIES PREFIX "")
 152     endif (DirectX_D3DX9_FOUND)
 153
 154     # d3d10.dll
 155     #if (DirectX_D3D10_FOUND)
 156     #    include_directories (${DirectX_D3D10_INCLUDE_DIR})
 157     #    add_custom_command (
 158     #        OUTPUT d3d10.cpp
 159     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 160     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 161     #    )
 162     #    add_library (d3d10 SHARED d3d10.def d3d10.cpp trace_write.cpp os_win32.cpp)
 163     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 164     #endif (DirectX_D3D10_FOUND)
 165
 166     # opengl32.dll
 167     add_custom_command (
 168         OUTPUT wgltrace.cpp
 169         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 170         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glenum.py winapi.py stdapi.py
 171     )
 172     add_library (opengl SHARED opengl32.def wgltrace.cpp trace_write.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 173     set_target_properties (opengl PROPERTIES
 174         PREFIX ""
 175         OUTPUT_NAME opengl32)
 176     if (MINGW)
 177         set_target_properties(opengl PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 178     endif (MINGW)
 179
 180 else ()
 181
 182     # libGL.so
 183     add_custom_command (
 184         OUTPUT glxtrace.cpp
 185         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 186         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glenum.py stdapi.py
 187     )
 188
 189     add_library (glxtrace SHARED glxtrace.cpp trace_write.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 190     set_target_properties (glxtrace PROPERTIES
 191         COMPILER_DEFINITIONS "-DRETRACE"
 192         PREFIX ""
 193     )
 194     target_link_libraries (glxtrace dl)
 195 endif ()
 196
 197 if (WIN32)
 198     set (os os_win32.cpp)
 199 else (WIN32)
 200     set (os os_posix.cpp)
 201 endif (WIN32)
 202
 203 add_library (trace trace_model.cpp trace_parser.cpp ${os})
 204
 205 add_executable (dump dump.cpp)
 206 target_link_libraries (dump trace)
 207
 208 if (GLUT_INCLUDE_DIR)
 209     add_custom_command (
 210         OUTPUT glretrace.cpp
 211         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace.cpp
 212         DEPENDS glretrace.py retrace.py codegen.py glapi.py glenum.py stdapi.py
 213     )
 214
 215     add_custom_command (
 216         OUTPUT glstate.cpp
 217         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate.cpp
 218         DEPENDS glstate.py glenum.py stdapi.py
 219     )
 220
 221     include_directories (
 222         ${CMAKE_CURRENT_BINARY_DIR}
 223         ${OPENGL_INCLUDE_PATH}
 224         ${GLUT_INCLUDE_DIR}
 225     )
 226
 227     add_executable (glretrace
 228         glretrace.cpp
 229         glstate.cpp
 230         image.cpp
 231         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 232     )
 233
 234     target_link_libraries (glretrace
 235         trace
 236         ${OPENGL_gl_LIBRARY}
 237         ${OPENGL_glu_LIBRARY}
 238         ${GLUT_glut_LIBRARY}
 239     )
 240 endif (GLUT_INCLUDE_DIR)
 241
 242 if (QT4_FOUND)
 243     add_subdirectory(gui)
 244 endif (QT4_FOUND)