git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 include_directories (${OPENGL_INCLUDE_DIR})
  44
  45 if (WIN32)
  46     find_package (DirectX)
  47 elseif (APPLE)
  48 else ()
  49     find_package (X11)
  50
  51     if (X11_FOUND)
  52         include_directories (${X11_INCLUDE_DIR})
  53         add_definitions (-DHAVE_X11)
  54     endif ()
  55
  56     if (ENABLE_EGL)
  57         if (NOT ENABLE_EGL STREQUAL "AUTO")
  58             set (REQUIRE_EGL REQUIRED)
  59         endif ()
  60         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  61         if (EGL_FOUND)
  62             include_directories (${EGL_INCLUDE_DIR})
  63             add_definitions (-DHAVE_EGL)
  64         endif ()
  65     else ()
  66         set (EGL_FOUND 0)
  67     endif ()
  68 endif ()
  69
  70
  71 ##############################################################################
  72 # Set global build options
  73
  74 include (CheckCXXCompilerFlag)
  75
  76 if (WIN32)
  77     # MSVC & MinGW only define & use APIENTRY
  78     add_definitions (-DGLAPIENTRY=__stdcall)
  79
  80     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  81     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  82 else (WIN32)
  83     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  84     if (CXX_COMPILER_FLAG_VISIBILITY)
  85         add_definitions ("-fvisibility=hidden")
  86     endif (CXX_COMPILER_FLAG_VISIBILITY)
  87 endif (WIN32)
  88
  89 if (MSVC)
  90     # C99 includes for msvc
  91     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  92
  93     # Enable math constants defines
  94     add_definitions (-D_USE_MATH_DEFINES)
  95
  96     # No min/max macros
  97     add_definitions (-DNOMINMAX)
  98
  99     # Adjust warnings
 100     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 101     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 102     add_definitions (-W4)
 103     add_definitions (-wd4063) # not a valid value for switch of enum
 104     add_definitions (-wd4127) # conditional expression is constant
 105     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 106     add_definitions (-wd4505) # unreferenced local function has been removed
 107     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 108     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 109     add_definitions (-wd4018) # signed/unsigned mismatch
 110
 111     # Use static runtime
 112     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 113     foreach (flag_var
 114         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 115         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 116     )
 117         if (${flag_var} MATCHES "/MD")
 118             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 119         endif (${flag_var} MATCHES "/MD")
 120     endforeach (flag_var)
 121 else ()
 122     # Adjust warnings
 123     add_definitions (-Wall)
 124     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 125     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 126 endif ()
 127
 128 if (MINGW)
 129     # Avoid depending on MinGW runtime DLLs
 130     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 131     if (HAVE_STATIC_LIBGCC_FLAG)
 132         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 133         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 134         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 135     endif ()
 136     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 137     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 138         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 139         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 140         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 141     endif ()
 142 endif ()
 143
 144
 145 # Put all executables into the same top level build directory, regardless of
 146 # which subdirectory they are declared
 147 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 148
 149
 150 ##############################################################################
 151 # Bundled dependencies
 152 #
 153 # We always use the bundled zlib, libpng, and snappy sources:
 154 # - on Windows to make it easy to deploy the wrappers DLLs
 155 # - on unices to prevent symbol collisions when tracing applications that link
 156 # against other versions of these libraries
 157
 158 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 159 set (ZLIB_LIBRARIES z_bundled)
 160 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 161
 162 include_directories (${ZLIB_INCLUDE_DIRS})
 163 link_libraries (${ZLIB_LIBRARIES})
 164
 165 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 166 set (SNAPPY_LIBRARIES snappy_bundled)
 167 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 168
 169 include_directories (${SNAPPY_INCLUDE_DIRS})
 170 link_libraries (${SNAPPY_LIBRARIES})
 171
 172 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 173 set (PNG_DEFINITIONS "")
 174 set (PNG_LIBRARIES png_bundled)
 175
 176 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 177 include_directories (${PNG_INCLUDE_DIR})
 178 add_definitions (${PNG_DEFINITIONS})
 179 link_libraries (${PNG_LIBRARIES})
 180
 181 if (MSVC)
 182     add_subdirectory (thirdparty/getopt EXCLUDE_FROM_ALL)
 183     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/getopt)
 184     set (GETOPT_LIBRARIES getopt_bundled)
 185 endif ()
 186
 187 # The Qt website provides binaries for Windows and MacOSX, and they are
 188 # automatically found by cmake without any manual intervention.  The situation
 189 # for QJSON is substantially different: there are no binaries for QJSON
 190 # available, and there is no standard installation directory that is detected
 191 # by cmake.
 192 #
 193 # By bundling the QJSON source, we make it much more easier to build the GUI on
 194 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 195 # AUTO.
 196 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 197     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 198     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 199     set (QJSON_LIBRARY_DIRS)
 200     set (QJSON_LIBRARIES qjson_bundled)
 201     set (QJSON_FOUND TRUE)
 202 endif ()
 203
 204 # For glext headers.  Needs to be before system includes as often system's GL
 205 # headers bundle and include glext.h and glxext.h
 206 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/glext)
 207
 208 # For EGL headers
 209 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 210
 211 ##############################################################################
 212 # Installation directories
 213
 214 if (WIN32 OR APPLE)
 215     # On Windows/MacOSX, applications are usually installed on a directory of
 216     # their own
 217     set (DOC_INSTALL_DIR doc)
 218 else ()
 219     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 220 endif ()
 221
 222 set (LIB_INSTALL_DIR lib/apitrace)
 223
 224 if (APPLE)
 225     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 226     # directories
 227     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 228 else ()
 229     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 230 endif ()
 231
 232 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 233 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 234
 235 # Expose the binary/install directories to source
 236 #
 237 # TODO: Use the same directory layout, for both build and install directories,
 238 # so that binaries can find each other using just relative paths.
 239 #
 240 add_definitions(
 241     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 242     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 243     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 244 )
 245
 246
 247 ##############################################################################
 248 # Common libraries / utilities
 249
 250 include_directories (
 251     ${CMAKE_CURRENT_BINARY_DIR}
 252     ${CMAKE_CURRENT_SOURCE_DIR}
 253     ${CMAKE_CURRENT_SOURCE_DIR}/common
 254 )
 255
 256 add_custom_command (
 257     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 258     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 259     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 260 )
 261
 262 # Wrap glproc.hpp as a target to prevent the command from being executed
 263 # multiple times simulatenously, when the targets that depend on it are built
 264 # in parallel.
 265 add_custom_target (glproc DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 266
 267 if (WIN32)
 268     set (os os_win32.cpp)
 269     set (glws_os glws_wgl.cpp)
 270 else ()
 271     set (os os_posix.cpp)
 272     if (APPLE)
 273         set (glws_os glws_cocoa.mm)
 274     else ()
 275         set (glws_os glws_glx.cpp)
 276     endif ()
 277 endif ()
 278
 279 add_library (common STATIC
 280     common/trace_callset.cpp
 281     common/trace_dump.cpp
 282     common/trace_file.cpp
 283     common/trace_file_read.cpp
 284     common/trace_file_write.cpp
 285     common/trace_file_zlib.cpp
 286     common/trace_file_snappy.cpp
 287     common/trace_model.cpp
 288     common/trace_parser.cpp
 289     common/trace_parser_flags.cpp
 290     common/trace_writer.cpp
 291     common/trace_writer_local.cpp
 292     common/trace_writer_model.cpp
 293     common/trace_loader.cpp
 294     common/trace_resource.cpp
 295     common/trace_tools_trace.cpp
 296     common/image.cpp
 297     common/image_bmp.cpp
 298     common/image_pnm.cpp
 299     common/image_png.cpp
 300     common/${os}
 301 )
 302
 303 set_target_properties (common PROPERTIES
 304     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 305     # Ensure it can be statically linked in shared libraries
 306     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 307 )
 308
 309 link_libraries (common)
 310
 311
 312 ##############################################################################
 313 # API tracers
 314
 315 if (WIN32)
 316     if (MINGW)
 317         # Silence warnings about @nn suffix mismatch
 318         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 319     endif (MINGW)
 320
 321     # ddraw.dll
 322     if (DirectX_D3D_INCLUDE_DIR)
 323         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 324         add_custom_command (
 325             OUTPUT ddrawtrace.cpp
 326             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 327             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 328         )
 329         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 330         set_target_properties (ddraw
 331             PROPERTIES PREFIX ""
 332             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 333             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 334         )
 335         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 336     endif (DirectX_D3D_INCLUDE_DIR)
 337
 338     # d3d8.dll
 339     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 340         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 341         add_custom_command (
 342             OUTPUT d3d8trace.cpp
 343             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 344             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 345         )
 346         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 347         set_target_properties (d3d8
 348             PROPERTIES PREFIX ""
 349             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 350             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 351         )
 352         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 353     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 354
 355     # d3d9.dll
 356     if (DirectX_D3DX9_INCLUDE_DIR)
 357         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 358         add_custom_command (
 359             OUTPUT d3d9trace.cpp
 360             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 361             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 362         )
 363         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 364         set_target_properties (d3d9
 365             PROPERTIES PREFIX ""
 366             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 367             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 368         )
 369         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 370     endif (DirectX_D3DX9_INCLUDE_DIR)
 371
 372     # d3d10.dll
 373     if (DirectX_D3D10_INCLUDE_DIR)
 374         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 375         add_custom_command (
 376             OUTPUT d3d10trace.cpp
 377             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 378             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 379         )
 380         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 381         set_target_properties (d3d10
 382             PROPERTIES PREFIX ""
 383             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 384             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 385         )
 386         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 387     endif (DirectX_D3D10_INCLUDE_DIR)
 388
 389     # opengl32.dll
 390     add_custom_command (
 391         OUTPUT wgltrace.cpp
 392         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 393         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 394     )
 395     add_library (wgltrace MODULE specs/opengl32.def
 396         wgltrace.cpp
 397         glcaps.cpp
 398         glproc_gl.cpp
 399     )
 400     add_dependencies (wgltrace glproc)
 401     set_target_properties (wgltrace PROPERTIES
 402         PREFIX ""
 403         OUTPUT_NAME opengl32
 404         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 405         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 406     )
 407     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 408
 409 elseif (APPLE)
 410     # OpenGL framework
 411     add_custom_command (
 412         OUTPUT cgltrace.cpp
 413         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 414         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 415     )
 416
 417     add_library (cgltrace SHARED
 418         cgltrace.cpp
 419         glcaps.cpp
 420         glproc_gl.cpp
 421     )
 422
 423     add_dependencies (cgltrace glproc)
 424
 425     set_target_properties (cgltrace PROPERTIES
 426         # OpenGL framework name
 427         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 428         # Specificy the version and reexport GLU symbols
 429         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 430         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 431         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 432     )
 433
 434     target_link_libraries (cgltrace
 435         pthread
 436         dl
 437     )
 438
 439     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 440 elseif (X11_FOUND)
 441     # libGL.so
 442     add_custom_command (
 443         OUTPUT glxtrace.cpp
 444         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 445         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 446     )
 447
 448     add_library (glxtrace SHARED
 449         glxtrace.cpp
 450         glcaps.cpp
 451         glproc_gl.cpp
 452     )
 453
 454     add_dependencies (glxtrace glproc)
 455
 456     set_target_properties (glxtrace PROPERTIES
 457         # avoid the default "lib" prefix
 458         PREFIX ""
 459         # Prevent symbol relocations internal to our wrapper library to be
 460         # overwritten by the application.
 461         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 462         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 463         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 464     )
 465
 466     target_link_libraries (glxtrace
 467         ${X11_X11_LIB}
 468         pthread
 469         dl
 470     )
 471
 472     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 473 endif ()
 474
 475
 476 if (EGL_FOUND)
 477     # libEGL.so/libGL.so
 478     add_custom_command (
 479         OUTPUT egltrace.cpp
 480         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 481         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 482     )
 483
 484     add_library (egltrace SHARED
 485         egltrace.cpp
 486         glcaps.cpp
 487         glproc_egl.cpp
 488     )
 489
 490     add_dependencies (egltrace glproc)
 491
 492     set_property (
 493         TARGET egltrace
 494         APPEND
 495         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 496     )
 497
 498     set_target_properties (egltrace PROPERTIES
 499         # avoid the default "lib" prefix
 500         PREFIX ""
 501         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 502         # Prevent symbol relocations internal to our wrapper library to be
 503         # overwritten by the application.
 504         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 505         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 506     )
 507
 508     target_link_libraries (egltrace
 509         pthread
 510         dl
 511     )
 512
 513     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 514 endif ()
 515
 516 ##############################################################################
 517 # API retracers
 518
 519 add_custom_command (
 520     OUTPUT glretrace_gl.cpp
 521     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 522     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 523 )
 524
 525 add_custom_command (
 526     OUTPUT glstate_params.cpp
 527     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 528     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 529 )
 530
 531 set (retrace_sources
 532     glretrace_gl.cpp
 533     glretrace_cgl.cpp
 534     glretrace_glx.cpp
 535     glretrace_wgl.cpp
 536     glretrace_egl.cpp
 537     glretrace_main.cpp
 538     glstate.cpp
 539     glstate_params.cpp
 540     retrace.cpp
 541     retrace_stdc.cpp
 542     glws.cpp
 543 )
 544
 545 if (WIN32 OR APPLE OR X11_FOUND)
 546     add_executable (glretrace
 547         ${retrace_sources}
 548         ${glws_os}
 549         glproc_gl.cpp
 550     )
 551
 552     add_dependencies (glretrace glproc)
 553
 554     set_property (
 555         TARGET glretrace
 556         APPEND
 557         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 558     )
 559
 560     target_link_libraries (glretrace
 561         common
 562     )
 563
 564     if (WIN32)
 565     else ()
 566         if (APPLE)
 567             target_link_libraries (glretrace
 568                 "-framework Cocoa"
 569                 "-framework ApplicationServices" # CGS*
 570                 ${OPENGL_gl_LIBRARY} # CGL*
 571             )
 572         else ()
 573             target_link_libraries (glretrace ${X11_X11_LIB})
 574         endif ()
 575
 576         target_link_libraries (glretrace
 577             # gdb doesn't like when pthreads is loaded through dlopen (which happens
 578             # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
 579             # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
 580             pthread
 581             dl
 582         )
 583
 584         if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 585             target_link_libraries (glretrace rt)
 586         endif ()
 587
 588     endif ()
 589
 590     install (TARGETS glretrace RUNTIME DESTINATION bin)
 591 endif ()
 592
 593 if (EGL_FOUND AND X11_FOUND AND NOT WIN32 AND NOT APPLE)
 594     add_executable (eglretrace
 595         ${retrace_sources}
 596         glws_egl_xlib.cpp
 597         glproc_egl.cpp
 598     )
 599
 600     add_dependencies (eglretrace glproc)
 601
 602     set_property (
 603         TARGET eglretrace
 604         APPEND
 605         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 606         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 607     )
 608
 609     target_link_libraries (eglretrace
 610         common
 611         ${X11_X11_LIB}
 612         pthread
 613         dl
 614     )
 615
 616     if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 617         target_link_libraries (eglretrace rt)
 618     endif ()
 619
 620     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 621 endif ()
 622
 623 ##############################################################################
 624 # CLI
 625
 626 add_subdirectory(cli)
 627
 628 ##############################################################################
 629 # Scripts (to support the CLI)
 630
 631 install (
 632     PROGRAMS
 633         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.py
 634         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 635         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 636     DESTINATION ${SCRIPTS_INSTALL_DIR}
 637 )
 638
 639 ##############################################################################
 640 # GUI
 641
 642 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 643     add_subdirectory(gui)
 644 endif ()
 645
 646
 647 ##############################################################################
 648 # Packaging
 649
 650 install (
 651     FILES
 652         BUGS.markdown
 653         LICENSE
 654         NEWS.markdown
 655         README.markdown
 656         TODO.markdown
 657     DESTINATION ${DOC_INSTALL_DIR}
 658 )
 659
 660 set (CPACK_PACKAGE_VERSION_MAJOR "3")
 661 set (CPACK_PACKAGE_VERSION_MINOR "0")
 662
 663 # Use current date in YYYYMMDD format as patch number
 664 execute_process (
 665     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 666     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 667 )
 668
 669 # cpack mistakenly detects Mingw-w64 as win32
 670 if (MINGW)
 671     if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 672         set (CPACK_SYSTEM_NAME win64)
 673     endif ()
 674 endif ()
 675
 676 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 677 if (WIN32)
 678     set (CPACK_GENERATOR "ZIP")
 679 elseif (APPLE)
 680     set (CPACK_GENERATOR "DragNDrop")
 681 else ()
 682     set (CPACK_GENERATOR "TBZ2")
 683 endif ()
 684
 685 include(CPack)