git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
   6
   7 # Set default built type
   8 if (NOT CMAKE_BUILD_TYPE)
   9     set (CMAKE_BUILD_TYPE Debug
  10         CACHE
  11         STRING "Choose the build type, options are: None, Debug, Release, RelWithDebInfo, or MinSizeRel."
  12         FORCE)
  13 endif (NOT CMAKE_BUILD_TYPE)
  14
  15 set (CMAKE_USE_PYTHON_VERSION 2.6)
  16
  17 find_package (PythonInterp REQUIRED)
  18 find_package (OpenGL REQUIRED)
  19 find_package (Qt4 COMPONENTS QtCore QtGui QtWebKit)
  20 find_package (QJSON)
  21
  22 if (NOT WIN32)
  23     # Always use the bundled zlib and libpng sources on Windows to make it easy
  24     # to deploy the wrappers DLLs
  25     find_package (ZLIB)
  26     find_package (PNG)
  27 else (NOT WIN32)
  28     find_package (DirectX)
  29 endif (NOT WIN32)
  30
  31 find_package (GLUT)
  32
  33 if (WIN32)
  34     # MSVC & MinGW only define & use APIENTRY
  35     add_definitions (-DGLAPIENTRY=__stdcall)
  36 endif (WIN32)
  37
  38 if (MSVC)
  39     # Enable math constants defines
  40     add_definitions (-D_USE_MATH_DEFINES)
  41
  42     # Adjust warnings
  43     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  44     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  45     add_definitions (-W4)
  46     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  47     add_definitions (-wd4505) # unreferenced local function has been removed
  48     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  49     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  50     add_definitions (-wd4018) # signed/unsigned mismatch
  51
  52     # Use static runtime
  53     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  54     foreach (flag_var
  55         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  56         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  57     )
  58         if (${flag_var} MATCHES "/MD")
  59             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  60         endif (${flag_var} MATCHES "/MD")
  61     endforeach (flag_var)
  62 else ()
  63     # Adjust warnings
  64     add_definitions (-Wall)
  65     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  66     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
  67 endif ()
  68
  69 # Use bundled ZLIB if system one can't be found
  70 if (ZLIB_FOUND)
  71     include_directories (${ZLIB_INCLUDE_DIRS})
  72     link_libraries (${ZLIB_LIBRARIES})
  73 else (ZLIB_FOUND)
  74     add_library (zlib STATIC
  75         zlib/adler32.c
  76         zlib/compress.c
  77         zlib/crc32.c
  78         zlib/gzio.c
  79         zlib/uncompr.c
  80         zlib/deflate.c
  81         zlib/trees.c
  82         zlib/zutil.c
  83         zlib/inflate.c
  84         zlib/infback.c
  85         zlib/inftrees.c
  86         zlib/inffast.c
  87     )
  88     include_directories (zlib)
  89     link_libraries (zlib)
  90 endif (ZLIB_FOUND)
  91
  92 # Use bundled LIBPNG if system one can't be found
  93 if (PNG_FOUND)
  94     include_directories (${PNG_INCLUDE_DIR})
  95     add_definitions (${PNG_DEFINITIONS})
  96     link_libraries (${PNG_LIBRARIES})
  97 else (PNG_FOUND)
  98     add_library (png STATIC
  99         libpng/png.c
 100         libpng/pngerror.c
 101         libpng/pngget.c
 102         libpng/pngmem.c
 103         libpng/pngpread.c
 104         libpng/pngread.c
 105         libpng/pngrio.c
 106         libpng/pngrtran.c
 107         libpng/pngrutil.c
 108         libpng/pngset.c
 109         libpng/pngtrans.c
 110         libpng/pngwio.c
 111         libpng/pngwrite.c
 112         libpng/pngwtran.c
 113         libpng/pngwutil.c
 114     )
 115     include_directories (libpng)
 116     link_libraries (png)
 117 endif (PNG_FOUND)
 118
 119 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 120
 121 add_custom_command (
 122     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 123     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 124     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py glapi.py glenum.py stdapi.py
 125 )
 126
 127 if (WIN32)
 128     # Put wrappers in a separate directory
 129     set (LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/wrappers)
 130
 131     # d3d8.dll
 132     #if (DirectX_D3D8_FOUND)
 133     #    include_directories (${DirectX_D3D8_INCLUDE_DIR})
 134     #    add_custom_command (
 135     #        OUTPUT d3d8.cpp
 136     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 137     #        DEPENDS d3d8.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 138     #    )
 139     #    add_library (d3d8 SHARED d3d8.def d3d8.cpp trace_write.cpp os_win32.cpp)
 140     #    set_target_properties (d3d8 PROPERTIES PREFIX "")
 141     #endif (DirectX_D3D8_FOUND)
 142
 143     # d3d9.dll
 144     if (DirectX_D3DX9_FOUND)
 145         include_directories (${DirectX_D3DX9_INCLUDE_DIR})
 146         add_custom_command (
 147             OUTPUT d3d9.cpp
 148             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 149             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py d3dshader.py winapi.py stdapi.py
 150         )
 151         add_library (d3d9 SHARED d3d9.def d3d9.cpp trace_write.cpp os_win32.cpp)
 152         set_target_properties (d3d9 PROPERTIES PREFIX "")
 153     endif (DirectX_D3DX9_FOUND)
 154
 155     # d3d10.dll
 156     #if (DirectX_D3D10_FOUND)
 157     #    include_directories (${DirectX_D3D10_INCLUDE_DIR})
 158     #    add_custom_command (
 159     #        OUTPUT d3d10.cpp
 160     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 161     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 162     #    )
 163     #    add_library (d3d10 SHARED d3d10.def d3d10.cpp trace_write.cpp os_win32.cpp)
 164     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 165     #endif (DirectX_D3D10_FOUND)
 166
 167     # opengl32.dll
 168     add_custom_command (
 169         OUTPUT wgltrace.cpp
 170         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 171         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glenum.py winapi.py stdapi.py
 172     )
 173     add_library (opengl SHARED opengl32.def wgltrace.cpp trace_write.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 174     set_target_properties (opengl PROPERTIES
 175         PREFIX ""
 176         OUTPUT_NAME opengl32)
 177     if (MINGW)
 178         set_target_properties(opengl PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 179     endif (MINGW)
 180
 181 else ()
 182
 183     # libGL.so
 184     add_custom_command (
 185         OUTPUT glxtrace.cpp
 186         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 187         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glenum.py stdapi.py
 188     )
 189
 190     add_library (glxtrace SHARED glxtrace.cpp trace_write.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 191     set_target_properties (glxtrace PROPERTIES
 192         COMPILER_DEFINITIONS "-DRETRACE"
 193         PREFIX ""
 194     )
 195     target_link_libraries (glxtrace dl)
 196 endif ()
 197
 198 if (WIN32)
 199     set (os os_win32.cpp)
 200 else (WIN32)
 201     set (os os_posix.cpp)
 202 endif (WIN32)
 203
 204 add_library (trace trace_model.cpp trace_parser.cpp ${os})
 205
 206 add_executable (dump dump.cpp)
 207 target_link_libraries (dump trace)
 208
 209 if (GLUT_INCLUDE_DIR)
 210     add_custom_command (
 211         OUTPUT glretrace.cpp
 212         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace.cpp
 213         DEPENDS glretrace.py retrace.py codegen.py glapi.py glenum.py stdapi.py
 214     )
 215
 216     add_custom_command (
 217         OUTPUT glstate.cpp
 218         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate.cpp
 219         DEPENDS glstate.py glenum.py stdapi.py
 220     )
 221
 222     include_directories (
 223         ${CMAKE_CURRENT_BINARY_DIR}
 224         ${OPENGL_INCLUDE_PATH}
 225         ${GLUT_INCLUDE_DIR}
 226     )
 227
 228     add_executable (glretrace
 229         glretrace.cpp
 230         glstate.cpp
 231         image.cpp
 232         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 233     )
 234
 235     target_link_libraries (glretrace
 236         trace
 237         ${OPENGL_gl_LIBRARY}
 238         ${OPENGL_glu_LIBRARY}
 239         ${GLUT_glut_LIBRARY}
 240     )
 241 endif (GLUT_INCLUDE_DIR)
 242
 243 if (QT4_FOUND AND QJSON_FOUND)
 244     add_subdirectory(gui)
 245 endif (QT4_FOUND AND QJSON_FOUND)