git.cworth.org Git - notmuch/blob - emacs/notmuch-lib.el

   1 ;;; notmuch-lib.el --- common variables, functions and function declarations
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Carl Worth <cworth@cworth.org>
  21
  22 ;;; Code:
  23
  24 (require 'cl-lib)
  25
  26 (require 'mm-util)
  27 (require 'mm-view)
  28 (require 'mm-decode)
  29
  30 (require 'notmuch-compat)
  31
  32 (unless (require 'notmuch-version nil t)
  33   (defconst notmuch-emacs-version "unknown"
  34     "Placeholder variable when notmuch-version.el[c] is not available."))
  35
  36 (defgroup notmuch nil
  37   "Notmuch mail reader for Emacs."
  38   :group 'mail)
  39
  40 (defgroup notmuch-hello nil
  41   "Overview of saved searches, tags, etc."
  42   :group 'notmuch)
  43
  44 (defgroup notmuch-search nil
  45   "Searching and sorting mail."
  46   :group 'notmuch)
  47
  48 (defgroup notmuch-show nil
  49   "Showing messages and threads."
  50   :group 'notmuch)
  51
  52 (defgroup notmuch-send nil
  53   "Sending messages from Notmuch."
  54   :group 'notmuch
  55   :group 'message)
  56
  57 (defgroup notmuch-tag nil
  58   "Tags and tagging in Notmuch."
  59   :group 'notmuch)
  60
  61 (defgroup notmuch-crypto nil
  62   "Processing and display of cryptographic MIME parts."
  63   :group 'notmuch)
  64
  65 (defgroup notmuch-hooks nil
  66   "Running custom code on well-defined occasions."
  67   :group 'notmuch)
  68
  69 (defgroup notmuch-external nil
  70   "Running external commands from within Notmuch."
  71   :group 'notmuch)
  72
  73 (defgroup notmuch-address nil
  74   "Address completion."
  75   :group 'notmuch)
  76
  77 (defgroup notmuch-faces nil
  78   "Graphical attributes for displaying text"
  79   :group 'notmuch)
  80
  81 (defcustom notmuch-command "notmuch"
  82   "Name of the notmuch binary.
  83
  84 This can be a relative or absolute path to the notmuch binary.
  85 If this is a relative path, it will be searched for in all of the
  86 directories given in `exec-path' (which is, by default, based on
  87 $PATH)."
  88   :type 'string
  89   :group 'notmuch-external)
  90
  91 (defcustom notmuch-search-oldest-first t
  92   "Show the oldest mail first when searching.
  93
  94 This variable defines the default sort order for displaying
  95 search results. Note that any filtered searches created by
  96 `notmuch-search-filter' retain the search order of the parent
  97 search."
  98   :type 'boolean
  99   :group 'notmuch-search)
 100
 101 (defcustom notmuch-poll-script nil
 102   "[Deprecated] Command to run to incorporate new mail into the notmuch database.
 103
 104 This option has been deprecated in favor of \"notmuch new\"
 105 hooks (see man notmuch-hooks).  To change the path to the notmuch
 106 binary, customize `notmuch-command'.
 107
 108 This variable controls the action invoked by
 109 `notmuch-poll-and-refresh-this-buffer' (bound by default to 'G')
 110 to incorporate new mail into the notmuch database.
 111
 112 If set to nil (the default), new mail is processed by invoking
 113 \"notmuch new\". Otherwise, this should be set to a string that
 114 gives the name of an external script that processes new mail. If
 115 set to the empty string, no command will be run.
 116
 117 The external script could do any of the following depending on
 118 the user's needs:
 119
 120 1. Invoke a program to transfer mail to the local mail store
 121 2. Invoke \"notmuch new\" to incorporate the new mail
 122 3. Invoke one or more \"notmuch tag\" commands to classify the mail"
 123   :type '(choice (const :tag "notmuch new" nil)
 124                  (const :tag "Disabled" "")
 125                  (string :tag "Custom script"))
 126   :group 'notmuch-external)
 127
 128 ;;
 129
 130 (defvar notmuch-search-history nil
 131   "Variable to store notmuch searches history.")
 132
 133 (defcustom notmuch-archive-tags '("-inbox")
 134   "List of tag changes to apply to a message or a thread when it is archived.
 135
 136 Tags starting with \"+\" (or not starting with either \"+\" or
 137 \"-\") in the list will be added, and tags starting with \"-\"
 138 will be removed from the message or thread being archived.
 139
 140 For example, if you wanted to remove an \"inbox\" tag and add an
 141 \"archived\" tag, you would set:
 142     (\"-inbox\" \"+archived\")"
 143   :type '(repeat string)
 144   :group 'notmuch-search
 145   :group 'notmuch-show)
 146
 147 (defvar notmuch-common-keymap
 148   (let ((map (make-sparse-keymap)))
 149     (define-key map "?" 'notmuch-help)
 150     (define-key map "q" 'notmuch-bury-or-kill-this-buffer)
 151     (define-key map "s" 'notmuch-search)
 152     (define-key map "t" 'notmuch-search-by-tag)
 153     (define-key map "z" 'notmuch-tree)
 154     (define-key map "u" 'notmuch-unthreaded)
 155     (define-key map "m" 'notmuch-mua-new-mail)
 156     (define-key map "g" 'notmuch-refresh-this-buffer)
 157     (define-key map "=" 'notmuch-refresh-this-buffer)
 158     (define-key map (kbd "M-=") 'notmuch-refresh-all-buffers)
 159     (define-key map "G" 'notmuch-poll-and-refresh-this-buffer)
 160     (define-key map "j" 'notmuch-jump-search)
 161     map)
 162   "Keymap shared by all notmuch modes.")
 163
 164 ;; By default clicking on a button does not select the window
 165 ;; containing the button (as opposed to clicking on a widget which
 166 ;; does). This means that the button action is then executed in the
 167 ;; current selected window which can cause problems if the button
 168 ;; changes the buffer (e.g., id: links) or moves point.
 169 ;;
 170 ;; This provides a button type which overrides mouse-action so that
 171 ;; the button's window is selected before the action is run. Other
 172 ;; notmuch buttons can get the same behaviour by inheriting from this
 173 ;; button type.
 174 (define-button-type 'notmuch-button-type
 175   'mouse-action (lambda (button)
 176                   (select-window (posn-window (event-start last-input-event)))
 177                   (button-activate button)))
 178
 179 (defun notmuch-command-to-string (&rest args)
 180   "Synchronously invoke \"notmuch\" with the given list of arguments.
 181
 182 If notmuch exits with a non-zero status, output from the process
 183 will appear in a buffer named \"*Notmuch errors*\" and an error
 184 will be signaled.
 185
 186 Otherwise the output will be returned."
 187   (with-temp-buffer
 188     (let* ((status (apply #'call-process notmuch-command nil t nil args))
 189            (output (buffer-string)))
 190       (notmuch-check-exit-status status (cons notmuch-command args) output)
 191       output)))
 192
 193 (defvar notmuch--cli-sane-p nil
 194   "Cache whether the CLI seems to be configured sanely.")
 195
 196 (defun notmuch-cli-sane-p ()
 197   "Return t if the cli seems to be configured sanely."
 198   (unless notmuch--cli-sane-p
 199     (let ((status (call-process notmuch-command nil nil nil
 200                                 "config" "get" "user.primary_email")))
 201       (setq notmuch--cli-sane-p (= status 0))))
 202   notmuch--cli-sane-p)
 203
 204 (defun notmuch-assert-cli-sane ()
 205   (unless (notmuch-cli-sane-p)
 206     (notmuch-logged-error
 207      "notmuch cli seems misconfigured or unconfigured."
 208      "Perhaps you haven't run \"notmuch setup\" yet? Try running this
 209 on the command line, and then retry your notmuch command")))
 210
 211 (defun notmuch-cli-version ()
 212   "Return a string with the notmuch cli command version number."
 213   (let ((long-string
 214          ;; Trim off the trailing newline.
 215          (substring (notmuch-command-to-string "--version") 0 -1)))
 216     (if (string-match "^notmuch\\( version\\)? \\(.*\\)$"
 217                       long-string)
 218         (match-string 2 long-string)
 219       "unknown")))
 220
 221 (defun notmuch-config-get (item)
 222   "Return a value from the notmuch configuration."
 223   (let* ((val (notmuch-command-to-string "config" "get" item))
 224          (len (length val)))
 225     ;; Trim off the trailing newline (if the value is empty or not
 226     ;; configured, there will be no newline)
 227     (if (and (> len 0) (= (aref val (- len 1)) ?\n))
 228         (substring val 0 -1)
 229       val)))
 230
 231 (defun notmuch-database-path ()
 232   "Return the database.path value from the notmuch configuration."
 233   (notmuch-config-get "database.path"))
 234
 235 (defun notmuch-user-name ()
 236   "Return the user.name value from the notmuch configuration."
 237   (notmuch-config-get "user.name"))
 238
 239 (defun notmuch-user-primary-email ()
 240   "Return the user.primary_email value from the notmuch configuration."
 241   (notmuch-config-get "user.primary_email"))
 242
 243 (defun notmuch-user-other-email ()
 244   "Return the user.other_email value (as a list) from the notmuch configuration."
 245   (split-string (notmuch-config-get "user.other_email") "\n" t))
 246
 247 (defun notmuch-user-emails ()
 248   (cons (notmuch-user-primary-email) (notmuch-user-other-email)))
 249
 250 (defun notmuch-poll ()
 251   "Run \"notmuch new\" or an external script to import mail.
 252
 253 Invokes `notmuch-poll-script', \"notmuch new\", or does nothing
 254 depending on the value of `notmuch-poll-script'."
 255   (interactive)
 256   (message "Polling mail...")
 257   (if (stringp notmuch-poll-script)
 258       (unless (string= notmuch-poll-script "")
 259         (unless (equal (call-process notmuch-poll-script nil nil) 0)
 260           (error "Notmuch: poll script `%s' failed!" notmuch-poll-script)))
 261     (notmuch-call-notmuch-process "new"))
 262   (message "Polling mail...done"))
 263
 264 (defun notmuch-bury-or-kill-this-buffer ()
 265   "Undisplay the current buffer.
 266
 267 Bury the current buffer, unless there is only one window showing
 268 it, in which case it is killed."
 269   (interactive)
 270   (if (> (length (get-buffer-window-list nil nil t)) 1)
 271       (bury-buffer)
 272     (kill-buffer)))
 273
 274 (defun notmuch-documentation-first-line (symbol)
 275   "Return the first line of the documentation string for SYMBOL."
 276   (let ((doc (documentation symbol)))
 277     (if doc
 278         (with-temp-buffer
 279           (insert (documentation symbol t))
 280           (goto-char (point-min))
 281           (let ((beg (point)))
 282             (end-of-line)
 283             (buffer-substring beg (point))))
 284       "")))
 285
 286 (defun notmuch-prefix-key-description (key)
 287   "Given a prefix key code, return a human-readable string representation.
 288
 289 This is basically just `format-kbd-macro' but we also convert ESC to M-."
 290   (let* ((key-vector (if (vectorp key) key (vector key)))
 291          (desc (format-kbd-macro key-vector)))
 292     (if (string= desc "ESC")
 293         "M-"
 294       (concat desc " "))))
 295
 296
 297 (defun notmuch-describe-key (actual-key binding prefix ua-keys tail)
 298   "Prepend cons cells describing prefix-arg ACTUAL-KEY and ACTUAL-KEY to TAIL.
 299
 300 It does not prepend if ACTUAL-KEY is already listed in TAIL."
 301   (let ((key-string (concat prefix (key-description actual-key))))
 302     ;; We don't include documentation if the key-binding is
 303     ;; over-ridden. Note, over-riding a binding automatically hides the
 304     ;; prefixed version too.
 305     (unless (assoc key-string tail)
 306       (when (and ua-keys (symbolp binding)
 307                  (get binding 'notmuch-prefix-doc))
 308         ;; Documentation for prefixed command
 309         (let ((ua-desc (key-description ua-keys)))
 310           (push (cons (concat ua-desc " " prefix (format-kbd-macro actual-key))
 311                       (get binding 'notmuch-prefix-doc))
 312                 tail)))
 313       ;; Documentation for command
 314       (push (cons key-string
 315                   (or (and (symbolp binding)
 316                            (get binding 'notmuch-doc))
 317                       (and (functionp binding)
 318                            (notmuch-documentation-first-line binding))))
 319             tail)))
 320   tail)
 321
 322 (defun notmuch-describe-remaps (remap-keymap ua-keys base-keymap prefix tail)
 323   ;; Remappings are represented as a binding whose first "event" is
 324   ;; 'remap.  Hence, if the keymap has any remappings, it will have a
 325   ;; binding whose "key" is 'remap, and whose "binding" is itself a
 326   ;; keymap that maps not from keys to commands, but from old (remapped)
 327   ;; functions to the commands to use in their stead.
 328   (map-keymap (lambda (command binding)
 329                 (mapc (lambda (actual-key)
 330                         (setq tail
 331                               (notmuch-describe-key actual-key binding
 332                                                     prefix ua-keys tail)))
 333                       (where-is-internal command base-keymap)))
 334               remap-keymap)
 335   tail)
 336
 337 (defun notmuch-describe-keymap (keymap ua-keys base-keymap &optional prefix tail)
 338   "Return a list of cons cells, each describing one binding in KEYMAP.
 339
 340 Each cons cell consists of a string giving a human-readable
 341 description of the key, and a one-line description of the bound
 342 function.  See `notmuch-help' for an overview of how this
 343 documentation is extracted.
 344
 345 UA-KEYS should be a key sequence bound to `universal-argument'.
 346 It will be used to describe bindings of commands that support a
 347 prefix argument.  PREFIX and TAIL are used internally."
 348   (map-keymap
 349    (lambda (key binding)
 350      (cond ((mouse-event-p key) nil)
 351            ((keymapp binding)
 352             (setq tail
 353                   (if (eq key 'remap)
 354                       (notmuch-describe-remaps
 355                        binding ua-keys base-keymap prefix tail)
 356                     (notmuch-describe-keymap
 357                      binding ua-keys base-keymap
 358                      (notmuch-prefix-key-description key)
 359                      tail))))
 360            (binding
 361             (setq tail
 362                   (notmuch-describe-key (vector key)
 363                                         binding prefix ua-keys tail)))))
 364    keymap)
 365   tail)
 366
 367 (defun notmuch-substitute-command-keys (doc)
 368   "Like `substitute-command-keys' but with documentation, not function names."
 369   (let ((beg 0))
 370     (while (string-match "\\\\{\\([^}[:space:]]*\\)}" doc beg)
 371       (let ((desc
 372              (save-match-data
 373                (let* ((keymap-name (substring doc
 374                                               (match-beginning 1)
 375                                               (match-end 1)))
 376                       (keymap (symbol-value (intern keymap-name)))
 377                       (ua-keys (where-is-internal 'universal-argument keymap t))
 378                       (desc-alist (notmuch-describe-keymap keymap ua-keys keymap))
 379                       (desc-list (mapcar (lambda (arg)
 380                                            (concat (car arg) "\t" (cdr arg)))
 381                                          desc-alist)))
 382                  (mapconcat #'identity desc-list "\n")))))
 383         (setq doc (replace-match desc 1 1 doc)))
 384       (setq beg (match-end 0)))
 385     doc))
 386
 387 (defun notmuch-help ()
 388   "Display help for the current notmuch mode.
 389
 390 This is similar to `describe-function' for the current major
 391 mode, but bindings tables are shown with documentation strings
 392 rather than command names.  By default, this uses the first line
 393 of each command's documentation string.  A command can override
 394 this by setting the 'notmuch-doc property of its command symbol.
 395 A command that supports a prefix argument can explicitly document
 396 its prefixed behavior by setting the 'notmuch-prefix-doc property
 397 of its command symbol."
 398   (interactive)
 399   (let* ((mode major-mode)
 400          (doc (substitute-command-keys
 401                (notmuch-substitute-command-keys (documentation mode t)))))
 402     (with-current-buffer (generate-new-buffer "*notmuch-help*")
 403       (insert doc)
 404       (goto-char (point-min))
 405       (set-buffer-modified-p nil)
 406       (view-buffer (current-buffer) 'kill-buffer-if-not-modified))))
 407
 408 (defun notmuch-subkeymap-help ()
 409   "Show help for a subkeymap."
 410   (interactive)
 411   (let* ((key (this-command-keys-vector))
 412          (prefix (make-vector (1- (length key)) nil))
 413          (i 0))
 414     (while (< i (length prefix))
 415       (aset prefix i (aref key i))
 416       (cl-incf i))
 417     (let* ((subkeymap (key-binding prefix))
 418            (ua-keys (where-is-internal 'universal-argument nil t))
 419            (prefix-string (notmuch-prefix-key-description prefix))
 420            (desc-alist (notmuch-describe-keymap
 421                         subkeymap ua-keys subkeymap prefix-string))
 422            (desc-list (mapcar (lambda (arg) (concat (car arg) "\t" (cdr arg)))
 423                               desc-alist))
 424            (desc (mapconcat #'identity desc-list "\n")))
 425       (with-help-window (help-buffer)
 426         (with-current-buffer standard-output
 427           (insert "\nPress 'q' to quit this window.\n\n")
 428           (insert desc)))
 429       (pop-to-buffer (help-buffer)))))
 430
 431 (defvar notmuch-buffer-refresh-function nil
 432   "Function to call to refresh the current buffer.")
 433 (make-variable-buffer-local 'notmuch-buffer-refresh-function)
 434
 435 (defun notmuch-refresh-this-buffer ()
 436   "Refresh the current buffer."
 437   (interactive)
 438   (when notmuch-buffer-refresh-function
 439     ;; Pass prefix argument, etc.
 440     (call-interactively notmuch-buffer-refresh-function)))
 441
 442 (defun notmuch-poll-and-refresh-this-buffer ()
 443   "Invoke `notmuch-poll' to import mail, then refresh the current buffer."
 444   (interactive)
 445   (notmuch-poll)
 446   (notmuch-refresh-this-buffer))
 447
 448 (defun notmuch-refresh-all-buffers ()
 449   "Invoke `notmuch-refresh-this-buffer' on all notmuch major-mode buffers.
 450
 451 The buffers are silently refreshed, i.e. they are not forced to
 452 be displayed."
 453   (interactive)
 454   (dolist (buffer (buffer-list))
 455     (let ((buffer-mode (buffer-local-value 'major-mode buffer)))
 456       (when (memq buffer-mode '(notmuch-show-mode
 457                                 notmuch-tree-mode
 458                                 notmuch-search-mode
 459                                 notmuch-hello-mode))
 460         (with-current-buffer buffer
 461           (notmuch-refresh-this-buffer))))))
 462
 463 (defun notmuch-prettify-subject (subject)
 464   ;; This function is used by `notmuch-search-process-filter' which
 465   ;; requires that we not disrupt its' matching state.
 466   (save-match-data
 467     (if (and subject
 468              (string-match "^[ \t]*$" subject))
 469         "[No Subject]"
 470       subject)))
 471
 472 (defun notmuch-sanitize (str)
 473   "Sanitize control character in STR.
 474
 475 This includes newlines, tabs, and other funny characters."
 476   (replace-regexp-in-string "[[:cntrl:]\x7f\u2028\u2029]+" " " str))
 477
 478 (defun notmuch-escape-boolean-term (term)
 479   "Escape a boolean term for use in a query.
 480
 481 The caller is responsible for prepending the term prefix and a
 482 colon.  This performs minimal escaping in order to produce
 483 user-friendly queries."
 484   (save-match-data
 485     (if (or (equal term "")
 486             ;; To be pessimistic, only pass through terms composed
 487             ;; entirely of ASCII printing characters other than ", (,
 488             ;; and ).
 489             (string-match "[^!#-'*-~]" term))
 490         ;; Requires escaping
 491         (concat "\"" (replace-regexp-in-string "\"" "\"\"" term t t) "\"")
 492       term)))
 493
 494 (defun notmuch-id-to-query (id)
 495   "Return a query that matches the message with id ID."
 496   (concat "id:" (notmuch-escape-boolean-term id)))
 497
 498 (defun notmuch-hex-encode (str)
 499   "Hex-encode STR (e.g., as used by batch tagging).
 500
 501 This replaces spaces, percents, and double quotes in STR with
 502 %NN where NN is the hexadecimal value of the character."
 503   (replace-regexp-in-string
 504    "[ %\"]" (lambda (match) (format "%%%02x" (aref match 0))) str))
 505
 506 ;;
 507
 508 (defun notmuch-common-do-stash (text)
 509   "Common function to stash text in kill ring, and display in minibuffer."
 510   (if text
 511       (progn
 512         (kill-new text)
 513         (message "Stashed: %s" text))
 514     ;; There is nothing to stash so stash an empty string so the user
 515     ;; doesn't accidentally paste something else somewhere.
 516     (kill-new "")
 517     (message "Nothing to stash!")))
 518
 519 ;;
 520
 521 (defun notmuch-remove-if-not (predicate list)
 522   "Return a copy of LIST with all items not satisfying PREDICATE removed."
 523   (let (out)
 524     (while list
 525       (when (funcall predicate (car list))
 526         (push (car list) out))
 527       (setq list (cdr list)))
 528     (nreverse out)))
 529
 530 (defun notmuch-plist-delete (plist property)
 531   (let* ((xplist (cons nil plist))
 532          (pred xplist))
 533     (while (cdr pred)
 534       (when (eq (cadr pred) property)
 535         (setcdr pred (cdddr pred)))
 536       (setq pred (cddr pred)))
 537     (cdr xplist)))
 538
 539 (defun notmuch-split-content-type (content-type)
 540   "Split content/type into 'content' and 'type'."
 541   (split-string content-type "/"))
 542
 543 (defun notmuch-match-content-type (t1 t2)
 544   "Return t if t1 and t2 are matching content types, taking wildcards into account."
 545   (let ((st1 (notmuch-split-content-type t1))
 546         (st2 (notmuch-split-content-type t2)))
 547     (if (or (string= (cadr st1) "*")
 548             (string= (cadr st2) "*"))
 549         ;; Comparison of content types should be case insensitive.
 550         (string= (downcase (car st1)) (downcase (car st2)))
 551       (string= (downcase t1) (downcase t2)))))
 552
 553 (defvar notmuch-multipart/alternative-discouraged
 554   '(;; Avoid HTML parts.
 555     "text/html"
 556     ;; multipart/related usually contain a text/html part and some
 557     ;; associated graphics.
 558     "multipart/related"))
 559
 560 (defun notmuch-multipart/alternative-determine-discouraged (msg)
 561   "Return the discouraged alternatives for the specified message."
 562   ;; If a function, return the result of calling it.
 563   (if (functionp notmuch-multipart/alternative-discouraged)
 564       (funcall notmuch-multipart/alternative-discouraged msg)
 565     ;; Otherwise simply return the value of the variable, which is
 566     ;; assumed to be a list of discouraged alternatives. This is the
 567     ;; default behaviour.
 568     notmuch-multipart/alternative-discouraged))
 569
 570 (defun notmuch-multipart/alternative-choose (msg types)
 571   "Return a list of preferred types from the given list of types
 572 for this message, if present."
 573   ;; Based on `mm-preferred-alternative-precedence'.
 574   (let ((discouraged (notmuch-multipart/alternative-determine-discouraged msg))
 575         (seq types))
 576     (dolist (pref (reverse discouraged))
 577       (dolist (elem (copy-sequence seq))
 578         (when (string-match pref elem)
 579           (setq seq (nconc (delete elem seq) (list elem))))))
 580     seq))
 581
 582 (defun notmuch-parts-filter-by-type (parts type)
 583   "Given a list of message parts, return a list containing the ones matching
 584 the given type."
 585   (cl-remove-if-not
 586    (lambda (part) (notmuch-match-content-type (plist-get part :content-type) type))
 587    parts))
 588
 589 (defun notmuch--get-bodypart-raw (msg part process-crypto binaryp cache)
 590   (let* ((plist-elem (if binaryp :content-binary :content))
 591          (data (or (plist-get part plist-elem)
 592                    (with-temp-buffer
 593                      ;; Emacs internally uses a UTF-8-like multibyte string
 594                      ;; representation by default (regardless of the coding
 595                      ;; system, which only affects how it goes from outside data
 596                      ;; to this internal representation).  This *almost* never
 597                      ;; matters.  Annoyingly, it does matter if we use this data
 598                      ;; in an image descriptor, since Emacs will use its internal
 599                      ;; data buffer directly and this multibyte representation
 600                      ;; corrupts binary image formats.  Since the caller is
 601                      ;; asking for binary data, a unibyte string is a more
 602                      ;; appropriate representation anyway.
 603                      (when binaryp
 604                        (set-buffer-multibyte nil))
 605                      (let ((args `("show" "--format=raw"
 606                                    ,(format "--part=%s" (plist-get part :id))
 607                                    ,@(and process-crypto '("--decrypt=true"))
 608                                    ,(notmuch-id-to-query (plist-get msg :id))))
 609                            (coding-system-for-read
 610                             (if binaryp
 611                                 'no-conversion
 612                               (let ((coding-system
 613                                      (mm-charset-to-coding-system
 614                                       (plist-get part :content-charset))))
 615                                 ;; Sadly,
 616                                 ;; `mm-charset-to-coding-system' seems
 617                                 ;; to return things that are not
 618                                 ;; considered acceptable values for
 619                                 ;; `coding-system-for-read'.
 620                                 (if (coding-system-p coding-system)
 621                                     coding-system
 622                                   ;; RFC 2047 says that the default
 623                                   ;; charset is US-ASCII. RFC6657
 624                                   ;; complicates this somewhat.
 625                                   'us-ascii)))))
 626                        (apply #'call-process
 627                               notmuch-command nil '(t nil) nil args)
 628                        (buffer-string))))))
 629     (when (and cache data)
 630       (plist-put part plist-elem data))
 631     data))
 632
 633 (defun notmuch-get-bodypart-binary (msg part process-crypto &optional cache)
 634   "Return the unprocessed content of PART in MSG as a unibyte string.
 635
 636 This returns the \"raw\" content of the given part after content
 637 transfer decoding, but with no further processing (see the
 638 discussion of --format=raw in man notmuch-show).  In particular,
 639 this does no charset conversion.
 640
 641 If CACHE is non-nil, the content of this part will be saved in
 642 MSG (if it isn't already)."
 643   (notmuch--get-bodypart-raw msg part process-crypto t cache))
 644
 645 (defun notmuch-get-bodypart-text (msg part process-crypto &optional cache)
 646   "Return the text content of PART in MSG.
 647
 648 This returns the content of the given part as a multibyte Lisp
 649 string after performing content transfer decoding and any
 650 necessary charset decoding.
 651
 652 If CACHE is non-nil, the content of this part will be saved in
 653 MSG (if it isn't already)."
 654   (notmuch--get-bodypart-raw msg part process-crypto nil cache))
 655
 656 ;; Workaround: The call to `mm-display-part' below triggers a bug in
 657 ;; Emacs 24 if it attempts to use the shr renderer to display an HTML
 658 ;; part with images in it (demonstrated in 24.1 and 24.2 on Debian and
 659 ;; Fedora 17, though unreproducible in other configurations).
 660 ;; `mm-shr' references the variable `gnus-inhibit-images' without
 661 ;; first loading gnus-art, which defines it, resulting in a
 662 ;; void-variable error.  Hence, we advise `mm-shr' to ensure gnus-art
 663 ;; is loaded.
 664 (define-advice mm-shr (:before (_handle) notmuch--load-gnus-args)
 665   "Require `gnus-art' since we use its variables."
 666   (require 'gnus-art nil t))
 667
 668 (defun notmuch-mm-display-part-inline (msg part content-type process-crypto)
 669   "Use the mm-decode/mm-view functions to display a part in the
 670 current buffer, if possible."
 671   (let ((display-buffer (current-buffer)))
 672     (with-temp-buffer
 673       ;; In case we already have :content, use it and tell mm-* that
 674       ;; it's already been charset-decoded by using the fake
 675       ;; `gnus-decoded' charset.  Otherwise, we'll fetch the binary
 676       ;; part content and let mm-* decode it.
 677       (let* ((have-content (plist-member part :content))
 678              (charset (if have-content
 679                           'gnus-decoded
 680                         (plist-get part :content-charset)))
 681              (handle (mm-make-handle (current-buffer)
 682                                      `(,content-type (charset . ,charset)))))
 683         ;; If the user wants the part inlined, insert the content and
 684         ;; test whether we are able to inline it (which includes both
 685         ;; capability and suitability tests).
 686         (when (mm-inlined-p handle)
 687           (if have-content
 688               (insert (notmuch-get-bodypart-text msg part process-crypto))
 689             (insert (notmuch-get-bodypart-binary msg part process-crypto)))
 690           (when (mm-inlinable-p handle)
 691             (set-buffer display-buffer)
 692             (mm-display-part handle)
 693             t))))))
 694
 695 ;; Converts a plist of headers to an alist of headers. The input plist should
 696 ;; have symbols of the form :Header as keys, and the resulting alist will have
 697 ;; symbols of the form 'Header as keys.
 698 (defun notmuch-headers-plist-to-alist (plist)
 699   (cl-loop for (key value . rest) on plist by #'cddr
 700            collect (cons (intern (substring (symbol-name key) 1)) value)))
 701
 702 (defun notmuch-face-ensure-list-form (face)
 703   "Return FACE in face list form.
 704
 705 If FACE is already a face list, it will be returned as-is.  If
 706 FACE is a face name or face plist, it will be returned as a
 707 single element face list."
 708   (if (and (listp face) (not (keywordp (car face))))
 709       face
 710     (list face)))
 711
 712 (defun notmuch-apply-face (object face &optional below start end)
 713   "Combine FACE into the 'face text property of OBJECT between START and END.
 714
 715 This function combines FACE with any existing faces between START
 716 and END in OBJECT.  Attributes specified by FACE take precedence
 717 over existing attributes unless BELOW is non-nil.
 718
 719 OBJECT may be a string, a buffer, or nil (which means the current
 720 buffer).  If object is a string, START and END are 0-based;
 721 otherwise they are buffer positions (integers or markers).  FACE
 722 must be a face name (a symbol or string), a property list of face
 723 attributes, or a list of these.  If START and/or END are omitted,
 724 they default to the beginning/end of OBJECT.  For convenience
 725 when applied to strings, this returns OBJECT."
 726   ;; A face property can have three forms: a face name (a string or
 727   ;; symbol), a property list, or a list of these two forms.  In the
 728   ;; list case, the faces will be combined, with the earlier faces
 729   ;; taking precedent.  Here we canonicalize everything to list form
 730   ;; to make it easy to combine.
 731   (let ((pos (cond (start start)
 732                    ((stringp object) 0)
 733                    (t 1)))
 734         (end (cond (end end)
 735                    ((stringp object) (length object))
 736                    (t (1+ (buffer-size object)))))
 737         (face-list (notmuch-face-ensure-list-form face)))
 738     (while (< pos end)
 739       (let* ((cur (get-text-property pos 'face object))
 740              (cur-list (notmuch-face-ensure-list-form cur))
 741              (new (cond ((null cur-list) face)
 742                         (below (append cur-list face-list))
 743                         (t (append face-list cur-list))))
 744              (next (next-single-property-change pos 'face object end)))
 745         (put-text-property pos next 'face new object)
 746         (setq pos next))))
 747   object)
 748
 749 (defun notmuch-map-text-property (start end prop func &optional object)
 750   "Transform text property PROP using FUNC.
 751
 752 Applies FUNC to each distinct value of the text property PROP
 753 between START and END of OBJECT, setting PROP to the value
 754 returned by FUNC."
 755   (while (< start end)
 756     (let ((value (get-text-property start prop object))
 757           (next (next-single-property-change start prop object end)))
 758       (put-text-property start next prop (funcall func value) object)
 759       (setq start next))))
 760
 761 (defun notmuch-logged-error (msg &optional extra)
 762   "Log MSG and EXTRA to *Notmuch errors* and signal MSG.
 763
 764 This logs MSG and EXTRA to the *Notmuch errors* buffer and
 765 signals MSG as an error.  If EXTRA is non-nil, text referring the
 766 user to the *Notmuch errors* buffer will be appended to the
 767 signaled error.  This function does not return."
 768   (with-current-buffer (get-buffer-create "*Notmuch errors*")
 769     (goto-char (point-max))
 770     (unless (bobp)
 771       (newline))
 772     (save-excursion
 773       (insert "[" (current-time-string) "]\n" msg)
 774       (unless (bolp)
 775         (newline))
 776       (when extra
 777         (insert extra)
 778         (unless (bolp)
 779           (newline)))))
 780   (error "%s%s" msg (if extra " (see *Notmuch errors* for more details)" "")))
 781
 782 (defun notmuch-check-async-exit-status (proc msg &optional command err)
 783   "If PROC exited abnormally, pop up an error buffer and signal an error.
 784
 785 This is a wrapper around `notmuch-check-exit-status' for
 786 asynchronous process sentinels.  PROC and MSG must be the
 787 arguments passed to the sentinel.  COMMAND and ERR, if provided,
 788 are passed to `notmuch-check-exit-status'.  If COMMAND is not
 789 provided, it is taken from `process-command'."
 790   (let ((exit-status
 791          (cl-case (process-status proc)
 792            ((exit) (process-exit-status proc))
 793            ((signal) msg))))
 794     (when exit-status
 795       (notmuch-check-exit-status exit-status
 796                                  (or command (process-command proc))
 797                                  nil err))))
 798
 799 (defun notmuch-check-exit-status (exit-status command &optional output err)
 800   "If EXIT-STATUS is non-zero, pop up an error buffer and signal an error.
 801
 802 If EXIT-STATUS is non-zero, pop up a notmuch error buffer
 803 describing the error and signal an Elisp error.  EXIT-STATUS must
 804 be a number indicating the exit status code of a process or a
 805 string describing the signal that terminated the process (such as
 806 returned by `call-process').  COMMAND must be a list giving the
 807 command and its arguments.  OUTPUT, if provided, is a string
 808 giving the output of command.  ERR, if provided, is the error
 809 output of command.  OUTPUT and ERR will be included in the error
 810 message."
 811   (cond
 812    ((eq exit-status 0) t)
 813    ((eq exit-status 20)
 814     (notmuch-logged-error "notmuch CLI version mismatch
 815 Emacs requested an older output format than supported by the notmuch CLI.
 816 You may need to restart Emacs or upgrade your notmuch Emacs package."))
 817    ((eq exit-status 21)
 818     (notmuch-logged-error "notmuch CLI version mismatch
 819 Emacs requested a newer output format than supported by the notmuch CLI.
 820 You may need to restart Emacs or upgrade your notmuch package."))
 821    (t
 822     (let* ((command-string
 823             (mapconcat (lambda (arg)
 824                          (shell-quote-argument
 825                           (cond ((stringp arg) arg)
 826                                 ((symbolp arg) (symbol-name arg))
 827                                 (t "*UNKNOWN ARGUMENT*"))))
 828                        command " "))
 829            (extra
 830             (concat "command: " command-string "\n"
 831                     (if (integerp exit-status)
 832                         (format "exit status: %s\n" exit-status)
 833                       (format "exit signal: %s\n" exit-status))
 834                     (and err    (concat "stderr:\n" err))
 835                     (and output (concat "stdout:\n" output)))))
 836       (if err
 837           ;; We have an error message straight from the CLI.
 838           (notmuch-logged-error
 839            (replace-regexp-in-string "[ \n\r\t\f]*\\'" "" err) extra)
 840         ;; We only have combined output from the CLI; don't inundate
 841         ;; the user with it.  Mimic `process-lines'.
 842         (notmuch-logged-error (format "%s exited with status %s"
 843                                       (car command) exit-status)
 844                               extra))
 845       ;; `notmuch-logged-error' does not return.
 846       ))))
 847
 848 (defun notmuch-call-notmuch--helper (destination args)
 849   "Helper for synchronous notmuch invocation commands.
 850
 851 This wraps `call-process'.  DESTINATION has the same meaning as
 852 for `call-process'.  ARGS is as described for
 853 `notmuch-call-notmuch-process'."
 854   (let (stdin-string)
 855     (while (keywordp (car args))
 856       (cl-case (car args)
 857         (:stdin-string (setq stdin-string (cadr args))
 858                        (setq args (cddr args)))
 859         (otherwise
 860          (error "Unknown keyword argument: %s" (car args)))))
 861     (if (null stdin-string)
 862         (apply #'call-process notmuch-command nil destination nil args)
 863       (insert stdin-string)
 864       (apply #'call-process-region (point-min) (point-max)
 865              notmuch-command t destination nil args))))
 866
 867 (defun notmuch-call-notmuch-process (&rest args)
 868   "Synchronously invoke `notmuch-command' with ARGS.
 869
 870 The caller may provide keyword arguments before ARGS.  Currently
 871 supported keyword arguments are:
 872
 873   :stdin-string STRING - Write STRING to stdin
 874
 875 If notmuch exits with a non-zero status, output from the process
 876 will appear in a buffer named \"*Notmuch errors*\" and an error
 877 will be signaled."
 878   (with-temp-buffer
 879     (let ((status (notmuch-call-notmuch--helper t args)))
 880       (notmuch-check-exit-status status (cons notmuch-command args)
 881                                  (buffer-string)))))
 882
 883 (defun notmuch-call-notmuch-sexp (&rest args)
 884   "Invoke `notmuch-command' with ARGS and return the parsed S-exp output.
 885
 886 This is equivalent to `notmuch-call-notmuch-process', but parses
 887 notmuch's output as an S-expression and returns the parsed value.
 888 Like `notmuch-call-notmuch-process', if notmuch exits with a
 889 non-zero status, this will report its output and signal an
 890 error."
 891   (with-temp-buffer
 892     (let ((err-file (make-temp-file "nmerr")))
 893       (unwind-protect
 894           (let ((status (notmuch-call-notmuch--helper (list t err-file) args))
 895                 (err (with-temp-buffer
 896                        (insert-file-contents err-file)
 897                        (unless (eobp)
 898                          (buffer-string)))))
 899             (notmuch-check-exit-status status (cons notmuch-command args)
 900                                        (buffer-string) err)
 901             (goto-char (point-min))
 902             (read (current-buffer)))
 903         (delete-file err-file)))))
 904
 905 (defun notmuch-start-notmuch (name buffer sentinel &rest args)
 906   "Start and return an asynchronous notmuch command.
 907
 908 This starts and returns an asynchronous process running
 909 `notmuch-command' with ARGS.  The exit status is checked via
 910 `notmuch-check-async-exit-status'.  Output written to stderr is
 911 redirected and displayed when the process exits (even if the
 912 process exits successfully).  NAME and BUFFER are the same as in
 913 `start-process'.  SENTINEL is a process sentinel function to call
 914 when the process exits, or nil for none.  The caller must *not*
 915 invoke `set-process-sentinel' directly on the returned process,
 916 as that will interfere with the handling of stderr and the exit
 917 status."
 918   (let (err-file err-buffer proc err-proc
 919                  ;; Find notmuch using Emacs' `exec-path'
 920                  (command (or (executable-find notmuch-command)
 921                               (error "Command not found: %s" notmuch-command))))
 922     (if (fboundp 'make-process)
 923         (progn
 924           (setq err-buffer (generate-new-buffer " *notmuch-stderr*"))
 925           ;; Emacs 25 and newer has `make-process', which allows
 926           ;; redirecting stderr independently from stdout to a
 927           ;; separate buffer. As this allows us to avoid using a
 928           ;; temporary file and shell invocation, use it when
 929           ;; available.
 930           (setq proc (make-process
 931                       :name name
 932                       :buffer buffer
 933                       :command (cons command args)
 934                       :connection-type 'pipe
 935                       :stderr err-buffer))
 936           (setq err-proc (get-buffer-process err-buffer))
 937           (process-put proc 'err-buffer err-buffer)
 938
 939           (process-put err-proc 'err-file err-file)
 940           (process-put err-proc 'err-buffer err-buffer)
 941           (set-process-sentinel err-proc #'notmuch-start-notmuch-error-sentinel))
 942       ;; On Emacs versions before 25, there is no way to capture
 943       ;; stdout and stderr separately for asynchronous processes, or
 944       ;; even to redirect stderr to a file, so we use a trivial shell
 945       ;; wrapper to send stderr to a temporary file and clean things
 946       ;; up in the sentinel.
 947       (setq err-file (make-temp-file "nmerr"))
 948       (let ((process-connection-type nil)) ;; Use a pipe
 949         (setq proc (apply #'start-process name buffer
 950                           "/bin/sh" "-c"
 951                           "exec 2>\"$1\"; shift; exec \"$0\" \"$@\""
 952                           command err-file args)))
 953       (process-put proc 'err-file err-file))
 954     (process-put proc 'sub-sentinel sentinel)
 955     (process-put proc 'real-command (cons notmuch-command args))
 956     (set-process-sentinel proc #'notmuch-start-notmuch-sentinel)
 957     proc))
 958
 959 (defun notmuch-start-notmuch-sentinel (proc event)
 960   "Process sentinel function used by `notmuch-start-notmuch'."
 961   (let* ((err-file (process-get proc 'err-file))
 962          (err-buffer (or (process-get proc 'err-buffer)
 963                          (find-file-noselect err-file)))
 964          (err (and (not (zerop (buffer-size err-buffer)))
 965                    (with-current-buffer err-buffer (buffer-string))))
 966          (sub-sentinel (process-get proc 'sub-sentinel))
 967          (real-command (process-get proc 'real-command)))
 968     (condition-case err
 969         (progn
 970           ;; Invoke the sub-sentinel, if any
 971           (when sub-sentinel
 972             (funcall sub-sentinel proc event))
 973           ;; Check the exit status.  This will signal an error if the
 974           ;; exit status is non-zero.  Don't do this if the process
 975           ;; buffer is dead since that means Emacs killed the process
 976           ;; and there's no point in telling the user that (but we
 977           ;; still check for and report stderr output below).
 978           (when (buffer-live-p (process-buffer proc))
 979             (notmuch-check-async-exit-status proc event real-command err))
 980           ;; If that didn't signal an error, then any error output was
 981           ;; really warning output.  Show warnings, if any.
 982           (let ((warnings
 983                  (and err
 984                       (with-current-buffer err-buffer
 985                         (goto-char (point-min))
 986                         (end-of-line)
 987                         ;; Show first line; stuff remaining lines in the
 988                         ;; errors buffer.
 989                         (let ((l1 (buffer-substring (point-min) (point))))
 990                           (skip-chars-forward "\n")
 991                           (cons l1 (and (not (eobp))
 992                                         (buffer-substring (point)
 993                                                           (point-max)))))))))
 994             (when warnings
 995               (notmuch-logged-error (car warnings) (cdr warnings)))))
 996       (error
 997        ;; Emacs behaves strangely if an error escapes from a sentinel,
 998        ;; so turn errors into messages.
 999        (message "%s" (error-message-string err))))
1000     (when err-file (ignore-errors (delete-file err-file)))))
1001
1002 (defun notmuch-start-notmuch-error-sentinel (proc event)
1003   (let* ((err-file (process-get proc 'err-file))
1004          ;; When `make-process' is available, use the error buffer
1005          ;; associated with the process, otherwise the error file.
1006          (err-buffer (or (process-get proc 'err-buffer)
1007                          (find-file-noselect err-file))))
1008     (when err-buffer (kill-buffer err-buffer))))
1009
1010 ;; This variable is used only buffer local, but it needs to be
1011 ;; declared globally first to avoid compiler warnings.
1012 (defvar notmuch-show-process-crypto nil)
1013 (make-variable-buffer-local 'notmuch-show-process-crypto)
1014
1015 (defun notmuch-interactive-region ()
1016   "Return the bounds of the current interactive region.
1017
1018 This returns (BEG END), where BEG and END are the bounds of the
1019 region if the region is active, or both `point' otherwise."
1020   (if (region-active-p)
1021       (list (region-beginning) (region-end))
1022     (list (point) (point))))
1023
1024 (define-obsolete-function-alias
1025   'notmuch-search-interactive-region
1026   'notmuch-interactive-region
1027   "notmuch 0.29")
1028
1029 (provide 'notmuch-lib)
1030
1031 ;;; notmuch-lib.el ends here