git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20
  21 ##############################################################################
  22 # Find dependencies
  23
  24 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  25
  26 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  27
  28 find_package (PythonInterp REQUIRED)
  29 find_package (OpenGL REQUIRED)
  30
  31 if (ENABLE_GUI)
  32     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  33         set (REQUIRE_GUI REQUIRED)
  34     endif ()
  35     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  36     find_package (QJSON ${REQUIRE_GUI})
  37 endif ()
  38
  39 if (WIN32)
  40     find_package (DirectX)
  41 elseif (APPLE)
  42 else ()
  43     find_package (X11 REQUIRED)
  44
  45     set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  46     set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  47
  48     include_directories (${X11_INCLUDE_DIR})
  49 endif ()
  50
  51
  52 ##############################################################################
  53 # Set global build options
  54
  55 include (CheckCXXCompilerFlag)
  56
  57 if (WIN32)
  58     # MSVC & MinGW only define & use APIENTRY
  59     add_definitions (-DGLAPIENTRY=__stdcall)
  60
  61     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  62     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  63 else (WIN32)
  64     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  65     if (CXX_COMPILER_FLAG_VISIBILITY)
  66         add_definitions ("-fvisibility=hidden")
  67     endif (CXX_COMPILER_FLAG_VISIBILITY)
  68 endif (WIN32)
  69
  70 if (MSVC)
  71     # C99 includes for msvc
  72     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  73
  74     # Enable math constants defines
  75     add_definitions (-D_USE_MATH_DEFINES)
  76
  77     # No min/max macros
  78     add_definitions (-DNOMINMAX)
  79
  80     # Adjust warnings
  81     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  82     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  83     add_definitions (-W4)
  84     add_definitions (-wd4063) # not a valid value for switch of enum
  85     add_definitions (-wd4127) # conditional expression is constant
  86     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  87     add_definitions (-wd4505) # unreferenced local function has been removed
  88     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  89     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  90     add_definitions (-wd4018) # signed/unsigned mismatch
  91
  92     # Use static runtime
  93     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  94     foreach (flag_var
  95         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  96         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  97     )
  98         if (${flag_var} MATCHES "/MD")
  99             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 100         endif (${flag_var} MATCHES "/MD")
 101     endforeach (flag_var)
 102 else ()
 103     # Adjust warnings
 104     add_definitions (-Wall)
 105     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 106     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 107 endif ()
 108
 109 if (MINGW)
 110     # Avoid depending on MinGW runtime DLLs
 111     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 112     if (HAVE_STATIC_LIBGCC_FLAG)
 113         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 114         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 115         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 116     endif ()
 117     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 118     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 119         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 120         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 121         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 122     endif ()
 123 endif ()
 124
 125
 126 # Put all executables into the same top level build directory, regardless of
 127 # which subdirectory they are declared
 128 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 129
 130
 131 ##############################################################################
 132 # Bundled dependencies
 133 #
 134 # We always use the bundled zlib, libpng, and snappy sources:
 135 # - on Windows to make it easy to deploy the wrappers DLLs
 136 # - on unices to prevent symbol collisions when tracing applications that link
 137 # against other versions of these libraries
 138
 139 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 140 set (ZLIB_LIBRARIES z_bundled)
 141 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 142
 143 include_directories (${ZLIB_INCLUDE_DIRS})
 144 link_libraries (${ZLIB_LIBRARIES})
 145
 146 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 147 set (SNAPPY_LIBRARIES snappy_bundled)
 148 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 149
 150 include_directories (${SNAPPY_INCLUDE_DIRS})
 151 link_libraries (${SNAPPY_LIBRARIES})
 152
 153 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 154 set (PNG_DEFINITIONS "")
 155 set (PNG_LIBRARIES png_bundled)
 156
 157 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 158 include_directories (${PNG_INCLUDE_DIR})
 159 add_definitions (${PNG_DEFINITIONS})
 160 link_libraries (${PNG_LIBRARIES})
 161
 162 # The Qt website provides binaries for Windows and MacOSX, and they are
 163 # automatically found by cmake without any manual intervention.  The situation
 164 # for QJSON is substantially different: there are no binaries for QJSON
 165 # available, and there is no standard installation directory that is detected
 166 # by cmake.
 167 #
 168 # By bundling the QJSON source, we make it much more easier to build the GUI on
 169 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 170 # AUTO.
 171 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 172     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 173     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 174     set (QJSON_LIBRARY_DIRS)
 175     set (QJSON_LIBRARIES qjson_bundled)
 176     set (QJSON_FOUND TRUE)
 177 endif ()
 178
 179 # For glext headers
 180 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 181
 182
 183 ##############################################################################
 184 # Installation directories
 185
 186 if (WIN32 OR APPLE)
 187     # On Windows/MacOSX, applications are usually installed on a directory of
 188     # their own
 189     set (DOC_INSTALL_DIR doc)
 190 else ()
 191     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 192 endif ()
 193
 194 if (APPLE)
 195     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 196     # directories
 197     set (WRAPPER_INSTALL_DIR lib/apitrace)
 198 else ()
 199     set (WRAPPER_INSTALL_DIR lib/apitrace/${CMAKE_SYSTEM_PROCESSOR})
 200 endif ()
 201
 202 # Expose the binary/install directories to source
 203 #
 204 # TODO: Use the same directory layout, for both build and install directories,
 205 # so that binaries can find each other using just relative paths.
 206 #
 207 add_definitions(
 208     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 209     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 210     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 211 )
 212
 213
 214 ##############################################################################
 215 # Common libraries / utilities
 216
 217 include_directories (
 218     ${CMAKE_CURRENT_SOURCE_DIR}
 219     ${CMAKE_CURRENT_SOURCE_DIR}/common
 220 )
 221
 222 add_custom_command (
 223     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 224     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 225     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 226 )
 227
 228 if (WIN32)
 229     set (os os_win32.cpp)
 230     set (glws_os glws_wgl.cpp)
 231 else ()
 232     set (os os_posix.cpp)
 233     if (APPLE)
 234         set (glws_os glws_cocoa.mm)
 235     else ()
 236         set (glws_os glws_glx.cpp)
 237     endif ()
 238 endif ()
 239
 240 add_library (common STATIC
 241     common/trace_file.cpp
 242     common/trace_file_zlib.cpp
 243     common/trace_file_snappy.cpp
 244     common/trace_model.cpp
 245     common/trace_parser.cpp
 246     common/trace_writer.cpp
 247     common/trace_writer_local.cpp
 248     common/trace_writer_model.cpp
 249     common/trace_loader.cpp
 250     common/image.cpp
 251     common/image_bmp.cpp
 252     common/image_pnm.cpp
 253     common/image_png.cpp
 254     common/${os}
 255 )
 256
 257 set_target_properties (common PROPERTIES
 258     # Ensure it can be statically linked in shared libraries
 259     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 260 )
 261
 262 link_libraries (common)
 263
 264
 265 ##############################################################################
 266 # API tracers
 267
 268 if (WIN32)
 269     if (MINGW)
 270         # Silence warnings about @nn suffix mismatch
 271         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 272     endif (MINGW)
 273
 274     # ddraw.dll
 275     if (DirectX_D3D_INCLUDE_DIR)
 276         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 277         add_custom_command (
 278             OUTPUT ddrawtrace.cpp
 279             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 280             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 281         )
 282         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 283         set_target_properties (ddraw
 284             PROPERTIES PREFIX ""
 285             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 286             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 287         )
 288         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 289     endif (DirectX_D3D_INCLUDE_DIR)
 290
 291     # d3d8.dll
 292     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 293         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 294         add_custom_command (
 295             OUTPUT d3d8trace.cpp
 296             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 297             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 298         )
 299         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 300         set_target_properties (d3d8
 301             PROPERTIES PREFIX ""
 302             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 303             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 304         )
 305         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 306     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 307
 308     # d3d9.dll
 309     if (DirectX_D3DX9_INCLUDE_DIR)
 310         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 311         add_custom_command (
 312             OUTPUT d3d9trace.cpp
 313             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 314             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 315         )
 316         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 317         set_target_properties (d3d9
 318             PROPERTIES PREFIX ""
 319             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 320             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 321         )
 322         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 323     endif (DirectX_D3DX9_INCLUDE_DIR)
 324
 325     # d3d10.dll
 326     if (DirectX_D3D10_INCLUDE_DIR)
 327         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 328         add_custom_command (
 329             OUTPUT d3d10trace.cpp
 330             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 331             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 332         )
 333         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 334         set_target_properties (d3d10
 335             PROPERTIES PREFIX ""
 336             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 337             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 338         )
 339         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 340     endif (DirectX_D3D10_INCLUDE_DIR)
 341
 342     # opengl32.dll
 343     add_custom_command (
 344         OUTPUT wgltrace.cpp
 345         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 346         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 347     )
 348     add_library (wgltrace MODULE specs/opengl32.def
 349         wgltrace.cpp
 350         glcaps.cpp
 351         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 352     )
 353     set_target_properties (wgltrace PROPERTIES
 354         PREFIX ""
 355         OUTPUT_NAME opengl32
 356         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 357         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 358     )
 359     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 360
 361 elseif (APPLE)
 362     # OpenGL framework
 363     add_custom_command (
 364         OUTPUT cgltrace.cpp
 365         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 366         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 367     )
 368
 369     add_library (cgltrace SHARED
 370         cgltrace.cpp
 371         glcaps.cpp
 372         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 373     )
 374
 375     set_target_properties (cgltrace PROPERTIES
 376         # OpenGL framework name
 377         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 378         # Specificy the version and reexport GLU symbols
 379         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 380         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 381         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 382     )
 383
 384     target_link_libraries (cgltrace dl)
 385
 386     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 387 else ()
 388     # libGL.so
 389     add_custom_command (
 390         OUTPUT glxtrace.cpp
 391         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 392         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 393     )
 394
 395     add_library (glxtrace SHARED
 396         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 397         glxtrace.cpp
 398         glcaps.cpp
 399         glsnapshot.cpp
 400     )
 401
 402     set_target_properties (glxtrace PROPERTIES
 403         # avoid the default "lib" prefix
 404         PREFIX ""
 405     )
 406
 407     # Prevent symbol relocations internal to our wrapper library to be
 408     # overwritten by the application.
 409     set_target_properties (glxtrace PROPERTIES
 410         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 411     )
 412
 413     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 414
 415     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 416 endif ()
 417
 418
 419 ##############################################################################
 420 # API retracers
 421
 422 add_custom_command (
 423     OUTPUT glretrace_gl.cpp
 424     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 425     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 426 )
 427
 428 add_custom_command (
 429     OUTPUT glstate_params.cpp
 430     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 431     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 432 )
 433
 434 include_directories (
 435     ${CMAKE_CURRENT_BINARY_DIR}
 436     ${OPENGL_INCLUDE_PATH}
 437 )
 438
 439 add_executable (glretrace
 440     glretrace_gl.cpp
 441     glretrace_cgl.cpp
 442     glretrace_glx.cpp
 443     glretrace_wgl.cpp
 444     glretrace_main.cpp
 445     glstate.cpp
 446     glstate_params.cpp
 447     retrace.cpp
 448     retrace_stdc.cpp
 449     glws.cpp
 450     ${glws_os}
 451     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 452 )
 453
 454 set_property (
 455     TARGET glretrace
 456     APPEND
 457     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 458 )
 459
 460 target_link_libraries (glretrace
 461     common
 462 )
 463
 464 if (WIN32)
 465     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 466 elseif (APPLE)
 467     target_link_libraries (glretrace
 468         "-framework Cocoa"
 469         "-framework ApplicationServices" # CGS*
 470         ${OPENGL_gl_LIBRARY} # CGL*
 471     )
 472 else ()
 473     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 474 endif ()
 475
 476 install (TARGETS glretrace RUNTIME DESTINATION bin)
 477
 478 ##############################################################################
 479 # CLI
 480
 481 add_subdirectory(cli)
 482
 483 ##############################################################################
 484 # GUI
 485
 486 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 487     add_subdirectory(gui)
 488 endif ()
 489
 490
 491 ##############################################################################
 492 # Packaging
 493
 494 install (
 495     FILES
 496         BUGS.markdown
 497         LICENSE
 498         NEWS.markdown
 499         README.markdown
 500         TODO.markdown
 501     DESTINATION ${DOC_INSTALL_DIR}
 502 )
 503
 504 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 505 set (CPACK_PACKAGE_VERSION_MINOR "0")
 506
 507 # Use current date in YYYYMMDD format as patch number
 508 execute_process (
 509     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 510     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 511 )
 512
 513 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 514 if (WIN32)
 515     set (CPACK_GENERATOR "ZIP")
 516 elseif (APPLE)
 517     set (CPACK_GENERATOR "DragNDrop")
 518 else ()
 519     set (CPACK_GENERATOR "TBZ2")
 520 endif ()
 521
 522 include(CPack)