git.cworth.org Git - apitrace/blob - glws_cocoa.mm

   1 /**************************************************************************
   2  *
   3  * Copyright 2011 VMware, Inc.
   4  * All Rights Reserved.
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining a copy
   7  * of this software and associated documentation files (the "Software"), to deal
   8  * in the Software without restriction, including without limitation the rights
   9  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  10  * copies of the Software, and to permit persons to whom the Software is
  11  * furnished to do so, subject to the following conditions:
  12  *
  13  * The above copyright notice and this permission notice shall be included in
  14  * all copies or substantial portions of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  19  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  21  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
  22  * THE SOFTWARE.
  23  *
  24  **************************************************************************/
  25
  26
  27 /**
  28  * Minimal Cocoa integration.
  29  *
  30  * See also:
  31  * - http://developer.apple.com/library/mac/#samplecode/CocoaGL/Introduction/Intro.html
  32  * - http://developer.apple.com/library/mac/#samplecode/Cocoa_With_Carbon_or_CPP/Introduction/Intro.html
  33  * - http://developer.apple.com/library/mac/#samplecode/glut/Introduction/Intro.html
  34  * - http://developer.apple.com/library/mac/#samplecode/GLEssentials/Introduction/Intro.html
  35  * - http://www.glfw.org/
  36  */
  37
  38
  39 #include <stdlib.h>
  40 #include <iostream>
  41
  42 #include <Cocoa/Cocoa.h>
  43
  44 #include "glws.hpp"
  45
  46
  47 namespace glws {
  48
  49
  50 NSAutoreleasePool *autoreleasePool = nil;
  51
  52
  53 class CocoaVisual : public Visual
  54 {
  55 public:
  56     NSOpenGLPixelFormat *pixelFormat;
  57
  58     CocoaVisual(NSOpenGLPixelFormat *pf) :
  59         pixelFormat(pf)
  60     {}
  61
  62     ~CocoaVisual() {
  63         [pixelFormat release];
  64     }
  65 };
  66
  67
  68 class CocoaDrawable : public Drawable
  69 {
  70 public:
  71     NSWindow *window;
  72     NSOpenGLContext *currentContext;
  73
  74     CocoaDrawable(const Visual *vis, int w, int h) :
  75         Drawable(vis, w, h),
  76         currentContext(nil)
  77     {
  78         NSOpenGLPixelFormat *pixelFormat = static_cast<const CocoaVisual *>(visual)->pixelFormat;
  79
  80         NSRect winRect = NSMakeRect(0, 0, w, h);
  81
  82         window = [[NSWindow alloc]
  83                          initWithContentRect:winRect
  84                                    styleMask:NSTitledWindowMask |
  85                                              NSClosableWindowMask |
  86                                              NSMiniaturizableWindowMask
  87                                      backing:NSBackingStoreRetained
  88                                        defer:NO];
  89         assert(window != nil);
  90
  91         NSOpenGLView *view = [[NSOpenGLView alloc]
  92                               initWithFrame:winRect
  93                                 pixelFormat:pixelFormat];
  94         assert(view != nil);
  95
  96         [window setContentView:view];
  97         [window setTitle:@"glretrace"];
  98
  99     }
 100
 101     ~CocoaDrawable() {
 102         [window release];
 103     }
 104
 105     void
 106     resize(int w, int h) {
 107         if (w == width && h == height) {
 108             return;
 109         }
 110
 111         [window setContentSize:NSMakeSize(w, h)];
 112
 113         if (currentContext != nil) {
 114             [currentContext update];
 115             [window makeKeyAndOrderFront:nil];
 116             [currentContext setView:[window contentView]];
 117             [currentContext makeCurrentContext];
 118         }
 119
 120         Drawable::resize(w, h);
 121     }
 122
 123     void show(void) {
 124         if (visible) {
 125             return;
 126         }
 127
 128         // TODO
 129
 130         Drawable::show();
 131     }
 132
 133     void swapBuffers(void) {
 134         if (currentContext != nil) {
 135             [currentContext flushBuffer];
 136         }
 137     }
 138 };
 139
 140
 141 class CocoaContext : public Context
 142 {
 143 public:
 144     NSOpenGLContext *context;
 145
 146     CocoaContext(const Visual *vis, Profile prof, NSOpenGLContext *ctx) :
 147         Context(vis, prof),
 148         context(ctx)
 149     {}
 150
 151     ~CocoaContext() {
 152         [context release];
 153     }
 154 };
 155
 156
 157 void
 158 init(void) {
 159     [NSApplication sharedApplication];
 160
 161     autoreleasePool = [[NSAutoreleasePool alloc] init];
 162
 163     [NSApp finishLaunching];
 164 }
 165
 166
 167 void
 168 cleanup(void) {
 169     [autoreleasePool release];
 170 }
 171
 172
 173 Visual *
 174 createVisual(bool doubleBuffer, Profile profile) {
 175     NSOpenGLPixelFormatAttribute single_attribs[] = {
 176         NSOpenGLPFAAlphaSize, (NSOpenGLPixelFormatAttribute)1,
 177         NSOpenGLPFAColorSize, (NSOpenGLPixelFormatAttribute)24,
 178         NSOpenGLPFADepthSize, (NSOpenGLPixelFormatAttribute)1,
 179         NSOpenGLPFAStencilSize, (NSOpenGLPixelFormatAttribute)1,
 180         (NSOpenGLPixelFormatAttribute)0
 181     };
 182
 183     NSOpenGLPixelFormatAttribute double_attribs[] = {
 184         NSOpenGLPFAAlphaSize, (NSOpenGLPixelFormatAttribute)1,
 185         NSOpenGLPFAColorSize, (NSOpenGLPixelFormatAttribute)24,
 186         NSOpenGLPFADoubleBuffer,
 187         NSOpenGLPFADepthSize, (NSOpenGLPixelFormatAttribute)1,
 188         NSOpenGLPFAStencilSize, (NSOpenGLPixelFormatAttribute)1,
 189         (NSOpenGLPixelFormatAttribute)0
 190     };
 191
 192     if (profile != PROFILE_COMPAT) {
 193         return nil;
 194     }
 195
 196     NSOpenGLPixelFormatAttribute *attribs = doubleBuffer ? double_attribs : single_attribs;
 197
 198     NSOpenGLPixelFormat *pixelFormat = [[NSOpenGLPixelFormat alloc]
 199                                      initWithAttributes:attribs];
 200
 201     return new CocoaVisual(pixelFormat);
 202 }
 203
 204 Drawable *
 205 createDrawable(const Visual *visual, int width, int height)
 206 {
 207     return new CocoaDrawable(visual, width, height);
 208 }
 209
 210 Context *
 211 createContext(const Visual *visual, Context *shareContext, Profile profile)
 212 {
 213     NSOpenGLPixelFormat *pixelFormat = static_cast<const CocoaVisual *>(visual)->pixelFormat;
 214     NSOpenGLContext *share_context = nil;
 215     NSOpenGLContext *context;
 216
 217     if (profile != PROFILE_COMPAT) {
 218         return nil;
 219     }
 220
 221     if (shareContext) {
 222         share_context = static_cast<CocoaContext*>(shareContext)->context;
 223     }
 224
 225     context = [[NSOpenGLContext alloc]
 226                initWithFormat:pixelFormat
 227                shareContext:share_context];
 228     assert(context != nil);
 229
 230     return new CocoaContext(visual, profile, context);
 231 }
 232
 233 bool
 234 makeCurrent(Drawable *drawable, Context *context)
 235 {
 236     if (!drawable || !context) {
 237         [NSOpenGLContext clearCurrentContext];
 238     } else {
 239         CocoaDrawable *cocoaDrawable = static_cast<CocoaDrawable *>(drawable);
 240         CocoaContext *cocoaContext = static_cast<CocoaContext *>(context);
 241
 242         [cocoaDrawable->window makeKeyAndOrderFront:nil];
 243         [cocoaContext->context setView:[cocoaDrawable->window contentView]];
 244         [cocoaContext->context makeCurrentContext];
 245
 246         cocoaDrawable->currentContext = cocoaContext->context;
 247     }
 248
 249     return TRUE;
 250 }
 251
 252 bool
 253 processEvents(void) {
 254    NSEvent* event;
 255
 256     do {
 257         event = [NSApp nextEventMatchingMask:NSAnyEventMask
 258                                    untilDate:[NSDate distantPast]
 259                                       inMode:NSDefaultRunLoopMode
 260                                      dequeue:YES];
 261         if (event)
 262             [NSApp sendEvent:event];
 263     } while (event);
 264
 265     return true;
 266 }
 267
 268
 269 } /* namespace glws */