git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 include_directories (${OPENGL_INCLUDE_DIR})
  44
  45 if (WIN32)
  46     find_package (DirectX)
  47 elseif (APPLE)
  48 else ()
  49     find_package (X11)
  50
  51     if (X11_FOUND)
  52         include_directories (${X11_INCLUDE_DIR})
  53         add_definitions (-DHAVE_X11)
  54     endif ()
  55
  56     if (ENABLE_EGL)
  57         if (NOT ENABLE_EGL STREQUAL "AUTO")
  58             set (REQUIRE_EGL REQUIRED)
  59         endif ()
  60         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  61         if (EGL_FOUND)
  62             include_directories (${EGL_INCLUDE_DIR})
  63             add_definitions (-DHAVE_EGL)
  64         endif ()
  65     else ()
  66         set (EGL_FOUND 0)
  67     endif ()
  68 endif ()
  69
  70
  71 ##############################################################################
  72 # Set global build options
  73
  74 include (CheckCXXCompilerFlag)
  75
  76 if (WIN32)
  77     # MSVC & MinGW only define & use APIENTRY
  78     add_definitions (-DGLAPIENTRY=__stdcall)
  79
  80     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  81     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  82 else (WIN32)
  83     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  84     if (CXX_COMPILER_FLAG_VISIBILITY)
  85         add_definitions ("-fvisibility=hidden")
  86     endif (CXX_COMPILER_FLAG_VISIBILITY)
  87 endif (WIN32)
  88
  89 if (MSVC)
  90     # C99 includes for msvc
  91     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  92
  93     # Enable math constants defines
  94     add_definitions (-D_USE_MATH_DEFINES)
  95
  96     # No min/max macros
  97     add_definitions (-DNOMINMAX)
  98
  99     # Adjust warnings
 100     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 101     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 102     add_definitions (-W4)
 103     add_definitions (-wd4063) # not a valid value for switch of enum
 104     add_definitions (-wd4127) # conditional expression is constant
 105     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 106     add_definitions (-wd4505) # unreferenced local function has been removed
 107     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 108     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 109     add_definitions (-wd4018) # signed/unsigned mismatch
 110
 111     # Use static runtime
 112     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 113     foreach (flag_var
 114         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 115         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 116     )
 117         if (${flag_var} MATCHES "/MD")
 118             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 119         endif (${flag_var} MATCHES "/MD")
 120     endforeach (flag_var)
 121 else ()
 122     # Adjust warnings
 123     add_definitions (-Wall)
 124     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 125     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 126 endif ()
 127
 128 if (MINGW)
 129     # Avoid depending on MinGW runtime DLLs
 130     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 131     if (HAVE_STATIC_LIBGCC_FLAG)
 132         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 133         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 134         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 135     endif ()
 136     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 137     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 138         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 139         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 140         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 141     endif ()
 142 endif ()
 143
 144
 145 # Put all executables into the same top level build directory, regardless of
 146 # which subdirectory they are declared
 147 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 148
 149
 150 ##############################################################################
 151 # Bundled dependencies
 152 #
 153 # We always use the bundled zlib, libpng, and snappy sources:
 154 # - on Windows to make it easy to deploy the wrappers DLLs
 155 # - on unices to prevent symbol collisions when tracing applications that link
 156 # against other versions of these libraries
 157
 158 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 159 set (ZLIB_LIBRARIES z_bundled)
 160 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 161
 162 include_directories (${ZLIB_INCLUDE_DIRS})
 163 link_libraries (${ZLIB_LIBRARIES})
 164
 165 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 166 set (SNAPPY_LIBRARIES snappy_bundled)
 167 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 168
 169 include_directories (${SNAPPY_INCLUDE_DIRS})
 170 link_libraries (${SNAPPY_LIBRARIES})
 171
 172 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 173 set (PNG_DEFINITIONS "")
 174 set (PNG_LIBRARIES png_bundled)
 175
 176 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 177 include_directories (${PNG_INCLUDE_DIR})
 178 add_definitions (${PNG_DEFINITIONS})
 179 link_libraries (${PNG_LIBRARIES})
 180
 181 # The Qt website provides binaries for Windows and MacOSX, and they are
 182 # automatically found by cmake without any manual intervention.  The situation
 183 # for QJSON is substantially different: there are no binaries for QJSON
 184 # available, and there is no standard installation directory that is detected
 185 # by cmake.
 186 #
 187 # By bundling the QJSON source, we make it much more easier to build the GUI on
 188 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 189 # AUTO.
 190 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 191     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 192     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 193     set (QJSON_LIBRARY_DIRS)
 194     set (QJSON_LIBRARIES qjson_bundled)
 195     set (QJSON_FOUND TRUE)
 196 endif ()
 197
 198 # For glext headers.  Needs to be before system includes as often system's GL
 199 # headers bundle and include glext.h and glxext.h
 200 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/glext)
 201
 202 # For EGL headers
 203 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 204
 205 ##############################################################################
 206 # Installation directories
 207
 208 if (WIN32 OR APPLE)
 209     # On Windows/MacOSX, applications are usually installed on a directory of
 210     # their own
 211     set (DOC_INSTALL_DIR doc)
 212 else ()
 213     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 214 endif ()
 215
 216 set (LIB_INSTALL_DIR lib/apitrace)
 217
 218 if (APPLE)
 219     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 220     # directories
 221     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 222 else ()
 223     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 224 endif ()
 225
 226 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 227 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 228
 229 # Expose the binary/install directories to source
 230 #
 231 # TODO: Use the same directory layout, for both build and install directories,
 232 # so that binaries can find each other using just relative paths.
 233 #
 234 add_definitions(
 235     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 236     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 237     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 238 )
 239
 240
 241 ##############################################################################
 242 # Common libraries / utilities
 243
 244 include_directories (
 245     ${CMAKE_CURRENT_BINARY_DIR}
 246     ${CMAKE_CURRENT_SOURCE_DIR}
 247     ${CMAKE_CURRENT_SOURCE_DIR}/common
 248 )
 249
 250 add_custom_command (
 251     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 252     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 253     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 254 )
 255
 256 # Wrap glproc.hpp as a target to prevent the command from being executed
 257 # multiple times simulatenously, when the targets that depend on it are built
 258 # in parallel.
 259 add_custom_target (glproc DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 260
 261 if (WIN32)
 262     set (os os_win32.cpp)
 263     set (glws_os glws_wgl.cpp)
 264 else ()
 265     set (os os_posix.cpp)
 266     if (APPLE)
 267         set (glws_os glws_cocoa.mm)
 268     else ()
 269         set (glws_os glws_glx.cpp)
 270     endif ()
 271 endif ()
 272
 273 add_library (common STATIC
 274     common/trace_dump.cpp
 275     common/trace_file.cpp
 276     common/trace_file_read.cpp
 277     common/trace_file_write.cpp
 278     common/trace_file_zlib.cpp
 279     common/trace_file_snappy.cpp
 280     common/trace_model.cpp
 281     common/trace_parser.cpp
 282     common/trace_parser_flags.cpp
 283     common/trace_writer.cpp
 284     common/trace_writer_local.cpp
 285     common/trace_writer_model.cpp
 286     common/trace_loader.cpp
 287     common/trace_resource.cpp
 288     common/trace_tools_trace.cpp
 289     common/image.cpp
 290     common/image_bmp.cpp
 291     common/image_pnm.cpp
 292     common/image_png.cpp
 293     common/${os}
 294 )
 295
 296 set_target_properties (common PROPERTIES
 297     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 298     # Ensure it can be statically linked in shared libraries
 299     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 300 )
 301
 302 link_libraries (common)
 303
 304
 305 ##############################################################################
 306 # API tracers
 307
 308 if (WIN32)
 309     if (MINGW)
 310         # Silence warnings about @nn suffix mismatch
 311         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 312     endif (MINGW)
 313
 314     # ddraw.dll
 315     if (DirectX_D3D_INCLUDE_DIR)
 316         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 317         add_custom_command (
 318             OUTPUT ddrawtrace.cpp
 319             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 320             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 321         )
 322         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 323         set_target_properties (ddraw
 324             PROPERTIES PREFIX ""
 325             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 326             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 327         )
 328         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 329     endif (DirectX_D3D_INCLUDE_DIR)
 330
 331     # d3d8.dll
 332     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 333         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 334         add_custom_command (
 335             OUTPUT d3d8trace.cpp
 336             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 337             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 338         )
 339         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 340         set_target_properties (d3d8
 341             PROPERTIES PREFIX ""
 342             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 343             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 344         )
 345         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 346     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 347
 348     # d3d9.dll
 349     if (DirectX_D3DX9_INCLUDE_DIR)
 350         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 351         add_custom_command (
 352             OUTPUT d3d9trace.cpp
 353             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 354             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 355         )
 356         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 357         set_target_properties (d3d9
 358             PROPERTIES PREFIX ""
 359             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 360             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 361         )
 362         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 363     endif (DirectX_D3DX9_INCLUDE_DIR)
 364
 365     # d3d10.dll
 366     if (DirectX_D3D10_INCLUDE_DIR)
 367         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 368         add_custom_command (
 369             OUTPUT d3d10trace.cpp
 370             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 371             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 372         )
 373         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 374         set_target_properties (d3d10
 375             PROPERTIES PREFIX ""
 376             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 377             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 378         )
 379         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 380     endif (DirectX_D3D10_INCLUDE_DIR)
 381
 382     # d2d1.dll, dwrite.dll
 383     if (DirectX_D2D1_INCLUDE_DIR)
 384         include_directories (SYSTEM ${DirectX_D2D1_INCLUDE_DIR})
 385
 386         add_custom_command (
 387             OUTPUT d2d1trace.cpp
 388             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d2d1trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d2d1trace.cpp
 389             DEPENDS d2d1trace.py trace.py specs/d2d1.py specs/d2d1.py specs/d2dbasetypes.py specs/d2derr.py specs/dwrite.py specs/dcommon.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 390         )
 391         add_library (d2d1 MODULE specs/d2d1.def d2d1trace.cpp)
 392         set_target_properties (d2d1
 393             PROPERTIES PREFIX ""
 394             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 395             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 396         )
 397         install (TARGETS d2d1 LIBRARY DESTINATION wrappers)
 398
 399         add_custom_command (
 400             OUTPUT dwritetrace.cpp
 401             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/dwritetrace.py > ${CMAKE_CURRENT_BINARY_DIR}/dwritetrace.cpp
 402             DEPENDS dwritetrace.py trace.py specs/d2d1.py specs/d2d1.py specs/d2dbasetypes.py specs/d2derr.py specs/dwrite.py specs/dcommon.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 403         )
 404         add_library (dwrite MODULE specs/dwrite.def dwritetrace.cpp)
 405         set_target_properties (dwrite
 406             PROPERTIES PREFIX ""
 407             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 408             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 409         )
 410         install (TARGETS dwrite LIBRARY DESTINATION wrappers)
 411     endif (DirectX_D2D1_INCLUDE_DIR)
 412
 413     # opengl32.dll
 414     add_custom_command (
 415         OUTPUT wgltrace.cpp
 416         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 417         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 418     )
 419     add_library (wgltrace MODULE specs/opengl32.def
 420         wgltrace.cpp
 421         glcaps.cpp
 422         glproc_gl.cpp
 423     )
 424     add_dependencies (wgltrace glproc)
 425     set_target_properties (wgltrace PROPERTIES
 426         PREFIX ""
 427         OUTPUT_NAME opengl32
 428         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 429         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 430     )
 431     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 432
 433 elseif (APPLE)
 434     # OpenGL framework
 435     add_custom_command (
 436         OUTPUT cgltrace.cpp
 437         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 438         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 439     )
 440
 441     add_library (cgltrace SHARED
 442         cgltrace.cpp
 443         glcaps.cpp
 444         glproc_gl.cpp
 445     )
 446
 447     add_dependencies (cgltrace glproc)
 448
 449     set_target_properties (cgltrace PROPERTIES
 450         # OpenGL framework name
 451         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 452         # Specificy the version and reexport GLU symbols
 453         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 454         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 455         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 456     )
 457
 458     target_link_libraries (cgltrace
 459         pthread
 460         dl
 461     )
 462
 463     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 464 elseif (X11_FOUND)
 465     # libGL.so
 466     add_custom_command (
 467         OUTPUT glxtrace.cpp
 468         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 469         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 470     )
 471
 472     add_library (glxtrace SHARED
 473         glxtrace.cpp
 474         glcaps.cpp
 475         glproc_gl.cpp
 476     )
 477
 478     add_dependencies (glxtrace glproc)
 479
 480     set_target_properties (glxtrace PROPERTIES
 481         # avoid the default "lib" prefix
 482         PREFIX ""
 483         # Prevent symbol relocations internal to our wrapper library to be
 484         # overwritten by the application.
 485         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 486         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 487         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 488     )
 489
 490     target_link_libraries (glxtrace
 491         ${X11_X11_LIB}
 492         pthread
 493         dl
 494     )
 495
 496     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 497 endif ()
 498
 499
 500 if (EGL_FOUND)
 501     # libEGL.so/libGL.so
 502     add_custom_command (
 503         OUTPUT egltrace.cpp
 504         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 505         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 506     )
 507
 508     add_library (egltrace SHARED
 509         egltrace.cpp
 510         glcaps.cpp
 511         glproc_egl.cpp
 512     )
 513
 514     add_dependencies (egltrace glproc)
 515
 516     set_property (
 517         TARGET egltrace
 518         APPEND
 519         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 520     )
 521
 522     set_target_properties (egltrace PROPERTIES
 523         # avoid the default "lib" prefix
 524         PREFIX ""
 525         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 526         # Prevent symbol relocations internal to our wrapper library to be
 527         # overwritten by the application.
 528         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 529         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 530     )
 531
 532     target_link_libraries (egltrace
 533         pthread
 534         dl
 535     )
 536
 537     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 538 endif ()
 539
 540 ##############################################################################
 541 # API retracers
 542
 543 add_custom_command (
 544     OUTPUT glretrace_gl.cpp
 545     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 546     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 547 )
 548
 549 add_custom_command (
 550     OUTPUT glstate_params.cpp
 551     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 552     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 553 )
 554
 555 set (retrace_sources
 556     glretrace_gl.cpp
 557     glretrace_cgl.cpp
 558     glretrace_glx.cpp
 559     glretrace_wgl.cpp
 560     glretrace_egl.cpp
 561     glretrace_main.cpp
 562     glstate.cpp
 563     glstate_params.cpp
 564     retrace.cpp
 565     retrace_stdc.cpp
 566     glws.cpp
 567 )
 568
 569 if (WIN32 OR APPLE OR X11_FOUND)
 570     add_executable (glretrace
 571         ${retrace_sources}
 572         ${glws_os}
 573         glproc_gl.cpp
 574     )
 575
 576     add_dependencies (glretrace glproc)
 577
 578     set_property (
 579         TARGET glretrace
 580         APPEND
 581         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 582     )
 583
 584     target_link_libraries (glretrace
 585         common
 586     )
 587
 588     if (WIN32)
 589     else ()
 590         if (APPLE)
 591             target_link_libraries (glretrace
 592                 "-framework Cocoa"
 593                 "-framework ApplicationServices" # CGS*
 594                 ${OPENGL_gl_LIBRARY} # CGL*
 595             )
 596         else ()
 597             target_link_libraries (glretrace ${X11_X11_LIB})
 598         endif ()
 599
 600         target_link_libraries (glretrace
 601             # gdb doesn't like when pthreads is loaded through dlopen (which happens
 602             # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
 603             # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
 604             pthread
 605             dl
 606         )
 607
 608         if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 609             target_link_libraries (glretrace rt)
 610         endif ()
 611
 612     endif ()
 613
 614     install (TARGETS glretrace RUNTIME DESTINATION bin)
 615 endif ()
 616
 617 if (EGL_FOUND AND X11_FOUND AND NOT WIN32 AND NOT APPLE)
 618     add_executable (eglretrace
 619         ${retrace_sources}
 620         glws_egl_xlib.cpp
 621         glproc_egl.cpp
 622     )
 623
 624     add_dependencies (eglretrace glproc)
 625
 626     set_property (
 627         TARGET eglretrace
 628         APPEND
 629         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 630         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 631     )
 632
 633     target_link_libraries (eglretrace
 634         common
 635         ${X11_X11_LIB}
 636         pthread
 637         dl
 638     )
 639
 640     if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 641         target_link_libraries (eglretrace rt)
 642     endif ()
 643
 644     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 645 endif ()
 646
 647 ##############################################################################
 648 # CLI
 649
 650 add_subdirectory(cli)
 651
 652 ##############################################################################
 653 # Scripts (to support the CLI)
 654
 655 install (
 656     PROGRAMS
 657         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh
 658         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 659         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 660     DESTINATION ${SCRIPTS_INSTALL_DIR}
 661 )
 662
 663 ##############################################################################
 664 # GUI
 665
 666 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 667     add_subdirectory(gui)
 668 endif ()
 669
 670
 671 ##############################################################################
 672 # Packaging
 673
 674 install (
 675     FILES
 676         BUGS.markdown
 677         LICENSE
 678         NEWS.markdown
 679         README.markdown
 680         TODO.markdown
 681     DESTINATION ${DOC_INSTALL_DIR}
 682 )
 683
 684 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 685 set (CPACK_PACKAGE_VERSION_MINOR "0")
 686
 687 # Use current date in YYYYMMDD format as patch number
 688 execute_process (
 689     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 690     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 691 )
 692
 693 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 694 if (WIN32)
 695     set (CPACK_GENERATOR "ZIP")
 696 elseif (APPLE)
 697     set (CPACK_GENERATOR "DragNDrop")
 698 else ()
 699     set (CPACK_GENERATOR "TBZ2")
 700 endif ()
 701
 702 include(CPack)