git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Find dependencies
   8
   9 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  10
  11 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  12
  13 find_package (PythonInterp REQUIRED)
  14 find_package (OpenGL REQUIRED)
  15 find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit)
  16 find_package (QJSON)
  17
  18 if (NOT WIN32)
  19     find_package (X11 REQUIRED)
  20
  21     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  22     # from the standard OpenGL framework which provides support for native Mac OS X
  23     # applications.
  24     if (APPLE)
  25         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  26         if (NOT X11_GL_INCLUDE_PATH)
  27             message (SEND_ERROR "Could not find GL/glx.h")
  28         endif (NOT X11_GL_INCLUDE_PATH)
  29         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  30
  31         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  32         if (NOT X11_GL_LIB)
  33             message (SEND_ERROR "Could not find libGL.dylib")
  34         endif (NOT X11_GL_LIB)
  35     else ()
  36         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  37         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  38     endif ()
  39
  40     include_directories (${X11_INCLUDE_DIR})
  41 endif (NOT WIN32)
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 endif (WIN32)
  46
  47
  48 ##############################################################################
  49 # Set global build options
  50
  51 include (CheckCXXCompilerFlag)
  52
  53 if (WIN32)
  54     # MSVC & MinGW only define & use APIENTRY
  55     add_definitions (-DGLAPIENTRY=__stdcall)
  56
  57     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  58     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  59 else (WIN32)
  60     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  61     if (CXX_COMPILER_FLAG_VISIBILITY)
  62         add_definitions ("-fvisibility=hidden")
  63     endif (CXX_COMPILER_FLAG_VISIBILITY)
  64 endif (WIN32)
  65
  66 if (MSVC)
  67     # C99 includes for msvc
  68     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  69
  70     # Enable math constants defines
  71     add_definitions (-D_USE_MATH_DEFINES)
  72
  73     # No min/max macros
  74     add_definitions (-DNOMINMAX)
  75
  76     # Adjust warnings
  77     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  78     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  79     add_definitions (-W4)
  80     add_definitions (-wd4063) # not a valid value for switch of enum
  81     add_definitions (-wd4127) # conditional expression is constant
  82     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  83     add_definitions (-wd4505) # unreferenced local function has been removed
  84     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  85     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  86     add_definitions (-wd4018) # signed/unsigned mismatch
  87
  88     # Use static runtime
  89     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  90     foreach (flag_var
  91         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  92         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  93     )
  94         if (${flag_var} MATCHES "/MD")
  95             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  96         endif (${flag_var} MATCHES "/MD")
  97     endforeach (flag_var)
  98 else ()
  99     # Adjust warnings
 100     add_definitions (-Wall)
 101     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 102     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 103 endif ()
 104
 105
 106 # Put all executables into the same top level build directory, regardless of
 107 # which subdirectory they are declared
 108 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 109
 110
 111 ##############################################################################
 112 # Bundled dependencies
 113 #
 114 # We always use the bundled zlib and libpng sources:
 115 # - on Windows to make it easy to deploy the wrappers DLLs
 116 # - on unices to prevent symbol collisions when tracing applications that link
 117 # against other versions of these libraries
 118
 119 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 120 set (ZLIB_LIBRARIES z_bundled)
 121 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 122
 123 include_directories (${ZLIB_INCLUDE_DIRS})
 124 link_libraries (${ZLIB_LIBRARIES})
 125
 126 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 127 set (PNG_DEFINITIONS "")
 128 set (PNG_LIBRARIES png_bundled)
 129
 130 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 131 include_directories (${PNG_INCLUDE_DIR})
 132 add_definitions (${PNG_DEFINITIONS})
 133 link_libraries (${PNG_LIBRARIES})
 134
 135 # For glext headers
 136 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 137
 138
 139 ##############################################################################
 140 # Common libraries / utilities
 141
 142 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 143
 144 add_custom_command (
 145     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 146     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 147     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 148 )
 149
 150 if (WIN32)
 151     set (os os_win32.cpp)
 152     set (glws glws_wgl.cpp)
 153 else (WIN32)
 154     set (os os_posix.cpp)
 155     set (glws glws_glx.cpp)
 156 endif (WIN32)
 157
 158 add_library (common
 159     trace_model.cpp
 160     trace_parser.cpp
 161     trace_writer.cpp
 162     trace_model_writer.cpp
 163     ${os}
 164 )
 165
 166 add_executable (tracedump tracedump.cpp)
 167 target_link_libraries (tracedump common)
 168 install (TARGETS tracedump RUNTIME DESTINATION bin)
 169
 170
 171 ##############################################################################
 172 # API tracers
 173
 174 if (WIN32)
 175     # ddraw.dll
 176     if (DirectX_D3D_INCLUDE_DIR)
 177         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 178         add_custom_command (
 179             OUTPUT ddraw.cpp
 180             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 181             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 182         )
 183         add_library (ddraw MODULE ddraw.def ddraw.cpp trace_writer.cpp os_win32.cpp)
 184         set_target_properties (ddraw
 185             PROPERTIES PREFIX ""
 186             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 187             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 188         )
 189         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 190     endif (DirectX_D3D_INCLUDE_DIR)
 191
 192     # d3d8.dll
 193     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 194         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 195         add_custom_command (
 196             OUTPUT d3d8.cpp
 197             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 198             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 199         )
 200         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 201         set_target_properties (d3d8
 202             PROPERTIES PREFIX ""
 203             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 204             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 205         )
 206         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 207     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 208
 209     # d3d9.dll
 210     if (DirectX_D3DX9_INCLUDE_DIR)
 211         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 212         add_custom_command (
 213             OUTPUT d3d9.cpp
 214             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 215             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 216         )
 217         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 218         set_target_properties (d3d9
 219             PROPERTIES PREFIX ""
 220             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 221             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 222         )
 223         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 224     endif (DirectX_D3DX9_INCLUDE_DIR)
 225
 226     # d3d10.dll
 227     #if (DirectX_D3D10_INCLUDE_DIR)
 228     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 229     #    add_custom_command (
 230     #        OUTPUT d3d10.cpp
 231     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 232     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 233     #    )
 234     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp trace_writer.cpp os_win32.cpp)
 235     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 236     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 237     #endif (DirectX_D3D10_INCLUDE_DIR)
 238
 239     # opengl32.dll
 240     add_custom_command (
 241         OUTPUT wgltrace.cpp
 242         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 243         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 244     )
 245     add_library (wgltrace MODULE opengl32.def wgltrace.cpp trace_writer.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 246     set_target_properties (wgltrace PROPERTIES
 247         PREFIX ""
 248         OUTPUT_NAME opengl32
 249         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 250         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 251     )
 252     if (MINGW)
 253         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 254     endif (MINGW)
 255     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 256
 257 elseif (APPLE)
 258     # OpenGL framework
 259     add_custom_command (
 260         OUTPUT cgltrace.cpp
 261         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 262         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 263     )
 264
 265     add_library (cgltrace SHARED cgltrace.cpp trace_writer.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 266
 267     set_target_properties (cgltrace PROPERTIES
 268         # OpenGL framework name
 269         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 270         # Specificy the version and reexport GLU symbols
 271         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 272         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 273         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 274     )
 275
 276     target_link_libraries (cgltrace dl)
 277
 278     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 279 else ()
 280     # libGL.so
 281     add_custom_command (
 282         OUTPUT glxtrace.cpp
 283         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 284         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 285     )
 286
 287     add_library (glxtrace SHARED
 288         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 289         glxtrace.cpp
 290         glsnapshot.cpp
 291         trace_writer.cpp
 292         image.cpp
 293         os_posix.cpp
 294     )
 295
 296     set_target_properties (glxtrace PROPERTIES
 297         # avoid the default "lib" prefix
 298         PREFIX ""
 299     )
 300
 301     # Prevent symbol relocations internal to our wrapper library to be
 302     # overwritten by the application.
 303     set_target_properties (glxtrace PROPERTIES
 304         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 305     )
 306
 307     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 308
 309     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 310 endif ()
 311
 312
 313 ##############################################################################
 314 # API retracers
 315
 316 add_custom_command (
 317     OUTPUT glretrace_gl.cpp
 318     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 319     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 320 )
 321
 322 add_custom_command (
 323     OUTPUT glstate_params.cpp
 324     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 325     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 326 )
 327
 328 include_directories (
 329     ${CMAKE_CURRENT_BINARY_DIR}
 330     ${OPENGL_INCLUDE_PATH}
 331 )
 332
 333 add_executable (glretrace
 334     glretrace_gl.cpp
 335     glretrace_cgl.cpp
 336     glretrace_glx.cpp
 337     glretrace_wgl.cpp
 338     glretrace_main.cpp
 339     glstate.cpp
 340     glstate_params.cpp
 341     retrace.cpp
 342     ${glws}
 343     image.cpp
 344     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 345 )
 346
 347 set_property (
 348     TARGET glretrace
 349     APPEND
 350     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 351 )
 352
 353 target_link_libraries (glretrace
 354     common
 355 )
 356
 357 if (WIN32)
 358     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 359 elseif (APPLE)
 360     # XXX: We use GLX on MacOSX, which is in a separate library.
 361     target_link_libraries (glretrace
 362         ${X11_GL_LIB}
 363         ${X11_X11_LIB}
 364         "-framework ApplicationServices" # CGS*
 365         ${OPENGL_gl_LIBRARY} # CGL*
 366     )
 367 else ()
 368     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 369 endif ()
 370
 371 install (TARGETS glretrace RUNTIME DESTINATION bin)
 372
 373
 374 ##############################################################################
 375 # GUI
 376
 377 if (QT4_FOUND AND QJSON_FOUND)
 378     add_subdirectory(gui)
 379 endif (QT4_FOUND AND QJSON_FOUND)
 380
 381
 382 ##############################################################################
 383 # Packaging
 384
 385 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 386
 387 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 388 set (CPACK_PACKAGE_VERSION_MINOR "0")
 389
 390 # Use current date in YYYYMMDD format as patch number
 391 execute_process (
 392     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 393     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 394 )
 395
 396 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 397 if (WIN32)
 398     set (CPACK_GENERATOR "ZIP")
 399 elseif (APPLE)
 400     set (CPACK_GENERATOR "DragNDrop")
 401 else ()
 402     set (CPACK_GENERATOR "TBZ2")
 403 endif ()
 404
 405 include(CPack)