git.cworth.org Git - notmuch/blob - emacs/notmuch-maildir-fcc.el

   1 ;;; notmuch-maildir-fcc.el --- inserting using a fcc handler  -*- lexical-binding: t -*-
   2
   3 ;; Copyright © Jesse Rosenthal
   4 ;;
   5 ;; This file is part of Notmuch.
   6 ;;
   7 ;; Notmuch is free software: you can redistribute it and/or modify it
   8 ;; under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11 ;;
  12 ;; Notmuch is distributed in the hope that it will be useful, but
  13 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15 ;; General Public License for more details.
  16 ;;
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with Notmuch.  If not, see <https://www.gnu.org/licenses/>.
  19 ;;
  20 ;; Authors: Jesse Rosenthal <jrosenthal@jhu.edu>
  21
  22 ;;; Code:
  23
  24 (require 'seq)
  25
  26 (require 'message)
  27
  28 (require 'notmuch-lib)
  29
  30 (defvar notmuch-maildir-fcc-count 0)
  31
  32 ;;; Options
  33
  34 (defcustom notmuch-fcc-dirs "sent"
  35   "Determines the Fcc Header which says where to save outgoing mail.
  36
  37 Three types of values are permitted:
  38
  39 - nil: no Fcc header is added,
  40
  41 - a string: the value of `notmuch-fcc-dirs' is the Fcc header to
  42   be used.
  43
  44 - an alist: the folder is chosen based on the From address of
  45   the current message according to an alist mapping regular
  46   expressions to folders or nil:
  47
  48      ((\"Sebastian@SSpaeth.de\" . \"privat\")
  49       (\"spaetz@sspaeth.de\" . \"OUTBOX.OSS\")
  50       (\".*\" . \"defaultinbox\"))
  51
  52   If none of the regular expressions match the From address, or
  53   if the cdr of the matching entry is nil, then no Fcc header
  54   will be added.
  55
  56 If `notmuch-maildir-use-notmuch-insert' is set (the default) then
  57 the header should be of the form \"folder +tag1 -tag2\" where
  58 folder is the folder (relative to the notmuch mailstore) to store
  59 the message in, and tag1 and tag2 are tag changes to apply to the
  60 stored message. This string is split using `split-string-and-unquote',
  61 so a folder name containing spaces can be specified by
  62 quoting each space with an immediately preceding backslash
  63 or surrounding the entire folder name in double quotes.
  64
  65 If `notmuch-maildir-use-notmuch-insert' is nil then the Fcc
  66 header should be the directory where the message should be
  67 saved. A relative directory will be understood to specify a
  68 directory within the notmuch mail store, (as set by the
  69 database.path option in the notmuch configuration file).
  70
  71 In all cases you will be prompted to create the folder or
  72 directory if it does not exist yet when sending a mail."
  73
  74   :type '(choice
  75           (const :tag "No FCC header" nil)
  76           (string :tag "A single folder")
  77           (repeat :tag "A folder based on the From header"
  78                   (cons regexp (choice (const :tag "No FCC header" nil)
  79                                        (string :tag "Folder")))))
  80   :require 'notmuch-fcc-initialization
  81   :group 'notmuch-send)
  82
  83 (defcustom notmuch-maildir-use-notmuch-insert t
  84   "Should fcc use notmuch insert instead of simple fcc."
  85   :type '(choice :tag "Fcc Method"
  86                  (const :tag "Use notmuch insert" t)
  87                  (const :tag "Use simple fcc" nil))
  88   :group 'notmuch-send)
  89
  90 ;;; Functions which set up the fcc header in the message buffer.
  91
  92 (defun notmuch-fcc-header-setup ()
  93   "Add an Fcc header to the current message buffer.
  94
  95 If the Fcc header is already set, then keep it as-is.
  96 Otherwise set it according to `notmuch-fcc-dirs'."
  97   (let ((subdir
  98          (cond
  99           ((or (not notmuch-fcc-dirs)
 100                (message-field-value "Fcc"))
 101            ;; Nothing set or an existing header.
 102            nil)
 103           ((stringp notmuch-fcc-dirs)
 104            notmuch-fcc-dirs)
 105           ((and (listp notmuch-fcc-dirs)
 106                 (stringp (car notmuch-fcc-dirs)))
 107            ;; Old style - no longer works.
 108            (error "Invalid `notmuch-fcc-dirs' setting (old style)"))
 109           ((listp notmuch-fcc-dirs)
 110            (if-let ((match (seq-some (let ((from (message-field-value "From")))
 111                                        (pcase-lambda (`(,regexp . ,folder))
 112                                          (and (string-match-p regexp from)
 113                                               (cons t folder))))
 114                                      notmuch-fcc-dirs)))
 115                (cdr match)
 116              (message "No Fcc header added.")
 117              nil))
 118           (t
 119            (error "Invalid `notmuch-fcc-dirs' setting (neither string nor list)")))))
 120     (when subdir
 121       (if notmuch-maildir-use-notmuch-insert
 122           (notmuch-maildir-add-notmuch-insert-style-fcc-header subdir)
 123         (notmuch-maildir-add-file-style-fcc-header subdir)))))
 124
 125 (defun notmuch-maildir-add-notmuch-insert-style-fcc-header (subdir)
 126   ;; Notmuch insert does not accept absolute paths, so check the user
 127   ;; really want this header inserted.
 128   (when (or (not (= (elt subdir 0) ?/))
 129             (y-or-n-p (format "Fcc header %s is an absolute path %s %s" subdir
 130                               "and notmuch insert is requested."
 131                               "Insert header anyway? ")))
 132     (message-add-header (concat "Fcc: " subdir))))
 133
 134 (defun notmuch-maildir-add-file-style-fcc-header (subdir)
 135   (message-add-header
 136    (concat "Fcc: "
 137            (file-truename
 138             ;; If the resulting directory is not an absolute path,
 139             ;; prepend the standard notmuch database path.
 140             (if (= (elt subdir 0) ?/)
 141                 subdir
 142               (concat (notmuch-database-path) "/" subdir))))))
 143
 144 ;;; Functions for saving a message using either method.
 145
 146 (defmacro with-temporary-notmuch-message-buffer (&rest body)
 147   "Set-up a temporary copy of the current message-mode buffer."
 148   `(let ((case-fold-search t)
 149          (buf (current-buffer))
 150          (mml-externalize-attachments message-fcc-externalize-attachments))
 151      (with-current-buffer (get-buffer-create " *message temp*")
 152        (message-clone-locals buf) ;; for message-encoded-mail-cache
 153        (erase-buffer)
 154        (insert-buffer-substring buf)
 155        ,@body)))
 156
 157 (defun notmuch-maildir-setup-message-for-saving ()
 158   "Setup message for saving.
 159
 160 This should be called on a temporary copy.
 161 This is taken from the function message-do-fcc."
 162   (if (not message-encoded-mail-cache)
 163       (message-encode-message-body)
 164     (erase-buffer)
 165     (insert message-encoded-mail-cache))
 166   (save-restriction
 167     (message-narrow-to-headers)
 168     (mail-encode-encoded-word-buffer))
 169   (goto-char (point-min))
 170   (when (re-search-forward
 171          (concat "^" (regexp-quote mail-header-separator) "$")
 172          nil t)
 173     (replace-match "" t t )))
 174
 175 (defun notmuch-maildir-message-do-fcc ()
 176   "Process Fcc headers in the current buffer.
 177
 178 This is a rearranged version of message mode's message-do-fcc."
 179   (let (files file)
 180     (save-excursion
 181       (save-restriction
 182         (message-narrow-to-headers)
 183         (setq file (message-fetch-field "fcc" t)))
 184       (when file
 185         (with-temporary-notmuch-message-buffer
 186          (notmuch-maildir-setup-message-for-saving)
 187          (save-restriction
 188            (message-narrow-to-headers)
 189            (while (setq file (message-fetch-field "fcc" t))
 190              (push file files)
 191              (message-remove-header "fcc" nil t)))
 192          ;; Process FCC operations.
 193          (mapc #'notmuch-fcc-handler files)
 194          (kill-buffer (current-buffer)))))))
 195
 196 (defun notmuch-fcc-handler (fcc-header)
 197   "Store message with notmuch insert or normal (file) fcc.
 198
 199 If `notmuch-maildir-use-notmuch-insert' is set then store the
 200 message using notmuch insert. Otherwise store the message using
 201 normal fcc."
 202   (message "Doing Fcc...")
 203   (if notmuch-maildir-use-notmuch-insert
 204       (notmuch-maildir-fcc-with-notmuch-insert fcc-header)
 205     (notmuch-maildir-fcc-file-fcc fcc-header))
 206   (message "Doing Fcc...done"))
 207
 208 ;;; Functions for saving a message using notmuch insert.
 209
 210 (defun notmuch-maildir-notmuch-insert-current-buffer (folder &optional create tags)
 211   "Use notmuch insert to put the current buffer in the database.
 212
 213 This inserts the current buffer as a message into the notmuch
 214 database in folder FOLDER. If CREATE is non-nil it will supply
 215 the --create-folder flag to create the folder if necessary. TAGS
 216 should be a list of tag changes to apply to the inserted message."
 217   (apply 'notmuch-call-notmuch-process
 218          :stdin-string (buffer-string) "insert"
 219          (append (and create (list "--create-folder"))
 220                  (list (concat "--folder=" folder))
 221                  tags)))
 222
 223 (defun notmuch-maildir-fcc-with-notmuch-insert (fcc-header &optional create)
 224   "Store message with notmuch insert.
 225
 226 The fcc-header should be of the form \"folder +tag1 -tag2\" where
 227 folder is the folder (relative to the notmuch mailstore) to store
 228 the message in, and tag1 and tag2 are tag changes to apply to the
 229 stored message. This string is split using `split-string-and-unquote',
 230 so a folder name containing spaces can be specified by
 231 quoting each space with an immediately preceding backslash
 232 or surrounding the entire folder name in double quotes.
 233
 234 If CREATE is non-nil then create the folder if necessary."
 235   (pcase-let ((`(,folder . ,tags)
 236                (split-string-and-unquote fcc-header)))
 237     (condition-case nil
 238         (notmuch-maildir-notmuch-insert-current-buffer folder create tags)
 239       ;; Since there are many reasons notmuch insert could fail, e.g.,
 240       ;; locked database, non-existent folder (which could be due to a
 241       ;; typo, or just the user want a new folder, let the user decide
 242       ;; how to deal with it.
 243       (error
 244        (let ((response (read-char-choice "Insert failed: \
 245 \(r)etry, (c)reate folder, (i)gnore, or (e)dit the header? " '(?r ?c ?i ?e))))
 246          (cl-case response
 247            (?r (notmuch-maildir-fcc-with-notmuch-insert fcc-header))
 248            (?c (notmuch-maildir-fcc-with-notmuch-insert fcc-header t))
 249            (?i t)
 250            (?e (notmuch-maildir-fcc-with-notmuch-insert
 251                 (read-from-minibuffer "Fcc header: " fcc-header)))))))))
 252
 253 ;;; Functions for saving a message using file fcc.
 254
 255 (defun notmuch-maildir-fcc-host-fixer (hostname)
 256   (replace-regexp-in-string "/\\|:"
 257                             (lambda (s)
 258                               (cond ((string-equal s "/") "\\057")
 259                                     ((string-equal s ":") "\\072")
 260                                     (t s)))
 261                             hostname
 262                             t
 263                             t))
 264
 265 (defun notmuch-maildir-fcc-make-uniq-maildir-id ()
 266   (let* ((ftime (float-time))
 267          (microseconds (mod (* 1000000 ftime) 1000000))
 268          (hostname (notmuch-maildir-fcc-host-fixer (system-name))))
 269     (cl-incf notmuch-maildir-fcc-count)
 270     (format "%d.%d_%d_%d.%s"
 271             ftime
 272             (emacs-pid)
 273             microseconds
 274             notmuch-maildir-fcc-count
 275             hostname)))
 276
 277 (defun notmuch-maildir-fcc-dir-is-maildir-p (dir)
 278   (and (file-exists-p (concat dir "/cur/"))
 279        (file-exists-p (concat dir "/new/"))
 280        (file-exists-p (concat dir "/tmp/"))))
 281
 282 (defun notmuch-maildir-fcc-create-maildir (path)
 283   (cond ((or (not (file-exists-p path)) (file-directory-p path))
 284          (make-directory (concat path "/cur/") t)
 285          (make-directory (concat path "/new/") t)
 286          (make-directory (concat path "/tmp/") t))
 287         ((file-regular-p path)
 288          (error "%s is a file. Can't create maildir." path))
 289         (t
 290          (error "I don't know how to create a maildir here"))))
 291
 292 (defun notmuch-maildir-fcc-save-buffer-to-tmp (destdir)
 293   "Returns the msg id of the message written to the temp directory
 294 if successful, nil if not."
 295   (let ((msg-id (notmuch-maildir-fcc-make-uniq-maildir-id)))
 296     (while (file-exists-p (concat destdir "/tmp/" msg-id))
 297       (setq msg-id (notmuch-maildir-fcc-make-uniq-maildir-id)))
 298     (cond ((notmuch-maildir-fcc-dir-is-maildir-p destdir)
 299            (write-file (concat destdir "/tmp/" msg-id))
 300            msg-id)
 301           (t
 302            (error "Can't write to %s. Not a maildir." destdir)))))
 303
 304 (defun notmuch-maildir-fcc-move-tmp-to-new (destdir msg-id)
 305   (add-name-to-file
 306    (concat destdir "/tmp/" msg-id)
 307    (concat destdir "/new/" msg-id ":2,")))
 308
 309 (defun notmuch-maildir-fcc-move-tmp-to-cur (destdir msg-id &optional mark-seen)
 310   (add-name-to-file
 311    (concat destdir "/tmp/" msg-id)
 312    (concat destdir "/cur/" msg-id ":2," (and mark-seen "S"))))
 313
 314 (defun notmuch-maildir-fcc-file-fcc (fcc-header)
 315   "Write the message to the file specified by FCC-HEADER.
 316
 317 If that fails, then offer the user a chance to correct the header
 318 or filesystem."
 319   (if (notmuch-maildir-fcc-dir-is-maildir-p fcc-header)
 320       (notmuch-maildir-fcc-write-buffer-to-maildir fcc-header t)
 321     ;; The fcc-header is not a valid maildir see if the user wants to
 322     ;; fix it in some way.
 323     (let* ((prompt (format "Fcc %s is not a maildir: \
 324 \(r)etry, (c)reate folder, (i)gnore, or (e)dit the header? " fcc-header))
 325            (response (read-char-choice prompt '(?r ?c ?i ?e))))
 326       (cl-case response
 327         (?r (notmuch-maildir-fcc-file-fcc fcc-header))
 328         (?c (if (file-writable-p fcc-header)
 329                 (notmuch-maildir-fcc-create-maildir fcc-header)
 330               (message "No permission to create %s." fcc-header)
 331               (sit-for 2))
 332             (notmuch-maildir-fcc-file-fcc fcc-header))
 333         (?i t)
 334         (?e (notmuch-maildir-fcc-file-fcc
 335              (read-from-minibuffer "Fcc header: " fcc-header)))))))
 336
 337 (defun notmuch-maildir-fcc-write-buffer-to-maildir (destdir &optional mark-seen)
 338   "Write the current buffer to maildir destdir.
 339
 340 If mark-seen is non-nil, then write it to \"cur/\", and mark it
 341 as read, otherwise write it to \"new/\". Return t if successful,
 342 and nil otherwise."
 343   (let ((orig-buffer (buffer-name)))
 344     (with-temp-buffer
 345       (insert-buffer-substring orig-buffer)
 346       (catch 'link-error
 347         (let ((msg-id (notmuch-maildir-fcc-save-buffer-to-tmp destdir)))
 348           (when msg-id
 349             (condition-case nil
 350                 (if mark-seen
 351                     (notmuch-maildir-fcc-move-tmp-to-cur destdir msg-id t)
 352                   (notmuch-maildir-fcc-move-tmp-to-new destdir msg-id))
 353               (file-already-exists
 354                (throw 'link-error nil))))
 355           (delete-file (concat destdir "/tmp/" msg-id))))
 356       t)))
 357
 358 ;;; _
 359
 360 (provide 'notmuch-maildir-fcc)
 361
 362 ;;; notmuch-maildir-fcc.el ends here