git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Find dependencies
   8
   9 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  10
  11 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  12
  13 find_package (PythonInterp REQUIRED)
  14 find_package (OpenGL REQUIRED)
  15 find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit)
  16 find_package (QJSON)
  17
  18 if (NOT WIN32)
  19     find_package (X11 REQUIRED)
  20
  21     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  22     # from the standard OpenGL framework which provides support for native Mac OS X
  23     # applications.
  24     if (APPLE)
  25         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  26         if (NOT X11_GL_INCLUDE_PATH)
  27             message (SEND_ERROR "Could not find GL/glx.h")
  28         endif (NOT X11_GL_INCLUDE_PATH)
  29         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  30
  31         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  32         if (NOT X11_GL_LIB)
  33             message (SEND_ERROR "Could not find libGL.dylib")
  34         endif (NOT X11_GL_LIB)
  35     else ()
  36         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  37         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  38     endif ()
  39
  40     include_directories (${X11_INCLUDE_DIR})
  41 endif (NOT WIN32)
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 endif (WIN32)
  46
  47
  48 ##############################################################################
  49 # Set global build options
  50
  51 include (CheckCXXCompilerFlag)
  52
  53 if (WIN32)
  54     # MSVC & MinGW only define & use APIENTRY
  55     add_definitions (-DGLAPIENTRY=__stdcall)
  56
  57     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  58     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  59 else (WIN32)
  60     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  61     if (CXX_COMPILER_FLAG_VISIBILITY)
  62         add_definitions ("-fvisibility=hidden")
  63     endif (CXX_COMPILER_FLAG_VISIBILITY)
  64 endif (WIN32)
  65
  66 if (MSVC)
  67     # C99 includes for msvc
  68     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  69
  70     # Enable math constants defines
  71     add_definitions (-D_USE_MATH_DEFINES)
  72
  73     # No min/max macros
  74     add_definitions (-DNOMINMAX)
  75
  76     # Adjust warnings
  77     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  78     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  79     add_definitions (-W4)
  80     add_definitions (-wd4063) # not a valid value for switch of enum
  81     add_definitions (-wd4127) # conditional expression is constant
  82     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  83     add_definitions (-wd4505) # unreferenced local function has been removed
  84     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  85     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  86     add_definitions (-wd4018) # signed/unsigned mismatch
  87
  88     # Use static runtime
  89     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  90     foreach (flag_var
  91         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  92         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  93     )
  94         if (${flag_var} MATCHES "/MD")
  95             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  96         endif (${flag_var} MATCHES "/MD")
  97     endforeach (flag_var)
  98 else ()
  99     # Adjust warnings
 100     add_definitions (-Wall)
 101     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 102     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 103 endif ()
 104
 105
 106 # Put all executables into the same top level build directory, regardless of
 107 # which subdirectory they are declared
 108 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 109
 110
 111 ##############################################################################
 112 # Bundled dependencies
 113 #
 114 # We always use the bundled zlib and libpng sources:
 115 # - on Windows to make it easy to deploy the wrappers DLLs
 116 # - on unices to prevent symbol collisions when tracing applications that link
 117 # against other versions of these libraries
 118
 119 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 120 set (ZLIB_LIBRARIES z_bundled)
 121 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 122
 123 include_directories (${ZLIB_INCLUDE_DIRS})
 124 link_libraries (${ZLIB_LIBRARIES})
 125
 126 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 127 set (PNG_DEFINITIONS "")
 128 set (PNG_LIBRARIES png_bundled)
 129
 130 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 131 include_directories (${PNG_INCLUDE_DIR})
 132 add_definitions (${PNG_DEFINITIONS})
 133 link_libraries (${PNG_LIBRARIES})
 134
 135 # For glext headers
 136 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 137
 138
 139 ##############################################################################
 140 # Common libraries / utilities
 141
 142 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 143
 144 add_custom_command (
 145     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 146     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 147     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 148 )
 149
 150 if (WIN32)
 151     set (os os_win32.cpp)
 152     set (glws glws_wgl.cpp)
 153 else (WIN32)
 154     set (os os_posix.cpp)
 155     set (glws glws_glx.cpp)
 156 endif (WIN32)
 157
 158 add_library (common
 159     trace_model.cpp
 160     trace_parser.cpp
 161     trace_writer.cpp
 162     trace_model_writer.cpp
 163     image.cpp
 164     image_bmp.cpp
 165     image_pnm.cpp
 166     image_png.cpp
 167     ${os}
 168 )
 169
 170 add_executable (tracedump tracedump.cpp)
 171 target_link_libraries (tracedump common)
 172 install (TARGETS tracedump RUNTIME DESTINATION bin)
 173
 174
 175 ##############################################################################
 176 # API tracers
 177
 178 if (WIN32)
 179     # ddraw.dll
 180     if (DirectX_D3D_INCLUDE_DIR)
 181         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 182         add_custom_command (
 183             OUTPUT ddraw.cpp
 184             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 185             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 186         )
 187         add_library (ddraw MODULE ddraw.def ddraw.cpp trace_writer.cpp os_win32.cpp)
 188         set_target_properties (ddraw
 189             PROPERTIES PREFIX ""
 190             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 191             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 192         )
 193         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 194     endif (DirectX_D3D_INCLUDE_DIR)
 195
 196     # d3d8.dll
 197     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 198         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 199         add_custom_command (
 200             OUTPUT d3d8.cpp
 201             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 202             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 203         )
 204         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 205         set_target_properties (d3d8
 206             PROPERTIES PREFIX ""
 207             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 208             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 209         )
 210         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 211     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 212
 213     # d3d9.dll
 214     if (DirectX_D3DX9_INCLUDE_DIR)
 215         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 216         add_custom_command (
 217             OUTPUT d3d9.cpp
 218             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 219             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 220         )
 221         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 222         set_target_properties (d3d9
 223             PROPERTIES PREFIX ""
 224             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 225             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 226         )
 227         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 228     endif (DirectX_D3DX9_INCLUDE_DIR)
 229
 230     # d3d10.dll
 231     #if (DirectX_D3D10_INCLUDE_DIR)
 232     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 233     #    add_custom_command (
 234     #        OUTPUT d3d10.cpp
 235     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 236     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 237     #    )
 238     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp trace_writer.cpp os_win32.cpp)
 239     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 240     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 241     #endif (DirectX_D3D10_INCLUDE_DIR)
 242
 243     # opengl32.dll
 244     add_custom_command (
 245         OUTPUT wgltrace.cpp
 246         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 247         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 248     )
 249     add_library (wgltrace MODULE opengl32.def wgltrace.cpp trace_writer.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 250     set_target_properties (wgltrace PROPERTIES
 251         PREFIX ""
 252         OUTPUT_NAME opengl32
 253         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 254         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 255     )
 256     if (MINGW)
 257         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 258     endif (MINGW)
 259     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 260
 261 elseif (APPLE)
 262     # OpenGL framework
 263     add_custom_command (
 264         OUTPUT cgltrace.cpp
 265         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 266         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 267     )
 268
 269     add_library (cgltrace SHARED cgltrace.cpp trace_writer.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 270
 271     set_target_properties (cgltrace PROPERTIES
 272         # OpenGL framework name
 273         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 274         # Specificy the version and reexport GLU symbols
 275         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 276         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 277         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 278     )
 279
 280     target_link_libraries (cgltrace dl)
 281
 282     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 283 else ()
 284     # libGL.so
 285     add_custom_command (
 286         OUTPUT glxtrace.cpp
 287         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 288         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 289     )
 290
 291     add_library (glxtrace SHARED
 292         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 293         glxtrace.cpp
 294         glsnapshot.cpp
 295         trace_writer.cpp
 296         image.cpp
 297         image_png.cpp
 298         os_posix.cpp
 299     )
 300
 301     set_target_properties (glxtrace PROPERTIES
 302         # avoid the default "lib" prefix
 303         PREFIX ""
 304     )
 305
 306     # Prevent symbol relocations internal to our wrapper library to be
 307     # overwritten by the application.
 308     set_target_properties (glxtrace PROPERTIES
 309         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 310     )
 311
 312     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 313
 314     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 315 endif ()
 316
 317
 318 ##############################################################################
 319 # API retracers
 320
 321 add_custom_command (
 322     OUTPUT glretrace_gl.cpp
 323     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 324     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 325 )
 326
 327 add_custom_command (
 328     OUTPUT glstate_params.cpp
 329     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 330     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 331 )
 332
 333 include_directories (
 334     ${CMAKE_CURRENT_BINARY_DIR}
 335     ${OPENGL_INCLUDE_PATH}
 336 )
 337
 338 add_executable (glretrace
 339     glretrace_gl.cpp
 340     glretrace_cgl.cpp
 341     glretrace_glx.cpp
 342     glretrace_wgl.cpp
 343     glretrace_main.cpp
 344     glstate.cpp
 345     glstate_params.cpp
 346     retrace.cpp
 347     ${glws}
 348     image.cpp
 349     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 350 )
 351
 352 set_property (
 353     TARGET glretrace
 354     APPEND
 355     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 356 )
 357
 358 target_link_libraries (glretrace
 359     common
 360 )
 361
 362 if (WIN32)
 363     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 364 elseif (APPLE)
 365     # XXX: We use GLX on MacOSX, which is in a separate library.
 366     target_link_libraries (glretrace
 367         ${X11_GL_LIB}
 368         ${X11_X11_LIB}
 369         "-framework ApplicationServices" # CGS*
 370         ${OPENGL_gl_LIBRARY} # CGL*
 371     )
 372 else ()
 373     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 374 endif ()
 375
 376 install (TARGETS glretrace RUNTIME DESTINATION bin)
 377
 378
 379 ##############################################################################
 380 # GUI
 381
 382 if (QT4_FOUND AND QJSON_FOUND)
 383     add_subdirectory(gui)
 384 endif (QT4_FOUND AND QJSON_FOUND)
 385
 386
 387 ##############################################################################
 388 # Packaging
 389
 390 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 391
 392 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 393 set (CPACK_PACKAGE_VERSION_MINOR "0")
 394
 395 # Use current date in YYYYMMDD format as patch number
 396 execute_process (
 397     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 398     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 399 )
 400
 401 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 402 if (WIN32)
 403     set (CPACK_GENERATOR "ZIP")
 404 elseif (APPLE)
 405     set (CPACK_GENERATOR "DragNDrop")
 406 else ()
 407     set (CPACK_GENERATOR "TBZ2")
 408 endif ()
 409
 410 include(CPack)