git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20
  21 ##############################################################################
  22 # Find dependencies
  23
  24 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  25
  26 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  27
  28 find_package (PythonInterp REQUIRED)
  29 find_package (OpenGL REQUIRED)
  30
  31 if (ENABLE_GUI)
  32     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  33         set (REQUIRE_GUI REQUIRED)
  34     endif ()
  35     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  36     find_package (QJSON ${REQUIRE_GUI})
  37 endif ()
  38
  39 if (NOT WIN32)
  40     find_package (X11 REQUIRED)
  41
  42     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  43     # from the standard OpenGL framework which provides support for native Mac OS X
  44     # applications.
  45     if (APPLE)
  46         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  47         if (NOT X11_GL_INCLUDE_PATH)
  48             message (SEND_ERROR "Could not find GL/glx.h")
  49         endif (NOT X11_GL_INCLUDE_PATH)
  50         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  51
  52         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  53         if (NOT X11_GL_LIB)
  54             message (SEND_ERROR "Could not find libGL.dylib")
  55         endif (NOT X11_GL_LIB)
  56     else ()
  57         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  58         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  59     endif ()
  60
  61     include_directories (${X11_INCLUDE_DIR})
  62 endif (NOT WIN32)
  63
  64 if (WIN32)
  65     find_package (DirectX)
  66 endif (WIN32)
  67
  68
  69 ##############################################################################
  70 # Set global build options
  71
  72 include (CheckCXXCompilerFlag)
  73
  74 if (WIN32)
  75     # MSVC & MinGW only define & use APIENTRY
  76     add_definitions (-DGLAPIENTRY=__stdcall)
  77
  78     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  79     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  80 else (WIN32)
  81     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  82     if (CXX_COMPILER_FLAG_VISIBILITY)
  83         add_definitions ("-fvisibility=hidden")
  84     endif (CXX_COMPILER_FLAG_VISIBILITY)
  85 endif (WIN32)
  86
  87 if (MSVC)
  88     # C99 includes for msvc
  89     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  90
  91     # Enable math constants defines
  92     add_definitions (-D_USE_MATH_DEFINES)
  93
  94     # No min/max macros
  95     add_definitions (-DNOMINMAX)
  96
  97     # Adjust warnings
  98     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  99     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 100     add_definitions (-W4)
 101     add_definitions (-wd4063) # not a valid value for switch of enum
 102     add_definitions (-wd4127) # conditional expression is constant
 103     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 104     add_definitions (-wd4505) # unreferenced local function has been removed
 105     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 106     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 107     add_definitions (-wd4018) # signed/unsigned mismatch
 108
 109     # Use static runtime
 110     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 111     foreach (flag_var
 112         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 113         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 114     )
 115         if (${flag_var} MATCHES "/MD")
 116             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 117         endif (${flag_var} MATCHES "/MD")
 118     endforeach (flag_var)
 119 else ()
 120     # Adjust warnings
 121     add_definitions (-Wall)
 122     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 123     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 124 endif ()
 125
 126
 127 # Put all executables into the same top level build directory, regardless of
 128 # which subdirectory they are declared
 129 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 130
 131
 132 ##############################################################################
 133 # Bundled dependencies
 134 #
 135 # We always use the bundled zlib, libpng, and snappy sources:
 136 # - on Windows to make it easy to deploy the wrappers DLLs
 137 # - on unices to prevent symbol collisions when tracing applications that link
 138 # against other versions of these libraries
 139
 140 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 141 set (ZLIB_LIBRARIES z_bundled)
 142 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 143
 144 include_directories (${ZLIB_INCLUDE_DIRS})
 145 link_libraries (${ZLIB_LIBRARIES})
 146
 147 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 148 set (SNAPPY_LIBRARIES snappy_bundled)
 149 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 150
 151 include_directories (${SNAPPY_INCLUDE_DIRS})
 152 link_libraries (${SNAPPY_LIBRARIES})
 153
 154 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 155 set (PNG_DEFINITIONS "")
 156 set (PNG_LIBRARIES png_bundled)
 157
 158 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 159 include_directories (${PNG_INCLUDE_DIR})
 160 add_definitions (${PNG_DEFINITIONS})
 161 link_libraries (${PNG_LIBRARIES})
 162
 163 # The Qt website provides binaries for Windows and MacOSX, and they are
 164 # automatically found by cmake without any manual intervention.  The situation
 165 # for QJSON is substantially different: there are no binaries for QJSON
 166 # available, and there is no standard installation directory that is detected
 167 # by cmake.
 168 #
 169 # By bundling the QJSON source, we make it much more easier to build the GUI on
 170 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 171 # AUTO.
 172 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 173     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 174     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 175     set (QJSON_LIBRARY_DIRS)
 176     set (QJSON_LIBRARIES qjson_bundled)
 177     set (QJSON_FOUND TRUE)
 178 endif ()
 179
 180 # For glext headers
 181 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 182
 183
 184 ##############################################################################
 185 # Common libraries / utilities
 186
 187 include_directories (
 188     ${CMAKE_CURRENT_SOURCE_DIR}
 189     ${CMAKE_CURRENT_SOURCE_DIR}/common
 190 )
 191
 192 add_custom_command (
 193     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 194     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 195     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 196 )
 197
 198 if (WIN32)
 199     set (os os_win32.cpp)
 200     set (glws glws_wgl.cpp)
 201 else (WIN32)
 202     set (os os_posix.cpp)
 203     set (glws glws_glx.cpp)
 204 endif (WIN32)
 205
 206 add_library (common
 207     common/trace_file.cpp
 208     common/trace_snappyfile.cpp
 209     common/trace_model.cpp
 210     common/trace_parser.cpp
 211     common/trace_writer.cpp
 212     common/trace_local_writer.cpp
 213     common/trace_model_writer.cpp
 214     common/trace_loader.cpp
 215     common/image.cpp
 216     common/image_bmp.cpp
 217     common/image_pnm.cpp
 218     common/image_png.cpp
 219     common/${os}
 220 )
 221
 222 set_target_properties (common PROPERTIES
 223     # Ensure it can be statically linked in shared libraries
 224     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}"
 225 )
 226
 227 link_libraries (common)
 228
 229 add_executable (tracedump tracedump.cpp)
 230 install (TARGETS tracedump RUNTIME DESTINATION bin)
 231
 232
 233 ##############################################################################
 234 # API tracers
 235
 236 if (WIN32)
 237     # ddraw.dll
 238     if (DirectX_D3D_INCLUDE_DIR)
 239         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 240         add_custom_command (
 241             OUTPUT ddrawtrace.cpp
 242             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 243             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 244         )
 245         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 246         set_target_properties (ddraw
 247             PROPERTIES PREFIX ""
 248             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 249             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 250         )
 251         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 252     endif (DirectX_D3D_INCLUDE_DIR)
 253
 254     # d3d8.dll
 255     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 256         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 257         add_custom_command (
 258             OUTPUT d3d8trace.cpp
 259             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 260             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 261         )
 262         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 263         set_target_properties (d3d8
 264             PROPERTIES PREFIX ""
 265             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 266             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 267         )
 268         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 269     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 270
 271     # d3d9.dll
 272     if (DirectX_D3DX9_INCLUDE_DIR)
 273         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 274         add_custom_command (
 275             OUTPUT d3d9trace.cpp
 276             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 277             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 278         )
 279         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 280         set_target_properties (d3d9
 281             PROPERTIES PREFIX ""
 282             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 283             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 284         )
 285         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 286     endif (DirectX_D3DX9_INCLUDE_DIR)
 287
 288     # d3d10.dll
 289     if (DirectX_D3D10_INCLUDE_DIR)
 290         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 291         add_custom_command (
 292             OUTPUT d3d10trace.cpp
 293             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 294             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/winapi.py specs/stdapi.py
 295         )
 296         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 297         set_target_properties (d3d10
 298             PROPERTIES PREFIX ""
 299             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 300             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 301         )
 302         install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 303     endif (DirectX_D3D10_INCLUDE_DIR)
 304
 305     # opengl32.dll
 306     add_custom_command (
 307         OUTPUT wgltrace.cpp
 308         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 309         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 310     )
 311     add_library (wgltrace MODULE specs/opengl32.def
 312         wgltrace.cpp
 313         glcaps.cpp
 314         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 315     )
 316     set_target_properties (wgltrace PROPERTIES
 317         PREFIX ""
 318         OUTPUT_NAME opengl32
 319         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 320         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 321     )
 322     if (MINGW)
 323         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup")
 324     endif (MINGW)
 325     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 326
 327 elseif (APPLE)
 328     # OpenGL framework
 329     add_custom_command (
 330         OUTPUT cgltrace.cpp
 331         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 332         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 333     )
 334
 335     add_library (cgltrace SHARED
 336         cgltrace.cpp
 337         glcaps.cpp
 338         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 339     )
 340
 341     set_target_properties (cgltrace PROPERTIES
 342         # OpenGL framework name
 343         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 344         # Specificy the version and reexport GLU symbols
 345         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 346         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 347         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 348     )
 349
 350     target_link_libraries (cgltrace dl)
 351
 352     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 353 else ()
 354     # libGL.so
 355     add_custom_command (
 356         OUTPUT glxtrace.cpp
 357         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 358         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 359     )
 360
 361     add_library (glxtrace SHARED
 362         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 363         glxtrace.cpp
 364         glcaps.cpp
 365         glsnapshot.cpp
 366     )
 367
 368     set_target_properties (glxtrace PROPERTIES
 369         # avoid the default "lib" prefix
 370         PREFIX ""
 371     )
 372
 373     # Prevent symbol relocations internal to our wrapper library to be
 374     # overwritten by the application.
 375     set_target_properties (glxtrace PROPERTIES
 376         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 377     )
 378
 379     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 380
 381     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 382 endif ()
 383
 384
 385 ##############################################################################
 386 # API retracers
 387
 388 add_custom_command (
 389     OUTPUT glretrace_gl.cpp
 390     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 391     DEPENDS glretrace.py retrace.py codegen.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 392 )
 393
 394 add_custom_command (
 395     OUTPUT glstate_params.cpp
 396     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 397     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 398 )
 399
 400 include_directories (
 401     ${CMAKE_CURRENT_BINARY_DIR}
 402     ${OPENGL_INCLUDE_PATH}
 403 )
 404
 405 add_executable (glretrace
 406     glretrace_gl.cpp
 407     glretrace_cgl.cpp
 408     glretrace_glx.cpp
 409     glretrace_wgl.cpp
 410     glretrace_main.cpp
 411     glstate.cpp
 412     glstate_params.cpp
 413     retrace.cpp
 414     ${glws}
 415     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 416 )
 417
 418 set_property (
 419     TARGET glretrace
 420     APPEND
 421     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 422 )
 423
 424 target_link_libraries (glretrace
 425     common
 426 )
 427
 428 if (WIN32)
 429     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 430 elseif (APPLE)
 431     # XXX: We use GLX on MacOSX, which is in a separate library.
 432     target_link_libraries (glretrace
 433         ${X11_GL_LIB}
 434         ${X11_X11_LIB}
 435         "-framework ApplicationServices" # CGS*
 436         ${OPENGL_gl_LIBRARY} # CGL*
 437     )
 438 else ()
 439     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 440 endif ()
 441
 442 install (TARGETS glretrace RUNTIME DESTINATION bin)
 443
 444
 445 ##############################################################################
 446 # GUI
 447
 448 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 449     add_subdirectory(gui)
 450 endif ()
 451
 452
 453 ##############################################################################
 454 # Packaging
 455
 456 install (
 457     FILES
 458         BUGS.markdown
 459         LICENSE
 460         NEWS.markdown
 461         README.markdown
 462         TODO.markdown
 463     DESTINATION doc)
 464
 465 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 466 set (CPACK_PACKAGE_VERSION_MINOR "0")
 467
 468 # Use current date in YYYYMMDD format as patch number
 469 execute_process (
 470     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 471     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 472 )
 473
 474 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 475 if (WIN32)
 476     set (CPACK_GENERATOR "ZIP")
 477 elseif (APPLE)
 478     set (CPACK_GENERATOR "DragNDrop")
 479 else ()
 480     set (CPACK_GENERATOR "TBZ2")
 481 endif ()
 482
 483 include(CPack)