git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 include_directories (${OPENGL_INCLUDE_DIR})
  44
  45 if (WIN32)
  46     find_package (DirectX)
  47 elseif (APPLE)
  48 else ()
  49     find_package (X11 REQUIRED)
  50
  51     include_directories (${X11_INCLUDE_DIR})
  52
  53     if (ENABLE_EGL)
  54         if (NOT ENABLE_EGL STREQUAL "AUTO")
  55             set (REQUIRE_EGL REQUIRED)
  56         endif ()
  57         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  58         if (EGL_FOUND)
  59             include_directories (${EGL_INCLUDE_DIR})
  60             add_definitions (-DHAVE_EGL)
  61         endif ()
  62     else ()
  63         set (EGL_FOUND 0)
  64     endif ()
  65 endif ()
  66
  67
  68 ##############################################################################
  69 # Set global build options
  70
  71 include (CheckCXXCompilerFlag)
  72
  73 if (WIN32)
  74     # MSVC & MinGW only define & use APIENTRY
  75     add_definitions (-DGLAPIENTRY=__stdcall)
  76
  77     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  78     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  79 else (WIN32)
  80     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  81     if (CXX_COMPILER_FLAG_VISIBILITY)
  82         add_definitions ("-fvisibility=hidden")
  83     endif (CXX_COMPILER_FLAG_VISIBILITY)
  84 endif (WIN32)
  85
  86 if (MSVC)
  87     # C99 includes for msvc
  88     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  89
  90     # Enable math constants defines
  91     add_definitions (-D_USE_MATH_DEFINES)
  92
  93     # No min/max macros
  94     add_definitions (-DNOMINMAX)
  95
  96     # Adjust warnings
  97     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  98     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  99     add_definitions (-W4)
 100     add_definitions (-wd4063) # not a valid value for switch of enum
 101     add_definitions (-wd4127) # conditional expression is constant
 102     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 103     add_definitions (-wd4505) # unreferenced local function has been removed
 104     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 105     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 106     add_definitions (-wd4018) # signed/unsigned mismatch
 107
 108     # Use static runtime
 109     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 110     foreach (flag_var
 111         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 112         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 113     )
 114         if (${flag_var} MATCHES "/MD")
 115             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 116         endif (${flag_var} MATCHES "/MD")
 117     endforeach (flag_var)
 118 else ()
 119     # Adjust warnings
 120     add_definitions (-Wall)
 121     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 122     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 123 endif ()
 124
 125 if (MINGW)
 126     # Avoid depending on MinGW runtime DLLs
 127     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 128     if (HAVE_STATIC_LIBGCC_FLAG)
 129         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 130         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 131         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 132     endif ()
 133     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 134     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 135         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 136         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 137         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 138     endif ()
 139 endif ()
 140
 141
 142 # Put all executables into the same top level build directory, regardless of
 143 # which subdirectory they are declared
 144 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 145
 146
 147 ##############################################################################
 148 # Bundled dependencies
 149 #
 150 # We always use the bundled zlib, libpng, and snappy sources:
 151 # - on Windows to make it easy to deploy the wrappers DLLs
 152 # - on unices to prevent symbol collisions when tracing applications that link
 153 # against other versions of these libraries
 154
 155 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 156 set (ZLIB_LIBRARIES z_bundled)
 157 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 158
 159 include_directories (${ZLIB_INCLUDE_DIRS})
 160 link_libraries (${ZLIB_LIBRARIES})
 161
 162 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 163 set (SNAPPY_LIBRARIES snappy_bundled)
 164 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 165
 166 include_directories (${SNAPPY_INCLUDE_DIRS})
 167 link_libraries (${SNAPPY_LIBRARIES})
 168
 169 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 170 set (PNG_DEFINITIONS "")
 171 set (PNG_LIBRARIES png_bundled)
 172
 173 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 174 include_directories (${PNG_INCLUDE_DIR})
 175 add_definitions (${PNG_DEFINITIONS})
 176 link_libraries (${PNG_LIBRARIES})
 177
 178 # The Qt website provides binaries for Windows and MacOSX, and they are
 179 # automatically found by cmake without any manual intervention.  The situation
 180 # for QJSON is substantially different: there are no binaries for QJSON
 181 # available, and there is no standard installation directory that is detected
 182 # by cmake.
 183 #
 184 # By bundling the QJSON source, we make it much more easier to build the GUI on
 185 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 186 # AUTO.
 187 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 188     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 189     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 190     set (QJSON_LIBRARY_DIRS)
 191     set (QJSON_LIBRARIES qjson_bundled)
 192     set (QJSON_FOUND TRUE)
 193 endif ()
 194
 195 # For glext headers
 196 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 197
 198 # For EGL headers
 199 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 200
 201 ##############################################################################
 202 # Installation directories
 203
 204 if (WIN32 OR APPLE)
 205     # On Windows/MacOSX, applications are usually installed on a directory of
 206     # their own
 207     set (DOC_INSTALL_DIR doc)
 208 else ()
 209     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 210 endif ()
 211
 212 set (LIB_INSTALL_DIR lib/apitrace)
 213
 214 if (APPLE)
 215     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 216     # directories
 217     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 218 else ()
 219     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 220 endif ()
 221
 222 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 223 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 224
 225 # Expose the binary/install directories to source
 226 #
 227 # TODO: Use the same directory layout, for both build and install directories,
 228 # so that binaries can find each other using just relative paths.
 229 #
 230 add_definitions(
 231     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 232     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 233     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 234 )
 235
 236
 237 ##############################################################################
 238 # Common libraries / utilities
 239
 240 include_directories (
 241     ${CMAKE_CURRENT_SOURCE_DIR}
 242     ${CMAKE_CURRENT_SOURCE_DIR}/common
 243 )
 244
 245 add_custom_command (
 246     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 247     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 248     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 249 )
 250
 251 if (WIN32)
 252     set (os os_win32.cpp)
 253     set (glws_os glws_wgl.cpp)
 254 else ()
 255     set (os os_posix.cpp)
 256     if (APPLE)
 257         set (glws_os glws_cocoa.mm)
 258     else ()
 259         set (glws_os glws_glx.cpp)
 260     endif ()
 261 endif ()
 262
 263 add_library (common STATIC
 264     common/trace_file.cpp
 265     common/trace_file_read.cpp
 266     common/trace_file_write.cpp
 267     common/trace_file_zlib.cpp
 268     common/trace_file_snappy.cpp
 269     common/trace_model.cpp
 270     common/trace_parser.cpp
 271     common/trace_writer.cpp
 272     common/trace_writer_local.cpp
 273     common/trace_writer_model.cpp
 274     common/trace_loader.cpp
 275     common/trace_resource.cpp
 276     common/trace_tools_trace.cpp
 277     common/image.cpp
 278     common/image_bmp.cpp
 279     common/image_pnm.cpp
 280     common/image_png.cpp
 281     common/${os}
 282 )
 283
 284 set_target_properties (common PROPERTIES
 285     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 286     # Ensure it can be statically linked in shared libraries
 287     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 288 )
 289
 290 link_libraries (common)
 291
 292
 293 ##############################################################################
 294 # API tracers
 295
 296 if (WIN32)
 297     if (MINGW)
 298         # Silence warnings about @nn suffix mismatch
 299         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 300     endif (MINGW)
 301
 302     # ddraw.dll
 303     if (DirectX_D3D_INCLUDE_DIR)
 304         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 305         add_custom_command (
 306             OUTPUT ddrawtrace.cpp
 307             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 308             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 309         )
 310         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 311         set_target_properties (ddraw
 312             PROPERTIES PREFIX ""
 313             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 314             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 315         )
 316         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 317     endif (DirectX_D3D_INCLUDE_DIR)
 318
 319     # d3d8.dll
 320     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 321         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 322         add_custom_command (
 323             OUTPUT d3d8trace.cpp
 324             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 325             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 326         )
 327         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 328         set_target_properties (d3d8
 329             PROPERTIES PREFIX ""
 330             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 331             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 332         )
 333         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 334     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 335
 336     # d3d9.dll
 337     if (DirectX_D3DX9_INCLUDE_DIR)
 338         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 339         add_custom_command (
 340             OUTPUT d3d9trace.cpp
 341             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 342             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 343         )
 344         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 345         set_target_properties (d3d9
 346             PROPERTIES PREFIX ""
 347             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 348             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 349         )
 350         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 351     endif (DirectX_D3DX9_INCLUDE_DIR)
 352
 353     # d3d10.dll
 354     if (DirectX_D3D10_INCLUDE_DIR)
 355         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 356         add_custom_command (
 357             OUTPUT d3d10trace.cpp
 358             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 359             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 360         )
 361         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 362         set_target_properties (d3d10
 363             PROPERTIES PREFIX ""
 364             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 365             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 366         )
 367         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 368     endif (DirectX_D3D10_INCLUDE_DIR)
 369
 370     # opengl32.dll
 371     add_custom_command (
 372         OUTPUT wgltrace.cpp
 373         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 374         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 375     )
 376     add_library (wgltrace MODULE specs/opengl32.def
 377         wgltrace.cpp
 378         glcaps.cpp
 379         glproc_gl.cpp
 380         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 381     )
 382     set_target_properties (wgltrace PROPERTIES
 383         PREFIX ""
 384         OUTPUT_NAME opengl32
 385         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 386         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 387     )
 388     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 389
 390 elseif (APPLE)
 391     # OpenGL framework
 392     add_custom_command (
 393         OUTPUT cgltrace.cpp
 394         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 395         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 396     )
 397
 398     add_library (cgltrace SHARED
 399         cgltrace.cpp
 400         glcaps.cpp
 401         glproc_gl.cpp
 402         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 403     )
 404
 405     set_target_properties (cgltrace PROPERTIES
 406         # OpenGL framework name
 407         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 408         # Specificy the version and reexport GLU symbols
 409         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 410         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 411         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 412     )
 413
 414     target_link_libraries (cgltrace dl)
 415
 416     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 417 else ()
 418     # libGL.so
 419     add_custom_command (
 420         OUTPUT glxtrace.cpp
 421         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 422         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 423     )
 424
 425     add_library (glxtrace SHARED
 426         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 427         glxtrace.cpp
 428         glcaps.cpp
 429         glproc_gl.cpp
 430     )
 431
 432     set_target_properties (glxtrace PROPERTIES
 433         # avoid the default "lib" prefix
 434         PREFIX ""
 435         # Prevent symbol relocations internal to our wrapper library to be
 436         # overwritten by the application.
 437         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 438         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 439         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 440     )
 441
 442     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 443
 444     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 445 endif ()
 446
 447
 448 if (EGL_FOUND)
 449     # libEGL.so/libGL.so
 450     add_custom_command (
 451         OUTPUT egltrace.cpp
 452         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 453         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 454     )
 455
 456     add_library (egltrace SHARED
 457         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 458         egltrace.cpp
 459         glcaps.cpp
 460         glproc_egl.cpp
 461     )
 462
 463     set_property (
 464         TARGET egltrace
 465         APPEND
 466         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 467     )
 468
 469     set_target_properties (egltrace PROPERTIES
 470         # avoid the default "lib" prefix
 471         PREFIX ""
 472         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 473         # Prevent symbol relocations internal to our wrapper library to be
 474         # overwritten by the application.
 475         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 476         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 477     )
 478
 479     target_link_libraries (egltrace dl)
 480
 481     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 482 endif ()
 483
 484 ##############################################################################
 485 # API retracers
 486
 487 add_custom_command (
 488     OUTPUT glretrace_gl.cpp
 489     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 490     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 491 )
 492
 493 add_custom_command (
 494     OUTPUT glstate_params.cpp
 495     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 496     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 497 )
 498
 499 include_directories (
 500     ${CMAKE_CURRENT_BINARY_DIR}
 501     ${OPENGL_INCLUDE_PATH}
 502 )
 503
 504 set (retrace_sources
 505     glretrace_gl.cpp
 506     glretrace_cgl.cpp
 507     glretrace_glx.cpp
 508     glretrace_wgl.cpp
 509     glretrace_egl.cpp
 510     glretrace_main.cpp
 511     glstate.cpp
 512     glstate_params.cpp
 513     retrace.cpp
 514     retrace_stdc.cpp
 515     glws.cpp
 516     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 517 )
 518
 519 add_executable (glretrace
 520     ${retrace_sources}
 521     ${glws_os}
 522     glproc_gl.cpp
 523 )
 524
 525 set_property (
 526     TARGET glretrace
 527     APPEND
 528     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 529 )
 530
 531 target_link_libraries (glretrace
 532     common
 533 )
 534
 535 if (WIN32)
 536 elseif (APPLE)
 537     target_link_libraries (glretrace
 538         "-framework Cocoa"
 539         "-framework ApplicationServices" # CGS*
 540         ${OPENGL_gl_LIBRARY} # CGL*
 541     )
 542 else ()
 543     target_link_libraries (glretrace ${X11_X11_LIB})
 544 endif ()
 545
 546 install (TARGETS glretrace RUNTIME DESTINATION bin)
 547
 548 if (EGL_FOUND AND NOT WIN32 AND NOT APPLE)
 549     add_executable (eglretrace
 550         ${retrace_sources}
 551         glws_egl_xlib.cpp
 552         glproc_egl.cpp
 553     )
 554
 555     set_property (
 556         TARGET eglretrace
 557         APPEND
 558         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 559         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 560     )
 561
 562     target_link_libraries (eglretrace
 563         common
 564     )
 565
 566     target_link_libraries (eglretrace
 567         ${X11_X11_LIB}
 568     )
 569
 570     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 571 endif ()
 572
 573 ##############################################################################
 574 # CLI
 575
 576 add_subdirectory(cli)
 577
 578 ##############################################################################
 579 # Scripts (to support the CLI)
 580
 581 install (
 582     PROGRAMS
 583         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh
 584         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 585         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 586     DESTINATION ${SCRIPTS_INSTALL_DIR}
 587 )
 588
 589 ##############################################################################
 590 # GUI
 591
 592 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 593     add_subdirectory(gui)
 594 endif ()
 595
 596
 597 ##############################################################################
 598 # Packaging
 599
 600 install (
 601     FILES
 602         BUGS.markdown
 603         LICENSE
 604         NEWS.markdown
 605         README.markdown
 606         TODO.markdown
 607     DESTINATION ${DOC_INSTALL_DIR}
 608 )
 609
 610 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 611 set (CPACK_PACKAGE_VERSION_MINOR "0")
 612
 613 # Use current date in YYYYMMDD format as patch number
 614 execute_process (
 615     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 616     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 617 )
 618
 619 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 620 if (WIN32)
 621     set (CPACK_GENERATOR "ZIP")
 622 elseif (APPLE)
 623     set (CPACK_GENERATOR "DragNDrop")
 624 else ()
 625     set (CPACK_GENERATOR "TBZ2")
 626 endif ()
 627
 628 include(CPack)