git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 elseif (APPLE)
  46 else ()
  47     find_package (X11 REQUIRED)
  48
  49     set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  50     set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  51
  52     include_directories (${X11_INCLUDE_DIR})
  53
  54     if (ENABLE_EGL)
  55         if (NOT ENABLE_EGL STREQUAL "AUTO")
  56             set (REQUIRE_EGL REQUIRED)
  57         endif ()
  58         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  59         if (EGL_FOUND)
  60             include_directories (${EGL_INCLUDE_DIR})
  61             add_definitions (-DHAVE_EGL)
  62         endif ()
  63     else ()
  64         set (EGL_FOUND 0)
  65     endif ()
  66 endif ()
  67
  68
  69 ##############################################################################
  70 # Set global build options
  71
  72 include (CheckCXXCompilerFlag)
  73
  74 if (WIN32)
  75     # MSVC & MinGW only define & use APIENTRY
  76     add_definitions (-DGLAPIENTRY=__stdcall)
  77
  78     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  79     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  80 else (WIN32)
  81     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  82     if (CXX_COMPILER_FLAG_VISIBILITY)
  83         add_definitions ("-fvisibility=hidden")
  84     endif (CXX_COMPILER_FLAG_VISIBILITY)
  85 endif (WIN32)
  86
  87 if (MSVC)
  88     # C99 includes for msvc
  89     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  90
  91     # Enable math constants defines
  92     add_definitions (-D_USE_MATH_DEFINES)
  93
  94     # No min/max macros
  95     add_definitions (-DNOMINMAX)
  96
  97     # Adjust warnings
  98     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  99     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 100     add_definitions (-W4)
 101     add_definitions (-wd4063) # not a valid value for switch of enum
 102     add_definitions (-wd4127) # conditional expression is constant
 103     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 104     add_definitions (-wd4505) # unreferenced local function has been removed
 105     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 106     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 107     add_definitions (-wd4018) # signed/unsigned mismatch
 108
 109     # Use static runtime
 110     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 111     foreach (flag_var
 112         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 113         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 114     )
 115         if (${flag_var} MATCHES "/MD")
 116             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 117         endif (${flag_var} MATCHES "/MD")
 118     endforeach (flag_var)
 119 else ()
 120     # Adjust warnings
 121     add_definitions (-Wall)
 122     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 123     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 124 endif ()
 125
 126 if (MINGW)
 127     # Avoid depending on MinGW runtime DLLs
 128     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 129     if (HAVE_STATIC_LIBGCC_FLAG)
 130         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 131         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 132         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 133     endif ()
 134     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 135     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 136         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 137         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 138         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 139     endif ()
 140 endif ()
 141
 142
 143 # Put all executables into the same top level build directory, regardless of
 144 # which subdirectory they are declared
 145 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 146
 147
 148 ##############################################################################
 149 # Bundled dependencies
 150 #
 151 # We always use the bundled zlib, libpng, and snappy sources:
 152 # - on Windows to make it easy to deploy the wrappers DLLs
 153 # - on unices to prevent symbol collisions when tracing applications that link
 154 # against other versions of these libraries
 155
 156 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 157 set (ZLIB_LIBRARIES z_bundled)
 158 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 159
 160 include_directories (${ZLIB_INCLUDE_DIRS})
 161 link_libraries (${ZLIB_LIBRARIES})
 162
 163 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 164 set (SNAPPY_LIBRARIES snappy_bundled)
 165 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 166
 167 include_directories (${SNAPPY_INCLUDE_DIRS})
 168 link_libraries (${SNAPPY_LIBRARIES})
 169
 170 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 171 set (PNG_DEFINITIONS "")
 172 set (PNG_LIBRARIES png_bundled)
 173
 174 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 175 include_directories (${PNG_INCLUDE_DIR})
 176 add_definitions (${PNG_DEFINITIONS})
 177 link_libraries (${PNG_LIBRARIES})
 178
 179 # The Qt website provides binaries for Windows and MacOSX, and they are
 180 # automatically found by cmake without any manual intervention.  The situation
 181 # for QJSON is substantially different: there are no binaries for QJSON
 182 # available, and there is no standard installation directory that is detected
 183 # by cmake.
 184 #
 185 # By bundling the QJSON source, we make it much more easier to build the GUI on
 186 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 187 # AUTO.
 188 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 189     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 190     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 191     set (QJSON_LIBRARY_DIRS)
 192     set (QJSON_LIBRARIES qjson_bundled)
 193     set (QJSON_FOUND TRUE)
 194 endif ()
 195
 196 # For glext headers
 197 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 198
 199 # For EGL headers
 200 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 201
 202 ##############################################################################
 203 # Installation directories
 204
 205 if (WIN32 OR APPLE)
 206     # On Windows/MacOSX, applications are usually installed on a directory of
 207     # their own
 208     set (DOC_INSTALL_DIR doc)
 209 else ()
 210     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 211 endif ()
 212
 213 set (LIB_INSTALL_DIR lib/apitrace)
 214
 215 if (APPLE)
 216     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 217     # directories
 218     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 219 else ()
 220     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 221 endif ()
 222
 223 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 224 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 225
 226 # Expose the binary/install directories to source
 227 #
 228 # TODO: Use the same directory layout, for both build and install directories,
 229 # so that binaries can find each other using just relative paths.
 230 #
 231 add_definitions(
 232     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 233     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 234     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 235 )
 236
 237
 238 ##############################################################################
 239 # Common libraries / utilities
 240
 241 include_directories (
 242     ${CMAKE_CURRENT_SOURCE_DIR}
 243     ${CMAKE_CURRENT_SOURCE_DIR}/common
 244 )
 245
 246 add_custom_command (
 247     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 248     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 249     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 250 )
 251
 252 if (WIN32)
 253     set (os os_win32.cpp)
 254     set (glws_os glws_wgl.cpp)
 255 else ()
 256     set (os os_posix.cpp)
 257     if (APPLE)
 258         set (glws_os glws_cocoa.mm)
 259     else ()
 260         set (glws_os glws_glx.cpp)
 261     endif ()
 262 endif ()
 263
 264 add_library (common STATIC
 265     common/trace_file.cpp
 266     common/trace_file_read.cpp
 267     common/trace_file_write.cpp
 268     common/trace_file_zlib.cpp
 269     common/trace_file_snappy.cpp
 270     common/trace_model.cpp
 271     common/trace_parser.cpp
 272     common/trace_parser_flags.cpp
 273     common/trace_writer.cpp
 274     common/trace_writer_local.cpp
 275     common/trace_writer_model.cpp
 276     common/trace_loader.cpp
 277     common/trace_resource.cpp
 278     common/trace_tools_trace.cpp
 279     common/image.cpp
 280     common/image_bmp.cpp
 281     common/image_pnm.cpp
 282     common/image_png.cpp
 283     common/${os}
 284 )
 285
 286 set_target_properties (common PROPERTIES
 287     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 288     # Ensure it can be statically linked in shared libraries
 289     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 290 )
 291
 292 link_libraries (common)
 293
 294
 295 ##############################################################################
 296 # API tracers
 297
 298 if (WIN32)
 299     if (MINGW)
 300         # Silence warnings about @nn suffix mismatch
 301         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 302     endif (MINGW)
 303
 304     # ddraw.dll
 305     if (DirectX_D3D_INCLUDE_DIR)
 306         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 307         add_custom_command (
 308             OUTPUT ddrawtrace.cpp
 309             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 310             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 311         )
 312         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 313         set_target_properties (ddraw
 314             PROPERTIES PREFIX ""
 315             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 316             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 317         )
 318         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 319     endif (DirectX_D3D_INCLUDE_DIR)
 320
 321     # d3d8.dll
 322     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 323         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 324         add_custom_command (
 325             OUTPUT d3d8trace.cpp
 326             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 327             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 328         )
 329         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 330         set_target_properties (d3d8
 331             PROPERTIES PREFIX ""
 332             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 333             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 334         )
 335         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 336     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 337
 338     # d3d9.dll
 339     if (DirectX_D3DX9_INCLUDE_DIR)
 340         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 341         add_custom_command (
 342             OUTPUT d3d9trace.cpp
 343             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 344             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 345         )
 346         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 347         set_target_properties (d3d9
 348             PROPERTIES PREFIX ""
 349             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 350             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 351         )
 352         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 353     endif (DirectX_D3DX9_INCLUDE_DIR)
 354
 355     # d3d10.dll
 356     if (DirectX_D3D10_INCLUDE_DIR)
 357         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 358         add_custom_command (
 359             OUTPUT d3d10trace.cpp
 360             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 361             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 362         )
 363         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 364         set_target_properties (d3d10
 365             PROPERTIES PREFIX ""
 366             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 367             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 368         )
 369         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 370     endif (DirectX_D3D10_INCLUDE_DIR)
 371
 372     # opengl32.dll
 373     add_custom_command (
 374         OUTPUT wgltrace.cpp
 375         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 376         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 377     )
 378     add_library (wgltrace MODULE specs/opengl32.def
 379         wgltrace.cpp
 380         glcaps.cpp
 381         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 382     )
 383     set_target_properties (wgltrace PROPERTIES
 384         PREFIX ""
 385         OUTPUT_NAME opengl32
 386         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 387         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 388     )
 389     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 390
 391 elseif (APPLE)
 392     # OpenGL framework
 393     add_custom_command (
 394         OUTPUT cgltrace.cpp
 395         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 396         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 397     )
 398
 399     add_library (cgltrace SHARED
 400         cgltrace.cpp
 401         glcaps.cpp
 402         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 403     )
 404
 405     set_target_properties (cgltrace PROPERTIES
 406         # OpenGL framework name
 407         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 408         # Specificy the version and reexport GLU symbols
 409         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 410         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 411         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 412     )
 413
 414     target_link_libraries (cgltrace dl)
 415
 416     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 417 else ()
 418     # libGL.so
 419     add_custom_command (
 420         OUTPUT glxtrace.cpp
 421         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 422         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 423     )
 424
 425     add_library (glxtrace SHARED
 426         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 427         glxtrace.cpp
 428         glcaps.cpp
 429     )
 430
 431     set_target_properties (glxtrace PROPERTIES
 432         # avoid the default "lib" prefix
 433         PREFIX ""
 434         # Prevent symbol relocations internal to our wrapper library to be
 435         # overwritten by the application.
 436         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 437         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 438         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 439     )
 440
 441     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 442
 443     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 444 endif ()
 445
 446
 447 if (EGL_FOUND)
 448     # libEGL.so/libGL.so
 449     add_custom_command (
 450         OUTPUT egltrace.cpp
 451         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 452         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 453     )
 454
 455     add_library (egltrace SHARED
 456         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 457         egltrace.cpp
 458         glcaps.cpp
 459     )
 460
 461     set_property (
 462         TARGET egltrace
 463         APPEND
 464         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 465     )
 466
 467     set_target_properties (egltrace PROPERTIES
 468         # avoid the default "lib" prefix
 469         PREFIX ""
 470         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 471         # Prevent symbol relocations internal to our wrapper library to be
 472         # overwritten by the application.
 473         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 474         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 475     )
 476
 477     target_link_libraries (egltrace dl)
 478
 479     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 480 endif ()
 481
 482 ##############################################################################
 483 # API retracers
 484
 485 add_custom_command (
 486     OUTPUT glretrace_gl.cpp
 487     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 488     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 489 )
 490
 491 add_custom_command (
 492     OUTPUT glstate_params.cpp
 493     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 494     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 495 )
 496
 497 include_directories (
 498     ${CMAKE_CURRENT_BINARY_DIR}
 499     ${OPENGL_INCLUDE_PATH}
 500 )
 501
 502 set (retrace_sources
 503     glretrace_gl.cpp
 504     glretrace_cgl.cpp
 505     glretrace_glx.cpp
 506     glretrace_wgl.cpp
 507     glretrace_egl.cpp
 508     glretrace_main.cpp
 509     glstate.cpp
 510     glstate_params.cpp
 511     retrace.cpp
 512     retrace_stdc.cpp
 513     glws.cpp
 514     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 515 )
 516
 517 add_executable (glretrace
 518     ${retrace_sources}
 519     ${glws_os}
 520 )
 521
 522 set_property (
 523     TARGET glretrace
 524     APPEND
 525     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 526 )
 527
 528 target_link_libraries (glretrace
 529     common
 530 )
 531
 532 if (WIN32)
 533     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 534 elseif (APPLE)
 535     target_link_libraries (glretrace
 536         "-framework Cocoa"
 537         "-framework ApplicationServices" # CGS*
 538         ${OPENGL_gl_LIBRARY} # CGL*
 539     )
 540 else ()
 541     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 542 endif ()
 543
 544 install (TARGETS glretrace RUNTIME DESTINATION bin)
 545
 546 if (EGL_FOUND AND NOT WIN32 AND NOT APPLE)
 547     add_executable (eglretrace
 548         ${retrace_sources}
 549         glws_egl_xlib.cpp
 550     )
 551
 552     set_property (
 553         TARGET eglretrace
 554         APPEND
 555         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 556         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 557     )
 558
 559     target_link_libraries (eglretrace
 560         common
 561     )
 562
 563     target_link_libraries (eglretrace
 564         ${EGL_LIBRARIES}
 565         ${OPENGL_gl_LIBRARY}
 566         ${X11_X11_LIB}
 567     )
 568
 569     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 570 endif ()
 571
 572 ##############################################################################
 573 # CLI
 574
 575 add_subdirectory(cli)
 576
 577 ##############################################################################
 578 # Scripts (to support the CLI)
 579
 580 install (
 581     PROGRAMS
 582         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh
 583         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 584         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 585     DESTINATION ${SCRIPTS_INSTALL_DIR}
 586 )
 587
 588 ##############################################################################
 589 # GUI
 590
 591 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 592     add_subdirectory(gui)
 593 endif ()
 594
 595
 596 ##############################################################################
 597 # Packaging
 598
 599 install (
 600     FILES
 601         BUGS.markdown
 602         LICENSE
 603         NEWS.markdown
 604         README.markdown
 605         TODO.markdown
 606     DESTINATION ${DOC_INSTALL_DIR}
 607 )
 608
 609 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 610 set (CPACK_PACKAGE_VERSION_MINOR "0")
 611
 612 # Use current date in YYYYMMDD format as patch number
 613 execute_process (
 614     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 615     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 616 )
 617
 618 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 619 if (WIN32)
 620     set (CPACK_GENERATOR "ZIP")
 621 elseif (APPLE)
 622     set (CPACK_GENERATOR "DragNDrop")
 623 else ()
 624     set (CPACK_GENERATOR "TBZ2")
 625 endif ()
 626
 627 include(CPack)