git.cworth.org Git - obsolete/notmuch-old/blob - emacs/notmuch-show.el

   1 ;; notmuch-show.el --- displaying notmuch forests.
   2 ;;
   3 ;; Copyright © Carl Worth
   4 ;; Copyright © David Edmondson
   5 ;;
   6 ;; This file is part of Notmuch.
   7 ;;
   8 ;; Notmuch is free software: you can redistribute it and/or modify it
   9 ;; under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12 ;;
  13 ;; Notmuch is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17 ;;
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Notmuch.  If not, see <http://www.gnu.org/licenses/>.
  20 ;;
  21 ;; Authors: Carl Worth <cworth@cworth.org>
  22 ;;          David Edmondson <dme@dme.org>
  23
  24 (eval-when-compile (require 'cl))
  25 (require 'mm-view)
  26 (require 'message)
  27 (require 'mm-decode)
  28 (require 'mailcap)
  29 (require 'icalendar)
  30 (require 'goto-addr)
  31
  32 (require 'notmuch-lib)
  33 (require 'notmuch-tag)
  34 (require 'notmuch-query)
  35 (require 'notmuch-wash)
  36 (require 'notmuch-mua)
  37 (require 'notmuch-crypto)
  38 (require 'notmuch-print)
  39
  40 (declare-function notmuch-call-notmuch-process "notmuch" (&rest args))
  41 (declare-function notmuch-search-next-thread "notmuch" nil)
  42 (declare-function notmuch-search-previous-thread "notmuch" nil)
  43 (declare-function notmuch-search-show-thread "notmuch" nil)
  44
  45 (defcustom notmuch-message-headers '("Subject" "To" "Cc" "Date")
  46   "Headers that should be shown in a message, in this order.
  47
  48 For an open message, all of these headers will be made visible
  49 according to `notmuch-message-headers-visible' or can be toggled
  50 with `notmuch-show-toggle-visibility-headers'. For a closed message,
  51 only the first header in the list will be visible."
  52   :type '(repeat string)
  53   :group 'notmuch-show)
  54
  55 (defcustom notmuch-message-headers-visible t
  56   "Should the headers be visible by default?
  57
  58 If this value is non-nil, then all of the headers defined in
  59 `notmuch-message-headers' will be visible by default in the display
  60 of each message. Otherwise, these headers will be hidden and
  61 `notmuch-show-toggle-visibility-headers' can be used to make them
  62 visible for any given message."
  63   :type 'boolean
  64   :group 'notmuch-show)
  65
  66 (defcustom notmuch-show-relative-dates t
  67   "Display relative dates in the message summary line."
  68   :type 'boolean
  69   :group 'notmuch-show)
  70
  71 (defvar notmuch-show-markup-headers-hook '(notmuch-show-colour-headers)
  72   "A list of functions called to decorate the headers listed in
  73 `notmuch-message-headers'.")
  74
  75 (defcustom notmuch-show-hook '(notmuch-show-turn-on-visual-line-mode)
  76   "Functions called after populating a `notmuch-show' buffer."
  77   :type 'hook
  78   :options '(notmuch-show-turn-on-visual-line-mode)
  79   :group 'notmuch-show
  80   :group 'notmuch-hooks)
  81
  82 (defcustom notmuch-show-insert-text/plain-hook '(notmuch-wash-wrap-long-lines
  83                                                  notmuch-wash-tidy-citations
  84                                                  notmuch-wash-elide-blank-lines
  85                                                  notmuch-wash-excerpt-citations)
  86   "Functions used to improve the display of text/plain parts."
  87   :type 'hook
  88   :options '(notmuch-wash-convert-inline-patch-to-part
  89              notmuch-wash-wrap-long-lines
  90              notmuch-wash-tidy-citations
  91              notmuch-wash-elide-blank-lines
  92              notmuch-wash-excerpt-citations)
  93   :group 'notmuch-show
  94   :group 'notmuch-hooks)
  95
  96 ;; Mostly useful for debugging.
  97 (defcustom notmuch-show-all-multipart/alternative-parts nil
  98   "Should all parts of multipart/alternative parts be shown?"
  99   :type 'boolean
 100   :group 'notmuch-show)
 101
 102 (defcustom notmuch-show-indent-messages-width 1
 103   "Width of message indentation in threads.
 104
 105 Messages are shown indented according to their depth in a thread.
 106 This variable determines the width of this indentation measured
 107 in number of blanks.  Defaults to `1', choose `0' to disable
 108 indentation."
 109   :type 'integer
 110   :group 'notmuch-show)
 111
 112 (defcustom notmuch-show-indent-multipart nil
 113   "Should the sub-parts of a multipart/* part be indented?"
 114   ;; dme: Not sure which is a good default.
 115   :type 'boolean
 116   :group 'notmuch-show)
 117
 118 (defcustom notmuch-show-part-button-default-action 'notmuch-show-save-part
 119   "Default part header button action (on ENTER or mouse click)."
 120   :group 'notmuch-show
 121   :type '(choice (const :tag "Save part"
 122                         notmuch-show-save-part)
 123                  (const :tag "View part"
 124                         notmuch-show-view-part)
 125                  (const :tag "View interactively"
 126                         notmuch-show-interactively-view-part)))
 127
 128 (defcustom notmuch-show-only-matching-messages nil
 129   "Only matching messages are shown by default."
 130   :type 'boolean
 131   :group 'notmuch-show)
 132
 133 (defvar notmuch-show-thread-id nil)
 134 (make-variable-buffer-local 'notmuch-show-thread-id)
 135 (put 'notmuch-show-thread-id 'permanent-local t)
 136
 137 (defvar notmuch-show-parent-buffer nil)
 138 (make-variable-buffer-local 'notmuch-show-parent-buffer)
 139 (put 'notmuch-show-parent-buffer 'permanent-local t)
 140
 141 (defvar notmuch-show-query-context nil)
 142 (make-variable-buffer-local 'notmuch-show-query-context)
 143 (put 'notmuch-show-query-context 'permanent-local t)
 144
 145 (defvar notmuch-show-process-crypto nil)
 146 (make-variable-buffer-local 'notmuch-show-process-crypto)
 147 (put 'notmuch-show-process-crypto 'permanent-local t)
 148
 149 (defvar notmuch-show-elide-non-matching-messages nil)
 150 (make-variable-buffer-local 'notmuch-show-elide-non-matching-messages)
 151 (put 'notmuch-show-elide-non-matching-messages 'permanent-local t)
 152
 153 (defvar notmuch-show-indent-content t)
 154 (make-variable-buffer-local 'notmuch-show-indent-content)
 155 (put 'notmuch-show-indent-content 'permanent-local t)
 156
 157 (defcustom notmuch-show-stash-mlarchive-link-alist
 158   '(("Gmane" . "http://mid.gmane.org/")
 159     ("MARC" . "http://marc.info/?i=")
 160     ("Mail Archive, The" . "http://mail-archive.com/search?l=mid&q=")
 161     ("LKML" . "http://lkml.kernel.org/r/")
 162     ;; FIXME: can these services be searched by `Message-Id' ?
 163     ;; ("MarkMail" . "http://markmail.org/")
 164     ;; ("Nabble" . "http://nabble.com/")
 165     ;; ("opensubscriber" . "http://opensubscriber.com/")
 166     )
 167   "List of Mailing List Archives to use when stashing links.
 168
 169 These URIs are concatenated with the current message's
 170 Message-Id in `notmuch-show-stash-mlarchive-link'."
 171   :type '(alist :key-type (string :tag "Name")
 172                 :value-type (string :tag "URL"))
 173   :group 'notmuch-show)
 174
 175 (defcustom notmuch-show-stash-mlarchive-link-default "Gmane"
 176   "Default Mailing List Archive to use when stashing links.
 177
 178 This is used when `notmuch-show-stash-mlarchive-link' isn't
 179 provided with an MLA argument nor `completing-read' input."
 180   :type `(choice
 181           ,@(mapcar
 182              (lambda (mla)
 183                (list 'const :tag (car mla) :value (car mla)))
 184              notmuch-show-stash-mlarchive-link-alist))
 185   :group 'notmuch-show)
 186
 187 (defcustom notmuch-show-mark-read-tags '("-unread")
 188   "List of tag changes to apply to a message when it is marked as read.
 189
 190 Tags starting with \"+\" (or not starting with either \"+\" or
 191 \"-\") in the list will be added, and tags starting with \"-\"
 192 will be removed from the message being marked as read.
 193
 194 For example, if you wanted to remove an \"unread\" tag and add a
 195 \"read\" tag (which would make little sense), you would set:
 196     (\"-unread\" \"+read\")"
 197   :type '(repeat string)
 198   :group 'notmuch-show)
 199
 200
 201 (defmacro with-current-notmuch-show-message (&rest body)
 202   "Evaluate body with current buffer set to the text of current message"
 203   `(save-excursion
 204      (let ((id (notmuch-show-get-message-id)))
 205        (let ((buf (generate-new-buffer (concat "*notmuch-msg-" id "*"))))
 206          (with-current-buffer buf
 207            (let ((coding-system-for-read 'no-conversion))
 208              (call-process notmuch-command nil t nil "show" "--format=raw" id)
 209              ,@body)
 210            (kill-buffer buf))))))
 211
 212 (defun notmuch-show-turn-on-visual-line-mode ()
 213   "Enable Visual Line mode."
 214   (visual-line-mode t))
 215
 216 (defun notmuch-show-view-all-mime-parts ()
 217   "Use external viewers to view all attachments from the current message."
 218   (interactive)
 219   (with-current-notmuch-show-message
 220    ;; We override the mm-inline-media-tests to indicate which message
 221    ;; parts are already sufficiently handled by the original
 222    ;; presentation of the message in notmuch-show mode. These parts
 223    ;; will be inserted directly into the temporary buffer of
 224    ;; with-current-notmuch-show-message and silently discarded.
 225    ;;
 226    ;; Any MIME part not explicitly mentioned here will be handled by an
 227    ;; external viewer as configured in the various mailcap files.
 228    (let ((mm-inline-media-tests '(
 229                                   ("text/.*" ignore identity)
 230                                   ("application/pgp-signature" ignore identity)
 231                                   ("multipart/alternative" ignore identity)
 232                                   ("multipart/mixed" ignore identity)
 233                                   ("multipart/related" ignore identity)
 234                                  )))
 235      (mm-display-parts (mm-dissect-buffer)))))
 236
 237 (defun notmuch-foreach-mime-part (function mm-handle)
 238   (cond ((stringp (car mm-handle))
 239          (dolist (part (cdr mm-handle))
 240            (notmuch-foreach-mime-part function part)))
 241         ((bufferp (car mm-handle))
 242          (funcall function mm-handle))
 243         (t (dolist (part mm-handle)
 244              (notmuch-foreach-mime-part function part)))))
 245
 246 (defun notmuch-count-attachments (mm-handle)
 247   (let ((count 0))
 248     (notmuch-foreach-mime-part
 249      (lambda (p)
 250        (let ((disposition (mm-handle-disposition p)))
 251          (and (listp disposition)
 252               (or (equal (car disposition) "attachment")
 253                   (and (equal (car disposition) "inline")
 254                        (assq 'filename disposition)))
 255               (incf count))))
 256      mm-handle)
 257     count))
 258
 259 (defun notmuch-save-attachments (mm-handle &optional queryp)
 260   (notmuch-foreach-mime-part
 261    (lambda (p)
 262      (let ((disposition (mm-handle-disposition p)))
 263        (and (listp disposition)
 264             (or (equal (car disposition) "attachment")
 265                 (and (equal (car disposition) "inline")
 266                      (assq 'filename disposition)))
 267             (or (not queryp)
 268                 (y-or-n-p
 269                  (concat "Save '" (cdr (assq 'filename disposition)) "' ")))
 270             (mm-save-part p))))
 271    mm-handle))
 272
 273 (defun notmuch-show-save-attachments ()
 274   "Save all attachments from the current message."
 275   (interactive)
 276   (with-current-notmuch-show-message
 277    (let ((mm-handle (mm-dissect-buffer)))
 278      (notmuch-save-attachments
 279       mm-handle (> (notmuch-count-attachments mm-handle) 1))))
 280   (message "Done"))
 281
 282 (defun notmuch-show-with-message-as-text (fn)
 283   "Apply FN to a text representation of the current message.
 284
 285 FN is called with one argument, the message properties. It should
 286 operation on the contents of the current buffer."
 287
 288   ;; Remake the header to ensure that all information is available.
 289   (let* ((to (notmuch-show-get-to))
 290          (cc (notmuch-show-get-cc))
 291          (from (notmuch-show-get-from))
 292          (subject (notmuch-show-get-subject))
 293          (date (notmuch-show-get-date))
 294          (tags (notmuch-show-get-tags))
 295          (depth (notmuch-show-get-depth))
 296
 297          (header (concat
 298                   "Subject: " subject "\n"
 299                   "To: " to "\n"
 300                   (if (not (string= cc ""))
 301                       (concat "Cc: " cc "\n")
 302                     "")
 303                   "From: " from "\n"
 304                   "Date: " date "\n"
 305                   (if tags
 306                       (concat "Tags: "
 307                               (mapconcat #'identity tags ", ") "\n")
 308                     "")))
 309          (all (buffer-substring (notmuch-show-message-top)
 310                                 (notmuch-show-message-bottom)))
 311
 312          (props (notmuch-show-get-message-properties))
 313          (indenting notmuch-show-indent-content))
 314     (with-temp-buffer
 315       (insert all)
 316       (if indenting
 317           (indent-rigidly (point-min) (point-max) (- depth)))
 318       ;; Remove the original header.
 319       (goto-char (point-min))
 320       (re-search-forward "^$" (point-max) nil)
 321       (delete-region (point-min) (point))
 322       (insert header)
 323       (funcall fn props))))
 324
 325 (defun notmuch-show-print-message ()
 326   "Print the current message."
 327   (interactive)
 328   (notmuch-show-with-message-as-text 'notmuch-print-message))
 329
 330 (defun notmuch-show-fontify-header ()
 331   (let ((face (cond
 332                ((looking-at "[Tt]o:")
 333                 'message-header-to)
 334                ((looking-at "[Bb]?[Cc][Cc]:")
 335                 'message-header-cc)
 336                ((looking-at "[Ss]ubject:")
 337                 'message-header-subject)
 338                ((looking-at "[Ff]rom:")
 339                 'message-header-from)
 340                (t
 341                 'message-header-other))))
 342
 343     (overlay-put (make-overlay (point) (re-search-forward ":"))
 344                  'face 'message-header-name)
 345     (overlay-put (make-overlay (point) (re-search-forward ".*$"))
 346                  'face face)))
 347
 348 (defun notmuch-show-colour-headers ()
 349   "Apply some colouring to the current headers."
 350   (goto-char (point-min))
 351   (while (looking-at "^[A-Za-z][-A-Za-z0-9]*:")
 352     (notmuch-show-fontify-header)
 353     (forward-line)))
 354
 355 (defun notmuch-show-spaces-n (n)
 356   "Return a string comprised of `n' spaces."
 357   (make-string n ? ))
 358
 359 (defun notmuch-show-update-tags (tags)
 360   "Update the displayed tags of the current message."
 361   (save-excursion
 362     (goto-char (notmuch-show-message-top))
 363     (if (re-search-forward "(\\([^()]*\\))$" (line-end-position) t)
 364         (let ((inhibit-read-only t))
 365           (replace-match (concat "("
 366                                  (notmuch-tag-format-tags tags)
 367                                  ")"))))))
 368
 369 (defun notmuch-clean-address (address)
 370   "Try to clean a single email ADDRESS for display. Return a cons
 371 cell of (AUTHOR_EMAIL AUTHOR_NAME). Return (ADDRESS nil) if
 372 parsing fails."
 373   (condition-case nil
 374     (let (p-name p-address)
 375       ;; It would be convenient to use `mail-header-parse-address',
 376       ;; but that expects un-decoded mailbox parts, whereas our
 377       ;; mailbox parts are already decoded (and hence may contain
 378       ;; UTF-8). Given that notmuch should handle most of the awkward
 379       ;; cases, some simple string deconstruction should be sufficient
 380       ;; here.
 381       (cond
 382        ;; "User <user@dom.ain>" style.
 383        ((string-match "\\(.*\\) <\\(.*\\)>" address)
 384         (setq p-name (match-string 1 address)
 385               p-address (match-string 2 address)))
 386
 387        ;; "<user@dom.ain>" style.
 388        ((string-match "<\\(.*\\)>" address)
 389         (setq p-address (match-string 1 address)))
 390
 391        ;; Everything else.
 392        (t
 393         (setq p-address address)))
 394
 395       (when p-name
 396         ;; Remove elements of the mailbox part that are not relevant for
 397         ;; display, even if they are required during transport:
 398         ;;
 399         ;; Backslashes.
 400         (setq p-name (replace-regexp-in-string "\\\\" "" p-name))
 401
 402         ;; Outer single and double quotes, which might be nested.
 403         (loop
 404          with start-of-loop
 405          do (setq start-of-loop p-name)
 406
 407          when (string-match "^\"\\(.*\\)\"$" p-name)
 408          do (setq p-name (match-string 1 p-name))
 409
 410          when (string-match "^'\\(.*\\)'$" p-name)
 411          do (setq p-name (match-string 1 p-name))
 412
 413          until (string= start-of-loop p-name)))
 414
 415       ;; If the address is 'foo@bar.com <foo@bar.com>' then show just
 416       ;; 'foo@bar.com'.
 417       (when (string= p-name p-address)
 418         (setq p-name nil))
 419
 420       (cons p-address p-name))
 421     (error (cons address nil))))
 422
 423 (defun notmuch-show-clean-address (address)
 424   "Try to clean a single email ADDRESS for display.  Return
 425 unchanged ADDRESS if parsing fails."
 426   (let* ((clean-address (notmuch-clean-address address))
 427          (p-address (car clean-address))
 428          (p-name (cdr clean-address)))
 429     ;; If no name, return just the address.
 430     (if (not p-name)
 431         p-address
 432       ;; Otherwise format the name and address together.
 433       (concat p-name " <" p-address ">"))))
 434
 435 (defun notmuch-show-insert-headerline (headers date tags depth)
 436   "Insert a notmuch style headerline based on HEADERS for a
 437 message at DEPTH in the current thread."
 438   (let ((start (point)))
 439     (insert (notmuch-show-spaces-n (* notmuch-show-indent-messages-width depth))
 440             (notmuch-show-clean-address (plist-get headers :From))
 441             " ("
 442             date
 443             ") ("
 444             (notmuch-tag-format-tags tags)
 445             ")\n")
 446     (overlay-put (make-overlay start (point)) 'face 'notmuch-message-summary-face)))
 447
 448 (defun notmuch-show-insert-header (header header-value)
 449   "Insert a single header."
 450   (insert header ": " header-value "\n"))
 451
 452 (defun notmuch-show-insert-headers (headers)
 453   "Insert the headers of the current message."
 454   (let ((start (point)))
 455     (mapc (lambda (header)
 456             (let* ((header-symbol (intern (concat ":" header)))
 457                    (header-value (plist-get headers header-symbol)))
 458               (if (and header-value
 459                        (not (string-equal "" header-value)))
 460                   (notmuch-show-insert-header header header-value))))
 461           notmuch-message-headers)
 462     (save-excursion
 463       (save-restriction
 464         (narrow-to-region start (point-max))
 465         (run-hooks 'notmuch-show-markup-headers-hook)))))
 466
 467 (define-button-type 'notmuch-show-part-button-type
 468   'action 'notmuch-show-part-button-default
 469   'keymap 'notmuch-show-part-button-map
 470   'follow-link t
 471   'face 'message-mml
 472   :supertype 'notmuch-button-type)
 473
 474 (defvar notmuch-show-part-button-map
 475   (let ((map (make-sparse-keymap)))
 476     (set-keymap-parent map button-map)
 477     (define-key map "s" 'notmuch-show-part-button-save)
 478     (define-key map "v" 'notmuch-show-part-button-view)
 479     (define-key map "o" 'notmuch-show-part-button-interactively-view)
 480     (define-key map "|" 'notmuch-show-part-button-pipe)
 481     map)
 482   "Submap for button commands")
 483 (fset 'notmuch-show-part-button-map notmuch-show-part-button-map)
 484
 485 (defun notmuch-show-insert-part-header (nth content-type declared-type &optional name comment)
 486   (let ((button)
 487         (base-label (concat (when name (concat name ": "))
 488                             declared-type
 489                             (unless (string-equal declared-type content-type)
 490                               (concat " (as " content-type ")"))
 491                             comment)))
 492
 493     (setq button
 494           (insert-button
 495            (concat "[ " base-label " ]")
 496            :base-label base-label
 497            :type 'notmuch-show-part-button-type
 498            :notmuch-part nth
 499            :notmuch-filename name
 500            :notmuch-content-type content-type))
 501     (insert "\n")
 502     ;; return button
 503     button))
 504
 505 ;; Functions handling particular MIME parts.
 506
 507 (defmacro notmuch-with-temp-part-buffer (message-id nth &rest body)
 508   (declare (indent 2))
 509   (let ((process-crypto (make-symbol "process-crypto")))
 510     `(let ((,process-crypto notmuch-show-process-crypto))
 511        (with-temp-buffer
 512          (setq notmuch-show-process-crypto ,process-crypto)
 513          ;; Always acquires the part via `notmuch part', even if it is
 514          ;; available in the JSON output.
 515          (insert (notmuch-get-bodypart-internal ,message-id ,nth notmuch-show-process-crypto))
 516          ,@body))))
 517
 518 (defun notmuch-show-save-part (message-id nth &optional filename content-type)
 519   (notmuch-with-temp-part-buffer message-id nth
 520     (let ((file (read-file-name
 521                  "Filename to save as: "
 522                  (or mailcap-download-directory "~/")
 523                  nil nil
 524                  filename)))
 525       ;; Don't re-compress .gz & al.  Arguably we should make
 526       ;; `file-name-handler-alist' nil, but that would chop
 527       ;; ange-ftp, which is reasonable to use here.
 528       (mm-write-region (point-min) (point-max) file nil nil nil 'no-conversion t))))
 529
 530 (defun notmuch-show-view-part (message-id nth &optional filename content-type )
 531   (notmuch-with-temp-part-buffer message-id nth
 532     (let* ((disposition (if filename `(attachment (filename . ,filename))))
 533            (handle (mm-make-handle (current-buffer) (list content-type)
 534                                    nil nil disposition))
 535            ;; Set the default save directory to be consistent with
 536            ;; `notmuch-show-save-part'.
 537            (mm-default-directory (or mailcap-download-directory "~/"))
 538            ;; set mm-inlined-types to nil to force an external viewer
 539            (mm-inlined-types nil))
 540       (mm-display-part handle))))
 541
 542 (defun notmuch-show-interactively-view-part (message-id nth &optional filename content-type)
 543   (notmuch-with-temp-part-buffer message-id nth
 544     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 545       (mm-interactively-view-part handle))))
 546
 547 (defun notmuch-show-pipe-part (message-id nth &optional filename content-type)
 548   (notmuch-with-temp-part-buffer message-id nth
 549     (let ((handle (mm-make-handle (current-buffer) (list content-type))))
 550       (mm-pipe-part handle))))
 551
 552 ;; This is taken from notmuch-wash: maybe it should be unified?
 553 (defun notmuch-show-toggle-part-invisibility (&optional button)
 554   (interactive)
 555   (let* ((button (or button (button-at (point))))
 556          (overlay (button-get button 'overlay)))
 557     (when overlay
 558       (let* ((show (overlay-get overlay 'invisible))
 559              (new-start (button-start button))
 560              (button-label (button-get button :base-label))
 561              (old-point (point))
 562              (inhibit-read-only t))
 563         (overlay-put overlay 'invisible (not show))
 564         (goto-char new-start)
 565         (insert "[ " button-label (if show " ]" " (hidden) ]"))
 566         (let ((old-end (button-end button)))
 567           (move-overlay button new-start (point))
 568           (delete-region (point) old-end))
 569         (goto-char (min old-point (1- (button-end button))))))))
 570
 571 (defun notmuch-show-multipart/*-to-list (part)
 572   (mapcar (lambda (inner-part) (plist-get inner-part :content-type))
 573           (plist-get part :content)))
 574
 575 (defun notmuch-show-insert-part-multipart/alternative (msg part content-type nth depth declared-type)
 576   (notmuch-show-insert-part-header nth declared-type content-type nil)
 577   (let ((chosen-type (car (notmuch-multipart/alternative-choose (notmuch-show-multipart/*-to-list part))))
 578         (inner-parts (plist-get part :content))
 579         (start (point)))
 580     ;; This inserts all parts of the chosen type rather than just one,
 581     ;; but it's not clear that this is the wrong thing to do - which
 582     ;; should be chosen if there are more than one that match?
 583     (mapc (lambda (inner-part)
 584             (let* ((inner-type (plist-get inner-part :content-type))
 585                   (hide (not (or notmuch-show-all-multipart/alternative-parts
 586                            (string= chosen-type inner-type)))))
 587               (notmuch-show-insert-bodypart msg inner-part depth hide)))
 588           inner-parts)
 589
 590     (when notmuch-show-indent-multipart
 591       (indent-rigidly start (point) 1)))
 592   t)
 593
 594 (defun notmuch-show-setup-w3m ()
 595   "Instruct w3m how to retrieve content from a \"related\" part of a message."
 596   (interactive)
 597   (if (boundp 'w3m-cid-retrieve-function-alist)
 598     (unless (assq 'notmuch-show-mode w3m-cid-retrieve-function-alist)
 599       (push (cons 'notmuch-show-mode 'notmuch-show-w3m-cid-retrieve)
 600             w3m-cid-retrieve-function-alist)))
 601   (setq mm-inline-text-html-with-images t))
 602
 603 (defvar w3m-current-buffer) ;; From `w3m.el'.
 604 (defvar notmuch-show-w3m-cid-store nil)
 605 (make-variable-buffer-local 'notmuch-show-w3m-cid-store)
 606
 607 (defun notmuch-show-w3m-cid-store-internal (content-id
 608                                             message-id
 609                                             part-number
 610                                             content-type
 611                                             content)
 612   (push (list content-id
 613               message-id
 614               part-number
 615               content-type
 616               content)
 617         notmuch-show-w3m-cid-store))
 618
 619 (defun notmuch-show-w3m-cid-store (msg part)
 620   (let ((content-id (plist-get part :content-id)))
 621     (when content-id
 622       (notmuch-show-w3m-cid-store-internal (concat "cid:" content-id)
 623                                            (plist-get msg :id)
 624                                            (plist-get part :id)
 625                                            (plist-get part :content-type)
 626                                            nil))))
 627
 628 (defun notmuch-show-w3m-cid-retrieve (url &rest args)
 629   (let ((matching-part (with-current-buffer w3m-current-buffer
 630                          (assoc url notmuch-show-w3m-cid-store))))
 631     (if matching-part
 632         (let ((message-id (nth 1 matching-part))
 633               (part-number (nth 2 matching-part))
 634               (content-type (nth 3 matching-part))
 635               (content (nth 4 matching-part)))
 636           ;; If we don't already have the content, get it and cache
 637           ;; it, as some messages reference the same cid: part many
 638           ;; times (hundreds!), which results in many calls to
 639           ;; `notmuch part'.
 640           (unless content
 641             (setq content (notmuch-get-bodypart-internal (notmuch-id-to-query message-id)
 642                                                               part-number notmuch-show-process-crypto))
 643             (with-current-buffer w3m-current-buffer
 644               (notmuch-show-w3m-cid-store-internal url
 645                                                    message-id
 646                                                    part-number
 647                                                    content-type
 648                                                    content)))
 649           (insert content)
 650           content-type)
 651       nil)))
 652
 653 (defun notmuch-show-insert-part-multipart/related (msg part content-type nth depth declared-type)
 654   (notmuch-show-insert-part-header nth declared-type content-type nil)
 655   (let ((inner-parts (plist-get part :content))
 656         (start (point)))
 657
 658     ;; We assume that the first part is text/html and the remainder
 659     ;; things that it references.
 660
 661     ;; Stash the non-primary parts.
 662     (mapc (lambda (part)
 663             (notmuch-show-w3m-cid-store msg part))
 664           (cdr inner-parts))
 665
 666     ;; Render the primary part.
 667     (notmuch-show-insert-bodypart msg (car inner-parts) depth)
 668
 669     (when notmuch-show-indent-multipart
 670       (indent-rigidly start (point) 1)))
 671   t)
 672
 673 (defun notmuch-show-insert-part-multipart/signed (msg part content-type nth depth declared-type)
 674   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 675     (button-put button 'face 'notmuch-crypto-part-header)
 676     ;; add signature status button if sigstatus provided
 677     (if (plist-member part :sigstatus)
 678         (let* ((from (notmuch-show-get-header :From msg))
 679                (sigstatus (car (plist-get part :sigstatus))))
 680           (notmuch-crypto-insert-sigstatus-button sigstatus from))
 681       ;; if we're not adding sigstatus, tell the user how they can get it
 682       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 683
 684   (let ((inner-parts (plist-get part :content))
 685         (start (point)))
 686     ;; Show all of the parts.
 687     (mapc (lambda (inner-part)
 688             (notmuch-show-insert-bodypart msg inner-part depth))
 689           inner-parts)
 690
 691     (when notmuch-show-indent-multipart
 692       (indent-rigidly start (point) 1)))
 693   t)
 694
 695 (defun notmuch-show-insert-part-multipart/encrypted (msg part content-type nth depth declared-type)
 696   (let ((button (notmuch-show-insert-part-header nth declared-type content-type nil)))
 697     (button-put button 'face 'notmuch-crypto-part-header)
 698     ;; add encryption status button if encstatus specified
 699     (if (plist-member part :encstatus)
 700         (let ((encstatus (car (plist-get part :encstatus))))
 701           (notmuch-crypto-insert-encstatus-button encstatus)
 702           ;; add signature status button if sigstatus specified
 703           (if (plist-member part :sigstatus)
 704               (let* ((from (notmuch-show-get-header :From msg))
 705                      (sigstatus (car (plist-get part :sigstatus))))
 706                 (notmuch-crypto-insert-sigstatus-button sigstatus from))))
 707       ;; if we're not adding encstatus, tell the user how they can get it
 708       (button-put button 'help-echo "Set notmuch-crypto-process-mime to process cryptographic MIME parts.")))
 709
 710   (let ((inner-parts (plist-get part :content))
 711         (start (point)))
 712     ;; Show all of the parts.
 713     (mapc (lambda (inner-part)
 714             (notmuch-show-insert-bodypart msg inner-part depth))
 715           inner-parts)
 716
 717     (when notmuch-show-indent-multipart
 718       (indent-rigidly start (point) 1)))
 719   t)
 720
 721 (defun notmuch-show-insert-part-multipart/* (msg part content-type nth depth declared-type)
 722   (notmuch-show-insert-part-header nth declared-type content-type nil)
 723   (let ((inner-parts (plist-get part :content))
 724         (start (point)))
 725     ;; Show all of the parts.
 726     (mapc (lambda (inner-part)
 727             (notmuch-show-insert-bodypart msg inner-part depth))
 728           inner-parts)
 729
 730     (when notmuch-show-indent-multipart
 731       (indent-rigidly start (point) 1)))
 732   t)
 733
 734 (defun notmuch-show-insert-part-message/rfc822 (msg part content-type nth depth declared-type)
 735   (notmuch-show-insert-part-header nth declared-type content-type nil)
 736   (let* ((message (car (plist-get part :content)))
 737          (body (car (plist-get message :body)))
 738          (start (point)))
 739
 740     ;; Override `notmuch-message-headers' to force `From' to be
 741     ;; displayed.
 742     (let ((notmuch-message-headers '("From" "Subject" "To" "Cc" "Date")))
 743       (notmuch-show-insert-headers (plist-get message :headers)))
 744
 745     ;; Blank line after headers to be compatible with the normal
 746     ;; message display.
 747     (insert "\n")
 748
 749     ;; Show the body
 750     (notmuch-show-insert-bodypart msg body depth)
 751
 752     (when notmuch-show-indent-multipart
 753       (indent-rigidly start (point) 1)))
 754   t)
 755
 756 (defun notmuch-show-insert-part-text/plain (msg part content-type nth depth declared-type)
 757   (let ((start (point)))
 758     ;; If this text/plain part is not the first part in the message,
 759     ;; insert a header to make this clear.
 760     (if (> nth 1)
 761         (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename)))
 762     (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 763     (save-excursion
 764       (save-restriction
 765         (narrow-to-region start (point-max))
 766         (run-hook-with-args 'notmuch-show-insert-text/plain-hook msg depth))))
 767   t)
 768
 769 (defun notmuch-show-insert-part-text/calendar (msg part content-type nth depth declared-type)
 770   (notmuch-show-insert-part-header nth declared-type content-type (plist-get part :filename))
 771   (insert (with-temp-buffer
 772             (insert (notmuch-get-bodypart-content msg part nth notmuch-show-process-crypto))
 773             ;; notmuch-get-bodypart-content provides "raw", non-converted
 774             ;; data. Replace CRLF with LF before icalendar can use it.
 775             (goto-char (point-min))
 776             (while (re-search-forward "\r\n" nil t)
 777               (replace-match "\n" nil nil))
 778             (let ((file (make-temp-file "notmuch-ical"))
 779                   result)
 780               (unwind-protect
 781                   (progn
 782                     (unless (icalendar-import-buffer file t)
 783                       (error "Icalendar import error. See *icalendar-errors* for more information"))
 784                     (set-buffer (get-file-buffer file))
 785                     (setq result (buffer-substring (point-min) (point-max)))
 786                     (set-buffer-modified-p nil)
 787                     (kill-buffer (current-buffer)))
 788                 (delete-file file))
 789               result)))
 790   t)
 791
 792 ;; For backwards compatibility.
 793 (defun notmuch-show-insert-part-text/x-vcalendar (msg part content-type nth depth declared-type)
 794   (notmuch-show-insert-part-text/calendar msg part content-type nth depth declared-type))
 795
 796 (defun notmuch-show-get-mime-type-of-application/octet-stream (part)
 797   ;; If we can deduce a MIME type from the filename of the attachment,
 798   ;; we return that.
 799   (if (plist-get part :filename)
 800       (let ((extension (file-name-extension (plist-get part :filename)))
 801             mime-type)
 802         (if extension
 803             (progn
 804               (mailcap-parse-mimetypes)
 805               (setq mime-type (mailcap-extension-to-mime extension))
 806               (if (and mime-type
 807                        (not (string-equal mime-type "application/octet-stream")))
 808                   mime-type
 809                 nil))
 810           nil))))
 811
 812 ;; Handler for wash generated inline patch fake parts.
 813 (defun notmuch-show-insert-part-inline-patch-fake-part (msg part content-type nth depth declared-type)
 814   (notmuch-show-insert-part-*/* msg part content-type nth depth declared-type))
 815
 816 (defun notmuch-show-insert-part-text/html (msg part content-type nth depth declared-type)
 817   ;; text/html handler to work around bugs in renderers and our
 818   ;; invisibile parts code. In particular w3m sets up a keymap which
 819   ;; "leaks" outside the invisible region and causes strange effects
 820   ;; in notmuch. We set mm-inline-text-html-with-w3m-keymap to nil to
 821   ;; tell w3m not to set a keymap (so the normal notmuch-show-mode-map
 822   ;; remains).
 823   (let ((mm-inline-text-html-with-w3m-keymap nil))
 824     (notmuch-show-insert-part-*/* msg part content-type nth depth declared-type)))
 825
 826 (defun notmuch-show-insert-part-*/* (msg part content-type nth depth declared-type)
 827   ;; This handler _must_ succeed - it is the handler of last resort.
 828   (notmuch-show-insert-part-header nth content-type declared-type (plist-get part :filename))
 829   (notmuch-mm-display-part-inline msg part nth content-type notmuch-show-process-crypto)
 830   t)
 831
 832 ;; Functions for determining how to handle MIME parts.
 833
 834 (defun notmuch-show-handlers-for (content-type)
 835   "Return a list of content handlers for a part of type CONTENT-TYPE."
 836   (let (result)
 837     (mapc (lambda (func)
 838             (if (functionp func)
 839                 (push func result)))
 840           ;; Reverse order of prefrence.
 841           (list (intern (concat "notmuch-show-insert-part-*/*"))
 842                 (intern (concat
 843                          "notmuch-show-insert-part-"
 844                          (car (notmuch-split-content-type content-type))
 845                          "/*"))
 846                 (intern (concat "notmuch-show-insert-part-" content-type))))
 847     result))
 848
 849 ;; \f
 850
 851 (defun notmuch-show-insert-bodypart-internal (msg part content-type nth depth declared-type)
 852   (let ((handlers (notmuch-show-handlers-for content-type)))
 853     ;; Run the content handlers until one of them returns a non-nil
 854     ;; value.
 855     (while (and handlers
 856                 (not (condition-case err
 857                          (funcall (car handlers) msg part content-type nth depth declared-type)
 858                        (error (progn
 859                                 (insert "!!! Bodypart insert error: ")
 860                                 (insert (error-message-string err))
 861                                 (insert " !!!\n") nil)))))
 862       (setq handlers (cdr handlers))))
 863   t)
 864
 865 (defun notmuch-show-create-part-overlays (msg beg end hide)
 866   "Add an overlay to the part between BEG and END"
 867   (let* ((button (button-at beg))
 868          (part-beg (and button (1+ (button-end button)))))
 869
 870     ;; If the part contains no text we do not make it toggleable. We
 871     ;; also need to check that the button is a genuine part button not
 872     ;; a notmuch-wash button.
 873     (when (and button (/= part-beg end) (button-get button :base-label))
 874       (button-put button 'overlay (make-overlay part-beg end))
 875       ;; We toggle the button for hidden parts as that gets the
 876       ;; button label right.
 877       (save-excursion
 878         (when hide
 879           (notmuch-show-toggle-part-invisibility button))))))
 880
 881 (defun notmuch-show-insert-bodypart (msg part depth &optional hide)
 882   "Insert the body part PART at depth DEPTH in the current thread.
 883
 884 If HIDE is non-nil then initially hide this part."
 885   (let* ((content-type (downcase (plist-get part :content-type)))
 886          (mime-type (or (and (string= content-type "application/octet-stream")
 887                              (notmuch-show-get-mime-type-of-application/octet-stream part))
 888                         (and (string= content-type "inline patch")
 889                              "text/x-diff")
 890                         content-type))
 891          (nth (plist-get part :id))
 892          (beg (point)))
 893
 894     (notmuch-show-insert-bodypart-internal msg part mime-type nth depth content-type)
 895     ;; Some of the body part handlers leave point somewhere up in the
 896     ;; part, so we make sure that we're down at the end.
 897     (goto-char (point-max))
 898     ;; Ensure that the part ends with a carriage return.
 899     (unless (bolp)
 900       (insert "\n"))
 901     (notmuch-show-create-part-overlays msg beg (point) hide)))
 902
 903 (defun notmuch-show-insert-body (msg body depth)
 904   "Insert the body BODY at depth DEPTH in the current thread."
 905   (mapc (lambda (part) (notmuch-show-insert-bodypart msg part depth)) body))
 906
 907 (defun notmuch-show-make-symbol (type)
 908   (make-symbol (concat "notmuch-show-" type)))
 909
 910 (defun notmuch-show-strip-re (string)
 911   (replace-regexp-in-string "^\\([Rr]e: *\\)+" "" string))
 912
 913 (defvar notmuch-show-previous-subject "")
 914 (make-variable-buffer-local 'notmuch-show-previous-subject)
 915
 916 (defun notmuch-show-insert-msg (msg depth)
 917   "Insert the message MSG at depth DEPTH in the current thread."
 918   (let* ((headers (plist-get msg :headers))
 919          ;; Indentation causes the buffer offset of the start/end
 920          ;; points to move, so we must use markers.
 921          message-start message-end
 922          content-start content-end
 923          headers-start headers-end
 924          (bare-subject (notmuch-show-strip-re (plist-get headers :Subject))))
 925
 926     (setq message-start (point-marker))
 927
 928     (notmuch-show-insert-headerline headers
 929                                     (or (if notmuch-show-relative-dates
 930                                             (plist-get msg :date_relative)
 931                                           nil)
 932                                         (plist-get headers :Date))
 933                                     (plist-get msg :tags) depth)
 934
 935     (setq content-start (point-marker))
 936
 937     ;; Set `headers-start' to point after the 'Subject:' header to be
 938     ;; compatible with the existing implementation. This just sets it
 939     ;; to after the first header.
 940     (notmuch-show-insert-headers headers)
 941     (save-excursion
 942       (goto-char content-start)
 943       ;; If the subject of this message is the same as that of the
 944       ;; previous message, don't display it when this message is
 945       ;; collapsed.
 946       (when (not (string= notmuch-show-previous-subject
 947                           bare-subject))
 948         (forward-line 1))
 949       (setq headers-start (point-marker)))
 950     (setq headers-end (point-marker))
 951
 952     (setq notmuch-show-previous-subject bare-subject)
 953
 954     ;; A blank line between the headers and the body.
 955     (insert "\n")
 956     (notmuch-show-insert-body msg (plist-get msg :body)
 957                               (if notmuch-show-indent-content depth 0))
 958     ;; Ensure that the body ends with a newline.
 959     (unless (bolp)
 960       (insert "\n"))
 961     (setq content-end (point-marker))
 962
 963     ;; Indent according to the depth in the thread.
 964     (if notmuch-show-indent-content
 965         (indent-rigidly content-start content-end (* notmuch-show-indent-messages-width depth)))
 966
 967     (setq message-end (point-max-marker))
 968
 969     ;; Save the extents of this message over the whole text of the
 970     ;; message.
 971     (put-text-property message-start message-end :notmuch-message-extent (cons message-start message-end))
 972
 973     ;; Create overlays used to control visibility
 974     (plist-put msg :headers-overlay (make-overlay headers-start headers-end))
 975     (plist-put msg :message-overlay (make-overlay headers-start content-end))
 976
 977     (plist-put msg :depth depth)
 978
 979     ;; Save the properties for this message. Currently this saves the
 980     ;; entire message (augmented it with other stuff), which seems
 981     ;; like overkill. We might save a reduced subset (for example, not
 982     ;; the content).
 983     (notmuch-show-set-message-properties msg)
 984
 985     ;; Set header visibility.
 986     (notmuch-show-headers-visible msg notmuch-message-headers-visible)
 987
 988     ;; Message visibility depends on whether it matched the search
 989     ;; criteria.
 990     (notmuch-show-message-visible msg (and (plist-get msg :match)
 991                                            (not (plist-get msg :excluded))))))
 992
 993 (defun notmuch-show-toggle-process-crypto ()
 994   "Toggle the processing of cryptographic MIME parts."
 995   (interactive)
 996   (setq notmuch-show-process-crypto (not notmuch-show-process-crypto))
 997   (message (if notmuch-show-process-crypto
 998                "Processing cryptographic MIME parts."
 999              "Not processing cryptographic MIME parts."))
1000   (notmuch-show-refresh-view))
1001
1002 (defun notmuch-show-toggle-elide-non-matching ()
1003   "Toggle the display of non-matching messages."
1004   (interactive)
1005   (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages))
1006   (message (if notmuch-show-elide-non-matching-messages
1007                "Showing matching messages only."
1008              "Showing all messages."))
1009   (notmuch-show-refresh-view))
1010
1011 (defun notmuch-show-toggle-thread-indentation ()
1012   "Toggle the indentation of threads."
1013   (interactive)
1014   (setq notmuch-show-indent-content (not notmuch-show-indent-content))
1015   (message (if notmuch-show-indent-content
1016                "Content is indented."
1017              "Content is not indented."))
1018   (notmuch-show-refresh-view))
1019
1020 (defun notmuch-show-insert-tree (tree depth)
1021   "Insert the message tree TREE at depth DEPTH in the current thread."
1022   (let ((msg (car tree))
1023         (replies (cadr tree)))
1024     ;; We test whether there is a message or just some replies.
1025     (when msg
1026       (notmuch-show-insert-msg msg depth))
1027     (notmuch-show-insert-thread replies (1+ depth))))
1028
1029 (defun notmuch-show-insert-thread (thread depth)
1030   "Insert the thread THREAD at depth DEPTH in the current forest."
1031   (mapc (lambda (tree) (notmuch-show-insert-tree tree depth)) thread))
1032
1033 (defun notmuch-show-insert-forest (forest)
1034   "Insert the forest of threads FOREST."
1035   (mapc (lambda (thread) (notmuch-show-insert-thread thread 0)) forest))
1036
1037 (defvar notmuch-id-regexp
1038   (concat
1039    ;; Match the id: prefix only if it begins a word (to disallow, for
1040    ;; example, matching cid:).
1041    "\\<id:\\("
1042    ;; If the term starts with a ", then parse Xapian's quoted boolean
1043    ;; term syntax, which allows for anything as long as embedded
1044    ;; double quotes escaped by doubling them.  We also disallow
1045    ;; newlines (which Xapian allows) to prevent runaway terms.
1046    "\"\\([^\"\n]\\|\"\"\\)*\""
1047    ;; Otherwise, parse Xapian's unquoted syntax, which goes up to the
1048    ;; next space or ).  We disallow [.,;] as the last character
1049    ;; because these are probably part of the surrounding text, and not
1050    ;; part of the id.  This doesn't match single character ids; meh.
1051    "\\|[^\"[:space:])][^[:space:])]*[^])[:space:].,:;?!]"
1052    "\\)")
1053   "The regexp used to match id: links in messages.")
1054
1055 (defvar notmuch-mid-regexp
1056   ;; goto-address-url-regexp matched cid: links, which have the same
1057   ;; grammar as the message ID part of a mid: link.  Construct the
1058   ;; regexp using the same technique as goto-address-url-regexp.
1059   (concat "\\<mid:\\(" thing-at-point-url-path-regexp "\\)")
1060   "The regexp used to match mid: links in messages.
1061
1062 See RFC 2392.")
1063
1064 (defun notmuch-show-buttonise-links (start end)
1065   "Buttonise URLs and mail addresses between START and END.
1066
1067 This also turns id:\"<message id>\"-parts and mid: links into
1068 buttons for a corresponding notmuch search."
1069   (goto-address-fontify-region start end)
1070   (save-excursion
1071     (let (links)
1072       (goto-char start)
1073       (while (re-search-forward notmuch-id-regexp end t)
1074         (push (list (match-beginning 0) (match-end 0)
1075                     (match-string-no-properties 0)) links))
1076       (goto-char start)
1077       (while (re-search-forward notmuch-mid-regexp end t)
1078         (let* ((mid-cid (match-string-no-properties 1))
1079                (mid (save-match-data
1080                       (string-match "^[^/]*" mid-cid)
1081                       (url-unhex-string (match-string 0 mid-cid)))))
1082           (push (list (match-beginning 0) (match-end 0)
1083                       (notmuch-id-to-query mid)) links)))
1084       (dolist (link links)
1085         ;; Remove the overlay created by goto-address-mode
1086         (remove-overlays (first link) (second link) 'goto-address t)
1087         (make-text-button (first link) (second link)
1088                           :type 'notmuch-button-type
1089                           'action `(lambda (arg)
1090                                      (notmuch-show ,(third link)))
1091                           'follow-link t
1092                           'help-echo "Mouse-1, RET: search for this message"
1093                           'face goto-address-mail-face)))))
1094
1095 ;;;###autoload
1096 (defun notmuch-show (thread-id &optional parent-buffer query-context buffer-name)
1097   "Run \"notmuch show\" with the given thread ID and display results.
1098
1099 The optional PARENT-BUFFER is the notmuch-search buffer from
1100 which this notmuch-show command was executed, (so that the
1101 next thread from that buffer can be show when done with this
1102 one).
1103
1104 The optional QUERY-CONTEXT is a notmuch search term. Only
1105 messages from the thread matching this search term are shown if
1106 non-nil.
1107
1108 The optional BUFFER-NAME provides the name of the buffer in
1109 which the message thread is shown. If it is nil (which occurs
1110 when the command is called interactively) the argument to the
1111 function is used."
1112   (interactive "sNotmuch show: ")
1113   (let ((buffer-name (generate-new-buffer-name
1114                       (or buffer-name
1115                           (concat "*notmuch-" thread-id "*")))))
1116     (switch-to-buffer (get-buffer-create buffer-name))
1117     ;; Set the default value for `notmuch-show-process-crypto' in this
1118     ;; buffer.
1119     (setq notmuch-show-process-crypto notmuch-crypto-process-mime)
1120     ;; Set the default value for
1121     ;; `notmuch-show-elide-non-matching-messages' in this buffer. If
1122     ;; there is a prefix argument, invert the default.
1123     (setq notmuch-show-elide-non-matching-messages notmuch-show-only-matching-messages)
1124     (if current-prefix-arg
1125         (setq notmuch-show-elide-non-matching-messages (not notmuch-show-elide-non-matching-messages)))
1126
1127     (setq notmuch-show-thread-id thread-id
1128           notmuch-show-parent-buffer parent-buffer
1129           notmuch-show-query-context query-context)
1130     (notmuch-show-build-buffer)
1131     (notmuch-show-goto-first-wanted-message)
1132     (current-buffer)))
1133
1134 (defun notmuch-show-build-buffer ()
1135   (let ((inhibit-read-only t))
1136
1137     (notmuch-show-mode)
1138     ;; Don't track undo information for this buffer
1139     (set 'buffer-undo-list t)
1140
1141     (erase-buffer)
1142     (goto-char (point-min))
1143     (save-excursion
1144       (let* ((basic-args (list notmuch-show-thread-id))
1145              (args (if notmuch-show-query-context
1146                        (append (list "\'") basic-args
1147                                (list "and (" notmuch-show-query-context ")\'"))
1148                      (append (list "\'") basic-args (list "\'"))))
1149              (cli-args (cons "--exclude=false"
1150                              (when notmuch-show-elide-non-matching-messages
1151                                (list "--entire-thread=false")))))
1152
1153         (notmuch-show-insert-forest (notmuch-query-get-threads (append cli-args args)))
1154         ;; If the query context reduced the results to nothing, run
1155         ;; the basic query.
1156         (when (and (eq (buffer-size) 0)
1157                    notmuch-show-query-context)
1158           (notmuch-show-insert-forest
1159            (notmuch-query-get-threads (append cli-args basic-args)))))
1160
1161       (jit-lock-register #'notmuch-show-buttonise-links)
1162
1163       ;; Set the header line to the subject of the first message.
1164       (setq header-line-format (notmuch-show-strip-re (notmuch-show-get-subject)))
1165
1166       (run-hooks 'notmuch-show-hook))))
1167
1168 (defun notmuch-show-capture-state ()
1169   "Capture the state of the current buffer.
1170
1171 This includes:
1172  - the list of open messages,
1173  - the current message."
1174   (list (notmuch-show-get-message-id) (notmuch-show-get-message-ids-for-open-messages)))
1175
1176 (defun notmuch-show-apply-state (state)
1177   "Apply STATE to the current buffer.
1178
1179 This includes:
1180  - opening the messages previously opened,
1181  - closing all other messages,
1182  - moving to the correct current message."
1183   (let ((current (car state))
1184         (open (cadr state)))
1185
1186     ;; Open those that were open.
1187     (goto-char (point-min))
1188     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1189                                            (member (notmuch-show-get-message-id) open))
1190           until (not (notmuch-show-goto-message-next)))
1191
1192     ;; Go to the previously open message.
1193     (goto-char (point-min))
1194     (unless (loop if (string= current (notmuch-show-get-message-id))
1195                   return t
1196                   until (not (notmuch-show-goto-message-next)))
1197       (goto-char (point-min))
1198       (message "Previously current message not found."))
1199     (notmuch-show-message-adjust)))
1200
1201 (defun notmuch-show-refresh-view (&optional reset-state)
1202   "Refresh the current view.
1203
1204 Refreshes the current view, observing changes in display
1205 preferences. If invoked with a prefix argument (or RESET-STATE is
1206 non-nil) then the state of the buffer (open/closed messages) is
1207 reset based on the original query."
1208   (interactive "P")
1209   (let ((inhibit-read-only t)
1210         (state (unless reset-state
1211                  (notmuch-show-capture-state))))
1212     ;; erase-buffer does not seem to remove overlays, which can lead
1213     ;; to weird effects such as remaining images, so remove them
1214     ;; manually.
1215     (remove-overlays)
1216     (erase-buffer)
1217     (notmuch-show-build-buffer)
1218     (if state
1219         (notmuch-show-apply-state state)
1220       ;; We're resetting state, so navigate to the first open message
1221       ;; and mark it read, just like opening a new show buffer.
1222       (notmuch-show-goto-first-wanted-message))))
1223
1224 (defvar notmuch-show-stash-map
1225   (let ((map (make-sparse-keymap)))
1226     (define-key map "c" 'notmuch-show-stash-cc)
1227     (define-key map "d" 'notmuch-show-stash-date)
1228     (define-key map "F" 'notmuch-show-stash-filename)
1229     (define-key map "f" 'notmuch-show-stash-from)
1230     (define-key map "i" 'notmuch-show-stash-message-id)
1231     (define-key map "I" 'notmuch-show-stash-message-id-stripped)
1232     (define-key map "s" 'notmuch-show-stash-subject)
1233     (define-key map "T" 'notmuch-show-stash-tags)
1234     (define-key map "t" 'notmuch-show-stash-to)
1235     (define-key map "l" 'notmuch-show-stash-mlarchive-link)
1236     (define-key map "L" 'notmuch-show-stash-mlarchive-link-and-go)
1237     map)
1238   "Submap for stash commands")
1239 (fset 'notmuch-show-stash-map notmuch-show-stash-map)
1240
1241 (defvar notmuch-show-mode-map
1242       (let ((map (make-sparse-keymap)))
1243         (define-key map "?" 'notmuch-help)
1244         (define-key map "q" 'notmuch-kill-this-buffer)
1245         (define-key map (kbd "<C-tab>") 'widget-backward)
1246         (define-key map (kbd "M-TAB") 'notmuch-show-previous-button)
1247         (define-key map (kbd "<backtab>") 'notmuch-show-previous-button)
1248         (define-key map (kbd "TAB") 'notmuch-show-next-button)
1249         (define-key map "s" 'notmuch-search)
1250         (define-key map "m" 'notmuch-mua-new-mail)
1251         (define-key map "f" 'notmuch-show-forward-message)
1252         (define-key map "r" 'notmuch-show-reply-sender)
1253         (define-key map "R" 'notmuch-show-reply)
1254         (define-key map "|" 'notmuch-show-pipe-message)
1255         (define-key map "w" 'notmuch-show-save-attachments)
1256         (define-key map "V" 'notmuch-show-view-raw-message)
1257         (define-key map "v" 'notmuch-show-view-all-mime-parts)
1258         (define-key map "c" 'notmuch-show-stash-map)
1259         (define-key map "=" 'notmuch-show-refresh-view)
1260         (define-key map "h" 'notmuch-show-toggle-visibility-headers)
1261         (define-key map "*" 'notmuch-show-tag-all)
1262         (define-key map "-" 'notmuch-show-remove-tag)
1263         (define-key map "+" 'notmuch-show-add-tag)
1264         (define-key map "X" 'notmuch-show-archive-thread-then-exit)
1265         (define-key map "x" 'notmuch-show-archive-message-then-next-or-exit)
1266         (define-key map "A" 'notmuch-show-archive-thread-then-next)
1267         (define-key map "a" 'notmuch-show-archive-message-then-next-or-next-thread)
1268         (define-key map "N" 'notmuch-show-next-message)
1269         (define-key map "P" 'notmuch-show-previous-message)
1270         (define-key map "n" 'notmuch-show-next-open-message)
1271         (define-key map "p" 'notmuch-show-previous-open-message)
1272         (define-key map (kbd "M-n") 'notmuch-show-next-thread-show)
1273         (define-key map (kbd "M-p") 'notmuch-show-previous-thread-show)
1274         (define-key map (kbd "DEL") 'notmuch-show-rewind)
1275         (define-key map " " 'notmuch-show-advance-and-archive)
1276         (define-key map (kbd "M-RET") 'notmuch-show-open-or-close-all)
1277         (define-key map (kbd "RET") 'notmuch-show-toggle-message)
1278         (define-key map "#" 'notmuch-show-print-message)
1279         (define-key map "!" 'notmuch-show-toggle-elide-non-matching)
1280         (define-key map "$" 'notmuch-show-toggle-process-crypto)
1281         (define-key map "<" 'notmuch-show-toggle-thread-indentation)
1282         (define-key map "t" 'toggle-truncate-lines)
1283         map)
1284       "Keymap for \"notmuch show\" buffers.")
1285 (fset 'notmuch-show-mode-map notmuch-show-mode-map)
1286
1287 (defun notmuch-show-mode ()
1288   "Major mode for viewing a thread with notmuch.
1289
1290 This buffer contains the results of the \"notmuch show\" command
1291 for displaying a single thread of email from your email archives.
1292
1293 By default, various components of email messages, (citations,
1294 signatures, already-read messages), are hidden. You can make
1295 these parts visible by clicking with the mouse button or by
1296 pressing RET after positioning the cursor on a hidden part, (for
1297 which \\[notmuch-show-next-button] and \\[notmuch-show-previous-button] are helpful).
1298
1299 Reading the thread sequentially is well-supported by pressing
1300 \\[notmuch-show-advance-and-archive]. This will scroll the current message (if necessary), advance
1301 to the next message, or advance to the next thread (if already on
1302 the last message of a thread).
1303
1304 Other commands are available to read or manipulate the thread
1305 more selectively, (such as '\\[notmuch-show-next-message]' and '\\[notmuch-show-previous-message]' to advance to messages
1306 without removing any tags, and '\\[notmuch-show-archive-thread]' to archive an entire thread
1307 without scrolling through with \\[notmuch-show-advance-and-archive]).
1308
1309 You can add or remove arbitrary tags from the current message with
1310 '\\[notmuch-show-add-tag]' or '\\[notmuch-show-remove-tag]'.
1311
1312 All currently available key bindings:
1313
1314 \\{notmuch-show-mode-map}"
1315   (interactive)
1316   (kill-all-local-variables)
1317   (use-local-map notmuch-show-mode-map)
1318   (setq major-mode 'notmuch-show-mode
1319         mode-name "notmuch-show")
1320   (setq buffer-read-only t
1321         truncate-lines t))
1322
1323 (defun notmuch-show-move-to-message-top ()
1324   (goto-char (notmuch-show-message-top)))
1325
1326 (defun notmuch-show-move-to-message-bottom ()
1327   (goto-char (notmuch-show-message-bottom)))
1328
1329 (defun notmuch-show-message-adjust ()
1330   (recenter 0))
1331
1332 ;; Movement related functions.
1333
1334 ;; There's some strangeness here where a text property applied to a
1335 ;; region a->b is not found when point is at b. We walk backwards
1336 ;; until finding the property.
1337 (defun notmuch-show-message-extent ()
1338   (let (r)
1339     (save-excursion
1340       (while (not (setq r (get-text-property (point) :notmuch-message-extent)))
1341         (backward-char)))
1342     r))
1343
1344 (defun notmuch-show-message-top ()
1345   (car (notmuch-show-message-extent)))
1346
1347 (defun notmuch-show-message-bottom ()
1348   (cdr (notmuch-show-message-extent)))
1349
1350 (defun notmuch-show-goto-message-next ()
1351   (let ((start (point)))
1352     (notmuch-show-move-to-message-bottom)
1353     (if (not (eobp))
1354         t
1355       (goto-char start)
1356       nil)))
1357
1358 (defun notmuch-show-goto-message-previous ()
1359   (notmuch-show-move-to-message-top)
1360   (if (bobp)
1361       nil
1362     (backward-char)
1363     (notmuch-show-move-to-message-top)
1364     t))
1365
1366 (defun notmuch-show-mapc (function)
1367   "Iterate through all messages in the current thread with
1368 `notmuch-show-goto-message-next' and call FUNCTION for side
1369 effects."
1370   (save-excursion
1371     (goto-char (point-min))
1372     (loop do (funcall function)
1373           while (notmuch-show-goto-message-next))))
1374
1375 ;; Functions relating to the visibility of messages and their
1376 ;; components.
1377
1378 (defun notmuch-show-message-visible (props visible-p)
1379   (overlay-put (plist-get props :message-overlay) 'invisible (not visible-p))
1380   (notmuch-show-set-prop :message-visible visible-p props))
1381
1382 (defun notmuch-show-headers-visible (props visible-p)
1383   (overlay-put (plist-get props :headers-overlay) 'invisible (not visible-p))
1384   (notmuch-show-set-prop :headers-visible visible-p props))
1385
1386 ;; Functions for setting and getting attributes of the current
1387 ;; message.
1388
1389 (defun notmuch-show-set-message-properties (props)
1390   (save-excursion
1391     (notmuch-show-move-to-message-top)
1392     (put-text-property (point) (+ (point) 1) :notmuch-message-properties props)))
1393
1394 (defun notmuch-show-get-message-properties ()
1395   "Return the properties of the current message as a plist.
1396
1397 Some useful entries are:
1398 :headers - Property list containing the headers :Date, :Subject, :From, etc.
1399 :body - Body of the message
1400 :tags - Tags for this message"
1401   (save-excursion
1402     (notmuch-show-move-to-message-top)
1403     (get-text-property (point) :notmuch-message-properties)))
1404
1405 (defun notmuch-show-set-prop (prop val &optional props)
1406   (let ((inhibit-read-only t)
1407         (props (or props
1408                    (notmuch-show-get-message-properties))))
1409     (plist-put props prop val)
1410     (notmuch-show-set-message-properties props)))
1411
1412 (defun notmuch-show-get-prop (prop &optional props)
1413   (let ((props (or props
1414                    (notmuch-show-get-message-properties))))
1415     (plist-get props prop)))
1416
1417 (defun notmuch-show-get-message-id (&optional bare)
1418   "Return an id: query for the Message-Id of the current message.
1419
1420 If optional argument BARE is non-nil, return
1421 the Message-Id without id: prefix and escaping."
1422   (if bare
1423       (notmuch-show-get-prop :id)
1424     (notmuch-id-to-query (notmuch-show-get-prop :id))))
1425
1426 (defun notmuch-show-get-messages-ids ()
1427   "Return all id: queries of messages in the current thread."
1428   (let ((message-ids))
1429     (notmuch-show-mapc
1430      (lambda () (push (notmuch-show-get-message-id) message-ids)))
1431     message-ids))
1432
1433 (defun notmuch-show-get-messages-ids-search ()
1434   "Return a search string for all message ids of messages in the
1435 current thread."
1436   (mapconcat 'identity (notmuch-show-get-messages-ids) " or "))
1437
1438 ;; dme: Would it make sense to use a macro for many of these?
1439
1440 (defun notmuch-show-get-filename ()
1441   "Return the filename of the current message."
1442   (notmuch-show-get-prop :filename))
1443
1444 (defun notmuch-show-get-header (header &optional props)
1445   "Return the named header of the current message, if any."
1446   (plist-get (notmuch-show-get-prop :headers props) header))
1447
1448 (defun notmuch-show-get-cc ()
1449   (notmuch-show-get-header :Cc))
1450
1451 (defun notmuch-show-get-date ()
1452   (notmuch-show-get-header :Date))
1453
1454 (defun notmuch-show-get-from ()
1455   (notmuch-show-get-header :From))
1456
1457 (defun notmuch-show-get-subject ()
1458   (notmuch-show-get-header :Subject))
1459
1460 (defun notmuch-show-get-to ()
1461   (notmuch-show-get-header :To))
1462
1463 (defun notmuch-show-get-depth ()
1464   (notmuch-show-get-prop :depth))
1465
1466 (defun notmuch-show-set-tags (tags)
1467   "Set the tags of the current message."
1468   (notmuch-show-set-prop :tags tags)
1469   (notmuch-show-update-tags tags))
1470
1471 (defun notmuch-show-get-tags ()
1472   "Return the tags of the current message."
1473   (notmuch-show-get-prop :tags))
1474
1475 (defun notmuch-show-message-visible-p ()
1476   "Is the current message visible?"
1477   (notmuch-show-get-prop :message-visible))
1478
1479 (defun notmuch-show-headers-visible-p ()
1480   "Are the headers of the current message visible?"
1481   (notmuch-show-get-prop :headers-visible))
1482
1483 (defun notmuch-show-mark-read (&optional unread)
1484   "Mark the current message as read.
1485
1486 Mark the current message as read by applying the tag changes in
1487 `notmuch-show-mark-read-tags' to it (remove the \"unread\" tag by
1488 default). If a prefix argument is given, the message will be
1489 marked as unread, i.e. the tag changes in
1490 `notmuch-show-mark-read-tags' will be reversed."
1491   (interactive "P")
1492   (when notmuch-show-mark-read-tags
1493     (apply 'notmuch-show-tag-message
1494            (notmuch-tag-change-list notmuch-show-mark-read-tags unread))))
1495
1496 ;; Functions for getting attributes of several messages in the current
1497 ;; thread.
1498
1499 (defun notmuch-show-get-message-ids-for-open-messages ()
1500   "Return a list of all id: queries for open messages in the current thread."
1501   (save-excursion
1502     (let (message-ids done)
1503       (goto-char (point-min))
1504       (while (not done)
1505         (if (notmuch-show-message-visible-p)
1506             (setq message-ids (append message-ids (list (notmuch-show-get-message-id)))))
1507         (setq done (not (notmuch-show-goto-message-next)))
1508         )
1509       message-ids
1510       )))
1511
1512 ;; Commands typically bound to keys.
1513
1514 (defun notmuch-show-advance ()
1515   "Advance through thread.
1516
1517 If the current message in the thread is not yet fully visible,
1518 scroll by a near screenful to read more of the message.
1519
1520 Otherwise, (the end of the current message is already within the
1521 current window), advance to the next open message."
1522   (interactive)
1523   (let* ((end-of-this-message (notmuch-show-message-bottom))
1524          (visible-end-of-this-message (1- end-of-this-message))
1525          (ret nil))
1526     (while (invisible-p visible-end-of-this-message)
1527       (setq visible-end-of-this-message
1528             (max (point-min)
1529                  (1- (previous-single-char-property-change
1530                       visible-end-of-this-message 'invisible)))))
1531     (cond
1532      ;; Ideally we would test `end-of-this-message' against the result
1533      ;; of `window-end', but that doesn't account for the fact that
1534      ;; the end of the message might be hidden.
1535      ((and visible-end-of-this-message
1536            (> visible-end-of-this-message (window-end)))
1537       ;; The bottom of this message is not visible - scroll.
1538       (scroll-up nil))
1539
1540      ((not (= end-of-this-message (point-max)))
1541       ;; This is not the last message - move to the next visible one.
1542       (notmuch-show-next-open-message))
1543
1544      ((not (= (point) (point-max)))
1545       ;; This is the last message, but the cursor is not at the end of
1546       ;; the buffer. Move it there.
1547       (goto-char (point-max)))
1548
1549      (t
1550       ;; This is the last message - change the return value
1551       (setq ret t)))
1552     ret))
1553
1554 (defun notmuch-show-advance-and-archive ()
1555   "Advance through thread and archive.
1556
1557 This command is intended to be one of the simplest ways to
1558 process a thread of email. It works exactly like
1559 notmuch-show-advance, in that it scrolls through messages in a
1560 show buffer, except that when it gets to the end of the buffer it
1561 archives the entire current thread, (remove the \"inbox\" tag
1562 from each message), kills the buffer, and displays the next
1563 thread from the search from which this thread was originally
1564 shown."
1565   (interactive)
1566   (if (notmuch-show-advance)
1567       (notmuch-show-archive-thread-then-next)))
1568
1569 (defun notmuch-show-rewind ()
1570   "Backup through the thread, (reverse scrolling compared to \\[notmuch-show-advance-and-archive]).
1571
1572 Specifically, if the beginning of the previous email is fewer
1573 than `window-height' lines from the current point, move to it
1574 just like `notmuch-show-previous-message'.
1575
1576 Otherwise, just scroll down a screenful of the current message.
1577
1578 This command does not modify any message tags, (it does not undo
1579 any effects from previous calls to
1580 `notmuch-show-advance-and-archive'."
1581   (interactive)
1582   (let ((start-of-message (notmuch-show-message-top))
1583         (start-of-window (window-start)))
1584     (cond
1585       ;; Either this message is properly aligned with the start of the
1586       ;; window or the start of this message is not visible on the
1587       ;; screen - scroll.
1588      ((or (= start-of-message start-of-window)
1589           (< start-of-message start-of-window))
1590       (scroll-down)
1591       ;; If a small number of lines from the previous message are
1592       ;; visible, realign so that the top of the current message is at
1593       ;; the top of the screen.
1594       (when (<= (count-screen-lines (window-start) start-of-message)
1595                 next-screen-context-lines)
1596         (goto-char (notmuch-show-message-top))
1597         (notmuch-show-message-adjust))
1598       ;; Move to the top left of the window.
1599       (goto-char (window-start)))
1600      (t
1601       ;; Move to the previous message.
1602       (notmuch-show-previous-message)))))
1603
1604 (defun notmuch-show-reply (&optional prompt-for-sender)
1605   "Reply to the sender and all recipients of the current message."
1606   (interactive "P")
1607   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender t))
1608
1609 (defun notmuch-show-reply-sender (&optional prompt-for-sender)
1610   "Reply to the sender of the current message."
1611   (interactive "P")
1612   (notmuch-mua-new-reply (notmuch-show-get-message-id) prompt-for-sender nil))
1613
1614 (defun notmuch-show-forward-message (&optional prompt-for-sender)
1615   "Forward the current message."
1616   (interactive "P")
1617   (with-current-notmuch-show-message
1618    (notmuch-mua-new-forward-message prompt-for-sender)))
1619
1620 (defun notmuch-show-next-message (&optional pop-at-end)
1621   "Show the next message.
1622
1623 If a prefix argument is given and this is the last message in the
1624 thread, navigate to the next thread in the parent search buffer."
1625   (interactive "P")
1626   (if (notmuch-show-goto-message-next)
1627       (progn
1628         (notmuch-show-mark-read)
1629         (notmuch-show-message-adjust))
1630     (if pop-at-end
1631         (notmuch-show-next-thread)
1632       (goto-char (point-max)))))
1633
1634 (defun notmuch-show-previous-message ()
1635   "Show the previous message or the start of the current message."
1636   (interactive)
1637   (if (= (point) (notmuch-show-message-top))
1638       (notmuch-show-goto-message-previous)
1639     (notmuch-show-move-to-message-top))
1640   (notmuch-show-mark-read)
1641   (notmuch-show-message-adjust))
1642
1643 (defun notmuch-show-next-open-message (&optional pop-at-end)
1644   "Show the next open message.
1645
1646 If a prefix argument is given and this is the last open message
1647 in the thread, navigate to the next thread in the parent search
1648 buffer. Return t if there was a next open message in the thread
1649 to show, nil otherwise."
1650   (interactive "P")
1651   (let (r)
1652     (while (and (setq r (notmuch-show-goto-message-next))
1653                 (not (notmuch-show-message-visible-p))))
1654     (if r
1655         (progn
1656           (notmuch-show-mark-read)
1657           (notmuch-show-message-adjust))
1658       (if pop-at-end
1659           (notmuch-show-next-thread)
1660         (goto-char (point-max))))
1661     r))
1662
1663 (defun notmuch-show-next-matching-message ()
1664   "Show the next matching message."
1665   (interactive)
1666   (let (r)
1667     (while (and (setq r (notmuch-show-goto-message-next))
1668                 (not (notmuch-show-get-prop :match))))
1669     (if r
1670         (progn
1671           (notmuch-show-mark-read)
1672           (notmuch-show-message-adjust))
1673       (goto-char (point-max)))))
1674
1675 (defun notmuch-show-open-if-matched ()
1676   "Open a message if it is matched (whether or not excluded)."
1677   (let ((props (notmuch-show-get-message-properties)))
1678     (notmuch-show-message-visible props (plist-get props :match))))
1679
1680 (defun notmuch-show-goto-first-wanted-message ()
1681   "Move to the first open message and mark it read"
1682   (goto-char (point-min))
1683   (if (notmuch-show-message-visible-p)
1684       (notmuch-show-mark-read)
1685     (notmuch-show-next-open-message))
1686   (when (eobp)
1687     ;; There are no matched non-excluded messages so open all matched
1688     ;; (necessarily excluded) messages and go to the first.
1689     (notmuch-show-mapc 'notmuch-show-open-if-matched)
1690     (force-window-update)
1691     (goto-char (point-min))
1692     (if (notmuch-show-message-visible-p)
1693         (notmuch-show-mark-read)
1694       (notmuch-show-next-open-message))))
1695
1696 (defun notmuch-show-previous-open-message ()
1697   "Show the previous open message."
1698   (interactive)
1699   (while (and (if (= (point) (notmuch-show-message-top))
1700                   (notmuch-show-goto-message-previous)
1701                 (notmuch-show-move-to-message-top))
1702               (not (notmuch-show-message-visible-p))))
1703   (notmuch-show-mark-read)
1704   (notmuch-show-message-adjust))
1705
1706 (defun notmuch-show-view-raw-message ()
1707   "View the file holding the current message."
1708   (interactive)
1709   (let* ((id (notmuch-show-get-message-id))
1710          (buf (get-buffer-create (concat "*notmuch-raw-" id "*"))))
1711     (call-process notmuch-command nil buf nil "show" "--format=raw" id)
1712     (switch-to-buffer buf)
1713     (goto-char (point-min))
1714     (set-buffer-modified-p nil)
1715     (view-buffer buf 'kill-buffer-if-not-modified)))
1716
1717 (defun notmuch-show-pipe-message (entire-thread command)
1718   "Pipe the contents of the current message (or thread) to the given command.
1719
1720 The given command will be executed with the raw contents of the
1721 current email message as stdin. Anything printed by the command
1722 to stdout or stderr will appear in the *notmuch-pipe* buffer.
1723
1724 When invoked with a prefix argument, the command will receive all
1725 open messages in the current thread (formatted as an mbox) rather
1726 than only the current message."
1727   (interactive "P\nsPipe message to command: ")
1728   (let (shell-command)
1729     (if entire-thread
1730         (setq shell-command
1731               (concat notmuch-command " show --format=mbox --exclude=false "
1732                       (shell-quote-argument
1733                        (mapconcat 'identity (notmuch-show-get-message-ids-for-open-messages) " OR "))
1734                       " | " command))
1735       (setq shell-command
1736             (concat notmuch-command " show --format=raw "
1737                     (shell-quote-argument (notmuch-show-get-message-id)) " | " command)))
1738     (let ((buf (get-buffer-create (concat "*notmuch-pipe*"))))
1739       (with-current-buffer buf
1740         (setq buffer-read-only nil)
1741         (erase-buffer)
1742         (let ((exit-code (call-process-shell-command shell-command nil buf)))
1743           (goto-char (point-max))
1744           (set-buffer-modified-p nil)
1745           (setq buffer-read-only t)
1746           (unless (zerop exit-code)
1747             (switch-to-buffer-other-window buf)
1748             (message (format "Command '%s' exited abnormally with code %d"
1749                              shell-command exit-code))))))))
1750
1751 (defun notmuch-show-tag-message (&rest tag-changes)
1752   "Change tags for the current message.
1753
1754 TAG-CHANGES is a list of tag operations for `notmuch-tag'."
1755   (let* ((current-tags (notmuch-show-get-tags))
1756          (new-tags (notmuch-update-tags current-tags tag-changes)))
1757     (unless (equal current-tags new-tags)
1758       (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes)
1759       (notmuch-show-set-tags new-tags))))
1760
1761 (defun notmuch-show-tag (&optional tag-changes)
1762   "Change tags for the current message.
1763
1764 See `notmuch-tag' for information on the format of TAG-CHANGES."
1765   (interactive)
1766   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-message-id) tag-changes))
1767   (let* ((current-tags (notmuch-show-get-tags))
1768          (new-tags (notmuch-update-tags current-tags tag-changes)))
1769     (unless (equal current-tags new-tags)
1770       (notmuch-show-set-tags new-tags))))
1771
1772 (defun notmuch-show-tag-all (&optional tag-changes)
1773   "Change tags for all messages in the current show buffer.
1774
1775 See `notmuch-tag' for information on the format of TAG-CHANGES."
1776   (interactive)
1777   (setq tag-changes (funcall 'notmuch-tag (notmuch-show-get-messages-ids-search) tag-changes))
1778   (notmuch-show-mapc
1779    (lambda ()
1780      (let* ((current-tags (notmuch-show-get-tags))
1781             (new-tags (notmuch-update-tags current-tags tag-changes)))
1782        (unless (equal current-tags new-tags)
1783          (notmuch-show-set-tags new-tags))))))
1784
1785 (defun notmuch-show-add-tag ()
1786   "Same as `notmuch-show-tag' but sets initial input to '+'."
1787   (interactive)
1788   (notmuch-show-tag "+"))
1789
1790 (defun notmuch-show-remove-tag ()
1791   "Same as `notmuch-show-tag' but sets initial input to '-'."
1792   (interactive)
1793   (notmuch-show-tag "-"))
1794
1795 (defun notmuch-show-toggle-visibility-headers ()
1796   "Toggle the visibility of the current message headers."
1797   (interactive)
1798   (let ((props (notmuch-show-get-message-properties)))
1799     (notmuch-show-headers-visible
1800      props
1801      (not (plist-get props :headers-visible))))
1802   (force-window-update))
1803
1804 (defun notmuch-show-toggle-message ()
1805   "Toggle the visibility of the current message."
1806   (interactive)
1807   (let ((props (notmuch-show-get-message-properties)))
1808     (notmuch-show-message-visible
1809      props
1810      (not (plist-get props :message-visible))))
1811   (force-window-update))
1812
1813 (defun notmuch-show-open-or-close-all ()
1814   "Set the visibility all of the messages in the current thread.
1815 By default make all of the messages visible. With a prefix
1816 argument, hide all of the messages."
1817   (interactive)
1818   (save-excursion
1819     (goto-char (point-min))
1820     (loop do (notmuch-show-message-visible (notmuch-show-get-message-properties)
1821                                            (not current-prefix-arg))
1822           until (not (notmuch-show-goto-message-next))))
1823   (force-window-update))
1824
1825 (defun notmuch-show-next-button ()
1826   "Advance point to the next button in the buffer."
1827   (interactive)
1828   (forward-button 1))
1829
1830 (defun notmuch-show-previous-button ()
1831   "Move point back to the previous button in the buffer."
1832   (interactive)
1833   (backward-button 1))
1834
1835 (defun notmuch-show-next-thread (&optional show previous)
1836   "Move to the next item in the search results, if any.
1837
1838 If SHOW is non-nil, open the next item in a show
1839 buffer. Otherwise just highlight the next item in the search
1840 buffer. If PREVIOUS is non-nil, move to the previous item in the
1841 search results instead."
1842   (interactive "P")
1843   (let ((parent-buffer notmuch-show-parent-buffer))
1844     (notmuch-kill-this-buffer)
1845     (when (buffer-live-p parent-buffer)
1846       (switch-to-buffer parent-buffer)
1847       (and (if previous
1848                (notmuch-search-previous-thread)
1849              (notmuch-search-next-thread))
1850            show
1851            (notmuch-search-show-thread)))))
1852
1853 (defun notmuch-show-next-thread-show ()
1854   "Show the next thread in the search results, if any."
1855   (interactive)
1856   (notmuch-show-next-thread t))
1857
1858 (defun notmuch-show-previous-thread-show ()
1859   "Show the previous thread in the search results, if any."
1860   (interactive)
1861   (notmuch-show-next-thread t t))
1862
1863 (defun notmuch-show-archive-thread (&optional unarchive)
1864   "Archive each message in thread.
1865
1866 Archive each message currently shown by applying the tag changes
1867 in `notmuch-archive-tags' to each (remove the \"inbox\" tag by
1868 default). If a prefix argument is given, the messages will be
1869 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1870 will be reversed.
1871
1872 Note: This command is safe from any race condition of new messages
1873 being delivered to the same thread. It does not archive the
1874 entire thread, but only the messages shown in the current
1875 buffer."
1876   (interactive "P")
1877   (when notmuch-archive-tags
1878     (notmuch-show-tag-all
1879      (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1880
1881 (defun notmuch-show-archive-thread-then-next ()
1882   "Archive all messages in the current buffer, then show next thread from search."
1883   (interactive)
1884   (notmuch-show-archive-thread)
1885   (notmuch-show-next-thread t))
1886
1887 (defun notmuch-show-archive-thread-then-exit ()
1888   "Archive all messages in the current buffer, then exit back to search results."
1889   (interactive)
1890   (notmuch-show-archive-thread)
1891   (notmuch-show-next-thread))
1892
1893 (defun notmuch-show-archive-message (&optional unarchive)
1894   "Archive the current message.
1895
1896 Archive the current message by applying the tag changes in
1897 `notmuch-archive-tags' to it (remove the \"inbox\" tag by
1898 default). If a prefix argument is given, the message will be
1899 \"unarchived\", i.e. the tag changes in `notmuch-archive-tags'
1900 will be reversed."
1901   (interactive "P")
1902   (when notmuch-archive-tags
1903     (apply 'notmuch-show-tag-message
1904            (notmuch-tag-change-list notmuch-archive-tags unarchive))))
1905
1906 (defun notmuch-show-archive-message-then-next-or-exit ()
1907   "Archive the current message, then show the next open message in the current thread.
1908
1909 If at the last open message in the current thread, then exit back
1910 to search results."
1911   (interactive)
1912   (notmuch-show-archive-message)
1913   (notmuch-show-next-open-message t))
1914
1915 (defun notmuch-show-archive-message-then-next-or-next-thread ()
1916   "Archive the current message, then show the next open message in the current thread.
1917
1918 If at the last open message in the current thread, then show next
1919 thread from search."
1920   (interactive)
1921   (notmuch-show-archive-message)
1922   (unless (notmuch-show-next-open-message)
1923     (notmuch-show-next-thread t)))
1924
1925 (defun notmuch-show-stash-cc ()
1926   "Copy CC field of current message to kill-ring."
1927   (interactive)
1928   (notmuch-common-do-stash (notmuch-show-get-cc)))
1929
1930 (defun notmuch-show-stash-date ()
1931   "Copy date of current message to kill-ring."
1932   (interactive)
1933   (notmuch-common-do-stash (notmuch-show-get-date)))
1934
1935 (defun notmuch-show-stash-filename ()
1936   "Copy filename of current message to kill-ring."
1937   (interactive)
1938   (notmuch-common-do-stash (notmuch-show-get-filename)))
1939
1940 (defun notmuch-show-stash-from ()
1941   "Copy From address of current message to kill-ring."
1942   (interactive)
1943   (notmuch-common-do-stash (notmuch-show-get-from)))
1944
1945 (defun notmuch-show-stash-message-id (&optional stash-thread-id)
1946   "Copy id: query matching the current message to kill-ring.
1947
1948 If invoked with a prefix argument (or STASH-THREAD-ID is
1949 non-nil), copy thread: query matching the current thread to
1950 kill-ring."
1951   (interactive "P")
1952   (if stash-thread-id
1953       (notmuch-common-do-stash notmuch-show-thread-id)
1954     (notmuch-common-do-stash (notmuch-show-get-message-id))))
1955
1956 (defun notmuch-show-stash-message-id-stripped ()
1957   "Copy message ID of current message (sans `id:' prefix) to kill-ring."
1958   (interactive)
1959   (notmuch-common-do-stash (notmuch-show-get-message-id t)))
1960
1961 (defun notmuch-show-stash-subject ()
1962   "Copy Subject field of current message to kill-ring."
1963   (interactive)
1964   (notmuch-common-do-stash (notmuch-show-get-subject)))
1965
1966 (defun notmuch-show-stash-tags ()
1967   "Copy tags of current message to kill-ring as a comma separated list."
1968   (interactive)
1969   (notmuch-common-do-stash (mapconcat 'identity (notmuch-show-get-tags) ",")))
1970
1971 (defun notmuch-show-stash-to ()
1972   "Copy To address of current message to kill-ring."
1973   (interactive)
1974   (notmuch-common-do-stash (notmuch-show-get-to)))
1975
1976 (defun notmuch-show-stash-mlarchive-link (&optional mla)
1977   "Copy an ML Archive URI for the current message to the kill-ring.
1978
1979 This presumes that the message is available at the selected Mailing List Archive.
1980
1981 If optional argument MLA is non-nil, use the provided key instead of prompting
1982 the user (see `notmuch-show-stash-mlarchive-link-alist')."
1983   (interactive)
1984   (notmuch-common-do-stash
1985    (concat (cdr (assoc
1986                  (or mla
1987                      (let ((completion-ignore-case t))
1988                        (completing-read
1989                         "Mailing List Archive: "
1990                         notmuch-show-stash-mlarchive-link-alist
1991                         nil t nil nil notmuch-show-stash-mlarchive-link-default)))
1992                  notmuch-show-stash-mlarchive-link-alist))
1993            (notmuch-show-get-message-id t))))
1994
1995 (defun notmuch-show-stash-mlarchive-link-and-go (&optional mla)
1996   "Copy an ML Archive URI for the current message to the kill-ring and visit it.
1997
1998 This presumes that the message is available at the selected Mailing List Archive.
1999
2000 If optional argument MLA is non-nil, use the provided key instead of prompting
2001 the user (see `notmuch-show-stash-mlarchive-link-alist')."
2002   (interactive)
2003   (notmuch-show-stash-mlarchive-link mla)
2004   (browse-url (current-kill 0 t)))
2005
2006 ;; Commands typically bound to buttons.
2007
2008 (defun notmuch-show-part-button-default (&optional button)
2009   (interactive)
2010   (let ((button (or button (button-at (point)))))
2011     (if (button-get button 'overlay)
2012         (notmuch-show-toggle-part-invisibility button)
2013       (notmuch-show-part-button-internal button notmuch-show-part-button-default-action))))
2014
2015 (defun notmuch-show-part-button-save (&optional button)
2016   (interactive)
2017   (notmuch-show-part-button-internal button #'notmuch-show-save-part))
2018
2019 (defun notmuch-show-part-button-view (&optional button)
2020   (interactive)
2021   (notmuch-show-part-button-internal button #'notmuch-show-view-part))
2022
2023 (defun notmuch-show-part-button-interactively-view (&optional button)
2024   (interactive)
2025   (notmuch-show-part-button-internal button #'notmuch-show-interactively-view-part))
2026
2027 (defun notmuch-show-part-button-pipe (&optional button)
2028   (interactive)
2029   (notmuch-show-part-button-internal button #'notmuch-show-pipe-part))
2030
2031 (defun notmuch-show-part-button-internal (button handler)
2032   (let ((button (or button (button-at (point)))))
2033     (if button
2034         (let ((nth (button-get button :notmuch-part)))
2035           (if nth
2036               (funcall handler (notmuch-show-get-message-id) nth
2037                        (button-get button :notmuch-filename)
2038                        (button-get button :notmuch-content-type)))))))
2039
2040 ;;
2041
2042 (provide 'notmuch-show)