git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Find dependencies
   8
   9 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  10
  11 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  12
  13 find_package (PythonInterp REQUIRED)
  14 find_package (OpenGL REQUIRED)
  15 find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit)
  16 find_package (QJSON)
  17
  18 if (NOT WIN32)
  19     find_package (X11 REQUIRED)
  20
  21     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  22     # from the standard OpenGL framework which provides support for native Mac OS X
  23     # applications.
  24     if (APPLE)
  25         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  26         if (NOT X11_GL_INCLUDE_PATH)
  27             message (SEND_ERROR "Could not find GL/glx.h")
  28         endif (NOT X11_GL_INCLUDE_PATH)
  29         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  30
  31         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  32         if (NOT X11_GL_LIB)
  33             message (SEND_ERROR "Could not find libGL.dylib")
  34         endif (NOT X11_GL_LIB)
  35     else ()
  36         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  37         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  38     endif ()
  39
  40     include_directories (${X11_INCLUDE_DIR})
  41 endif (NOT WIN32)
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 endif (WIN32)
  46
  47
  48 ##############################################################################
  49 # Set global build options
  50
  51 include (CheckCXXCompilerFlag)
  52
  53 if (WIN32)
  54     # MSVC & MinGW only define & use APIENTRY
  55     add_definitions (-DGLAPIENTRY=__stdcall)
  56
  57     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  58     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  59 else (WIN32)
  60     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  61     if (CXX_COMPILER_FLAG_VISIBILITY)
  62         add_definitions ("-fvisibility=hidden")
  63     endif (CXX_COMPILER_FLAG_VISIBILITY)
  64 endif (WIN32)
  65
  66 if (MSVC)
  67     # C99 includes for msvc
  68     include_directories (msvc)
  69
  70     # Enable math constants defines
  71     add_definitions (-D_USE_MATH_DEFINES)
  72
  73     # No min/max macros
  74     add_definitions (-DNOMINMAX)
  75
  76     # Adjust warnings
  77     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  78     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  79     add_definitions (-W4)
  80     add_definitions (-wd4063) # not a valid value for switch of enum
  81     add_definitions (-wd4127) # conditional expression is constant
  82     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  83     add_definitions (-wd4505) # unreferenced local function has been removed
  84     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  85     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  86     add_definitions (-wd4018) # signed/unsigned mismatch
  87
  88     # Use static runtime
  89     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  90     foreach (flag_var
  91         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  92         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  93     )
  94         if (${flag_var} MATCHES "/MD")
  95             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  96         endif (${flag_var} MATCHES "/MD")
  97     endforeach (flag_var)
  98 else ()
  99     # Adjust warnings
 100     add_definitions (-Wall)
 101     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 102     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 103 endif ()
 104
 105
 106 # Put all executables into the same top level build directory, regardless of
 107 # which subdirectory they are declared
 108 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 109
 110 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 111
 112
 113 ##############################################################################
 114 # Bundled dependencies
 115 #
 116 # We always use the bundled zlib and libpng sources:
 117 # - on Windows to make it easy to deploy the wrappers DLLs
 118 # - on unices to prevent symbol collisions when tracing applications that link
 119 # against other versions of these libraries
 120
 121 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/zlib)
 122 set (ZLIB_LIBRARIES z_bundled)
 123 add_subdirectory (zlib EXCLUDE_FROM_ALL)
 124
 125 include_directories (${ZLIB_INCLUDE_DIRS})
 126 link_libraries (${ZLIB_LIBRARIES})
 127
 128 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/libpng)
 129 set (PNG_DEFINITIONS "")
 130 set (PNG_LIBRARIES png_bundled)
 131
 132 add_subdirectory (libpng EXCLUDE_FROM_ALL)
 133 include_directories (${PNG_INCLUDE_DIR})
 134 add_definitions (${PNG_DEFINITIONS})
 135 link_libraries (${PNG_LIBRARIES})
 136
 137
 138 ##############################################################################
 139 # Common libraries / utilities
 140
 141 add_custom_command (
 142     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 143     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 144     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 145 )
 146
 147 if (WIN32)
 148     set (os os_win32.cpp)
 149     set (glws glws_wgl.cpp)
 150 else (WIN32)
 151     set (os os_posix.cpp)
 152     set (glws glws_glx.cpp)
 153 endif (WIN32)
 154
 155 add_library (trace trace_model.cpp trace_parser.cpp trace_writer.cpp trace_model_writer.cpp ${os})
 156
 157 add_executable (tracedump tracedump.cpp)
 158 target_link_libraries (tracedump trace)
 159 install (TARGETS tracedump RUNTIME DESTINATION bin)
 160
 161
 162 ##############################################################################
 163 # API tracers
 164
 165 if (WIN32)
 166     # ddraw.dll
 167     if (DirectX_D3D_INCLUDE_DIR)
 168         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 169         add_custom_command (
 170             OUTPUT ddraw.cpp
 171             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 172             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 173         )
 174         add_library (ddraw MODULE ddraw.def ddraw.cpp trace_writer.cpp os_win32.cpp)
 175         set_target_properties (ddraw
 176             PROPERTIES PREFIX ""
 177             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 178             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 179         )
 180         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 181     endif (DirectX_D3D_INCLUDE_DIR)
 182
 183     # d3d8.dll
 184     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 185         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 186         add_custom_command (
 187             OUTPUT d3d8.cpp
 188             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 189             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 190         )
 191         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 192         set_target_properties (d3d8
 193             PROPERTIES PREFIX ""
 194             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 195             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 196         )
 197         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 198     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 199
 200     # d3d9.dll
 201     if (DirectX_D3DX9_INCLUDE_DIR)
 202         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 203         add_custom_command (
 204             OUTPUT d3d9.cpp
 205             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 206             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 207         )
 208         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 209         set_target_properties (d3d9
 210             PROPERTIES PREFIX ""
 211             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 212             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 213         )
 214         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 215     endif (DirectX_D3DX9_INCLUDE_DIR)
 216
 217     # d3d10.dll
 218     #if (DirectX_D3D10_INCLUDE_DIR)
 219     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 220     #    add_custom_command (
 221     #        OUTPUT d3d10.cpp
 222     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 223     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 224     #    )
 225     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp trace_writer.cpp os_win32.cpp)
 226     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 227     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 228     #endif (DirectX_D3D10_INCLUDE_DIR)
 229
 230     # opengl32.dll
 231     add_custom_command (
 232         OUTPUT wgltrace.cpp
 233         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 234         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 235     )
 236     add_library (wgltrace MODULE opengl32.def wgltrace.cpp trace_writer.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 237     set_target_properties (wgltrace PROPERTIES
 238         PREFIX ""
 239         OUTPUT_NAME opengl32
 240         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 241         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 242     )
 243     if (MINGW)
 244         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 245     endif (MINGW)
 246     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 247
 248 elseif (APPLE)
 249     # OpenGL framework
 250     add_custom_command (
 251         OUTPUT cgltrace.cpp
 252         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 253         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 254     )
 255
 256     add_library (cgltrace SHARED cgltrace.cpp trace_writer.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 257
 258     set_target_properties (cgltrace PROPERTIES
 259         # OpenGL framework name
 260         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 261         # Specificy the version and reexport GLU symbols
 262         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 263         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 264         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 265     )
 266
 267     target_link_libraries (cgltrace dl)
 268
 269     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 270 else ()
 271     # libGL.so
 272     add_custom_command (
 273         OUTPUT glxtrace.cpp
 274         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 275         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 276     )
 277
 278     add_library (glxtrace SHARED
 279         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 280         glxtrace.cpp
 281         glsnapshot.cpp
 282         trace_writer.cpp
 283         image.cpp
 284         os_posix.cpp
 285     )
 286
 287     set_target_properties (glxtrace PROPERTIES
 288         # avoid the default "lib" prefix
 289         PREFIX ""
 290     )
 291
 292     # Prevent symbol relocations internal to our wrapper library to be
 293     # overwritten by the application.
 294     set_target_properties (glxtrace PROPERTIES
 295         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 296     )
 297
 298     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 299
 300     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 301 endif ()
 302
 303
 304 ##############################################################################
 305 # API retracers
 306
 307 add_custom_command (
 308     OUTPUT glretrace_gl.cpp
 309     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 310     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 311 )
 312
 313 add_custom_command (
 314     OUTPUT glstate_params.cpp
 315     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 316     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 317 )
 318
 319 include_directories (
 320     ${CMAKE_CURRENT_BINARY_DIR}
 321     ${OPENGL_INCLUDE_PATH}
 322 )
 323
 324 add_executable (glretrace
 325     glretrace_gl.cpp
 326     glretrace_cgl.cpp
 327     glretrace_glx.cpp
 328     glretrace_wgl.cpp
 329     glretrace_main.cpp
 330     glstate.cpp
 331     glstate_params.cpp
 332     retrace.cpp
 333     ${glws}
 334     image.cpp
 335     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 336 )
 337
 338 set_property (
 339     TARGET glretrace
 340     APPEND
 341     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 342 )
 343
 344 target_link_libraries (glretrace
 345     trace
 346 )
 347
 348 if (WIN32)
 349     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 350 elseif (APPLE)
 351     # XXX: We use GLX on MacOSX, which is in a separate library.
 352     target_link_libraries (glretrace
 353         ${X11_GL_LIB}
 354         ${X11_X11_LIB}
 355         "-framework ApplicationServices" # CGS*
 356         ${OPENGL_gl_LIBRARY} # CGL*
 357     )
 358 else ()
 359     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 360 endif ()
 361
 362 install (TARGETS glretrace RUNTIME DESTINATION bin)
 363
 364
 365 ##############################################################################
 366 # GUI
 367
 368 if (QT4_FOUND AND QJSON_FOUND)
 369     add_subdirectory(gui)
 370 endif (QT4_FOUND AND QJSON_FOUND)
 371
 372
 373 ##############################################################################
 374 # Packaging
 375
 376 install (FILES LICENSE README TODO DESTINATION doc)
 377
 378 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 379 set (CPACK_PACKAGE_VERSION_MINOR "0")
 380
 381 # Use current date in YYYYMMDD format as patch number
 382 execute_process (
 383     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 384     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 385 )
 386
 387 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 388 if (WIN32)
 389     set (CPACK_GENERATOR "ZIP")
 390 elseif (APPLE)
 391     set (CPACK_GENERATOR "DragNDrop")
 392 else ()
 393     set (CPACK_GENERATOR "TBZ2")
 394 endif ()
 395
 396 include(CPack)