git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8 #
   9 # We use a cached string variable instead of the standard (boolean) OPTION
  10 # command so that we can default to auto-detecting optional depencies, while
  11 # still providing a mechanism to force/disable these optional dependencies, as
  12 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  13
  14 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  15
  16
  17 ##############################################################################
  18 # Find dependencies
  19
  20 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  21
  22 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  23
  24 find_package (PythonInterp REQUIRED)
  25 find_package (OpenGL REQUIRED)
  26
  27 if (ENABLE_GUI)
  28     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  29         set (REQUIRE_GUI REQUIRED)
  30     endif ()
  31     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  32     find_package (QJSON ${REQUIRE_GUI})
  33 endif ()
  34
  35 if (NOT WIN32)
  36     find_package (X11 REQUIRED)
  37
  38     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  39     # from the standard OpenGL framework which provides support for native Mac OS X
  40     # applications.
  41     if (APPLE)
  42         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  43         if (NOT X11_GL_INCLUDE_PATH)
  44             message (SEND_ERROR "Could not find GL/glx.h")
  45         endif (NOT X11_GL_INCLUDE_PATH)
  46         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  47
  48         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  49         if (NOT X11_GL_LIB)
  50             message (SEND_ERROR "Could not find libGL.dylib")
  51         endif (NOT X11_GL_LIB)
  52     else ()
  53         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  54         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  55     endif ()
  56
  57     include_directories (${X11_INCLUDE_DIR})
  58 endif (NOT WIN32)
  59
  60 if (WIN32)
  61     find_package (DirectX)
  62 endif (WIN32)
  63
  64
  65 ##############################################################################
  66 # Set global build options
  67
  68 include (CheckCXXCompilerFlag)
  69
  70 if (WIN32)
  71     # MSVC & MinGW only define & use APIENTRY
  72     add_definitions (-DGLAPIENTRY=__stdcall)
  73
  74     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  75     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  76 else (WIN32)
  77     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  78     if (CXX_COMPILER_FLAG_VISIBILITY)
  79         add_definitions ("-fvisibility=hidden")
  80     endif (CXX_COMPILER_FLAG_VISIBILITY)
  81 endif (WIN32)
  82
  83 if (MSVC)
  84     # C99 includes for msvc
  85     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  86
  87     # Enable math constants defines
  88     add_definitions (-D_USE_MATH_DEFINES)
  89
  90     # No min/max macros
  91     add_definitions (-DNOMINMAX)
  92
  93     # Adjust warnings
  94     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  95     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  96     add_definitions (-W4)
  97     add_definitions (-wd4063) # not a valid value for switch of enum
  98     add_definitions (-wd4127) # conditional expression is constant
  99     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 100     add_definitions (-wd4505) # unreferenced local function has been removed
 101     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 102     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 103     add_definitions (-wd4018) # signed/unsigned mismatch
 104
 105     # Use static runtime
 106     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 107     foreach (flag_var
 108         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 109         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 110     )
 111         if (${flag_var} MATCHES "/MD")
 112             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 113         endif (${flag_var} MATCHES "/MD")
 114     endforeach (flag_var)
 115 else ()
 116     # Adjust warnings
 117     add_definitions (-Wall)
 118     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 119     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 120 endif ()
 121
 122
 123 # Put all executables into the same top level build directory, regardless of
 124 # which subdirectory they are declared
 125 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 126
 127
 128 ##############################################################################
 129 # Bundled dependencies
 130 #
 131 # We always use the bundled zlib and libpng sources:
 132 # - on Windows to make it easy to deploy the wrappers DLLs
 133 # - on unices to prevent symbol collisions when tracing applications that link
 134 # against other versions of these libraries
 135
 136 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 137 set (ZLIB_LIBRARIES z_bundled)
 138 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 139
 140 include_directories (${ZLIB_INCLUDE_DIRS})
 141 link_libraries (${ZLIB_LIBRARIES})
 142
 143 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 144 set (SNAPPY_LIBRARIES snappy_bundled)
 145 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 146
 147 include_directories (${SNAPPY_INCLUDE_DIRS})
 148 link_libraries (${SNAPPY_LIBRARIES})
 149
 150 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 151 set (PNG_DEFINITIONS "")
 152 set (PNG_LIBRARIES png_bundled)
 153
 154 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 155 include_directories (${PNG_INCLUDE_DIR})
 156 add_definitions (${PNG_DEFINITIONS})
 157 link_libraries (${PNG_LIBRARIES})
 158
 159 # For glext headers
 160 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 161
 162
 163 ##############################################################################
 164 # Common libraries / utilities
 165
 166 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 167
 168 add_custom_command (
 169     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 170     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 171     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 172 )
 173
 174 if (WIN32)
 175     set (os os_win32.cpp)
 176     set (glws glws_wgl.cpp)
 177 else (WIN32)
 178     set (os os_posix.cpp)
 179     set (glws glws_glx.cpp)
 180 endif (WIN32)
 181
 182 add_library (common
 183     trace_file.cpp
 184     trace_snappyfile.cpp
 185     trace_model.cpp
 186     trace_parser.cpp
 187     trace_writer.cpp
 188     trace_local_writer.cpp
 189     trace_model_writer.cpp
 190     image.cpp
 191     image_bmp.cpp
 192     image_pnm.cpp
 193     image_png.cpp
 194     ${os}
 195 )
 196
 197 set_target_properties (common PROPERTIES
 198     # Ensure it can be statically linked in shared libraries
 199     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}"
 200 )
 201
 202 link_libraries (common)
 203
 204 add_executable (tracedump tracedump.cpp)
 205 install (TARGETS tracedump RUNTIME DESTINATION bin)
 206
 207
 208 ##############################################################################
 209 # API tracers
 210
 211 if (WIN32)
 212     # ddraw.dll
 213     if (DirectX_D3D_INCLUDE_DIR)
 214         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 215         add_custom_command (
 216             OUTPUT ddraw.cpp
 217             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 218             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 219         )
 220         add_library (ddraw MODULE ddraw.def ddraw.cpp)
 221         set_target_properties (ddraw
 222             PROPERTIES PREFIX ""
 223             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 224             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 225         )
 226         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 227     endif (DirectX_D3D_INCLUDE_DIR)
 228
 229     # d3d8.dll
 230     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 231         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 232         add_custom_command (
 233             OUTPUT d3d8.cpp
 234             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 235             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 236         )
 237         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp)
 238         set_target_properties (d3d8
 239             PROPERTIES PREFIX ""
 240             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 241             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 242         )
 243         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 244     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 245
 246     # d3d9.dll
 247     if (DirectX_D3DX9_INCLUDE_DIR)
 248         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 249         add_custom_command (
 250             OUTPUT d3d9.cpp
 251             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 252             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 253         )
 254         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp)
 255         set_target_properties (d3d9
 256             PROPERTIES PREFIX ""
 257             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 258             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 259         )
 260         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 261     endif (DirectX_D3DX9_INCLUDE_DIR)
 262
 263     # d3d10.dll
 264     if (DirectX_D3D10_INCLUDE_DIR)
 265         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 266         add_custom_command (
 267             OUTPUT d3d10.cpp
 268             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 269             DEPENDS d3d10misc.py d3d10.py winapi.py stdapi.py
 270         )
 271         add_library (d3d10 MODULE d3d10.def d3d10.cpp)
 272         set_target_properties (d3d10 PROPERTIES PREFIX "")
 273         install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 274     endif (DirectX_D3D10_INCLUDE_DIR)
 275
 276     # opengl32.dll
 277     add_custom_command (
 278         OUTPUT wgltrace.cpp
 279         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 280         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 281     )
 282     add_library (wgltrace MODULE opengl32.def
 283         wgltrace.cpp
 284         glcaps.cpp
 285         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 286     )
 287     set_target_properties (wgltrace PROPERTIES
 288         PREFIX ""
 289         OUTPUT_NAME opengl32
 290         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 291         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 292     )
 293     if (MINGW)
 294         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 295     endif (MINGW)
 296     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 297
 298 elseif (APPLE)
 299     # OpenGL framework
 300     add_custom_command (
 301         OUTPUT cgltrace.cpp
 302         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 303         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 304     )
 305
 306     add_library (cgltrace SHARED
 307         cgltrace.cpp
 308         glcaps.cpp
 309         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 310     )
 311
 312     set_target_properties (cgltrace PROPERTIES
 313         # OpenGL framework name
 314         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 315         # Specificy the version and reexport GLU symbols
 316         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 317         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 318         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 319     )
 320
 321     target_link_libraries (cgltrace dl)
 322
 323     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 324 else ()
 325     # libGL.so
 326     add_custom_command (
 327         OUTPUT glxtrace.cpp
 328         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 329         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 330     )
 331
 332     add_library (glxtrace SHARED
 333         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 334         glxtrace.cpp
 335         glcaps.cpp
 336         glsnapshot.cpp
 337     )
 338
 339     set_target_properties (glxtrace PROPERTIES
 340         # avoid the default "lib" prefix
 341         PREFIX ""
 342     )
 343
 344     # Prevent symbol relocations internal to our wrapper library to be
 345     # overwritten by the application.
 346     set_target_properties (glxtrace PROPERTIES
 347         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 348     )
 349
 350     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 351
 352     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 353 endif ()
 354
 355
 356 ##############################################################################
 357 # API retracers
 358
 359 add_custom_command (
 360     OUTPUT glretrace_gl.cpp
 361     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 362     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 363 )
 364
 365 add_custom_command (
 366     OUTPUT glstate_params.cpp
 367     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 368     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 369 )
 370
 371 include_directories (
 372     ${CMAKE_CURRENT_BINARY_DIR}
 373     ${OPENGL_INCLUDE_PATH}
 374 )
 375
 376 add_executable (glretrace
 377     glretrace_gl.cpp
 378     glretrace_cgl.cpp
 379     glretrace_glx.cpp
 380     glretrace_wgl.cpp
 381     glretrace_main.cpp
 382     glstate.cpp
 383     glstate_params.cpp
 384     retrace.cpp
 385     ${glws}
 386     image.cpp
 387     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 388 )
 389
 390 set_property (
 391     TARGET glretrace
 392     APPEND
 393     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 394 )
 395
 396 target_link_libraries (glretrace
 397     common
 398 )
 399
 400 if (WIN32)
 401     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 402 elseif (APPLE)
 403     # XXX: We use GLX on MacOSX, which is in a separate library.
 404     target_link_libraries (glretrace
 405         ${X11_GL_LIB}
 406         ${X11_X11_LIB}
 407         "-framework ApplicationServices" # CGS*
 408         ${OPENGL_gl_LIBRARY} # CGL*
 409     )
 410 else ()
 411     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 412 endif ()
 413
 414 install (TARGETS glretrace RUNTIME DESTINATION bin)
 415
 416
 417 ##############################################################################
 418 # GUI
 419
 420 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 421     add_subdirectory(gui)
 422 endif ()
 423
 424
 425 ##############################################################################
 426 # Packaging
 427
 428 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 429
 430 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 431 set (CPACK_PACKAGE_VERSION_MINOR "0")
 432
 433 # Use current date in YYYYMMDD format as patch number
 434 execute_process (
 435     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 436     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 437 )
 438
 439 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 440 if (WIN32)
 441     set (CPACK_GENERATOR "ZIP")
 442 elseif (APPLE)
 443     set (CPACK_GENERATOR "DragNDrop")
 444 else ()
 445     set (CPACK_GENERATOR "TBZ2")
 446 endif ()
 447
 448 include(CPack)