git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8 #
   9 # We use a cached string variable instead of the standard (boolean) OPTION
  10 # command so that we can default to auto-detecting optional depencies, while
  11 # still providing a mechanism to force/disable these optional dependencies, as
  12 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  13
  14 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  15
  16
  17 ##############################################################################
  18 # Find dependencies
  19
  20 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  21
  22 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  23
  24 find_package (PythonInterp REQUIRED)
  25 find_package (OpenGL REQUIRED)
  26 find_package (Snappy REQUIRED)
  27
  28 if (ENABLE_GUI)
  29     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  30         set (REQUIRE_GUI REQUIRED)
  31     endif ()
  32     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  33     find_package (QJSON ${REQUIRE_GUI})
  34 endif ()
  35
  36 if (NOT WIN32)
  37     find_package (X11 REQUIRED)
  38
  39     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  40     # from the standard OpenGL framework which provides support for native Mac OS X
  41     # applications.
  42     if (APPLE)
  43         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  44         if (NOT X11_GL_INCLUDE_PATH)
  45             message (SEND_ERROR "Could not find GL/glx.h")
  46         endif (NOT X11_GL_INCLUDE_PATH)
  47         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  48
  49         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  50         if (NOT X11_GL_LIB)
  51             message (SEND_ERROR "Could not find libGL.dylib")
  52         endif (NOT X11_GL_LIB)
  53     else ()
  54         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  55         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  56     endif ()
  57
  58     include_directories (${X11_INCLUDE_DIR})
  59 endif (NOT WIN32)
  60
  61 if (WIN32)
  62     find_package (DirectX)
  63 endif (WIN32)
  64
  65
  66 ##############################################################################
  67 # Set global build options
  68
  69 include (CheckCXXCompilerFlag)
  70
  71 if (WIN32)
  72     # MSVC & MinGW only define & use APIENTRY
  73     add_definitions (-DGLAPIENTRY=__stdcall)
  74
  75     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  76     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  77 else (WIN32)
  78     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  79     if (CXX_COMPILER_FLAG_VISIBILITY)
  80         add_definitions ("-fvisibility=hidden")
  81     endif (CXX_COMPILER_FLAG_VISIBILITY)
  82 endif (WIN32)
  83
  84 if (MSVC)
  85     # C99 includes for msvc
  86     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  87
  88     # Enable math constants defines
  89     add_definitions (-D_USE_MATH_DEFINES)
  90
  91     # No min/max macros
  92     add_definitions (-DNOMINMAX)
  93
  94     # Adjust warnings
  95     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  96     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  97     add_definitions (-W4)
  98     add_definitions (-wd4063) # not a valid value for switch of enum
  99     add_definitions (-wd4127) # conditional expression is constant
 100     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 101     add_definitions (-wd4505) # unreferenced local function has been removed
 102     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 103     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 104     add_definitions (-wd4018) # signed/unsigned mismatch
 105
 106     # Use static runtime
 107     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 108     foreach (flag_var
 109         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 110         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 111     )
 112         if (${flag_var} MATCHES "/MD")
 113             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 114         endif (${flag_var} MATCHES "/MD")
 115     endforeach (flag_var)
 116 else ()
 117     # Adjust warnings
 118     add_definitions (-Wall)
 119     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 120     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 121 endif ()
 122
 123
 124 # Put all executables into the same top level build directory, regardless of
 125 # which subdirectory they are declared
 126 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 127
 128
 129 ##############################################################################
 130 # Bundled dependencies
 131 #
 132 # We always use the bundled zlib and libpng sources:
 133 # - on Windows to make it easy to deploy the wrappers DLLs
 134 # - on unices to prevent symbol collisions when tracing applications that link
 135 # against other versions of these libraries
 136
 137 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 138 set (ZLIB_LIBRARIES z_bundled)
 139 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 140
 141 include_directories (${ZLIB_INCLUDE_DIRS})
 142 link_libraries (${ZLIB_LIBRARIES})
 143
 144 link_libraries(${SNAPPY_LIBRARIES})
 145
 146 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 147 set (PNG_DEFINITIONS "")
 148 set (PNG_LIBRARIES png_bundled)
 149
 150 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 151 include_directories (${PNG_INCLUDE_DIR})
 152 add_definitions (${PNG_DEFINITIONS})
 153 link_libraries (${PNG_LIBRARIES})
 154
 155 # For glext headers
 156 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 157
 158
 159 ##############################################################################
 160 # Common libraries / utilities
 161
 162 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 163
 164 add_custom_command (
 165     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 166     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 167     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 168 )
 169
 170 if (WIN32)
 171     set (os os_win32.cpp)
 172     set (glws glws_wgl.cpp)
 173 else (WIN32)
 174     set (os os_posix.cpp)
 175     set (glws glws_glx.cpp)
 176 endif (WIN32)
 177
 178 add_library (common
 179     trace_file.cpp
 180     trace_model.cpp
 181     trace_parser.cpp
 182     trace_writer.cpp
 183     trace_model_writer.cpp
 184     image.cpp
 185     image_bmp.cpp
 186     image_pnm.cpp
 187     image_png.cpp
 188     ${os}
 189 )
 190
 191 set_target_properties (common PROPERTIES
 192     # Ensure it can be statically linked in shared libraries
 193     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}"
 194 )
 195
 196 link_libraries (common)
 197
 198 add_executable (tracedump tracedump.cpp)
 199 install (TARGETS tracedump RUNTIME DESTINATION bin)
 200
 201
 202 ##############################################################################
 203 # API tracers
 204
 205 if (WIN32)
 206     # ddraw.dll
 207     if (DirectX_D3D_INCLUDE_DIR)
 208         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 209         add_custom_command (
 210             OUTPUT ddraw.cpp
 211             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 212             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 213         )
 214         add_library (ddraw MODULE ddraw.def ddraw.cpp)
 215         set_target_properties (ddraw
 216             PROPERTIES PREFIX ""
 217             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 218             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 219         )
 220         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 221     endif (DirectX_D3D_INCLUDE_DIR)
 222
 223     # d3d8.dll
 224     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 225         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 226         add_custom_command (
 227             OUTPUT d3d8.cpp
 228             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 229             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 230         )
 231         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp)
 232         set_target_properties (d3d8
 233             PROPERTIES PREFIX ""
 234             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 235             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 236         )
 237         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 238     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 239
 240     # d3d9.dll
 241     if (DirectX_D3DX9_INCLUDE_DIR)
 242         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 243         add_custom_command (
 244             OUTPUT d3d9.cpp
 245             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 246             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 247         )
 248         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp)
 249         set_target_properties (d3d9
 250             PROPERTIES PREFIX ""
 251             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 252             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 253         )
 254         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 255     endif (DirectX_D3DX9_INCLUDE_DIR)
 256
 257     # d3d10.dll
 258     #if (DirectX_D3D10_INCLUDE_DIR)
 259     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 260     #    add_custom_command (
 261     #        OUTPUT d3d10.cpp
 262     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 263     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 264     #    )
 265     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp)
 266     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 267     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 268     #endif (DirectX_D3D10_INCLUDE_DIR)
 269
 270     # opengl32.dll
 271     add_custom_command (
 272         OUTPUT wgltrace.cpp
 273         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 274         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 275     )
 276     add_library (wgltrace MODULE opengl32.def
 277         wgltrace.cpp
 278         glcaps.cpp
 279         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 280     )
 281     set_target_properties (wgltrace PROPERTIES
 282         PREFIX ""
 283         OUTPUT_NAME opengl32
 284         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 285         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 286     )
 287     if (MINGW)
 288         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 289     endif (MINGW)
 290     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 291
 292 elseif (APPLE)
 293     # OpenGL framework
 294     add_custom_command (
 295         OUTPUT cgltrace.cpp
 296         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 297         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 298     )
 299
 300     add_library (cgltrace SHARED
 301         cgltrace.cpp
 302         glcaps.cpp
 303         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 304     )
 305
 306     set_target_properties (cgltrace PROPERTIES
 307         # OpenGL framework name
 308         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 309         # Specificy the version and reexport GLU symbols
 310         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 311         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 312         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 313     )
 314
 315     target_link_libraries (cgltrace dl)
 316
 317     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 318 else ()
 319     # libGL.so
 320     add_custom_command (
 321         OUTPUT glxtrace.cpp
 322         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 323         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 324     )
 325
 326     add_library (glxtrace SHARED
 327         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 328         glxtrace.cpp
 329         glcaps.cpp
 330         glsnapshot.cpp
 331     )
 332
 333     set_target_properties (glxtrace PROPERTIES
 334         # avoid the default "lib" prefix
 335         PREFIX ""
 336     )
 337
 338     # Prevent symbol relocations internal to our wrapper library to be
 339     # overwritten by the application.
 340     set_target_properties (glxtrace PROPERTIES
 341         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 342     )
 343
 344     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 345
 346     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 347 endif ()
 348
 349
 350 ##############################################################################
 351 # API retracers
 352
 353 add_custom_command (
 354     OUTPUT glretrace_gl.cpp
 355     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 356     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 357 )
 358
 359 add_custom_command (
 360     OUTPUT glstate_params.cpp
 361     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 362     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 363 )
 364
 365 include_directories (
 366     ${CMAKE_CURRENT_BINARY_DIR}
 367     ${OPENGL_INCLUDE_PATH}
 368 )
 369
 370 add_executable (glretrace
 371     glretrace_gl.cpp
 372     glretrace_cgl.cpp
 373     glretrace_glx.cpp
 374     glretrace_wgl.cpp
 375     glretrace_main.cpp
 376     glstate.cpp
 377     glstate_params.cpp
 378     retrace.cpp
 379     ${glws}
 380     image.cpp
 381     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 382 )
 383
 384 set_property (
 385     TARGET glretrace
 386     APPEND
 387     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 388 )
 389
 390 target_link_libraries (glretrace
 391     common
 392 )
 393
 394 if (WIN32)
 395     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 396 elseif (APPLE)
 397     # XXX: We use GLX on MacOSX, which is in a separate library.
 398     target_link_libraries (glretrace
 399         ${X11_GL_LIB}
 400         ${X11_X11_LIB}
 401         "-framework ApplicationServices" # CGS*
 402         ${OPENGL_gl_LIBRARY} # CGL*
 403     )
 404 else ()
 405     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 406 endif ()
 407
 408 install (TARGETS glretrace RUNTIME DESTINATION bin)
 409
 410
 411 ##############################################################################
 412 # GUI
 413
 414 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 415     add_subdirectory(gui)
 416 endif ()
 417
 418
 419 ##############################################################################
 420 # Packaging
 421
 422 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 423
 424 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 425 set (CPACK_PACKAGE_VERSION_MINOR "0")
 426
 427 # Use current date in YYYYMMDD format as patch number
 428 execute_process (
 429     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 430     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 431 )
 432
 433 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 434 if (WIN32)
 435     set (CPACK_GENERATOR "ZIP")
 436 elseif (APPLE)
 437     set (CPACK_GENERATOR "DragNDrop")
 438 else ()
 439     set (CPACK_GENERATOR "TBZ2")
 440 endif ()
 441
 442 include(CPack)