git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3
   4 # Use clang on MacOSX. gcc doesn't support __thread key, and Apple has
   5 # abandoned it for clang.  This must be done before the project is defined.
   6 # But DONT force clang if we are cross-compiling to Android.
   7 if (APPLE AND NOT ANDROID_NDK)
   8     set (CMAKE_C_COMPILER "clang")
   9     set (CMAKE_CXX_COMPILER "clang++")
  10 endif ()
  11
  12
  13 project (apitrace)
  14
  15
  16 ##############################################################################
  17 # Options
  18
  19 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  20 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  21     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  22 endif ()
  23
  24 # We use a cached string variable instead of the standard (boolean) OPTION
  25 # command so that we can default to auto-detecting optional depencies, while
  26 # still providing a mechanism to force/disable these optional dependencies, as
  27 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  28 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  29
  30 set (ENABLE_CLI true CACHE BOOL "Enable command Line interface.")
  31
  32 set (ENABLE_EGL true CACHE BOOL "Enable EGL support.")
  33
  34
  35 ##############################################################################
  36 # Find dependencies
  37
  38 # Check for compiler TLS support.  We don't use compiler TLS support on Windows
  39 # because, even if the compiler supports it, Windows XP does not support TLS on
  40 # DLLs.
  41 if (NOT WIN32)
  42     include (CheckCXXSourceCompiles)
  43     check_cxx_source_compiles("__thread int i; int main() { return 0; }" HAVE_COMPILER_TLS)
  44     if (HAVE_COMPILER_TLS)
  45         add_definitions (-DHAVE_COMPILER_TLS=__thread)
  46     else ()
  47         message (WARNING "C++ compiler does not support __thread keyword.")
  48     endif ()
  49 endif ()
  50
  51 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  52
  53 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  54
  55 if (ANDROID)
  56     set (ENABLE_GUI false)
  57 else ()
  58     macro (find_host_package)
  59         find_package (${ARGN})
  60     endmacro()
  61 endif ()
  62
  63 find_host_package (PythonInterp REQUIRED)
  64 find_package (Threads)
  65
  66 if (ENABLE_GUI)
  67     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  68         set (REQUIRE_GUI REQUIRED)
  69     endif ()
  70     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  71 endif ()
  72
  73 if (WIN32)
  74     find_package (DirectX)
  75     set (ENABLE_EGL false)
  76 elseif (APPLE)
  77     set (ENABLE_EGL false)
  78 else ()
  79     find_package (X11)
  80
  81     if (X11_FOUND)
  82         include_directories (${X11_INCLUDE_DIR})
  83         add_definitions (-DHAVE_X11)
  84     else ()
  85         # Print a clear message when X11 is not found
  86         include (FindPackageMessage)
  87         find_package_message (X11 "Could not find X11" "")
  88     endif ()
  89 endif ()
  90
  91
  92 ##############################################################################
  93 # Set global build options
  94
  95 include (CheckCXXCompilerFlag)
  96
  97 if (WIN32)
  98     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  99     add_definitions (-D_WIN32_WINNT=0x0601 -DWINVER=0x0601)
 100 else (WIN32)
 101     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
 102     if (CXX_COMPILER_FLAG_VISIBILITY)
 103         add_definitions ("-fvisibility=hidden")
 104     endif ()
 105 endif ()
 106
 107 if (MSVC)
 108     # C99 includes for MSVC
 109     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msinttypes)
 110
 111     # No RTTI required
 112     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /GR-")
 113
 114     # Enable math constants defines
 115     add_definitions (-D_USE_MATH_DEFINES)
 116
 117     # No min/max macros
 118     add_definitions (-DNOMINMAX)
 119
 120     # Adjust warnings
 121     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 122     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 123     add_definitions (-W4)
 124     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 125     add_definitions (-wd4018) # signed/unsigned mismatch
 126     add_definitions (-wd4063) # not a valid value for switch of enum
 127     add_definitions (-wd4100) # unreferenced formal parameter
 128     add_definitions (-wd4127) # conditional expression is constant
 129     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 130     add_definitions (-wd4505) # unreferenced local function has been removed
 131     add_definitions (-wd4512) # assignment operator could not be generated
 132     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 133
 134     # Use static runtime
 135     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 136     foreach (flag_var
 137         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 138         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 139     )
 140         if (${flag_var} MATCHES "/MD")
 141             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 142         endif ()
 143     endforeach (flag_var)
 144 else ()
 145     # Adjust warnings
 146     add_definitions (-Wall)
 147     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 148     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 149
 150     # No RTTI required
 151     #set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-rtti")
 152
 153     # Use GDB extensions if available
 154     if (CMAKE_COMPILER_IS_GNUC)
 155         set (CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -ggdb -O0")
 156         set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -ggdb")
 157     endif ()
 158     if (CMAKE_COMPILER_IS_GNUCXX)
 159         set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -ggdb -O0")
 160         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} -ggdb")
 161     endif ()
 162
 163     # Be nice to Eclipse
 164     add_definitions (-fmessage-length=0)
 165 endif ()
 166
 167 if (MINGW)
 168     # Avoid depending on MinGW runtime DLLs
 169     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 170     if (HAVE_STATIC_LIBGCC_FLAG)
 171         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 172         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 173         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 174     endif ()
 175     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 176     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 177         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 178         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 179         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 180     endif ()
 181 endif ()
 182
 183 if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 184     # For RTLD_DEFAULT and RTLD_NEXT
 185     add_definitions (-D_GNU_SOURCE)
 186 endif ()
 187
 188
 189 # Put all executables into the same top level build directory, regardless of
 190 # which subdirectory they are declared
 191 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 192
 193
 194 ##############################################################################
 195 # Installation directories
 196
 197 if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 198     # Debian multiarch support
 199     execute_process(COMMAND dpkg-architecture -qDEB_HOST_MULTIARCH
 200         OUTPUT_VARIABLE ARCH_SUBDIR
 201         ERROR_QUIET
 202         OUTPUT_STRIP_TRAILING_WHITESPACE
 203     )
 204     CHECK_INCLUDE_FILES(proc/readproc.h READPROC_H_FOUND)
 205     if (READPROC_H_FOUND)
 206         add_definitions (-DHAVE_READPROC_H)
 207         find_library (proc_LIBRARY NAMES proc procps)
 208     endif ()
 209 endif()
 210
 211 if (WIN32 OR APPLE)
 212     # On Windows/MacOSX, applications are usually installed on a directory of
 213     # their own
 214     set (DOC_INSTALL_DIR doc)
 215     set (LIB_INSTALL_DIR lib)
 216     set (LIB_ARCH_INSTALL_DIR lib)
 217 else ()
 218     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 219     set (LIB_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 220     if (ARCH_SUBDIR)
 221         set (LIB_ARCH_INSTALL_DIR lib/${ARCH_SUBDIR}/${CMAKE_PROJECT_NAME})
 222     else ()
 223         set (LIB_ARCH_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 224     endif ()
 225 endif ()
 226
 227 set (SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 228 set (WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 229
 230
 231 ##############################################################################
 232 # Bundled dependencies
 233 #
 234 # We always use the bundled zlib, libpng, and snappy sources:
 235 # - on Windows to make it easy to deploy the wrappers DLLs
 236 # - on unices to prevent symbol collisions when tracing applications that link
 237 # against other versions of these libraries
 238
 239 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 240 set (ZLIB_LIBRARIES z_bundled)
 241 add_subdirectory (thirdparty/zlib)
 242
 243 include_directories (${ZLIB_INCLUDE_DIRS})
 244
 245 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 246 set (SNAPPY_LIBRARIES snappy_bundled)
 247 add_subdirectory (thirdparty/snappy)
 248
 249 include_directories (${SNAPPY_INCLUDE_DIRS})
 250
 251 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 252 set (PNG_DEFINITIONS "")
 253 set (PNG_LIBRARIES png_bundled)
 254
 255 add_subdirectory (thirdparty/libpng)
 256
 257 if (MSVC)
 258     add_subdirectory (thirdparty/getopt)
 259     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/getopt)
 260     set (GETOPT_LIBRARIES getopt_bundled)
 261 endif ()
 262
 263 if (WIN32)
 264     add_subdirectory (thirdparty/less)
 265     add_subdirectory (thirdparty/directxtex)
 266 endif ()
 267
 268 if (CMAKE_EXECUTABLE_FORMAT STREQUAL "ELF")
 269     add_subdirectory (thirdparty/libbacktrace)
 270     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libbacktrace)
 271     set (LIBBACKTRACE_LIBRARIES backtrace)
 272 endif ()
 273
 274 # Always use bundled QJSon.
 275 # - The packaged versions QJson are very old, and do not support NaN/Infinity.
 276 # - To make it easier to build the GUI on Windows and MacOSX, as there are no
 277 # binaries at all.
 278 if (QT4_FOUND)
 279     add_definitions (-DQJSON_EXPORT=)
 280     add_subdirectory (thirdparty/qjson)
 281     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 282     set (QJSON_LIBRARY_DIRS)
 283     set (QJSON_LIBRARIES qjson_bundled)
 284     set (QJSON_FOUND TRUE)
 285 endif ()
 286
 287 # We use bundled headers for all Khronos APIs, to guarantee support for both
 288 # OpenGL and OpenGL ES at build time, because the OpenGL and OpenGL ES 1 APIs
 289 # are so intertwined that conditional compilation extremely difficult. This
 290 # also avoids missing/inconsistent declarations in system headers.
 291 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khronos)
 292
 293
 294 ##############################################################################
 295 # Common libraries / utilities
 296
 297 include_directories (
 298     ${CMAKE_CURRENT_BINARY_DIR}
 299     ${CMAKE_CURRENT_SOURCE_DIR}
 300     ${CMAKE_CURRENT_SOURCE_DIR}/common
 301 )
 302
 303 if (WIN32)
 304     set (os os_win32.cpp)
 305     set (glws_os glws_wgl.cpp)
 306 else ()
 307     set (os os_posix.cpp)
 308     if (APPLE)
 309         set (glws_os glws_cocoa.mm)
 310     else ()
 311         set (glws_os glws_glx.cpp)
 312     endif ()
 313 endif ()
 314
 315 add_library (common STATIC
 316     common/trace_callset.cpp
 317     common/trace_dump.cpp
 318     common/trace_fast_callset.cpp
 319     common/trace_file.cpp
 320     common/trace_file_read.cpp
 321     common/trace_file_write.cpp
 322     common/trace_file_zlib.cpp
 323     common/trace_file_snappy.cpp
 324     common/trace_model.cpp
 325     common/trace_parser.cpp
 326     common/trace_parser_flags.cpp
 327     common/trace_writer.cpp
 328     common/trace_writer_local.cpp
 329     common/trace_writer_model.cpp
 330     common/trace_loader.cpp
 331     common/trace_profiler.cpp
 332     common/trace_option.cpp
 333     common/${os}
 334     common/trace_backtrace.cpp
 335 )
 336
 337 set_target_properties (common PROPERTIES
 338     # Ensure it can be statically linked in shared libraries
 339     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 340 )
 341
 342 if (ANDROID)
 343     target_link_libraries (common
 344         log
 345     )
 346 endif ()
 347
 348
 349 ##############################################################################
 350 # Sub-directories
 351
 352 add_subdirectory (dispatch)
 353 add_subdirectory (helpers)
 354 add_subdirectory (wrappers)
 355 add_subdirectory (image)
 356 add_subdirectory (retrace)
 357
 358
 359 ##############################################################################
 360 # CLI
 361
 362 if (ENABLE_CLI)
 363     if (WIN32)
 364         add_subdirectory (inject)
 365     endif ()
 366     add_subdirectory (cli)
 367 endif ()
 368
 369 ##############################################################################
 370 # Scripts (to support the CLI)
 371
 372 install (
 373     PROGRAMS
 374         scripts/highlight.py
 375         scripts/jsondiff.py
 376         scripts/profileshader.py
 377         scripts/retracediff.py
 378         scripts/snapdiff.py
 379         scripts/tracecheck.py
 380         scripts/tracediff.py
 381         scripts/unpickle.py
 382     DESTINATION ${SCRIPTS_INSTALL_DIR}
 383 )
 384 if (WIN32)
 385     install (
 386         PROGRAMS scripts/convert.py
 387         DESTINATION ${SCRIPTS_INSTALL_DIR}
 388     )
 389 endif ()
 390
 391 ##############################################################################
 392 # GUI
 393
 394 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 395     add_subdirectory(gui)
 396 endif ()
 397
 398
 399 ##############################################################################
 400 # Packaging
 401
 402 install (
 403     FILES
 404         BUGS.markdown
 405         NEWS.markdown
 406         README.markdown
 407     DESTINATION ${DOC_INSTALL_DIR}
 408 )
 409 install (
 410     FILES LICENSE
 411     DESTINATION ${DOC_INSTALL_DIR}
 412     RENAME LICENSE.txt
 413 )
 414 if (MSVC)
 415     install (
 416         FILES thirdparty/msinttypes/LICENSE
 417         DESTINATION ${DOC_INSTALL_DIR}
 418         RENAME LICENSE-msinttypes.txt
 419     )
 420 endif ()
 421
 422 set (CPACK_PACKAGE_VERSION_MAJOR "4")
 423 set (CPACK_PACKAGE_VERSION_MINOR "0")
 424
 425 # Use current date in YYYYMMDD format as patch number
 426 execute_process (
 427     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 428     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 429 )
 430
 431 # cpack mistakenly detects Mingw-w64 as win32
 432 if (MINGW)
 433     if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 434         set (CPACK_SYSTEM_NAME win64)
 435     endif ()
 436 endif ()
 437
 438 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 439 if (WIN32)
 440     set (CPACK_GENERATOR "ZIP")
 441 elseif (APPLE)
 442     set (CPACK_GENERATOR "DragNDrop")
 443 else ()
 444     set (CPACK_GENERATOR "TBZ2")
 445 endif ()
 446
 447 include(CPack)