git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
   6
   7 # Set default built type
   8 if (NOT CMAKE_BUILD_TYPE)
   9     set (CMAKE_BUILD_TYPE Debug
  10         CACHE
  11         STRING "Choose the build type, options are: None, Debug, Release, RelWithDebInfo, or MinSizeRel."
  12         FORCE)
  13 endif (NOT CMAKE_BUILD_TYPE)
  14
  15 set (CMAKE_USE_PYTHON_VERSION 2.6)
  16
  17 find_package (PythonInterp REQUIRED)
  18 find_package (OpenGL REQUIRED)
  19 find_package (Qt4 COMPONENTS QtCore QtGui QtWebKit)
  20 find_package (QJSON)
  21
  22 if (NOT WIN32)
  23     # Always use the bundled zlib and libpng sources on Windows to make it easy
  24     # to deploy the wrappers DLLs
  25     find_package (ZLIB)
  26     find_package (PNG)
  27     find_package (X11 REQUIRED)
  28
  29     # We use GLX on MacOSX, which is in a separate library
  30     if (APPLE)
  31         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  32         set(X11_LIBRARIES ${X11_LIBRARIES} ${X11_GL_LIB})
  33     endif (APPLE)
  34 else (NOT WIN32)
  35     find_package (DirectX)
  36 endif (NOT WIN32)
  37
  38 if (WIN32)
  39     # MSVC & MinGW only define & use APIENTRY
  40     add_definitions (-DGLAPIENTRY=__stdcall)
  41 endif (WIN32)
  42
  43 if (MSVC)
  44     # C99 includes for msvc
  45     include_directories (msvc)
  46
  47     # Enable math constants defines
  48     add_definitions (-D_USE_MATH_DEFINES)
  49
  50     # No min/max macros
  51     add_definitions (-DNOMINMAX)
  52
  53     # Adjust warnings
  54     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  55     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  56     add_definitions (-W4)
  57     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  58     add_definitions (-wd4505) # unreferenced local function has been removed
  59     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  60     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  61     add_definitions (-wd4018) # signed/unsigned mismatch
  62
  63     # Use static runtime
  64     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  65     foreach (flag_var
  66         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  67         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  68     )
  69         if (${flag_var} MATCHES "/MD")
  70             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  71         endif (${flag_var} MATCHES "/MD")
  72     endforeach (flag_var)
  73 else ()
  74     # Adjust warnings
  75     add_definitions (-Wall)
  76     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  77     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
  78 endif ()
  79
  80 # Put all executables into the same top level build directory, regardless of
  81 # which subdirectory they are declared
  82 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
  83
  84 # Use bundled ZLIB if system one can't be found
  85 if (ZLIB_FOUND)
  86     include_directories (${ZLIB_INCLUDE_DIRS})
  87     link_libraries (${ZLIB_LIBRARIES})
  88 else (ZLIB_FOUND)
  89     add_library (zlib STATIC
  90         zlib/adler32.c
  91         zlib/compress.c
  92         zlib/crc32.c
  93         zlib/gzio.c
  94         zlib/uncompr.c
  95         zlib/deflate.c
  96         zlib/trees.c
  97         zlib/zutil.c
  98         zlib/inflate.c
  99         zlib/infback.c
 100         zlib/inftrees.c
 101         zlib/inffast.c
 102     )
 103     include_directories (zlib)
 104     link_libraries (zlib)
 105 endif (ZLIB_FOUND)
 106
 107 # Use bundled LIBPNG if system one can't be found
 108 if (PNG_FOUND)
 109     include_directories (${PNG_INCLUDE_DIR})
 110     add_definitions (${PNG_DEFINITIONS})
 111     link_libraries (${PNG_LIBRARIES})
 112 else (PNG_FOUND)
 113     add_library (png STATIC
 114         libpng/png.c
 115         libpng/pngerror.c
 116         libpng/pngget.c
 117         libpng/pngmem.c
 118         libpng/pngpread.c
 119         libpng/pngread.c
 120         libpng/pngrio.c
 121         libpng/pngrtran.c
 122         libpng/pngrutil.c
 123         libpng/pngset.c
 124         libpng/pngtrans.c
 125         libpng/pngwio.c
 126         libpng/pngwrite.c
 127         libpng/pngwtran.c
 128         libpng/pngwutil.c
 129     )
 130     include_directories (libpng)
 131     link_libraries (png)
 132 endif (PNG_FOUND)
 133
 134 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 135
 136 add_custom_command (
 137     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 138     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 139     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py glapi.py glenum.py stdapi.py
 140 )
 141
 142 if (WIN32)
 143     # Put wrappers in a separate directory
 144     set (LIBRARY_OUTPUT_PATH ${PROJECT_BINARY_DIR}/wrappers)
 145
 146     # d3d8.dll
 147     #if (DirectX_D3D8_FOUND)
 148     #    include_directories (${DirectX_D3D8_INCLUDE_DIR})
 149     #    add_custom_command (
 150     #        OUTPUT d3d8.cpp
 151     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 152     #        DEPENDS d3d8.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 153     #    )
 154     #    add_library (d3d8 SHARED d3d8.def d3d8.cpp trace_write.cpp os_win32.cpp)
 155     #    set_target_properties (d3d8 PROPERTIES PREFIX "")
 156     #endif (DirectX_D3D8_FOUND)
 157
 158     # d3d9.dll
 159     if (DirectX_D3DX9_FOUND)
 160         include_directories (${DirectX_D3DX9_INCLUDE_DIR})
 161         add_custom_command (
 162             OUTPUT d3d9.cpp
 163             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 164             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py d3dshader.py winapi.py stdapi.py
 165         )
 166         add_library (d3d9 SHARED d3d9.def d3d9.cpp trace_write.cpp os_win32.cpp)
 167         set_target_properties (d3d9 PROPERTIES PREFIX "")
 168     endif (DirectX_D3DX9_FOUND)
 169
 170     # d3d10.dll
 171     #if (DirectX_D3D10_FOUND)
 172     #    include_directories (${DirectX_D3D10_INCLUDE_DIR})
 173     #    add_custom_command (
 174     #        OUTPUT d3d10.cpp
 175     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 176     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 177     #    )
 178     #    add_library (d3d10 SHARED d3d10.def d3d10.cpp trace_write.cpp os_win32.cpp)
 179     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 180     #endif (DirectX_D3D10_FOUND)
 181
 182     # opengl32.dll
 183     add_custom_command (
 184         OUTPUT wgltrace.cpp
 185         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 186         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glenum.py winapi.py stdapi.py
 187     )
 188     add_library (opengl SHARED opengl32.def wgltrace.cpp trace_write.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 189     set_target_properties (opengl PROPERTIES
 190         PREFIX ""
 191         OUTPUT_NAME opengl32)
 192     if (MINGW)
 193         set_target_properties(opengl PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 194     endif (MINGW)
 195
 196 else ()
 197     include_directories (${X11_INCLUDE_DIR})
 198
 199     # libGL.so
 200     add_custom_command (
 201         OUTPUT glxtrace.cpp
 202         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 203         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glenum.py stdapi.py
 204     )
 205
 206     add_library (glxtrace SHARED glxtrace.cpp trace_write.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 207
 208     set_target_properties (glxtrace PROPERTIES
 209         PREFIX ""
 210     )
 211
 212     target_link_libraries (glxtrace dl)
 213 endif ()
 214
 215 if (WIN32)
 216     set (os os_win32.cpp)
 217     set (glws glws_wgl.cpp)
 218 else (WIN32)
 219     set (os os_posix.cpp)
 220     set (glws glws_glx.cpp)
 221 endif (WIN32)
 222
 223 add_library (trace trace_model.cpp trace_parser.cpp trace_write.cpp ${os})
 224
 225 add_executable (tracedump tracedump.cpp)
 226 target_link_libraries (tracedump trace)
 227
 228 add_custom_command (
 229     OUTPUT glretrace_gl.cpp
 230     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 231     DEPENDS glretrace.py retrace.py codegen.py glapi.py glenum.py stdapi.py
 232 )
 233
 234 add_custom_command (
 235     OUTPUT glretrace_state.cpp
 236     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_state.cpp
 237     DEPENDS glstate.py glapi.py glenum.py stdapi.py
 238 )
 239
 240 include_directories (
 241     ${CMAKE_CURRENT_BINARY_DIR}
 242     ${OPENGL_INCLUDE_PATH}
 243 )
 244
 245 add_executable (glretrace
 246     glretrace_gl.cpp
 247     glretrace_main.cpp
 248     glretrace_state.cpp
 249     retrace.cpp
 250     ${glws}
 251     image.cpp
 252     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 253 )
 254
 255 set_property (
 256     TARGET glretrace
 257     APPEND
 258     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 259 )
 260
 261 target_link_libraries (glretrace
 262     trace
 263     ${OPENGL_gl_LIBRARY}
 264 )
 265
 266 if (NOT WIN32)
 267     target_link_libraries (glretrace ${X11_LIBRARIES})
 268 endif (NOT WIN32)
 269
 270 if (QT4_FOUND AND QJSON_FOUND)
 271     add_subdirectory(gui)
 272 endif (QT4_FOUND AND QJSON_FOUND)