git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Find dependencies
   8
   9 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  10
  11 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  12
  13 find_package (PythonInterp REQUIRED)
  14 find_package (OpenGL REQUIRED)
  15 find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit)
  16 find_package (QJSON)
  17
  18 if (NOT WIN32)
  19     find_package (X11 REQUIRED)
  20
  21     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  22     # from the standard OpenGL framework which provides support for native Mac OS X
  23     # applications.
  24     if (APPLE)
  25         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  26         if (NOT X11_GL_INCLUDE_PATH)
  27             message (SEND_ERROR "Could not find GL/glx.h")
  28         endif (NOT X11_GL_INCLUDE_PATH)
  29         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  30
  31         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  32         if (NOT X11_GL_LIB)
  33             message (SEND_ERROR "Could not find libGL.dylib")
  34         endif (NOT X11_GL_LIB)
  35     else ()
  36         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  37         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  38     endif ()
  39
  40     include_directories (${X11_INCLUDE_DIR})
  41 endif (NOT WIN32)
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 endif (WIN32)
  46
  47
  48 ##############################################################################
  49 # Set global build options
  50
  51 include (CheckCXXCompilerFlag)
  52
  53 if (WIN32)
  54     # MSVC & MinGW only define & use APIENTRY
  55     add_definitions (-DGLAPIENTRY=__stdcall)
  56
  57     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  58     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  59 else (WIN32)
  60     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  61     if (CXX_COMPILER_FLAG_VISIBILITY)
  62         add_definitions ("-fvisibility=hidden")
  63     endif (CXX_COMPILER_FLAG_VISIBILITY)
  64 endif (WIN32)
  65
  66 if (MSVC)
  67     # C99 includes for msvc
  68     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  69
  70     # Enable math constants defines
  71     add_definitions (-D_USE_MATH_DEFINES)
  72
  73     # No min/max macros
  74     add_definitions (-DNOMINMAX)
  75
  76     # Adjust warnings
  77     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  78     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  79     add_definitions (-W4)
  80     add_definitions (-wd4063) # not a valid value for switch of enum
  81     add_definitions (-wd4127) # conditional expression is constant
  82     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  83     add_definitions (-wd4505) # unreferenced local function has been removed
  84     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  85     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  86     add_definitions (-wd4018) # signed/unsigned mismatch
  87
  88     # Use static runtime
  89     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  90     foreach (flag_var
  91         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  92         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  93     )
  94         if (${flag_var} MATCHES "/MD")
  95             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  96         endif (${flag_var} MATCHES "/MD")
  97     endforeach (flag_var)
  98 else ()
  99     # Adjust warnings
 100     add_definitions (-Wall)
 101     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 102     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 103 endif ()
 104
 105
 106 # Put all executables into the same top level build directory, regardless of
 107 # which subdirectory they are declared
 108 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 109
 110
 111 ##############################################################################
 112 # Bundled dependencies
 113 #
 114 # We always use the bundled zlib and libpng sources:
 115 # - on Windows to make it easy to deploy the wrappers DLLs
 116 # - on unices to prevent symbol collisions when tracing applications that link
 117 # against other versions of these libraries
 118
 119 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 120 set (ZLIB_LIBRARIES z_bundled)
 121 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 122
 123 include_directories (${ZLIB_INCLUDE_DIRS})
 124 link_libraries (${ZLIB_LIBRARIES})
 125
 126 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 127 set (PNG_DEFINITIONS "")
 128 set (PNG_LIBRARIES png_bundled)
 129
 130 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 131 include_directories (${PNG_INCLUDE_DIR})
 132 add_definitions (${PNG_DEFINITIONS})
 133 link_libraries (${PNG_LIBRARIES})
 134
 135 # For glext headers
 136 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 137
 138
 139 ##############################################################################
 140 # Common libraries / utilities
 141
 142 add_custom_command (
 143     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 144     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 145     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 146 )
 147
 148 if (WIN32)
 149     set (os os_win32.cpp)
 150     set (glws glws_wgl.cpp)
 151 else (WIN32)
 152     set (os os_posix.cpp)
 153     set (glws glws_glx.cpp)
 154 endif (WIN32)
 155
 156 add_library (trace trace_model.cpp trace_parser.cpp trace_writer.cpp trace_model_writer.cpp ${os})
 157
 158 add_executable (tracedump tracedump.cpp)
 159 target_link_libraries (tracedump trace)
 160 install (TARGETS tracedump RUNTIME DESTINATION bin)
 161
 162
 163 ##############################################################################
 164 # API tracers
 165
 166 if (WIN32)
 167     # ddraw.dll
 168     if (DirectX_D3D_INCLUDE_DIR)
 169         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 170         add_custom_command (
 171             OUTPUT ddraw.cpp
 172             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 173             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 174         )
 175         add_library (ddraw MODULE ddraw.def ddraw.cpp trace_writer.cpp os_win32.cpp)
 176         set_target_properties (ddraw
 177             PROPERTIES PREFIX ""
 178             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 179             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 180         )
 181         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 182     endif (DirectX_D3D_INCLUDE_DIR)
 183
 184     # d3d8.dll
 185     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 186         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 187         add_custom_command (
 188             OUTPUT d3d8.cpp
 189             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 190             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 191         )
 192         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 193         set_target_properties (d3d8
 194             PROPERTIES PREFIX ""
 195             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 196             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 197         )
 198         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 199     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 200
 201     # d3d9.dll
 202     if (DirectX_D3DX9_INCLUDE_DIR)
 203         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 204         add_custom_command (
 205             OUTPUT d3d9.cpp
 206             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 207             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 208         )
 209         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 210         set_target_properties (d3d9
 211             PROPERTIES PREFIX ""
 212             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 213             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 214         )
 215         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 216     endif (DirectX_D3DX9_INCLUDE_DIR)
 217
 218     # d3d10.dll
 219     #if (DirectX_D3D10_INCLUDE_DIR)
 220     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 221     #    add_custom_command (
 222     #        OUTPUT d3d10.cpp
 223     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 224     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 225     #    )
 226     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp trace_writer.cpp os_win32.cpp)
 227     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 228     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 229     #endif (DirectX_D3D10_INCLUDE_DIR)
 230
 231     # opengl32.dll
 232     add_custom_command (
 233         OUTPUT wgltrace.cpp
 234         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 235         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 236     )
 237     add_library (wgltrace MODULE opengl32.def wgltrace.cpp trace_writer.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 238     set_target_properties (wgltrace PROPERTIES
 239         PREFIX ""
 240         OUTPUT_NAME opengl32
 241         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 242         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 243     )
 244     if (MINGW)
 245         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 246     endif (MINGW)
 247     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 248
 249 elseif (APPLE)
 250     # OpenGL framework
 251     add_custom_command (
 252         OUTPUT cgltrace.cpp
 253         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 254         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 255     )
 256
 257     add_library (cgltrace SHARED cgltrace.cpp trace_writer.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 258
 259     set_target_properties (cgltrace PROPERTIES
 260         # OpenGL framework name
 261         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 262         # Specificy the version and reexport GLU symbols
 263         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 264         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 265         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 266     )
 267
 268     target_link_libraries (cgltrace dl)
 269
 270     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 271 else ()
 272     # libGL.so
 273     add_custom_command (
 274         OUTPUT glxtrace.cpp
 275         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 276         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 277     )
 278
 279     add_library (glxtrace SHARED
 280         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 281         glxtrace.cpp
 282         glsnapshot.cpp
 283         trace_writer.cpp
 284         image.cpp
 285         os_posix.cpp
 286     )
 287
 288     set_target_properties (glxtrace PROPERTIES
 289         # avoid the default "lib" prefix
 290         PREFIX ""
 291     )
 292
 293     # Prevent symbol relocations internal to our wrapper library to be
 294     # overwritten by the application.
 295     set_target_properties (glxtrace PROPERTIES
 296         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 297     )
 298
 299     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 300
 301     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 302 endif ()
 303
 304
 305 ##############################################################################
 306 # API retracers
 307
 308 add_custom_command (
 309     OUTPUT glretrace_gl.cpp
 310     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 311     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 312 )
 313
 314 add_custom_command (
 315     OUTPUT glstate_params.cpp
 316     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 317     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 318 )
 319
 320 include_directories (
 321     ${CMAKE_CURRENT_BINARY_DIR}
 322     ${OPENGL_INCLUDE_PATH}
 323 )
 324
 325 add_executable (glretrace
 326     glretrace_gl.cpp
 327     glretrace_cgl.cpp
 328     glretrace_glx.cpp
 329     glretrace_wgl.cpp
 330     glretrace_main.cpp
 331     glstate.cpp
 332     glstate_params.cpp
 333     retrace.cpp
 334     ${glws}
 335     image.cpp
 336     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 337 )
 338
 339 set_property (
 340     TARGET glretrace
 341     APPEND
 342     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 343 )
 344
 345 target_link_libraries (glretrace
 346     trace
 347 )
 348
 349 if (WIN32)
 350     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 351 elseif (APPLE)
 352     # XXX: We use GLX on MacOSX, which is in a separate library.
 353     target_link_libraries (glretrace
 354         ${X11_GL_LIB}
 355         ${X11_X11_LIB}
 356         "-framework ApplicationServices" # CGS*
 357         ${OPENGL_gl_LIBRARY} # CGL*
 358     )
 359 else ()
 360     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 361 endif ()
 362
 363 install (TARGETS glretrace RUNTIME DESTINATION bin)
 364
 365
 366 ##############################################################################
 367 # GUI
 368
 369 if (QT4_FOUND AND QJSON_FOUND)
 370     add_subdirectory(gui)
 371 endif (QT4_FOUND AND QJSON_FOUND)
 372
 373
 374 ##############################################################################
 375 # Packaging
 376
 377 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 378
 379 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 380 set (CPACK_PACKAGE_VERSION_MINOR "0")
 381
 382 # Use current date in YYYYMMDD format as patch number
 383 execute_process (
 384     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 385     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 386 )
 387
 388 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 389 if (WIN32)
 390     set (CPACK_GENERATOR "ZIP")
 391 elseif (APPLE)
 392     set (CPACK_GENERATOR "DragNDrop")
 393 else ()
 394     set (CPACK_GENERATOR "TBZ2")
 395 endif ()
 396
 397 include(CPack)