git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8 #
   9 # We use a cached string variable instead of the standard (boolean) OPTION
  10 # command so that we can default to auto-detecting optional depencies, while
  11 # still providing a mechanism to force/disable these optional dependencies, as
  12 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  13
  14 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  15
  16
  17 ##############################################################################
  18 # Find dependencies
  19
  20 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  21
  22 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  23
  24 find_package (PythonInterp REQUIRED)
  25 find_package (OpenGL REQUIRED)
  26
  27 if (ENABLE_GUI)
  28     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  29         set (REQUIRE_GUI REQUIRED)
  30     endif ()
  31     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  32     find_package (QJSON ${REQUIRE_GUI})
  33 endif ()
  34
  35 if (NOT WIN32)
  36     find_package (X11 REQUIRED)
  37
  38     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  39     # from the standard OpenGL framework which provides support for native Mac OS X
  40     # applications.
  41     if (APPLE)
  42         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  43         if (NOT X11_GL_INCLUDE_PATH)
  44             message (SEND_ERROR "Could not find GL/glx.h")
  45         endif (NOT X11_GL_INCLUDE_PATH)
  46         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  47
  48         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  49         if (NOT X11_GL_LIB)
  50             message (SEND_ERROR "Could not find libGL.dylib")
  51         endif (NOT X11_GL_LIB)
  52     else ()
  53         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  54         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  55     endif ()
  56
  57     include_directories (${X11_INCLUDE_DIR})
  58 endif (NOT WIN32)
  59
  60 if (WIN32)
  61     find_package (DirectX)
  62 endif (WIN32)
  63
  64
  65 ##############################################################################
  66 # Set global build options
  67
  68 include (CheckCXXCompilerFlag)
  69
  70 if (WIN32)
  71     # MSVC & MinGW only define & use APIENTRY
  72     add_definitions (-DGLAPIENTRY=__stdcall)
  73
  74     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  75     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  76 else (WIN32)
  77     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  78     if (CXX_COMPILER_FLAG_VISIBILITY)
  79         add_definitions ("-fvisibility=hidden")
  80     endif (CXX_COMPILER_FLAG_VISIBILITY)
  81 endif (WIN32)
  82
  83 if (MSVC)
  84     # C99 includes for msvc
  85     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  86
  87     # Enable math constants defines
  88     add_definitions (-D_USE_MATH_DEFINES)
  89
  90     # No min/max macros
  91     add_definitions (-DNOMINMAX)
  92
  93     # Adjust warnings
  94     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  95     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  96     add_definitions (-W4)
  97     add_definitions (-wd4063) # not a valid value for switch of enum
  98     add_definitions (-wd4127) # conditional expression is constant
  99     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 100     add_definitions (-wd4505) # unreferenced local function has been removed
 101     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 102     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 103     add_definitions (-wd4018) # signed/unsigned mismatch
 104
 105     # Use static runtime
 106     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 107     foreach (flag_var
 108         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 109         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 110     )
 111         if (${flag_var} MATCHES "/MD")
 112             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 113         endif (${flag_var} MATCHES "/MD")
 114     endforeach (flag_var)
 115 else ()
 116     # Adjust warnings
 117     add_definitions (-Wall)
 118     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 119     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 120 endif ()
 121
 122
 123 # Put all executables into the same top level build directory, regardless of
 124 # which subdirectory they are declared
 125 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 126
 127
 128 ##############################################################################
 129 # Bundled dependencies
 130 #
 131 # We always use the bundled zlib and libpng sources:
 132 # - on Windows to make it easy to deploy the wrappers DLLs
 133 # - on unices to prevent symbol collisions when tracing applications that link
 134 # against other versions of these libraries
 135
 136 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 137 set (ZLIB_LIBRARIES z_bundled)
 138 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 139
 140 include_directories (${ZLIB_INCLUDE_DIRS})
 141 link_libraries (${ZLIB_LIBRARIES})
 142
 143 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 144 set (SNAPPY_LIBRARIES snappy_bundled)
 145 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 146
 147 include_directories (${SNAPPY_INCLUDE_DIRS})
 148 link_libraries (${SNAPPY_LIBRARIES})
 149
 150 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 151 set (PNG_DEFINITIONS "")
 152 set (PNG_LIBRARIES png_bundled)
 153
 154 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 155 include_directories (${PNG_INCLUDE_DIR})
 156 add_definitions (${PNG_DEFINITIONS})
 157 link_libraries (${PNG_LIBRARIES})
 158
 159 # For glext headers
 160 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 161
 162
 163 ##############################################################################
 164 # Common libraries / utilities
 165
 166 include_directories (
 167     ${CMAKE_CURRENT_SOURCE_DIR}
 168     ${CMAKE_CURRENT_SOURCE_DIR}/common
 169 )
 170
 171 add_custom_command (
 172     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 173     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 174     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 175 )
 176
 177 if (WIN32)
 178     set (os os_win32.cpp)
 179     set (glws glws_wgl.cpp)
 180 else (WIN32)
 181     set (os os_posix.cpp)
 182     set (glws glws_glx.cpp)
 183 endif (WIN32)
 184
 185 add_library (common
 186     common/trace_file.cpp
 187     common/trace_snappyfile.cpp
 188     common/trace_model.cpp
 189     common/trace_parser.cpp
 190     common/trace_writer.cpp
 191     common/trace_local_writer.cpp
 192     common/trace_model_writer.cpp
 193     common/trace_loader.cpp
 194     common/image.cpp
 195     common/image_bmp.cpp
 196     common/image_pnm.cpp
 197     common/image_png.cpp
 198     common/${os}
 199 )
 200
 201 set_target_properties (common PROPERTIES
 202     # Ensure it can be statically linked in shared libraries
 203     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}"
 204 )
 205
 206 link_libraries (common)
 207
 208 add_executable (tracedump tracedump.cpp)
 209 install (TARGETS tracedump RUNTIME DESTINATION bin)
 210
 211
 212 ##############################################################################
 213 # API tracers
 214
 215 if (WIN32)
 216     # ddraw.dll
 217     if (DirectX_D3D_INCLUDE_DIR)
 218         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 219         add_custom_command (
 220             OUTPUT ddrawtrace.cpp
 221             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 222             DEPENDS ddrawtrace.py d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 223         )
 224         add_library (ddraw MODULE ddraw.def ddrawtrace.cpp)
 225         set_target_properties (ddraw
 226             PROPERTIES PREFIX ""
 227             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 228             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 229         )
 230         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 231     endif (DirectX_D3D_INCLUDE_DIR)
 232
 233     # d3d8.dll
 234     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 235         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 236         add_custom_command (
 237             OUTPUT d3d8trace.cpp
 238             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 239             DEPENDS d3d8trace.py d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 240         )
 241         add_library (d3d8 MODULE d3d8.def d3d8trace.cpp d3dshader.cpp)
 242         set_target_properties (d3d8
 243             PROPERTIES PREFIX ""
 244             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 245             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 246         )
 247         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 248     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 249
 250     # d3d9.dll
 251     if (DirectX_D3DX9_INCLUDE_DIR)
 252         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 253         add_custom_command (
 254             OUTPUT d3d9trace.cpp
 255             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 256             DEPENDS d3d9trace.py d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 257         )
 258         add_library (d3d9 MODULE d3d9.def d3d9trace.cpp d3dshader.cpp)
 259         set_target_properties (d3d9
 260             PROPERTIES PREFIX ""
 261             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 262             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 263         )
 264         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 265     endif (DirectX_D3DX9_INCLUDE_DIR)
 266
 267     # d3d10.dll
 268     if (DirectX_D3D10_INCLUDE_DIR)
 269         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 270         add_custom_command (
 271             OUTPUT d3d10trace.cpp
 272             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 273             DEPENDS d3d10misc.py d3d10.py winapi.py stdapi.py
 274         )
 275         add_library (d3d10 MODULE d3d10.def d3d10trace.cpp)
 276         set_target_properties (d3d10 PROPERTIES PREFIX "")
 277         install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 278     endif (DirectX_D3D10_INCLUDE_DIR)
 279
 280     # opengl32.dll
 281     add_custom_command (
 282         OUTPUT wgltrace.cpp
 283         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 284         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 285     )
 286     add_library (wgltrace MODULE opengl32.def
 287         wgltrace.cpp
 288         glcaps.cpp
 289         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 290     )
 291     set_target_properties (wgltrace PROPERTIES
 292         PREFIX ""
 293         OUTPUT_NAME opengl32
 294         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 295         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 296     )
 297     if (MINGW)
 298         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 299     endif (MINGW)
 300     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 301
 302 elseif (APPLE)
 303     # OpenGL framework
 304     add_custom_command (
 305         OUTPUT cgltrace.cpp
 306         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 307         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 308     )
 309
 310     add_library (cgltrace SHARED
 311         cgltrace.cpp
 312         glcaps.cpp
 313         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 314     )
 315
 316     set_target_properties (cgltrace PROPERTIES
 317         # OpenGL framework name
 318         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 319         # Specificy the version and reexport GLU symbols
 320         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 321         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 322         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 323     )
 324
 325     target_link_libraries (cgltrace dl)
 326
 327     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 328 else ()
 329     # libGL.so
 330     add_custom_command (
 331         OUTPUT glxtrace.cpp
 332         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 333         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 334     )
 335
 336     add_library (glxtrace SHARED
 337         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 338         glxtrace.cpp
 339         glcaps.cpp
 340         glsnapshot.cpp
 341     )
 342
 343     set_target_properties (glxtrace PROPERTIES
 344         # avoid the default "lib" prefix
 345         PREFIX ""
 346     )
 347
 348     # Prevent symbol relocations internal to our wrapper library to be
 349     # overwritten by the application.
 350     set_target_properties (glxtrace PROPERTIES
 351         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 352     )
 353
 354     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 355
 356     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 357 endif ()
 358
 359
 360 ##############################################################################
 361 # API retracers
 362
 363 add_custom_command (
 364     OUTPUT glretrace_gl.cpp
 365     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 366     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 367 )
 368
 369 add_custom_command (
 370     OUTPUT glstate_params.cpp
 371     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 372     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 373 )
 374
 375 include_directories (
 376     ${CMAKE_CURRENT_BINARY_DIR}
 377     ${OPENGL_INCLUDE_PATH}
 378 )
 379
 380 add_executable (glretrace
 381     glretrace_gl.cpp
 382     glretrace_cgl.cpp
 383     glretrace_glx.cpp
 384     glretrace_wgl.cpp
 385     glretrace_main.cpp
 386     glstate.cpp
 387     glstate_params.cpp
 388     retrace.cpp
 389     ${glws}
 390     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 391 )
 392
 393 set_property (
 394     TARGET glretrace
 395     APPEND
 396     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 397 )
 398
 399 target_link_libraries (glretrace
 400     common
 401 )
 402
 403 if (WIN32)
 404     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 405 elseif (APPLE)
 406     # XXX: We use GLX on MacOSX, which is in a separate library.
 407     target_link_libraries (glretrace
 408         ${X11_GL_LIB}
 409         ${X11_X11_LIB}
 410         "-framework ApplicationServices" # CGS*
 411         ${OPENGL_gl_LIBRARY} # CGL*
 412     )
 413 else ()
 414     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 415 endif ()
 416
 417 install (TARGETS glretrace RUNTIME DESTINATION bin)
 418
 419
 420 ##############################################################################
 421 # GUI
 422
 423 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 424     add_subdirectory(gui)
 425 endif ()
 426
 427
 428 ##############################################################################
 429 # Packaging
 430
 431 install (
 432     FILES
 433         BUGS.markdown
 434         LICENSE
 435         NEWS.markdown
 436         README.markdown
 437         TODO.markdown
 438     DESTINATION doc)
 439
 440 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 441 set (CPACK_PACKAGE_VERSION_MINOR "0")
 442
 443 # Use current date in YYYYMMDD format as patch number
 444 execute_process (
 445     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 446     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 447 )
 448
 449 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 450 if (WIN32)
 451     set (CPACK_GENERATOR "ZIP")
 452 elseif (APPLE)
 453     set (CPACK_GENERATOR "DragNDrop")
 454 else ()
 455     set (CPACK_GENERATOR "TBZ2")
 456 endif ()
 457
 458 include(CPack)