git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 include_directories (${OPENGL_INCLUDE_DIR})
  44
  45 if (WIN32)
  46     find_package (DirectX)
  47 elseif (APPLE)
  48 else ()
  49     find_package (X11 REQUIRED)
  50
  51     include_directories (${X11_INCLUDE_DIR})
  52
  53     if (ENABLE_EGL)
  54         if (NOT ENABLE_EGL STREQUAL "AUTO")
  55             set (REQUIRE_EGL REQUIRED)
  56         endif ()
  57         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  58         if (EGL_FOUND)
  59             include_directories (${EGL_INCLUDE_DIR})
  60             add_definitions (-DHAVE_EGL)
  61         endif ()
  62     else ()
  63         set (EGL_FOUND 0)
  64     endif ()
  65 endif ()
  66
  67
  68 ##############################################################################
  69 # Set global build options
  70
  71 include (CheckCXXCompilerFlag)
  72
  73 if (WIN32)
  74     # MSVC & MinGW only define & use APIENTRY
  75     add_definitions (-DGLAPIENTRY=__stdcall)
  76
  77     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  78     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  79 else (WIN32)
  80     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  81     if (CXX_COMPILER_FLAG_VISIBILITY)
  82         add_definitions ("-fvisibility=hidden")
  83     endif (CXX_COMPILER_FLAG_VISIBILITY)
  84 endif (WIN32)
  85
  86 if (MSVC)
  87     # C99 includes for msvc
  88     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  89
  90     # Enable math constants defines
  91     add_definitions (-D_USE_MATH_DEFINES)
  92
  93     # No min/max macros
  94     add_definitions (-DNOMINMAX)
  95
  96     # Adjust warnings
  97     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  98     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  99     add_definitions (-W4)
 100     add_definitions (-wd4063) # not a valid value for switch of enum
 101     add_definitions (-wd4127) # conditional expression is constant
 102     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 103     add_definitions (-wd4505) # unreferenced local function has been removed
 104     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 105     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 106     add_definitions (-wd4018) # signed/unsigned mismatch
 107
 108     # Use static runtime
 109     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 110     foreach (flag_var
 111         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 112         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 113     )
 114         if (${flag_var} MATCHES "/MD")
 115             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 116         endif (${flag_var} MATCHES "/MD")
 117     endforeach (flag_var)
 118 else ()
 119     # Adjust warnings
 120     add_definitions (-Wall)
 121     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 122     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 123 endif ()
 124
 125 if (MINGW)
 126     # Avoid depending on MinGW runtime DLLs
 127     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 128     if (HAVE_STATIC_LIBGCC_FLAG)
 129         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 130         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 131         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 132     endif ()
 133     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 134     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 135         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 136         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 137         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 138     endif ()
 139 endif ()
 140
 141
 142 # Put all executables into the same top level build directory, regardless of
 143 # which subdirectory they are declared
 144 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 145
 146
 147 ##############################################################################
 148 # Bundled dependencies
 149 #
 150 # We always use the bundled zlib, libpng, and snappy sources:
 151 # - on Windows to make it easy to deploy the wrappers DLLs
 152 # - on unices to prevent symbol collisions when tracing applications that link
 153 # against other versions of these libraries
 154
 155 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 156 set (ZLIB_LIBRARIES z_bundled)
 157 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 158
 159 include_directories (${ZLIB_INCLUDE_DIRS})
 160 link_libraries (${ZLIB_LIBRARIES})
 161
 162 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 163 set (SNAPPY_LIBRARIES snappy_bundled)
 164 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 165
 166 include_directories (${SNAPPY_INCLUDE_DIRS})
 167 link_libraries (${SNAPPY_LIBRARIES})
 168
 169 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 170 set (PNG_DEFINITIONS "")
 171 set (PNG_LIBRARIES png_bundled)
 172
 173 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 174 include_directories (${PNG_INCLUDE_DIR})
 175 add_definitions (${PNG_DEFINITIONS})
 176 link_libraries (${PNG_LIBRARIES})
 177
 178 # The Qt website provides binaries for Windows and MacOSX, and they are
 179 # automatically found by cmake without any manual intervention.  The situation
 180 # for QJSON is substantially different: there are no binaries for QJSON
 181 # available, and there is no standard installation directory that is detected
 182 # by cmake.
 183 #
 184 # By bundling the QJSON source, we make it much more easier to build the GUI on
 185 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 186 # AUTO.
 187 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 188     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 189     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 190     set (QJSON_LIBRARY_DIRS)
 191     set (QJSON_LIBRARIES qjson_bundled)
 192     set (QJSON_FOUND TRUE)
 193 endif ()
 194
 195 # For glext headers
 196 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 197
 198 # For EGL headers
 199 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 200
 201 ##############################################################################
 202 # Installation directories
 203
 204 if (WIN32 OR APPLE)
 205     # On Windows/MacOSX, applications are usually installed on a directory of
 206     # their own
 207     set (DOC_INSTALL_DIR doc)
 208 else ()
 209     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 210 endif ()
 211
 212 set (LIB_INSTALL_DIR lib/apitrace)
 213
 214 if (APPLE)
 215     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 216     # directories
 217     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 218 else ()
 219     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 220 endif ()
 221
 222 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 223 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 224
 225 # Expose the binary/install directories to source
 226 #
 227 # TODO: Use the same directory layout, for both build and install directories,
 228 # so that binaries can find each other using just relative paths.
 229 #
 230 add_definitions(
 231     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 232     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 233     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 234 )
 235
 236
 237 ##############################################################################
 238 # Common libraries / utilities
 239
 240 include_directories (
 241     ${CMAKE_CURRENT_SOURCE_DIR}
 242     ${CMAKE_CURRENT_SOURCE_DIR}/common
 243 )
 244
 245 add_custom_command (
 246     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 247     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 248     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 249 )
 250
 251 if (WIN32)
 252     set (os os_win32.cpp)
 253     set (glws_os glws_wgl.cpp)
 254 else ()
 255     set (os os_posix.cpp)
 256     if (APPLE)
 257         set (glws_os glws_cocoa.mm)
 258     else ()
 259         set (glws_os glws_glx.cpp)
 260     endif ()
 261 endif ()
 262
 263 add_library (common STATIC
 264     common/trace_file.cpp
 265     common/trace_file_read.cpp
 266     common/trace_file_write.cpp
 267     common/trace_file_zlib.cpp
 268     common/trace_file_snappy.cpp
 269     common/trace_model.cpp
 270     common/trace_parser.cpp
 271     common/trace_parser_flags.cpp
 272     common/trace_writer.cpp
 273     common/trace_writer_local.cpp
 274     common/trace_writer_model.cpp
 275     common/trace_loader.cpp
 276     common/trace_resource.cpp
 277     common/trace_tools_trace.cpp
 278     common/image.cpp
 279     common/image_bmp.cpp
 280     common/image_pnm.cpp
 281     common/image_png.cpp
 282     common/${os}
 283 )
 284
 285 set_target_properties (common PROPERTIES
 286     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 287     # Ensure it can be statically linked in shared libraries
 288     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 289 )
 290
 291 link_libraries (common)
 292
 293
 294 ##############################################################################
 295 # API tracers
 296
 297 if (WIN32)
 298     if (MINGW)
 299         # Silence warnings about @nn suffix mismatch
 300         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 301     endif (MINGW)
 302
 303     # ddraw.dll
 304     if (DirectX_D3D_INCLUDE_DIR)
 305         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 306         add_custom_command (
 307             OUTPUT ddrawtrace.cpp
 308             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 309             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 310         )
 311         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 312         set_target_properties (ddraw
 313             PROPERTIES PREFIX ""
 314             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 315             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 316         )
 317         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 318     endif (DirectX_D3D_INCLUDE_DIR)
 319
 320     # d3d8.dll
 321     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 322         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 323         add_custom_command (
 324             OUTPUT d3d8trace.cpp
 325             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 326             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 327         )
 328         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 329         set_target_properties (d3d8
 330             PROPERTIES PREFIX ""
 331             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 332             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 333         )
 334         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 335     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 336
 337     # d3d9.dll
 338     if (DirectX_D3DX9_INCLUDE_DIR)
 339         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 340         add_custom_command (
 341             OUTPUT d3d9trace.cpp
 342             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 343             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 344         )
 345         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 346         set_target_properties (d3d9
 347             PROPERTIES PREFIX ""
 348             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 349             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 350         )
 351         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 352     endif (DirectX_D3DX9_INCLUDE_DIR)
 353
 354     # d3d10.dll
 355     if (DirectX_D3D10_INCLUDE_DIR)
 356         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 357         add_custom_command (
 358             OUTPUT d3d10trace.cpp
 359             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 360             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 361         )
 362         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 363         set_target_properties (d3d10
 364             PROPERTIES PREFIX ""
 365             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 366             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 367         )
 368         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 369     endif (DirectX_D3D10_INCLUDE_DIR)
 370
 371     # opengl32.dll
 372     add_custom_command (
 373         OUTPUT wgltrace.cpp
 374         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 375         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 376     )
 377     add_library (wgltrace MODULE specs/opengl32.def
 378         wgltrace.cpp
 379         glcaps.cpp
 380         glproc_gl.cpp
 381         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 382     )
 383     set_target_properties (wgltrace PROPERTIES
 384         PREFIX ""
 385         OUTPUT_NAME opengl32
 386         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 387         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 388     )
 389     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 390
 391 elseif (APPLE)
 392     # OpenGL framework
 393     add_custom_command (
 394         OUTPUT cgltrace.cpp
 395         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 396         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 397     )
 398
 399     add_library (cgltrace SHARED
 400         cgltrace.cpp
 401         glcaps.cpp
 402         glproc_gl.cpp
 403         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 404     )
 405
 406     set_target_properties (cgltrace PROPERTIES
 407         # OpenGL framework name
 408         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 409         # Specificy the version and reexport GLU symbols
 410         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 411         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 412         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 413     )
 414
 415     target_link_libraries (cgltrace dl)
 416
 417     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 418 else ()
 419     # libGL.so
 420     add_custom_command (
 421         OUTPUT glxtrace.cpp
 422         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 423         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 424     )
 425
 426     add_library (glxtrace SHARED
 427         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 428         glxtrace.cpp
 429         glcaps.cpp
 430         glproc_gl.cpp
 431     )
 432
 433     set_target_properties (glxtrace PROPERTIES
 434         # avoid the default "lib" prefix
 435         PREFIX ""
 436         # Prevent symbol relocations internal to our wrapper library to be
 437         # overwritten by the application.
 438         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 439         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 440         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 441     )
 442
 443     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 444
 445     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 446 endif ()
 447
 448
 449 if (EGL_FOUND)
 450     # libEGL.so/libGL.so
 451     add_custom_command (
 452         OUTPUT egltrace.cpp
 453         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 454         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 455     )
 456
 457     add_library (egltrace SHARED
 458         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 459         egltrace.cpp
 460         glcaps.cpp
 461         glproc_egl.cpp
 462     )
 463
 464     set_property (
 465         TARGET egltrace
 466         APPEND
 467         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 468     )
 469
 470     set_target_properties (egltrace PROPERTIES
 471         # avoid the default "lib" prefix
 472         PREFIX ""
 473         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 474         # Prevent symbol relocations internal to our wrapper library to be
 475         # overwritten by the application.
 476         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 477         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 478     )
 479
 480     target_link_libraries (egltrace dl)
 481
 482     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 483 endif ()
 484
 485 ##############################################################################
 486 # API retracers
 487
 488 add_custom_command (
 489     OUTPUT glretrace_gl.cpp
 490     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 491     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 492 )
 493
 494 add_custom_command (
 495     OUTPUT glstate_params.cpp
 496     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 497     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 498 )
 499
 500 include_directories (
 501     ${CMAKE_CURRENT_BINARY_DIR}
 502     ${OPENGL_INCLUDE_PATH}
 503 )
 504
 505 set (retrace_sources
 506     glretrace_gl.cpp
 507     glretrace_cgl.cpp
 508     glretrace_glx.cpp
 509     glretrace_wgl.cpp
 510     glretrace_egl.cpp
 511     glretrace_main.cpp
 512     glstate.cpp
 513     glstate_params.cpp
 514     retrace.cpp
 515     retrace_stdc.cpp
 516     glws.cpp
 517     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 518 )
 519
 520 add_executable (glretrace
 521     ${retrace_sources}
 522     ${glws_os}
 523     glproc_gl.cpp
 524 )
 525
 526 set_property (
 527     TARGET glretrace
 528     APPEND
 529     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 530 )
 531
 532 target_link_libraries (glretrace
 533     common
 534 )
 535
 536 if (WIN32)
 537 else ()
 538     if (APPLE)
 539         target_link_libraries (glretrace
 540             "-framework Cocoa"
 541             "-framework ApplicationServices" # CGS*
 542             ${OPENGL_gl_LIBRARY} # CGL*
 543         )
 544     else ()
 545         target_link_libraries (glretrace ${X11_X11_LIB} pthread)
 546     endif ()
 547
 548     # gdb doesn't like when pthreads is loaded through dlopen (which happens
 549     # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
 550     # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
 551     target_link_libraries (glretrace pthread)
 552 endif ()
 553
 554 install (TARGETS glretrace RUNTIME DESTINATION bin)
 555
 556 if (EGL_FOUND AND NOT WIN32 AND NOT APPLE)
 557     add_executable (eglretrace
 558         ${retrace_sources}
 559         glws_egl_xlib.cpp
 560         glproc_egl.cpp
 561     )
 562
 563     set_property (
 564         TARGET eglretrace
 565         APPEND
 566         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 567         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 568     )
 569
 570     target_link_libraries (eglretrace
 571         common
 572         ${X11_X11_LIB}
 573         pthread
 574     )
 575
 576     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 577 endif ()
 578
 579 ##############################################################################
 580 # CLI
 581
 582 add_subdirectory(cli)
 583
 584 ##############################################################################
 585 # Scripts (to support the CLI)
 586
 587 install (
 588     PROGRAMS
 589         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh
 590         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 591         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 592     DESTINATION ${SCRIPTS_INSTALL_DIR}
 593 )
 594
 595 ##############################################################################
 596 # GUI
 597
 598 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 599     add_subdirectory(gui)
 600 endif ()
 601
 602
 603 ##############################################################################
 604 # Packaging
 605
 606 install (
 607     FILES
 608         BUGS.markdown
 609         LICENSE
 610         NEWS.markdown
 611         README.markdown
 612         TODO.markdown
 613     DESTINATION ${DOC_INSTALL_DIR}
 614 )
 615
 616 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 617 set (CPACK_PACKAGE_VERSION_MINOR "0")
 618
 619 # Use current date in YYYYMMDD format as patch number
 620 execute_process (
 621     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 622     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 623 )
 624
 625 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 626 if (WIN32)
 627     set (CPACK_GENERATOR "ZIP")
 628 elseif (APPLE)
 629     set (CPACK_GENERATOR "DragNDrop")
 630 else ()
 631     set (CPACK_GENERATOR "TBZ2")
 632 endif ()
 633
 634 include(CPack)