git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
   6
   7 # Set default built type
   8 if (NOT CMAKE_BUILD_TYPE)
   9     set (CMAKE_BUILD_TYPE Debug
  10         CACHE
  11         STRING "Choose the build type, options are: None, Debug, Release, RelWithDebInfo, or MinSizeRel."
  12         FORCE)
  13 endif (NOT CMAKE_BUILD_TYPE)
  14
  15 set (CMAKE_USE_PYTHON_VERSION 2.6)
  16
  17 find_package (PythonInterp REQUIRED)
  18 find_package (OpenGL REQUIRED)
  19
  20 if (NOT WIN32)
  21     # Always use the bundled zlib and libpng sources on Windows to make it easy
  22     # to deploy the wrappers DLLs
  23     find_package (ZLIB)
  24     find_package (PNG)
  25 else (NOT WIN32)
  26     find_package (DirectX)
  27 endif (NOT WIN32)
  28
  29 find_package (GLUT)
  30
  31 if (WIN32)
  32     # MSVC & MinGW only define & use APIENTRY
  33     add_definitions (-DGLAPIENTRY=__stdcall)
  34 endif (WIN32)
  35
  36 if (MSVC)
  37     # Enable math constants defines
  38     add_definitions (-D_USE_MATH_DEFINES)
  39
  40     # Adjust warnings
  41     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  42     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  43     add_definitions (-W4)
  44     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  45     add_definitions (-wd4505) # unreferenced local function has been removed
  46     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  47     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  48     add_definitions (-wd4018) # signed/unsigned mismatch
  49
  50     # Use static runtime
  51     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  52     foreach (flag_var
  53         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  54         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  55     )
  56         if (${flag_var} MATCHES "/MD")
  57             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  58         endif (${flag_var} MATCHES "/MD")
  59     endforeach (flag_var)
  60 else ()
  61     # Adjust warnings
  62     add_definitions (-Wall)
  63     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  64     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
  65 endif ()
  66
  67 # Use bundled ZLIB if system one can't be found
  68 if (ZLIB_FOUND)
  69     include_directories (${ZLIB_INCLUDE_DIRS})
  70     link_libraries (${ZLIB_LIBRARIES})
  71 else (ZLIB_FOUND)
  72     add_library (zlib STATIC
  73         zlib/adler32.c
  74         zlib/compress.c
  75         zlib/crc32.c
  76         zlib/gzio.c
  77         zlib/uncompr.c
  78         zlib/deflate.c
  79         zlib/trees.c
  80         zlib/zutil.c
  81         zlib/inflate.c
  82         zlib/infback.c
  83         zlib/inftrees.c
  84         zlib/inffast.c
  85     )
  86     include_directories (zlib)
  87     link_libraries (zlib)
  88 endif (ZLIB_FOUND)
  89
  90 # Use bundled LIBPNG if system one can't be found
  91 if (PNG_FOUND)
  92     include_directories (${PNG_INCLUDE_DIR})
  93     add_definitions (${PNG_DEFINITIONS})
  94     link_libraries (${PNG_LIBRARIES})
  95 else (PNG_FOUND)
  96     add_library (png STATIC
  97         libpng/png.c
  98         libpng/pngerror.c
  99         libpng/pngget.c
 100         libpng/pngmem.c
 101         libpng/pngpread.c
 102         libpng/pngread.c
 103         libpng/pngrio.c
 104         libpng/pngrtran.c
 105         libpng/pngrutil.c
 106         libpng/pngset.c
 107         libpng/pngtrans.c
 108         libpng/pngwio.c
 109         libpng/pngwrite.c
 110         libpng/pngwtran.c
 111         libpng/pngwutil.c
 112     )
 113     include_directories (libpng)
 114     link_libraries (png)
 115 endif (PNG_FOUND)
 116
 117 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 118
 119 if (WIN32)
 120     # Put wrappers in a separate directory
 121     set (LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/wrappers)
 122
 123     # d3d8.dll
 124     #if (DirectX_D3D8_FOUND)
 125     #    include_directories (${DirectX_D3D8_INCLUDE_DIR})
 126     #    add_custom_command (
 127     #        OUTPUT d3d8.cpp
 128     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 129     #        DEPENDS d3d8.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 130     #    )
 131     #    add_library (d3d8 SHARED d3d8.def d3d8.cpp trace_write.cpp os_win32.cpp)
 132     #    set_target_properties (d3d8 PROPERTIES PREFIX "")
 133     #endif (DirectX_D3D8_FOUND)
 134
 135     # d3d9.dll
 136     if (DirectX_D3DX9_FOUND)
 137         include_directories (${DirectX_D3DX9_INCLUDE_DIR})
 138         add_custom_command (
 139             OUTPUT d3d9.cpp
 140             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 141             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py d3dshader.py winapi.py stdapi.py
 142         )
 143         add_library (d3d9 SHARED d3d9.def d3d9.cpp trace_write.cpp os_win32.cpp)
 144         set_target_properties (d3d9 PROPERTIES PREFIX "")
 145     endif (DirectX_D3DX9_FOUND)
 146
 147     # d3d10.dll
 148     #if (DirectX_D3D10_FOUND)
 149     #    include_directories (${DirectX_D3D10_INCLUDE_DIR})
 150     #    add_custom_command (
 151     #        OUTPUT d3d10.cpp
 152     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 153     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 154     #    )
 155     #    add_library (d3d10 SHARED d3d10.def d3d10.cpp trace_write.cpp os_win32.cpp)
 156     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 157     #endif (DirectX_D3D10_FOUND)
 158
 159     # opengl32.dll
 160     add_custom_command (
 161         OUTPUT wgltrace.cpp
 162         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 163         DEPENDS wgltrace.py trace.py wglapi.py glapi.py glenum.py winapi.py stdapi.py
 164     )
 165     add_library (opengl SHARED opengl32.def wgltrace.cpp trace_write.cpp os_win32.cpp)
 166     set_target_properties (opengl PROPERTIES
 167         PREFIX ""
 168         OUTPUT_NAME opengl32)
 169     if (MINGW)
 170         SET_TARGET_PROPERTIES(opengl PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 171     endif (MINGW)
 172
 173 else ()
 174
 175     # libGL.so
 176     add_custom_command (
 177         OUTPUT glxtrace.cpp
 178         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 179         DEPENDS glxtrace.py trace.py glxapi.py glapi.py glenum.py stdapi.py
 180     )
 181
 182     add_library (glxtrace SHARED glxtrace.cpp trace_write.cpp os_posix.cpp)
 183     set_target_properties (glxtrace PROPERTIES PREFIX "")
 184     target_link_libraries (glxtrace dl)
 185 endif ()
 186
 187 add_executable (dump dump.cpp trace_model.cpp)
 188
 189 if (WIN32)
 190     set (os os_win32.cpp)
 191 else (WIN32)
 192     set (os os_posix.cpp)
 193 endif (WIN32)
 194
 195 if (GLUT_INCLUDE_DIR)
 196     add_custom_command (
 197         OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 198         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 199         DEPENDS glproc.py wglapi.py glxapi.py glapi.py glenum.py stdapi.py
 200     )
 201
 202     add_custom_command (
 203         OUTPUT glretrace.cpp
 204         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace.cpp
 205         DEPENDS glretrace.py retrace.py codegen.py glapi.py glenum.py stdapi.py
 206     )
 207
 208     include_directories (
 209         ${CMAKE_CURRENT_BINARY_DIR}
 210         ${OPENGL_INCLUDE_PATH}
 211         ${GLUT_INCLUDE_DIR}
 212     )
 213
 214     add_executable (glretrace glretrace.cpp trace_model.cpp image.cpp ${os} ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 215
 216     target_link_libraries (glretrace
 217         ${OPENGL_gl_LIBRARY}
 218         ${OPENGL_glu_LIBRARY}
 219         ${GLUT_glut_LIBRARY}
 220     )
 221 endif (GLUT_INCLUDE_DIR)
 222
 223