git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Find dependencies
   8
   9 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  10
  11 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  12
  13 find_package (PythonInterp REQUIRED)
  14 find_package (OpenGL REQUIRED)
  15 find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit)
  16 find_package (QJSON)
  17
  18 if (NOT WIN32)
  19     find_package (X11 REQUIRED)
  20
  21     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  22     # from the standard OpenGL framework which provides support for native Mac OS X
  23     # applications.
  24     if (APPLE)
  25         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  26         if (NOT X11_GL_INCLUDE_PATH)
  27             message (SEND_ERROR "Could not find GL/glx.h")
  28         endif (NOT X11_GL_INCLUDE_PATH)
  29         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  30
  31         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  32         if (NOT X11_GL_LIB)
  33             message (SEND_ERROR "Could not find libGL.dylib")
  34         endif (NOT X11_GL_LIB)
  35     else ()
  36         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  37         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  38     endif ()
  39
  40     include_directories (${X11_INCLUDE_DIR})
  41 endif (NOT WIN32)
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 endif (WIN32)
  46
  47
  48 ##############################################################################
  49 # Set global build options
  50
  51 include (CheckCXXCompilerFlag)
  52
  53 if (WIN32)
  54     # MSVC & MinGW only define & use APIENTRY
  55     add_definitions (-DGLAPIENTRY=__stdcall)
  56
  57     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  58     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  59 else (WIN32)
  60     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  61     if (CXX_COMPILER_FLAG_VISIBILITY)
  62         add_definitions ("-fvisibility=hidden")
  63     endif (CXX_COMPILER_FLAG_VISIBILITY)
  64 endif (WIN32)
  65
  66 if (MSVC)
  67     # C99 includes for msvc
  68     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  69
  70     # Enable math constants defines
  71     add_definitions (-D_USE_MATH_DEFINES)
  72
  73     # No min/max macros
  74     add_definitions (-DNOMINMAX)
  75
  76     # Adjust warnings
  77     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  78     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  79     add_definitions (-W4)
  80     add_definitions (-wd4063) # not a valid value for switch of enum
  81     add_definitions (-wd4127) # conditional expression is constant
  82     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  83     add_definitions (-wd4505) # unreferenced local function has been removed
  84     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  85     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  86     add_definitions (-wd4018) # signed/unsigned mismatch
  87
  88     # Use static runtime
  89     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  90     foreach (flag_var
  91         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  92         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  93     )
  94         if (${flag_var} MATCHES "/MD")
  95             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  96         endif (${flag_var} MATCHES "/MD")
  97     endforeach (flag_var)
  98 else ()
  99     # Adjust warnings
 100     add_definitions (-Wall)
 101     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 102     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 103 endif ()
 104
 105
 106 # Put all executables into the same top level build directory, regardless of
 107 # which subdirectory they are declared
 108 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 109
 110
 111 ##############################################################################
 112 # Bundled dependencies
 113 #
 114 # We always use the bundled zlib and libpng sources:
 115 # - on Windows to make it easy to deploy the wrappers DLLs
 116 # - on unices to prevent symbol collisions when tracing applications that link
 117 # against other versions of these libraries
 118
 119 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 120 set (ZLIB_LIBRARIES z_bundled)
 121 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 122
 123 include_directories (${ZLIB_INCLUDE_DIRS})
 124 link_libraries (${ZLIB_LIBRARIES})
 125
 126 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 127 set (PNG_DEFINITIONS "")
 128 set (PNG_LIBRARIES png_bundled)
 129
 130 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 131 include_directories (${PNG_INCLUDE_DIR})
 132 add_definitions (${PNG_DEFINITIONS})
 133 link_libraries (${PNG_LIBRARIES})
 134
 135 # For glext headers
 136 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 137
 138
 139 ##############################################################################
 140 # Common libraries / utilities
 141
 142 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 143
 144 add_custom_command (
 145     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 146     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 147     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 148 )
 149
 150 if (WIN32)
 151     set (os os_win32.cpp)
 152     set (glws glws_wgl.cpp)
 153 else (WIN32)
 154     set (os os_posix.cpp)
 155     set (glws glws_glx.cpp)
 156 endif (WIN32)
 157
 158 add_library (trace trace_model.cpp trace_parser.cpp trace_writer.cpp trace_model_writer.cpp ${os})
 159
 160 add_executable (tracedump tracedump.cpp)
 161 target_link_libraries (tracedump trace)
 162 install (TARGETS tracedump RUNTIME DESTINATION bin)
 163
 164
 165 ##############################################################################
 166 # API tracers
 167
 168 if (WIN32)
 169     # ddraw.dll
 170     if (DirectX_D3D_INCLUDE_DIR)
 171         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 172         add_custom_command (
 173             OUTPUT ddraw.cpp
 174             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 175             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 176         )
 177         add_library (ddraw MODULE ddraw.def ddraw.cpp trace_writer.cpp os_win32.cpp)
 178         set_target_properties (ddraw
 179             PROPERTIES PREFIX ""
 180             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 181             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 182         )
 183         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 184     endif (DirectX_D3D_INCLUDE_DIR)
 185
 186     # d3d8.dll
 187     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 188         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 189         add_custom_command (
 190             OUTPUT d3d8.cpp
 191             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 192             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 193         )
 194         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 195         set_target_properties (d3d8
 196             PROPERTIES PREFIX ""
 197             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 198             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 199         )
 200         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 201     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 202
 203     # d3d9.dll
 204     if (DirectX_D3DX9_INCLUDE_DIR)
 205         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 206         add_custom_command (
 207             OUTPUT d3d9.cpp
 208             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 209             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 210         )
 211         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 212         set_target_properties (d3d9
 213             PROPERTIES PREFIX ""
 214             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 215             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 216         )
 217         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 218     endif (DirectX_D3DX9_INCLUDE_DIR)
 219
 220     # d3d10.dll
 221     #if (DirectX_D3D10_INCLUDE_DIR)
 222     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 223     #    add_custom_command (
 224     #        OUTPUT d3d10.cpp
 225     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 226     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 227     #    )
 228     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp trace_writer.cpp os_win32.cpp)
 229     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 230     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 231     #endif (DirectX_D3D10_INCLUDE_DIR)
 232
 233     # opengl32.dll
 234     add_custom_command (
 235         OUTPUT wgltrace.cpp
 236         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 237         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 238     )
 239     add_library (wgltrace MODULE opengl32.def wgltrace.cpp trace_writer.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 240     set_target_properties (wgltrace PROPERTIES
 241         PREFIX ""
 242         OUTPUT_NAME opengl32
 243         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 244         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 245     )
 246     if (MINGW)
 247         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 248     endif (MINGW)
 249     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 250
 251 elseif (APPLE)
 252     # OpenGL framework
 253     add_custom_command (
 254         OUTPUT cgltrace.cpp
 255         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 256         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 257     )
 258
 259     add_library (cgltrace SHARED cgltrace.cpp trace_writer.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 260
 261     set_target_properties (cgltrace PROPERTIES
 262         # OpenGL framework name
 263         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 264         # Specificy the version and reexport GLU symbols
 265         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 266         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 267         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 268     )
 269
 270     target_link_libraries (cgltrace dl)
 271
 272     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 273 else ()
 274     # libGL.so
 275     add_custom_command (
 276         OUTPUT glxtrace.cpp
 277         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 278         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 279     )
 280
 281     add_library (glxtrace SHARED
 282         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 283         glxtrace.cpp
 284         glsnapshot.cpp
 285         trace_writer.cpp
 286         image.cpp
 287         os_posix.cpp
 288     )
 289
 290     set_target_properties (glxtrace PROPERTIES
 291         # avoid the default "lib" prefix
 292         PREFIX ""
 293     )
 294
 295     # Prevent symbol relocations internal to our wrapper library to be
 296     # overwritten by the application.
 297     set_target_properties (glxtrace PROPERTIES
 298         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 299     )
 300
 301     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 302
 303     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 304 endif ()
 305
 306
 307 ##############################################################################
 308 # API retracers
 309
 310 add_custom_command (
 311     OUTPUT glretrace_gl.cpp
 312     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 313     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 314 )
 315
 316 add_custom_command (
 317     OUTPUT glstate_params.cpp
 318     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 319     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 320 )
 321
 322 include_directories (
 323     ${CMAKE_CURRENT_BINARY_DIR}
 324     ${OPENGL_INCLUDE_PATH}
 325 )
 326
 327 add_executable (glretrace
 328     glretrace_gl.cpp
 329     glretrace_cgl.cpp
 330     glretrace_glx.cpp
 331     glretrace_wgl.cpp
 332     glretrace_main.cpp
 333     glstate.cpp
 334     glstate_params.cpp
 335     retrace.cpp
 336     ${glws}
 337     image.cpp
 338     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 339 )
 340
 341 set_property (
 342     TARGET glretrace
 343     APPEND
 344     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 345 )
 346
 347 target_link_libraries (glretrace
 348     trace
 349 )
 350
 351 if (WIN32)
 352     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 353 elseif (APPLE)
 354     # XXX: We use GLX on MacOSX, which is in a separate library.
 355     target_link_libraries (glretrace
 356         ${X11_GL_LIB}
 357         ${X11_X11_LIB}
 358         "-framework ApplicationServices" # CGS*
 359         ${OPENGL_gl_LIBRARY} # CGL*
 360     )
 361 else ()
 362     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 363 endif ()
 364
 365 install (TARGETS glretrace RUNTIME DESTINATION bin)
 366
 367
 368 ##############################################################################
 369 # GUI
 370
 371 if (QT4_FOUND AND QJSON_FOUND)
 372     add_subdirectory(gui)
 373 endif (QT4_FOUND AND QJSON_FOUND)
 374
 375
 376 ##############################################################################
 377 # Packaging
 378
 379 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 380
 381 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 382 set (CPACK_PACKAGE_VERSION_MINOR "0")
 383
 384 # Use current date in YYYYMMDD format as patch number
 385 execute_process (
 386     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 387     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 388 )
 389
 390 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 391 if (WIN32)
 392     set (CPACK_GENERATOR "ZIP")
 393 elseif (APPLE)
 394     set (CPACK_GENERATOR "DragNDrop")
 395 else ()
 396     set (CPACK_GENERATOR "TBZ2")
 397 endif ()
 398
 399 include(CPack)