git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.6)
   2
   3 project (apitrace)
   4
   5 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
   6
   7 find_package (PythonInterp REQUIRED)
   8 find_package (OpenGL REQUIRED)
   9 find_package (ZLIB)
  10
  11 find_package (DirectX)
  12
  13 find_package (GLUT)
  14
  15 find_library (GLEW_glew_LIBRARY GLEW
  16         /usr/lib
  17 )
  18
  19 find_path (GLEW_INCLUDE_DIR GL/glew.h
  20       /usr/include/GL
  21 )
  22
  23 if (WIN32)
  24         # Nobody likes to include windows.h:
  25         # - Microsoft's GL/gl.h header depends on windows.h but doesn't include it;
  26         # - GLEW temporarily defines the necessary defines but undefines them later
  27         # - certain GLUT distributions don't include it;
  28         # - most of our programs are meant to be portable so don't include it.
  29         #
  30         # We could try to replicate the windows.h definitions required by
  31         # GL/gl.h, but the build time savings don't compensate the constant
  32         # headaches that brings, so instead we force windows.h to be included
  33         # on every file.
  34         if (MSVC)
  35                 add_definitions (-FIwindows.h)
  36         else (MSVC)
  37                 add_definitions (--include windows.h)
  38         endif (MSVC)
  39
  40         # MSVC & MinGW only define & use APIENTRY
  41         add_definitions (-DGLAPIENTRY=__stdcall)
  42
  43         link_libraries (winmm)
  44 endif (WIN32)
  45
  46 if (MSVC)
  47         # Enable math constants defines
  48         add_definitions (-D_USE_MATH_DEFINES)
  49
  50         # Adjust warnings
  51         add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  52         add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  53         add_definitions (-W4)
  54         add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  55         add_definitions (-wd4505) # unreferenced local function has been removed
  56         add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  57
  58         # Use static runtime
  59         # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  60         foreach (flag_var
  61                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  62                 CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  63         )
  64                 if (${flag_var} MATCHES "/MD")
  65                         string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  66                 endif (${flag_var} MATCHES "/MD")
  67         endforeach (flag_var)
  68 else ()
  69         add_definitions (-Wall)
  70 endif ()
  71
  72 # Use bundled ZLIB if system one can't be found
  73 if (NOT ZLIB_FOUND)
  74         add_library (zlib STATIC
  75                 zlib/adler32.c
  76                 zlib/compress.c
  77                 zlib/crc32.c
  78                 zlib/gzio.c
  79                 zlib/uncompr.c
  80                 zlib/deflate.c
  81                 zlib/trees.c
  82                 zlib/zutil.c
  83                 zlib/inflate.c
  84                 zlib/infback.c
  85                 zlib/inftrees.c
  86                 zlib/inffast.c
  87         )
  88
  89         include_directories (zlib)
  90         link_libraries (zlib)
  91 else (NOT ZLIB_FOUND)
  92         include_directories (${ZLIB_INCLUDE_DIRS})
  93         link_libraries (${ZLIB_LIBRARIES})
  94 endif (NOT ZLIB_FOUND)
  95
  96 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
  97
  98 if (WIN32)
  99         # Put wrappers in a separate directory
 100         set (LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/wrappers)
 101
 102         # d3d8.dll
 103         if (DirectX_D3D8_FOUND)
 104                 include_directories (${DirectX_D3D8_INCLUDE_DIR})
 105                 add_custom_command (
 106                         OUTPUT d3d8.cpp
 107                         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 108                         DEPENDS d3d8.py d3d8types.py d3d8caps.py windows.py base.py
 109                 )
 110                 add_library (d3d8 SHARED d3d8.def d3d8.cpp log.cpp os_win32.cpp)
 111                 set_target_properties (d3d8 PROPERTIES PREFIX "")
 112         endif (DirectX_D3D8_FOUND)
 113
 114         # d3d9.dll
 115         if (DirectX_D3DX9_FOUND)
 116                 include_directories (${DirectX_D3DX9_INCLUDE_DIR})
 117                 add_custom_command (
 118                         OUTPUT d3d9.cpp
 119                         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 120                         DEPENDS d3d9.py d3d9types.py d3d9caps.py d3dshader.py windows.py base.py
 121                 )
 122                 add_library (d3d9 SHARED d3d9.def d3d9.cpp log.cpp os_win32.cpp)
 123                 set_target_properties (d3d9 PROPERTIES PREFIX "")
 124         endif (DirectX_D3DX9_FOUND)
 125
 126         # d3d10.dll
 127         if (DirectX_D3D10_FOUND)
 128                 include_directories (${DirectX_D3D10_INCLUDE_DIR})
 129                 add_custom_command (
 130                         OUTPUT d3d10.cpp
 131                         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 132                         DEPENDS d3d10misc.py windows.py base.py
 133                 )
 134                 add_library (d3d10 SHARED d3d10.def d3d10.cpp log.cpp os_win32.cpp)
 135                 set_target_properties (d3d10 PROPERTIES PREFIX "")
 136         endif (DirectX_D3D10_FOUND)
 137
 138         # opengl32.dll
 139         add_custom_command (
 140                 OUTPUT opengl32.cpp
 141                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.py > ${CMAKE_CURRENT_BINARY_DIR}/opengl32.cpp
 142                 DEPENDS opengl32.py gl.py windows.py base.py
 143         )
 144         add_library (opengl SHARED opengl32.def opengl32.cpp log.cpp os_win32.cpp)
 145         set_target_properties (opengl PROPERTIES
 146                 PREFIX ""
 147                 OUTPUT_NAME opengl32)
 148         if (MINGW)
 149                 SET_TARGET_PROPERTIES(opengl PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 150         endif (MINGW)
 151
 152 else ()
 153
 154         # libGL.so
 155         add_custom_command (
 156                 OUTPUT glx.cpp
 157                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glx.py > ${CMAKE_CURRENT_BINARY_DIR}/glx.cpp
 158                 DEPENDS glx.py gl.py dl.py base.py
 159         )
 160         add_library (glxtrace SHARED glx.cpp log.cpp os_posix.cpp)
 161         set_target_properties (glxtrace PROPERTIES PREFIX "")
 162         target_link_libraries (glxtrace dl)
 163 endif ()
 164
 165 add_executable (dump dump.cpp trace_model.cpp)
 166
 167
 168 if (GLEW_INCLUDE_DIR)
 169         add_custom_command (
 170                 OUTPUT glretrace.cpp
 171                 COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace.cpp
 172                 DEPENDS glretrace.py glx.py gl.py dl.py base.py
 173         )
 174
 175         include_directories (
 176                 ${OPENGL_INCLUDE_PATH}
 177                 ${GLUT_INCLUDE_DIR}
 178                 ${GLEW_INCLUDE_DIR}
 179         )
 180
 181         add_executable (glretrace glretrace.cpp trace_model.cpp)
 182
 183         target_link_libraries (glretrace
 184                 ${OPENGL_gl_LIBRARY}
 185                 ${OPENGL_glu_LIBRARY}
 186                 ${GLUT_glut_LIBRARY}
 187                 ${GLEW_glew_LIBRARY}
 188         )
 189 endif (GLEW_INCLUDE_DIR)
 190
 191