git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3
   4 # Use clang on MacOSX. gcc doesn't support __thread key, and Apple has
   5 # abandoned it for clang.  This must be done before the project is defined.
   6 if (APPLE)
   7     set (CMAKE_C_COMPILER "clang")
   8     set (CMAKE_CXX_COMPILER "clang++")
   9 endif ()
  10
  11
  12 project (apitrace)
  13
  14
  15 ##############################################################################
  16 # Options
  17
  18 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  19 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  20     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  21 endif ()
  22
  23 # We use a cached string variable instead of the standard (boolean) OPTION
  24 # command so that we can default to auto-detecting optional depencies, while
  25 # still providing a mechanism to force/disable these optional dependencies, as
  26 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  27 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  28
  29 set (ENABLE_CLI true CACHE BOOL "Enable command Line interface.")
  30
  31 set (ENABLE_EGL true CACHE BOOL "Enable EGL support.")
  32
  33
  34 ##############################################################################
  35 # Find dependencies
  36
  37 # Ensure __thread is support
  38 if (NOT MSVC)
  39     include (CheckCXXSourceCompiles)
  40     check_cxx_source_compiles("__thread int i; int main() { return 0; }" HAVE_COMPILER_TLS)
  41     if (NOT HAVE_COMPILER_TLS)
  42         if (APPLE)
  43             message (FATAL_ERROR "C++ compiler does not support __thread keyword. Please install XCode 4.5 or higher.")
  44         else (MINGW32)
  45             message (FATAL_ERROR "C++ compiler does not support __thread keyword. Please use MinGW g++ version 4.4 or higher")
  46         else ()
  47             message (FATAL_ERROR "C++ compiler does not support __thread keyword.")
  48         endif ()
  49     endif ()
  50 endif ()
  51
  52 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  53
  54 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  55
  56 if (ANDROID)
  57     set (ENABLE_GUI false)
  58 else ()
  59     macro (find_host_package)
  60         find_package (${ARGN})
  61     endmacro()
  62 endif ()
  63
  64 find_host_package (PythonInterp REQUIRED)
  65 find_package (Threads)
  66
  67 if (ENABLE_GUI)
  68     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  69         set (REQUIRE_GUI REQUIRED)
  70     endif ()
  71     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  72 endif ()
  73
  74 if (WIN32)
  75     find_package (DirectX)
  76     set (ENABLE_EGL false)
  77 elseif (APPLE)
  78     set (ENABLE_EGL false)
  79 else ()
  80     find_package (X11)
  81
  82     if (X11_FOUND)
  83         include_directories (${X11_INCLUDE_DIR})
  84         add_definitions (-DHAVE_X11)
  85     else ()
  86         # Print a clear message when X11 is not found
  87         include (FindPackageMessage)
  88         find_package_message (X11 "Could not find X11" "")
  89     endif ()
  90 endif ()
  91
  92
  93 ##############################################################################
  94 # Set global build options
  95
  96 include (CheckCXXCompilerFlag)
  97
  98 if (WIN32)
  99     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
 100     add_definitions (-D_WIN32_WINNT=0x0601 -DWINVER=0x0601)
 101 else (WIN32)
 102     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
 103     if (CXX_COMPILER_FLAG_VISIBILITY)
 104         add_definitions ("-fvisibility=hidden")
 105     endif ()
 106 endif ()
 107
 108 if (MSVC)
 109     # C99 includes for MSVC
 110     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msinttypes)
 111
 112     # Enable math constants defines
 113     add_definitions (-D_USE_MATH_DEFINES)
 114
 115     # No min/max macros
 116     add_definitions (-DNOMINMAX)
 117
 118     # Adjust warnings
 119     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 120     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 121     add_definitions (-W4)
 122     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 123     add_definitions (-wd4018) # signed/unsigned mismatch
 124     add_definitions (-wd4063) # not a valid value for switch of enum
 125     add_definitions (-wd4100) # unreferenced formal parameter
 126     add_definitions (-wd4127) # conditional expression is constant
 127     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 128     add_definitions (-wd4505) # unreferenced local function has been removed
 129     add_definitions (-wd4512) # assignment operator could not be generated
 130     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 131
 132     # Use static runtime
 133     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 134     foreach (flag_var
 135         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 136         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 137     )
 138         if (${flag_var} MATCHES "/MD")
 139             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 140         endif ()
 141     endforeach (flag_var)
 142 else ()
 143     # Adjust warnings
 144     add_definitions (-Wall)
 145     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 146     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 147
 148     # Use GDB extensions if available
 149     if (CMAKE_COMPILER_IS_GNUC)
 150         set (CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -ggdb -O0")
 151         set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -ggdb")
 152     endif ()
 153     if (CMAKE_COMPILER_IS_GNUCXX)
 154         set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -ggdb -O0")
 155         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} -ggdb")
 156     endif ()
 157
 158     # Be nice to Eclipse
 159     add_definitions (-fmessage-length=0)
 160 endif ()
 161
 162 if (MINGW)
 163     # Avoid depending on MinGW runtime DLLs
 164     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 165     if (HAVE_STATIC_LIBGCC_FLAG)
 166         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 167         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 168         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 169     endif ()
 170     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 171     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 172         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 173         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 174         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 175     endif ()
 176 endif ()
 177
 178
 179 # Put all executables into the same top level build directory, regardless of
 180 # which subdirectory they are declared
 181 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 182
 183
 184 ##############################################################################
 185 # Installation directories
 186
 187 if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 188     # Debian multiarch support
 189     execute_process(COMMAND dpkg-architecture -qDEB_HOST_MULTIARCH
 190         OUTPUT_VARIABLE ARCH_SUBDIR
 191         ERROR_QUIET
 192         OUTPUT_STRIP_TRAILING_WHITESPACE
 193     )
 194 endif()
 195
 196 if (WIN32 OR APPLE)
 197     # On Windows/MacOSX, applications are usually installed on a directory of
 198     # their own
 199     set (DOC_INSTALL_DIR doc)
 200     set (LIB_INSTALL_DIR lib)
 201     set (LIB_ARCH_INSTALL_DIR lib)
 202 else ()
 203     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 204     set (LIB_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 205     if (ARCH_SUBDIR)
 206         set (LIB_ARCH_INSTALL_DIR lib/${ARCH_SUBDIR}/${CMAKE_PROJECT_NAME})
 207     else ()
 208         set (LIB_ARCH_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 209     endif ()
 210 endif ()
 211
 212 set (SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 213 set (WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 214
 215
 216 ##############################################################################
 217 # Bundled dependencies
 218 #
 219 # We always use the bundled zlib, libpng, and snappy sources:
 220 # - on Windows to make it easy to deploy the wrappers DLLs
 221 # - on unices to prevent symbol collisions when tracing applications that link
 222 # against other versions of these libraries
 223
 224 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 225 set (ZLIB_LIBRARIES z_bundled)
 226 add_subdirectory (thirdparty/zlib)
 227
 228 include_directories (${ZLIB_INCLUDE_DIRS})
 229
 230 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 231 set (SNAPPY_LIBRARIES snappy_bundled)
 232 add_subdirectory (thirdparty/snappy)
 233
 234 include_directories (${SNAPPY_INCLUDE_DIRS})
 235
 236 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 237 set (PNG_DEFINITIONS "")
 238 set (PNG_LIBRARIES png_bundled)
 239
 240 add_subdirectory (thirdparty/libpng)
 241
 242 if (MSVC)
 243     add_subdirectory (thirdparty/getopt)
 244     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/getopt)
 245     set (GETOPT_LIBRARIES getopt_bundled)
 246 endif ()
 247
 248 if (WIN32)
 249     add_subdirectory (thirdparty/less)
 250 endif ()
 251
 252 # Always use bundled QJSon.
 253 # - The packaged versions QJson are very old, and do not support NaN/Infinity.
 254 # - To make it easier to build the GUI on Windows and MacOSX, as there are no
 255 # binaries at all.
 256 if (QT4_FOUND)
 257     add_definitions (-DQJSON_EXPORT=)
 258     add_subdirectory (thirdparty/qjson)
 259     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 260     set (QJSON_LIBRARY_DIRS)
 261     set (QJSON_LIBRARIES qjson_bundled)
 262     set (QJSON_FOUND TRUE)
 263 endif ()
 264
 265 # We use bundled headers for all Khronos APIs, to guarantee support for both
 266 # OpenGL and OpenGL ES at build time, because the OpenGL and OpenGL ES 1 APIs
 267 # are so intertwined that conditional compilation extremely difficult. This
 268 # also avoids missing/inconsistent declarations in system headers.
 269 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khronos)
 270
 271
 272 ##############################################################################
 273 # Common libraries / utilities
 274
 275 include_directories (
 276     ${CMAKE_CURRENT_BINARY_DIR}
 277     ${CMAKE_CURRENT_SOURCE_DIR}
 278     ${CMAKE_CURRENT_SOURCE_DIR}/common
 279 )
 280
 281 if (WIN32)
 282     set (os os_win32.cpp)
 283     set (glws_os glws_wgl.cpp)
 284 else ()
 285     set (os os_posix.cpp)
 286     if (APPLE)
 287         set (glws_os glws_cocoa.mm)
 288     else ()
 289         set (glws_os glws_glx.cpp)
 290     endif ()
 291 endif ()
 292
 293 add_library (common STATIC
 294     common/trace_callset.cpp
 295     common/trace_dump.cpp
 296     common/trace_file.cpp
 297     common/trace_file_read.cpp
 298     common/trace_file_write.cpp
 299     common/trace_file_zlib.cpp
 300     common/trace_file_snappy.cpp
 301     common/trace_model.cpp
 302     common/trace_parser.cpp
 303     common/trace_parser_flags.cpp
 304     common/trace_writer.cpp
 305     common/trace_writer_local.cpp
 306     common/trace_writer_model.cpp
 307     common/trace_loader.cpp
 308     common/trace_profiler.cpp
 309     common/trace_option.cpp
 310     common/${os}
 311 )
 312
 313 set_target_properties (common PROPERTIES
 314     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 315     # Ensure it can be statically linked in shared libraries
 316     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 317 )
 318
 319 if (ANDROID)
 320     target_link_libraries (common
 321         log
 322     )
 323 endif ()
 324
 325
 326 ##############################################################################
 327 # Sub-directories
 328
 329 add_subdirectory (dispatch)
 330 add_subdirectory (helpers)
 331 add_subdirectory (wrappers)
 332 add_subdirectory (image)
 333 add_subdirectory (retrace)
 334
 335
 336 ##############################################################################
 337 # CLI
 338
 339 if (ENABLE_CLI)
 340     if (WIN32)
 341         add_subdirectory (inject)
 342     endif ()
 343     add_subdirectory (cli)
 344 endif ()
 345
 346 ##############################################################################
 347 # Scripts (to support the CLI)
 348
 349 install (
 350     PROGRAMS
 351         scripts/highlight.py
 352         scripts/jsondiff.py
 353         scripts/profileshader.py
 354         scripts/retracediff.py
 355         scripts/snapdiff.py
 356         scripts/tracecheck.py
 357         scripts/tracediff.py
 358         scripts/unpickle.py
 359     DESTINATION ${SCRIPTS_INSTALL_DIR}
 360 )
 361 if (WIN32)
 362     install (
 363         PROGRAMS scripts/convert.py
 364         DESTINATION ${SCRIPTS_INSTALL_DIR}
 365     )
 366 endif ()
 367
 368 ##############################################################################
 369 # GUI
 370
 371 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 372     add_subdirectory(gui)
 373 endif ()
 374
 375
 376 ##############################################################################
 377 # Packaging
 378
 379 install (
 380     FILES
 381         BUGS.markdown
 382         NEWS.markdown
 383         README.markdown
 384     DESTINATION ${DOC_INSTALL_DIR}
 385 )
 386 install (
 387     FILES LICENSE
 388     DESTINATION ${DOC_INSTALL_DIR}
 389     RENAME LICENSE.txt
 390 )
 391 if (MSVC)
 392     install (
 393         FILES thirdparty/msinttypes/LICENSE
 394         DESTINATION ${DOC_INSTALL_DIR}
 395         RENAME LICENSE-msinttypes.txt
 396     )
 397 endif ()
 398
 399 set (CPACK_PACKAGE_VERSION_MAJOR "3")
 400 set (CPACK_PACKAGE_VERSION_MINOR "0")
 401
 402 # Use current date in YYYYMMDD format as patch number
 403 execute_process (
 404     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 405     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 406 )
 407
 408 # cpack mistakenly detects Mingw-w64 as win32
 409 if (MINGW)
 410     if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 411         set (CPACK_SYSTEM_NAME win64)
 412     endif ()
 413 endif ()
 414
 415 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 416 if (WIN32)
 417     set (CPACK_GENERATOR "ZIP")
 418 elseif (APPLE)
 419     set (CPACK_GENERATOR "DragNDrop")
 420 else ()
 421     set (CPACK_GENERATOR "TBZ2")
 422 endif ()
 423
 424 include(CPack)