+
+##############################################################################
+# Options
+
+# On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
+if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
+ set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
+endif ()
+
+# We use a cached string variable instead of the standard (boolean) OPTION
+# command so that we can default to auto-detecting optional depencies, while
+# still providing a mechanism to force/disable these optional dependencies, as
+# prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
+set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
+
+set (ENABLE_CLI true CACHE BOOL "Enable command Line interface.")
+
+set (ENABLE_EGL true CACHE BOOL "Enable EGL support.")
+
+
+##############################################################################
+# Find dependencies
+
+# Ensure __thread is support
+if (NOT MSVC)
+ include (CheckCXXSourceCompiles)
+ check_cxx_source_compiles("__thread int i; int main() { return 0; }" HAVE_COMPILER_TLS)
+ if (NOT HAVE_COMPILER_TLS)
+ if (APPLE)
+ message (FATAL_ERROR "C++ compiler does not support __thread keyword. Please install XCode 4.5 or higher.")
+ else (MINGW32)
+ message (FATAL_ERROR "C++ compiler does not support __thread keyword. Please use MinGW g++ version 4.4 or higher")
+ else ()
+ message (FATAL_ERROR "C++ compiler does not support __thread keyword.")
+ endif ()
+ endif ()
+endif ()
+
+set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
+
+set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
+
+if (ANDROID)
+ set (ENABLE_GUI false)
+else ()
+ macro (find_host_package)
+ find_package (${ARGN})
+ endmacro()
+endif ()
+
+find_host_package (PythonInterp REQUIRED)
+find_package (Threads)
+
+if (ENABLE_GUI)
+ if (NOT (ENABLE_GUI STREQUAL "AUTO"))
+ set (REQUIRE_GUI REQUIRED)
+ endif ()
+ find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
+endif ()
+
+if (WIN32)
+ find_package (DirectX)
+ set (ENABLE_EGL false)
+elseif (APPLE)
+ set (ENABLE_EGL false)
+else ()
+ find_package (X11)
+
+ if (X11_FOUND)
+ include_directories (${X11_INCLUDE_DIR})
+ add_definitions (-DHAVE_X11)
+ else ()
+ # Print a clear message when X11 is not found
+ include (FindPackageMessage)
+ find_package_message (X11 "Could not find X11" "")
+ endif ()
+endif ()
+
+
+##############################################################################
+# Set global build options
+
+include (CheckCXXCompilerFlag)
+
+if (WIN32)
+ # http://msdn.microsoft.com/en-us/library/aa383745.aspx
+ add_definitions (-D_WIN32_WINNT=0x0601 -DWINVER=0x0601)
+else (WIN32)
+ CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
+ if (CXX_COMPILER_FLAG_VISIBILITY)
+ add_definitions ("-fvisibility=hidden")
+ endif ()
+endif ()
+
+if (MSVC)
+ # C99 includes for msvc
+ include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
+
+ # Enable math constants defines
+ add_definitions (-D_USE_MATH_DEFINES)
+
+ # No min/max macros
+ add_definitions (-DNOMINMAX)
+
+ # Adjust warnings
+ add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
+ add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
+ add_definitions (-W4)
+ # XXX: it's safer to use ssize_t everywhere instead of disabling warning
+ add_definitions (-wd4018) # signed/unsigned mismatch
+ add_definitions (-wd4063) # not a valid value for switch of enum
+ add_definitions (-wd4100) # unreferenced formal parameter
+ add_definitions (-wd4127) # conditional expression is constant
+ add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
+ add_definitions (-wd4505) # unreferenced local function has been removed
+ add_definitions (-wd4512) # assignment operator could not be generated
+ add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
+
+ # Use static runtime
+ # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
+ foreach (flag_var
+ CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
+ CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
+ )
+ if (${flag_var} MATCHES "/MD")
+ string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
+ endif ()
+ endforeach (flag_var)
+else ()
+ # Adjust warnings
+ add_definitions (-Wall)
+ # XXX: it's safer to use ssize_t everywhere instead of disabling warning
+ add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
+
+ # Use GDB extensions if available
+ if (CMAKE_COMPILER_IS_GNUC)
+ set (CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -ggdb -O0")
+ set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -ggdb")
+ endif ()
+ if (CMAKE_COMPILER_IS_GNUCXX)
+ set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -ggdb -O0")
+ set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} -ggdb")
+ endif ()
+
+ # Be nice to Eclipse
+ add_definitions (-fmessage-length=0)
+endif ()
+
+if (MINGW)
+ # Avoid depending on MinGW runtime DLLs
+ check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
+ if (HAVE_STATIC_LIBGCC_FLAG)
+ set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
+ set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
+ set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
+ endif ()
+ check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
+ if (HAVE_STATIC_LIBSTDCXX_FLAG)
+ set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
+ set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
+ set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
+ endif ()
+endif ()
+
+
+# Put all executables into the same top level build directory, regardless of
+# which subdirectory they are declared
+set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
+
+
+##############################################################################
+# Bundled dependencies
+#
+# We always use the bundled zlib, libpng, and snappy sources:
+# - on Windows to make it easy to deploy the wrappers DLLs
+# - on unices to prevent symbol collisions when tracing applications that link
+# against other versions of these libraries
+
+set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
+set (ZLIB_LIBRARIES z_bundled)
+add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
+
+include_directories (${ZLIB_INCLUDE_DIRS})
+
+set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
+set (SNAPPY_LIBRARIES snappy_bundled)
+add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
+
+include_directories (${SNAPPY_INCLUDE_DIRS})
+
+set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
+set (PNG_DEFINITIONS "")
+set (PNG_LIBRARIES png_bundled)
+
+add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
+include_directories (${PNG_INCLUDE_DIR})
+add_definitions (${PNG_DEFINITIONS})