git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20
  21 ##############################################################################
  22 # Find dependencies
  23
  24 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  25
  26 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  27
  28 find_package (PythonInterp REQUIRED)
  29 find_package (OpenGL REQUIRED)
  30
  31 if (ENABLE_GUI)
  32     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  33         set (REQUIRE_GUI REQUIRED)
  34     endif ()
  35     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  36     find_package (QJSON ${REQUIRE_GUI})
  37 endif ()
  38
  39 if (WIN32)
  40     find_package (DirectX)
  41 elseif (APPLE)
  42 else ()
  43     find_package (X11 REQUIRED)
  44
  45     set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  46     set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  47
  48     include_directories (${X11_INCLUDE_DIR})
  49 endif ()
  50
  51
  52 ##############################################################################
  53 # Set global build options
  54
  55 include (CheckCXXCompilerFlag)
  56
  57 if (WIN32)
  58     # MSVC & MinGW only define & use APIENTRY
  59     add_definitions (-DGLAPIENTRY=__stdcall)
  60
  61     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  62     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  63 else (WIN32)
  64     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  65     if (CXX_COMPILER_FLAG_VISIBILITY)
  66         add_definitions ("-fvisibility=hidden")
  67     endif (CXX_COMPILER_FLAG_VISIBILITY)
  68 endif (WIN32)
  69
  70 if (MSVC)
  71     # C99 includes for msvc
  72     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  73
  74     # Enable math constants defines
  75     add_definitions (-D_USE_MATH_DEFINES)
  76
  77     # No min/max macros
  78     add_definitions (-DNOMINMAX)
  79
  80     # Adjust warnings
  81     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  82     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  83     add_definitions (-W4)
  84     add_definitions (-wd4063) # not a valid value for switch of enum
  85     add_definitions (-wd4127) # conditional expression is constant
  86     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  87     add_definitions (-wd4505) # unreferenced local function has been removed
  88     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  89     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  90     add_definitions (-wd4018) # signed/unsigned mismatch
  91
  92     # Use static runtime
  93     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  94     foreach (flag_var
  95         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  96         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  97     )
  98         if (${flag_var} MATCHES "/MD")
  99             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 100         endif (${flag_var} MATCHES "/MD")
 101     endforeach (flag_var)
 102 else ()
 103     # Adjust warnings
 104     add_definitions (-Wall)
 105     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 106     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 107 endif ()
 108
 109 if (MINGW)
 110     # Avoid depending on MinGW runtime DLLs
 111     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 112     if (HAVE_STATIC_LIBGCC_FLAG)
 113         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 114         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 115         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 116     endif ()
 117     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 118     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 119         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 120         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 121         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 122     endif ()
 123 endif ()
 124
 125
 126 # Put all executables into the same top level build directory, regardless of
 127 # which subdirectory they are declared
 128 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 129
 130
 131 ##############################################################################
 132 # Bundled dependencies
 133 #
 134 # We always use the bundled zlib, libpng, and snappy sources:
 135 # - on Windows to make it easy to deploy the wrappers DLLs
 136 # - on unices to prevent symbol collisions when tracing applications that link
 137 # against other versions of these libraries
 138
 139 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 140 set (ZLIB_LIBRARIES z_bundled)
 141 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 142
 143 include_directories (${ZLIB_INCLUDE_DIRS})
 144 link_libraries (${ZLIB_LIBRARIES})
 145
 146 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 147 set (SNAPPY_LIBRARIES snappy_bundled)
 148 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 149
 150 include_directories (${SNAPPY_INCLUDE_DIRS})
 151 link_libraries (${SNAPPY_LIBRARIES})
 152
 153 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 154 set (PNG_DEFINITIONS "")
 155 set (PNG_LIBRARIES png_bundled)
 156
 157 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 158 include_directories (${PNG_INCLUDE_DIR})
 159 add_definitions (${PNG_DEFINITIONS})
 160 link_libraries (${PNG_LIBRARIES})
 161
 162 # The Qt website provides binaries for Windows and MacOSX, and they are
 163 # automatically found by cmake without any manual intervention.  The situation
 164 # for QJSON is substantially different: there are no binaries for QJSON
 165 # available, and there is no standard installation directory that is detected
 166 # by cmake.
 167 #
 168 # By bundling the QJSON source, we make it much more easier to build the GUI on
 169 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 170 # AUTO.
 171 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 172     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 173     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 174     set (QJSON_LIBRARY_DIRS)
 175     set (QJSON_LIBRARIES qjson_bundled)
 176     set (QJSON_FOUND TRUE)
 177 endif ()
 178
 179 # For glext headers
 180 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 181
 182
 183 ##############################################################################
 184 # Installation directories
 185
 186 if (WIN32 OR APPLE)
 187     # On Windows/MacOSX, applications are usually installed on a directory of
 188     # their own
 189     set (DOC_INSTALL_DIR doc)
 190 else ()
 191     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 192 endif ()
 193
 194 set (LIB_INSTALL_DIR lib/apitrace)
 195
 196 if (APPLE)
 197     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 198     # directories
 199     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 200 else ()
 201     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 202 endif ()
 203
 204 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 205 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 206
 207 # Expose the binary/install directories to source
 208 #
 209 # TODO: Use the same directory layout, for both build and install directories,
 210 # so that binaries can find each other using just relative paths.
 211 #
 212 add_definitions(
 213     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 214     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 215     -DAPITRACE_SCRIPTS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${SCRIPTS_INSTALL_DIR}"
 216     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 217 )
 218
 219
 220 ##############################################################################
 221 # Common libraries / utilities
 222
 223 include_directories (
 224     ${CMAKE_CURRENT_SOURCE_DIR}
 225     ${CMAKE_CURRENT_SOURCE_DIR}/common
 226 )
 227
 228 add_custom_command (
 229     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 230     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 231     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 232 )
 233
 234 if (WIN32)
 235     set (os os_win32.cpp)
 236     set (glws_os glws_wgl.cpp)
 237 else ()
 238     set (os os_posix.cpp)
 239     if (APPLE)
 240         set (glws_os glws_cocoa.mm)
 241     else ()
 242         set (glws_os glws_glx.cpp)
 243     endif ()
 244 endif ()
 245
 246 add_library (common STATIC
 247     common/trace_file.cpp
 248     common/trace_file_zlib.cpp
 249     common/trace_file_snappy.cpp
 250     common/trace_model.cpp
 251     common/trace_parser.cpp
 252     common/trace_writer.cpp
 253     common/trace_writer_local.cpp
 254     common/trace_writer_model.cpp
 255     common/trace_loader.cpp
 256     common/trace_tools_trace.cpp
 257     common/image.cpp
 258     common/image_bmp.cpp
 259     common/image_pnm.cpp
 260     common/image_png.cpp
 261     common/${os}
 262 )
 263
 264 set_target_properties (common PROPERTIES
 265     # Ensure it can be statically linked in shared libraries
 266     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 267 )
 268
 269 link_libraries (common)
 270
 271
 272 ##############################################################################
 273 # API tracers
 274
 275 if (WIN32)
 276     if (MINGW)
 277         # Silence warnings about @nn suffix mismatch
 278         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 279     endif (MINGW)
 280
 281     # ddraw.dll
 282     if (DirectX_D3D_INCLUDE_DIR)
 283         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 284         add_custom_command (
 285             OUTPUT ddrawtrace.cpp
 286             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 287             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 288         )
 289         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 290         set_target_properties (ddraw
 291             PROPERTIES PREFIX ""
 292             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 293             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 294         )
 295         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 296     endif (DirectX_D3D_INCLUDE_DIR)
 297
 298     # d3d8.dll
 299     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 300         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 301         add_custom_command (
 302             OUTPUT d3d8trace.cpp
 303             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 304             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 305         )
 306         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 307         set_target_properties (d3d8
 308             PROPERTIES PREFIX ""
 309             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 310             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 311         )
 312         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 313     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 314
 315     # d3d9.dll
 316     if (DirectX_D3DX9_INCLUDE_DIR)
 317         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 318         add_custom_command (
 319             OUTPUT d3d9trace.cpp
 320             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 321             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 322         )
 323         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 324         set_target_properties (d3d9
 325             PROPERTIES PREFIX ""
 326             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 327             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 328         )
 329         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 330     endif (DirectX_D3DX9_INCLUDE_DIR)
 331
 332     # d3d10.dll
 333     if (DirectX_D3D10_INCLUDE_DIR)
 334         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 335         add_custom_command (
 336             OUTPUT d3d10trace.cpp
 337             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 338             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 339         )
 340         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 341         set_target_properties (d3d10
 342             PROPERTIES PREFIX ""
 343             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 344             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 345         )
 346         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 347     endif (DirectX_D3D10_INCLUDE_DIR)
 348
 349     # opengl32.dll
 350     add_custom_command (
 351         OUTPUT wgltrace.cpp
 352         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 353         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 354     )
 355     add_library (wgltrace MODULE specs/opengl32.def
 356         wgltrace.cpp
 357         glcaps.cpp
 358         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 359     )
 360     set_target_properties (wgltrace PROPERTIES
 361         PREFIX ""
 362         OUTPUT_NAME opengl32
 363         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 364         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 365     )
 366     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 367
 368 elseif (APPLE)
 369     # OpenGL framework
 370     add_custom_command (
 371         OUTPUT cgltrace.cpp
 372         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 373         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 374     )
 375
 376     add_library (cgltrace SHARED
 377         cgltrace.cpp
 378         glcaps.cpp
 379         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 380     )
 381
 382     set_target_properties (cgltrace PROPERTIES
 383         # OpenGL framework name
 384         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 385         # Specificy the version and reexport GLU symbols
 386         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 387         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 388         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 389     )
 390
 391     target_link_libraries (cgltrace dl)
 392
 393     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 394 else ()
 395     # libGL.so
 396     add_custom_command (
 397         OUTPUT glxtrace.cpp
 398         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 399         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 400     )
 401
 402     add_library (glxtrace SHARED
 403         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 404         glxtrace.cpp
 405         glcaps.cpp
 406         glsnapshot.cpp
 407     )
 408
 409     set_target_properties (glxtrace PROPERTIES
 410         # avoid the default "lib" prefix
 411         PREFIX ""
 412         # Prevent symbol relocations internal to our wrapper library to be
 413         # overwritten by the application.
 414         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 415         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 416         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 417     )
 418
 419     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 420
 421     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 422 endif ()
 423
 424
 425 ##############################################################################
 426 # API retracers
 427
 428 add_custom_command (
 429     OUTPUT glretrace_gl.cpp
 430     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 431     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 432 )
 433
 434 add_custom_command (
 435     OUTPUT glstate_params.cpp
 436     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 437     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 438 )
 439
 440 include_directories (
 441     ${CMAKE_CURRENT_BINARY_DIR}
 442     ${OPENGL_INCLUDE_PATH}
 443 )
 444
 445 add_executable (glretrace
 446     glretrace_gl.cpp
 447     glretrace_cgl.cpp
 448     glretrace_glx.cpp
 449     glretrace_wgl.cpp
 450     glretrace_main.cpp
 451     glstate.cpp
 452     glstate_params.cpp
 453     retrace.cpp
 454     retrace_stdc.cpp
 455     glws.cpp
 456     ${glws_os}
 457     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 458 )
 459
 460 set_property (
 461     TARGET glretrace
 462     APPEND
 463     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 464 )
 465
 466 target_link_libraries (glretrace
 467     common
 468 )
 469
 470 if (WIN32)
 471     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 472 elseif (APPLE)
 473     target_link_libraries (glretrace
 474         "-framework Cocoa"
 475         "-framework ApplicationServices" # CGS*
 476         ${OPENGL_gl_LIBRARY} # CGL*
 477     )
 478 else ()
 479     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 480 endif ()
 481
 482 install (TARGETS glretrace RUNTIME DESTINATION bin)
 483
 484 ##############################################################################
 485 # CLI
 486
 487 add_subdirectory(cli)
 488
 489 ##############################################################################
 490 # Scripts (to support the CLI)
 491
 492 install (PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh DESTINATION ${LIB_INSTALL_DIR}/scripts)
 493
 494 ##############################################################################
 495 # GUI
 496
 497 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 498     add_subdirectory(gui)
 499 endif ()
 500
 501
 502 ##############################################################################
 503 # Packaging
 504
 505 install (
 506     FILES
 507         BUGS.markdown
 508         LICENSE
 509         NEWS.markdown
 510         README.markdown
 511         TODO.markdown
 512     DESTINATION ${DOC_INSTALL_DIR}
 513 )
 514
 515 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 516 set (CPACK_PACKAGE_VERSION_MINOR "0")
 517
 518 # Use current date in YYYYMMDD format as patch number
 519 execute_process (
 520     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 521     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 522 )
 523
 524 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 525 if (WIN32)
 526     set (CPACK_GENERATOR "ZIP")
 527 elseif (APPLE)
 528     set (CPACK_GENERATOR "DragNDrop")
 529 else ()
 530     set (CPACK_GENERATOR "TBZ2")
 531 endif ()
 532
 533 include(CPack)