git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 elseif (APPLE)
  46 else ()
  47     find_package (X11 REQUIRED)
  48
  49     set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  50     set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  51
  52     include_directories (${X11_INCLUDE_DIR})
  53
  54     if (ENABLE_EGL)
  55         if (NOT ENABLE_EGL STREQUAL "AUTO")
  56             set (REQUIRE_EGL REQUIRED)
  57         endif ()
  58         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  59         if (EGL_FOUND)
  60             include_directories (${EGL_INCLUDE_DIR})
  61             add_definitions (-DHAVE_EGL)
  62         endif ()
  63     else ()
  64         set (EGL_FOUND 0)
  65     endif ()
  66 endif ()
  67
  68
  69 ##############################################################################
  70 # Set global build options
  71
  72 include (CheckCXXCompilerFlag)
  73
  74 if (WIN32)
  75     # MSVC & MinGW only define & use APIENTRY
  76     add_definitions (-DGLAPIENTRY=__stdcall)
  77
  78     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  79     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  80 else (WIN32)
  81     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  82     if (CXX_COMPILER_FLAG_VISIBILITY)
  83         add_definitions ("-fvisibility=hidden")
  84     endif (CXX_COMPILER_FLAG_VISIBILITY)
  85 endif (WIN32)
  86
  87 if (MSVC)
  88     # C99 includes for msvc
  89     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  90
  91     # Enable math constants defines
  92     add_definitions (-D_USE_MATH_DEFINES)
  93
  94     # No min/max macros
  95     add_definitions (-DNOMINMAX)
  96
  97     # Adjust warnings
  98     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  99     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 100     add_definitions (-W4)
 101     add_definitions (-wd4063) # not a valid value for switch of enum
 102     add_definitions (-wd4127) # conditional expression is constant
 103     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 104     add_definitions (-wd4505) # unreferenced local function has been removed
 105     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 106     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 107     add_definitions (-wd4018) # signed/unsigned mismatch
 108
 109     # Use static runtime
 110     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 111     foreach (flag_var
 112         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 113         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 114     )
 115         if (${flag_var} MATCHES "/MD")
 116             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 117         endif (${flag_var} MATCHES "/MD")
 118     endforeach (flag_var)
 119 else ()
 120     # Adjust warnings
 121     add_definitions (-Wall)
 122     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 123     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 124 endif ()
 125
 126 if (MINGW)
 127     # Avoid depending on MinGW runtime DLLs
 128     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 129     if (HAVE_STATIC_LIBGCC_FLAG)
 130         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 131         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 132         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 133     endif ()
 134     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 135     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 136         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 137         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 138         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 139     endif ()
 140 endif ()
 141
 142
 143 # Put all executables into the same top level build directory, regardless of
 144 # which subdirectory they are declared
 145 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 146
 147
 148 ##############################################################################
 149 # Bundled dependencies
 150 #
 151 # We always use the bundled zlib, libpng, and snappy sources:
 152 # - on Windows to make it easy to deploy the wrappers DLLs
 153 # - on unices to prevent symbol collisions when tracing applications that link
 154 # against other versions of these libraries
 155
 156 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 157 set (ZLIB_LIBRARIES z_bundled)
 158 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 159
 160 include_directories (${ZLIB_INCLUDE_DIRS})
 161 link_libraries (${ZLIB_LIBRARIES})
 162
 163 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 164 set (SNAPPY_LIBRARIES snappy_bundled)
 165 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 166
 167 include_directories (${SNAPPY_INCLUDE_DIRS})
 168 link_libraries (${SNAPPY_LIBRARIES})
 169
 170 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 171 set (PNG_DEFINITIONS "")
 172 set (PNG_LIBRARIES png_bundled)
 173
 174 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 175 include_directories (${PNG_INCLUDE_DIR})
 176 add_definitions (${PNG_DEFINITIONS})
 177 link_libraries (${PNG_LIBRARIES})
 178
 179 # The Qt website provides binaries for Windows and MacOSX, and they are
 180 # automatically found by cmake without any manual intervention.  The situation
 181 # for QJSON is substantially different: there are no binaries for QJSON
 182 # available, and there is no standard installation directory that is detected
 183 # by cmake.
 184 #
 185 # By bundling the QJSON source, we make it much more easier to build the GUI on
 186 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 187 # AUTO.
 188 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 189     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 190     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 191     set (QJSON_LIBRARY_DIRS)
 192     set (QJSON_LIBRARIES qjson_bundled)
 193     set (QJSON_FOUND TRUE)
 194 endif ()
 195
 196 # For glext headers
 197 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 198
 199 # For EGL headers
 200 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 201
 202 ##############################################################################
 203 # Installation directories
 204
 205 if (WIN32 OR APPLE)
 206     # On Windows/MacOSX, applications are usually installed on a directory of
 207     # their own
 208     set (DOC_INSTALL_DIR doc)
 209 else ()
 210     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 211 endif ()
 212
 213 set (LIB_INSTALL_DIR lib/apitrace)
 214
 215 if (APPLE)
 216     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 217     # directories
 218     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 219 else ()
 220     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 221 endif ()
 222
 223 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 224 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 225
 226 # Expose the binary/install directories to source
 227 #
 228 # TODO: Use the same directory layout, for both build and install directories,
 229 # so that binaries can find each other using just relative paths.
 230 #
 231 add_definitions(
 232     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 233     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 234     -DAPITRACE_SCRIPTS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${SCRIPTS_INSTALL_DIR}"
 235     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 236 )
 237
 238
 239 ##############################################################################
 240 # Common libraries / utilities
 241
 242 include_directories (
 243     ${CMAKE_CURRENT_SOURCE_DIR}
 244     ${CMAKE_CURRENT_SOURCE_DIR}/common
 245 )
 246
 247 add_custom_command (
 248     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 249     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 250     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 251 )
 252
 253 if (WIN32)
 254     set (os os_win32.cpp)
 255     set (glws_os glws_wgl.cpp)
 256 else ()
 257     set (os os_posix.cpp)
 258     if (APPLE)
 259         set (glws_os glws_cocoa.mm)
 260     else ()
 261         set (glws_os glws_glx.cpp)
 262     endif ()
 263 endif ()
 264
 265 add_library (common STATIC
 266     common/trace_file.cpp
 267     common/trace_file_zlib.cpp
 268     common/trace_file_snappy.cpp
 269     common/trace_model.cpp
 270     common/trace_parser.cpp
 271     common/trace_writer.cpp
 272     common/trace_writer_local.cpp
 273     common/trace_writer_model.cpp
 274     common/trace_loader.cpp
 275     common/trace_tools_trace.cpp
 276     common/image.cpp
 277     common/image_bmp.cpp
 278     common/image_pnm.cpp
 279     common/image_png.cpp
 280     common/${os}
 281 )
 282
 283 set_target_properties (common PROPERTIES
 284     # Ensure it can be statically linked in shared libraries
 285     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 286 )
 287
 288 link_libraries (common)
 289
 290
 291 ##############################################################################
 292 # API tracers
 293
 294 if (WIN32)
 295     if (MINGW)
 296         # Silence warnings about @nn suffix mismatch
 297         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 298     endif (MINGW)
 299
 300     # ddraw.dll
 301     if (DirectX_D3D_INCLUDE_DIR)
 302         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 303         add_custom_command (
 304             OUTPUT ddrawtrace.cpp
 305             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 306             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 307         )
 308         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 309         set_target_properties (ddraw
 310             PROPERTIES PREFIX ""
 311             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 312             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 313         )
 314         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 315     endif (DirectX_D3D_INCLUDE_DIR)
 316
 317     # d3d8.dll
 318     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 319         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 320         add_custom_command (
 321             OUTPUT d3d8trace.cpp
 322             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 323             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 324         )
 325         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 326         set_target_properties (d3d8
 327             PROPERTIES PREFIX ""
 328             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 329             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 330         )
 331         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 332     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 333
 334     # d3d9.dll
 335     if (DirectX_D3DX9_INCLUDE_DIR)
 336         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 337         add_custom_command (
 338             OUTPUT d3d9trace.cpp
 339             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 340             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 341         )
 342         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 343         set_target_properties (d3d9
 344             PROPERTIES PREFIX ""
 345             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 346             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 347         )
 348         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 349     endif (DirectX_D3DX9_INCLUDE_DIR)
 350
 351     # d3d10.dll
 352     if (DirectX_D3D10_INCLUDE_DIR)
 353         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 354         add_custom_command (
 355             OUTPUT d3d10trace.cpp
 356             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 357             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 358         )
 359         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 360         set_target_properties (d3d10
 361             PROPERTIES PREFIX ""
 362             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 363             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 364         )
 365         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 366     endif (DirectX_D3D10_INCLUDE_DIR)
 367
 368     # opengl32.dll
 369     add_custom_command (
 370         OUTPUT wgltrace.cpp
 371         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 372         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 373     )
 374     add_library (wgltrace MODULE specs/opengl32.def
 375         wgltrace.cpp
 376         glcaps.cpp
 377         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 378     )
 379     set_target_properties (wgltrace PROPERTIES
 380         PREFIX ""
 381         OUTPUT_NAME opengl32
 382         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 383         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 384     )
 385     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 386
 387 elseif (APPLE)
 388     # OpenGL framework
 389     add_custom_command (
 390         OUTPUT cgltrace.cpp
 391         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 392         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 393     )
 394
 395     add_library (cgltrace SHARED
 396         cgltrace.cpp
 397         glcaps.cpp
 398         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 399     )
 400
 401     set_target_properties (cgltrace PROPERTIES
 402         # OpenGL framework name
 403         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 404         # Specificy the version and reexport GLU symbols
 405         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 406         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 407         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 408     )
 409
 410     target_link_libraries (cgltrace dl)
 411
 412     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 413 else ()
 414     # libGL.so
 415     add_custom_command (
 416         OUTPUT glxtrace.cpp
 417         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 418         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 419     )
 420
 421     add_library (glxtrace SHARED
 422         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 423         glxtrace.cpp
 424         glcaps.cpp
 425     )
 426
 427     set_target_properties (glxtrace PROPERTIES
 428         # avoid the default "lib" prefix
 429         PREFIX ""
 430         # Prevent symbol relocations internal to our wrapper library to be
 431         # overwritten by the application.
 432         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 433         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 434         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 435     )
 436
 437     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 438
 439     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 440 endif ()
 441
 442
 443 if (EGL_FOUND)
 444     # libEGL.so/libGL.so
 445     add_custom_command (
 446         OUTPUT egltrace.cpp
 447         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 448         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 449     )
 450
 451     add_library (egltrace SHARED
 452         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 453         egltrace.cpp
 454         glcaps.cpp
 455     )
 456
 457     set_property (
 458         TARGET egltrace
 459         APPEND
 460         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 461     )
 462
 463     set_target_properties (egltrace PROPERTIES
 464         # avoid the default "lib" prefix
 465         PREFIX ""
 466         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 467         # Prevent symbol relocations internal to our wrapper library to be
 468         # overwritten by the application.
 469         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 470         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 471     )
 472
 473     target_link_libraries (egltrace dl)
 474
 475     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 476 endif ()
 477
 478 ##############################################################################
 479 # API retracers
 480
 481 add_custom_command (
 482     OUTPUT glretrace_gl.cpp
 483     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 484     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 485 )
 486
 487 add_custom_command (
 488     OUTPUT glstate_params.cpp
 489     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 490     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 491 )
 492
 493 include_directories (
 494     ${CMAKE_CURRENT_BINARY_DIR}
 495     ${OPENGL_INCLUDE_PATH}
 496 )
 497
 498 set (retrace_sources
 499     glretrace_gl.cpp
 500     glretrace_cgl.cpp
 501     glretrace_glx.cpp
 502     glretrace_wgl.cpp
 503     glretrace_egl.cpp
 504     glretrace_main.cpp
 505     glstate.cpp
 506     glstate_params.cpp
 507     retrace.cpp
 508     retrace_stdc.cpp
 509     glws.cpp
 510     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 511 )
 512
 513 add_executable (glretrace
 514     ${retrace_sources}
 515     ${glws_os}
 516 )
 517
 518 set_property (
 519     TARGET glretrace
 520     APPEND
 521     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 522 )
 523
 524 target_link_libraries (glretrace
 525     common
 526 )
 527
 528 if (WIN32)
 529     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 530 elseif (APPLE)
 531     target_link_libraries (glretrace
 532         "-framework Cocoa"
 533         "-framework ApplicationServices" # CGS*
 534         ${OPENGL_gl_LIBRARY} # CGL*
 535     )
 536 else ()
 537     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 538 endif ()
 539
 540 install (TARGETS glretrace RUNTIME DESTINATION bin)
 541
 542 if (EGL_FOUND AND NOT WIN32 AND NOT APPLE)
 543     add_executable (eglretrace
 544         ${retrace_sources}
 545         glws_egl_xlib.cpp
 546     )
 547
 548     set_property (
 549         TARGET eglretrace
 550         APPEND
 551         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 552         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 553     )
 554
 555     target_link_libraries (eglretrace
 556         common
 557     )
 558
 559     target_link_libraries (eglretrace
 560         ${EGL_LIBRARIES}
 561         ${OPENGL_gl_LIBRARY}
 562         ${X11_X11_LIB}
 563     )
 564
 565     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 566 endif ()
 567
 568 ##############################################################################
 569 # CLI
 570
 571 add_subdirectory(cli)
 572
 573 ##############################################################################
 574 # Scripts (to support the CLI)
 575
 576 install (PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh DESTINATION ${LIB_INSTALL_DIR}/scripts)
 577 install (PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py DESTINATION ${LIB_INSTALL_DIR}/scripts)
 578
 579 ##############################################################################
 580 # GUI
 581
 582 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 583     add_subdirectory(gui)
 584 endif ()
 585
 586
 587 ##############################################################################
 588 # Packaging
 589
 590 install (
 591     FILES
 592         BUGS.markdown
 593         LICENSE
 594         NEWS.markdown
 595         README.markdown
 596         TODO.markdown
 597     DESTINATION ${DOC_INSTALL_DIR}
 598 )
 599
 600 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 601 set (CPACK_PACKAGE_VERSION_MINOR "0")
 602
 603 # Use current date in YYYYMMDD format as patch number
 604 execute_process (
 605     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 606     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 607 )
 608
 609 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 610 if (WIN32)
 611     set (CPACK_GENERATOR "ZIP")
 612 elseif (APPLE)
 613     set (CPACK_GENERATOR "DragNDrop")
 614 else ()
 615     set (CPACK_GENERATOR "TBZ2")
 616 endif ()
 617
 618 include(CPack)