git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8 #
   9 # We use a cached string variable instead of the standard (boolean) OPTION
  10 # command so that we can default to auto-detecting optional depencies, while
  11 # still providing a mechanism to force/disable these optional dependencies, as
  12 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  13
  14 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  15
  16
  17 ##############################################################################
  18 # Find dependencies
  19
  20 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  21
  22 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  23
  24 find_package (PythonInterp REQUIRED)
  25 find_package (OpenGL REQUIRED)
  26
  27 if (ENABLE_GUI)
  28     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  29         set (REQUIRE_GUI REQUIRED)
  30     endif ()
  31     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  32     find_package (QJSON ${REQUIRE_GUI})
  33 endif ()
  34
  35 if (NOT WIN32)
  36     find_package (X11 REQUIRED)
  37
  38     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  39     # from the standard OpenGL framework which provides support for native Mac OS X
  40     # applications.
  41     if (APPLE)
  42         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  43         if (NOT X11_GL_INCLUDE_PATH)
  44             message (SEND_ERROR "Could not find GL/glx.h")
  45         endif (NOT X11_GL_INCLUDE_PATH)
  46         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  47
  48         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  49         if (NOT X11_GL_LIB)
  50             message (SEND_ERROR "Could not find libGL.dylib")
  51         endif (NOT X11_GL_LIB)
  52     else ()
  53         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  54         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  55     endif ()
  56
  57     include_directories (${X11_INCLUDE_DIR})
  58 endif (NOT WIN32)
  59
  60 if (WIN32)
  61     find_package (DirectX)
  62 endif (WIN32)
  63
  64
  65 ##############################################################################
  66 # Set global build options
  67
  68 include (CheckCXXCompilerFlag)
  69
  70 if (WIN32)
  71     # MSVC & MinGW only define & use APIENTRY
  72     add_definitions (-DGLAPIENTRY=__stdcall)
  73
  74     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  75     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  76 else (WIN32)
  77     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  78     if (CXX_COMPILER_FLAG_VISIBILITY)
  79         add_definitions ("-fvisibility=hidden")
  80     endif (CXX_COMPILER_FLAG_VISIBILITY)
  81 endif (WIN32)
  82
  83 if (MSVC)
  84     # C99 includes for msvc
  85     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  86
  87     # Enable math constants defines
  88     add_definitions (-D_USE_MATH_DEFINES)
  89
  90     # No min/max macros
  91     add_definitions (-DNOMINMAX)
  92
  93     # Adjust warnings
  94     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  95     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  96     add_definitions (-W4)
  97     add_definitions (-wd4063) # not a valid value for switch of enum
  98     add_definitions (-wd4127) # conditional expression is constant
  99     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 100     add_definitions (-wd4505) # unreferenced local function has been removed
 101     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 102     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 103     add_definitions (-wd4018) # signed/unsigned mismatch
 104
 105     # Use static runtime
 106     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 107     foreach (flag_var
 108         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 109         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 110     )
 111         if (${flag_var} MATCHES "/MD")
 112             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 113         endif (${flag_var} MATCHES "/MD")
 114     endforeach (flag_var)
 115 else ()
 116     # Adjust warnings
 117     add_definitions (-Wall)
 118     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 119     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 120 endif ()
 121
 122
 123 # Put all executables into the same top level build directory, regardless of
 124 # which subdirectory they are declared
 125 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 126
 127
 128 ##############################################################################
 129 # Bundled dependencies
 130 #
 131 # We always use the bundled zlib and libpng sources:
 132 # - on Windows to make it easy to deploy the wrappers DLLs
 133 # - on unices to prevent symbol collisions when tracing applications that link
 134 # against other versions of these libraries
 135
 136 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 137 set (ZLIB_LIBRARIES z_bundled)
 138 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 139
 140 include_directories (${ZLIB_INCLUDE_DIRS})
 141 link_libraries (${ZLIB_LIBRARIES})
 142
 143 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 144 set (SNAPPY_LIBRARIES snappy_bundled)
 145 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 146
 147 include_directories (${SNAPPY_INCLUDE_DIRS})
 148 link_libraries (${SNAPPY_LIBRARIES})
 149
 150 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 151 set (PNG_DEFINITIONS "")
 152 set (PNG_LIBRARIES png_bundled)
 153
 154 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 155 include_directories (${PNG_INCLUDE_DIR})
 156 add_definitions (${PNG_DEFINITIONS})
 157 link_libraries (${PNG_LIBRARIES})
 158
 159 # For glext headers
 160 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 161
 162
 163 ##############################################################################
 164 # Common libraries / utilities
 165
 166 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 167
 168 add_custom_command (
 169     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 170     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 171     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 172 )
 173
 174 if (WIN32)
 175     set (os os_win32.cpp)
 176     set (glws glws_wgl.cpp)
 177 else (WIN32)
 178     set (os os_posix.cpp)
 179     set (glws glws_glx.cpp)
 180 endif (WIN32)
 181
 182 add_library (common
 183     trace_file.cpp
 184     trace_model.cpp
 185     trace_parser.cpp
 186     trace_writer.cpp
 187     trace_model_writer.cpp
 188     image.cpp
 189     image_bmp.cpp
 190     image_pnm.cpp
 191     image_png.cpp
 192     ${os}
 193 )
 194
 195 set_target_properties (common PROPERTIES
 196     # Ensure it can be statically linked in shared libraries
 197     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}"
 198 )
 199
 200 link_libraries (common)
 201
 202 add_executable (tracedump tracedump.cpp)
 203 install (TARGETS tracedump RUNTIME DESTINATION bin)
 204
 205
 206 ##############################################################################
 207 # API tracers
 208
 209 if (WIN32)
 210     # ddraw.dll
 211     if (DirectX_D3D_INCLUDE_DIR)
 212         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 213         add_custom_command (
 214             OUTPUT ddraw.cpp
 215             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 216             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 217         )
 218         add_library (ddraw MODULE ddraw.def ddraw.cpp)
 219         set_target_properties (ddraw
 220             PROPERTIES PREFIX ""
 221             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 222             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 223         )
 224         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 225     endif (DirectX_D3D_INCLUDE_DIR)
 226
 227     # d3d8.dll
 228     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 229         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 230         add_custom_command (
 231             OUTPUT d3d8.cpp
 232             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 233             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 234         )
 235         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp)
 236         set_target_properties (d3d8
 237             PROPERTIES PREFIX ""
 238             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 239             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 240         )
 241         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 242     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 243
 244     # d3d9.dll
 245     if (DirectX_D3DX9_INCLUDE_DIR)
 246         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 247         add_custom_command (
 248             OUTPUT d3d9.cpp
 249             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 250             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 251         )
 252         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp)
 253         set_target_properties (d3d9
 254             PROPERTIES PREFIX ""
 255             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 256             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 257         )
 258         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 259     endif (DirectX_D3DX9_INCLUDE_DIR)
 260
 261     # d3d10.dll
 262     #if (DirectX_D3D10_INCLUDE_DIR)
 263     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 264     #    add_custom_command (
 265     #        OUTPUT d3d10.cpp
 266     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 267     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 268     #    )
 269     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp)
 270     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 271     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 272     #endif (DirectX_D3D10_INCLUDE_DIR)
 273
 274     # opengl32.dll
 275     add_custom_command (
 276         OUTPUT wgltrace.cpp
 277         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 278         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 279     )
 280     add_library (wgltrace MODULE opengl32.def
 281         wgltrace.cpp
 282         glcaps.cpp
 283         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 284     )
 285     set_target_properties (wgltrace PROPERTIES
 286         PREFIX ""
 287         OUTPUT_NAME opengl32
 288         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 289         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 290     )
 291     if (MINGW)
 292         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 293     endif (MINGW)
 294     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 295
 296 elseif (APPLE)
 297     # OpenGL framework
 298     add_custom_command (
 299         OUTPUT cgltrace.cpp
 300         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 301         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 302     )
 303
 304     add_library (cgltrace SHARED
 305         cgltrace.cpp
 306         glcaps.cpp
 307         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 308     )
 309
 310     set_target_properties (cgltrace PROPERTIES
 311         # OpenGL framework name
 312         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 313         # Specificy the version and reexport GLU symbols
 314         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 315         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 316         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 317     )
 318
 319     target_link_libraries (cgltrace dl)
 320
 321     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 322 else ()
 323     # libGL.so
 324     add_custom_command (
 325         OUTPUT glxtrace.cpp
 326         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 327         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 328     )
 329
 330     add_library (glxtrace SHARED
 331         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 332         glxtrace.cpp
 333         glcaps.cpp
 334         glsnapshot.cpp
 335     )
 336
 337     set_target_properties (glxtrace PROPERTIES
 338         # avoid the default "lib" prefix
 339         PREFIX ""
 340     )
 341
 342     # Prevent symbol relocations internal to our wrapper library to be
 343     # overwritten by the application.
 344     set_target_properties (glxtrace PROPERTIES
 345         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 346     )
 347
 348     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 349
 350     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 351 endif ()
 352
 353
 354 ##############################################################################
 355 # API retracers
 356
 357 add_custom_command (
 358     OUTPUT glretrace_gl.cpp
 359     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 360     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 361 )
 362
 363 add_custom_command (
 364     OUTPUT glstate_params.cpp
 365     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 366     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 367 )
 368
 369 include_directories (
 370     ${CMAKE_CURRENT_BINARY_DIR}
 371     ${OPENGL_INCLUDE_PATH}
 372 )
 373
 374 add_executable (glretrace
 375     glretrace_gl.cpp
 376     glretrace_cgl.cpp
 377     glretrace_glx.cpp
 378     glretrace_wgl.cpp
 379     glretrace_main.cpp
 380     glstate.cpp
 381     glstate_params.cpp
 382     retrace.cpp
 383     ${glws}
 384     image.cpp
 385     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 386 )
 387
 388 set_property (
 389     TARGET glretrace
 390     APPEND
 391     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 392 )
 393
 394 target_link_libraries (glretrace
 395     common
 396 )
 397
 398 if (WIN32)
 399     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 400 elseif (APPLE)
 401     # XXX: We use GLX on MacOSX, which is in a separate library.
 402     target_link_libraries (glretrace
 403         ${X11_GL_LIB}
 404         ${X11_X11_LIB}
 405         "-framework ApplicationServices" # CGS*
 406         ${OPENGL_gl_LIBRARY} # CGL*
 407     )
 408 else ()
 409     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 410 endif ()
 411
 412 install (TARGETS glretrace RUNTIME DESTINATION bin)
 413
 414
 415 ##############################################################################
 416 # GUI
 417
 418 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 419     add_subdirectory(gui)
 420 endif ()
 421
 422
 423 ##############################################################################
 424 # Packaging
 425
 426 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 427
 428 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 429 set (CPACK_PACKAGE_VERSION_MINOR "0")
 430
 431 # Use current date in YYYYMMDD format as patch number
 432 execute_process (
 433     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 434     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 435 )
 436
 437 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 438 if (WIN32)
 439     set (CPACK_GENERATOR "ZIP")
 440 elseif (APPLE)
 441     set (CPACK_GENERATOR "DragNDrop")
 442 else ()
 443     set (CPACK_GENERATOR "TBZ2")
 444 endif ()
 445
 446 include(CPack)