git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 include_directories (${OPENGL_INCLUDE_DIR})
  44
  45 if (WIN32)
  46     find_package (DirectX)
  47 elseif (APPLE)
  48 else ()
  49     find_package (X11 REQUIRED)
  50
  51     include_directories (${X11_INCLUDE_DIR})
  52
  53     if (ENABLE_EGL)
  54         if (NOT ENABLE_EGL STREQUAL "AUTO")
  55             set (REQUIRE_EGL REQUIRED)
  56         endif ()
  57         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  58         if (EGL_FOUND)
  59             include_directories (${EGL_INCLUDE_DIR})
  60             add_definitions (-DHAVE_EGL)
  61         endif ()
  62     else ()
  63         set (EGL_FOUND 0)
  64     endif ()
  65 endif ()
  66
  67
  68 ##############################################################################
  69 # Set global build options
  70
  71 include (CheckCXXCompilerFlag)
  72
  73 if (WIN32)
  74     # MSVC & MinGW only define & use APIENTRY
  75     add_definitions (-DGLAPIENTRY=__stdcall)
  76
  77     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  78     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  79 else (WIN32)
  80     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  81     if (CXX_COMPILER_FLAG_VISIBILITY)
  82         add_definitions ("-fvisibility=hidden")
  83     endif (CXX_COMPILER_FLAG_VISIBILITY)
  84 endif (WIN32)
  85
  86 if (MSVC)
  87     # C99 includes for msvc
  88     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  89
  90     # Enable math constants defines
  91     add_definitions (-D_USE_MATH_DEFINES)
  92
  93     # No min/max macros
  94     add_definitions (-DNOMINMAX)
  95
  96     # Adjust warnings
  97     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  98     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  99     add_definitions (-W4)
 100     add_definitions (-wd4063) # not a valid value for switch of enum
 101     add_definitions (-wd4127) # conditional expression is constant
 102     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 103     add_definitions (-wd4505) # unreferenced local function has been removed
 104     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 105     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 106     add_definitions (-wd4018) # signed/unsigned mismatch
 107
 108     # Use static runtime
 109     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 110     foreach (flag_var
 111         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 112         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 113     )
 114         if (${flag_var} MATCHES "/MD")
 115             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 116         endif (${flag_var} MATCHES "/MD")
 117     endforeach (flag_var)
 118 else ()
 119     # Adjust warnings
 120     add_definitions (-Wall)
 121     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 122     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 123 endif ()
 124
 125 if (MINGW)
 126     # Avoid depending on MinGW runtime DLLs
 127     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 128     if (HAVE_STATIC_LIBGCC_FLAG)
 129         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 130         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 131         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 132     endif ()
 133     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 134     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 135         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 136         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 137         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 138     endif ()
 139 endif ()
 140
 141
 142 # Put all executables into the same top level build directory, regardless of
 143 # which subdirectory they are declared
 144 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 145
 146
 147 ##############################################################################
 148 # Bundled dependencies
 149 #
 150 # We always use the bundled zlib, libpng, and snappy sources:
 151 # - on Windows to make it easy to deploy the wrappers DLLs
 152 # - on unices to prevent symbol collisions when tracing applications that link
 153 # against other versions of these libraries
 154
 155 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 156 set (ZLIB_LIBRARIES z_bundled)
 157 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 158
 159 include_directories (${ZLIB_INCLUDE_DIRS})
 160 link_libraries (${ZLIB_LIBRARIES})
 161
 162 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 163 set (SNAPPY_LIBRARIES snappy_bundled)
 164 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 165
 166 include_directories (${SNAPPY_INCLUDE_DIRS})
 167 link_libraries (${SNAPPY_LIBRARIES})
 168
 169 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 170 set (PNG_DEFINITIONS "")
 171 set (PNG_LIBRARIES png_bundled)
 172
 173 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 174 include_directories (${PNG_INCLUDE_DIR})
 175 add_definitions (${PNG_DEFINITIONS})
 176 link_libraries (${PNG_LIBRARIES})
 177
 178 # The Qt website provides binaries for Windows and MacOSX, and they are
 179 # automatically found by cmake without any manual intervention.  The situation
 180 # for QJSON is substantially different: there are no binaries for QJSON
 181 # available, and there is no standard installation directory that is detected
 182 # by cmake.
 183 #
 184 # By bundling the QJSON source, we make it much more easier to build the GUI on
 185 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 186 # AUTO.
 187 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 188     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 189     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 190     set (QJSON_LIBRARY_DIRS)
 191     set (QJSON_LIBRARIES qjson_bundled)
 192     set (QJSON_FOUND TRUE)
 193 endif ()
 194
 195 # For glext headers
 196 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 197
 198 # For EGL headers
 199 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 200
 201 ##############################################################################
 202 # Installation directories
 203
 204 if (WIN32 OR APPLE)
 205     # On Windows/MacOSX, applications are usually installed on a directory of
 206     # their own
 207     set (DOC_INSTALL_DIR doc)
 208 else ()
 209     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 210 endif ()
 211
 212 set (LIB_INSTALL_DIR lib/apitrace)
 213
 214 if (APPLE)
 215     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 216     # directories
 217     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 218 else ()
 219     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 220 endif ()
 221
 222 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 223 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 224
 225 # Expose the binary/install directories to source
 226 #
 227 # TODO: Use the same directory layout, for both build and install directories,
 228 # so that binaries can find each other using just relative paths.
 229 #
 230 add_definitions(
 231     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 232     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 233     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 234 )
 235
 236
 237 ##############################################################################
 238 # Common libraries / utilities
 239
 240 include_directories (
 241     ${CMAKE_CURRENT_BINARY_DIR}
 242     ${CMAKE_CURRENT_SOURCE_DIR}
 243     ${CMAKE_CURRENT_SOURCE_DIR}/common
 244 )
 245
 246 add_custom_command (
 247     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 248     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 249     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 250 )
 251
 252 # Wrap glproc.hpp as a target to prevent the command from being executed
 253 # multiple times simulatenously, when the targets that depend on it are built
 254 # in parallel.
 255 add_custom_target (glproc DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 256
 257 if (WIN32)
 258     set (os os_win32.cpp)
 259     set (glws_os glws_wgl.cpp)
 260 else ()
 261     set (os os_posix.cpp)
 262     if (APPLE)
 263         set (glws_os glws_cocoa.mm)
 264     else ()
 265         set (glws_os glws_glx.cpp)
 266     endif ()
 267 endif ()
 268
 269 add_library (common STATIC
 270     common/trace_dump.cpp
 271     common/trace_file.cpp
 272     common/trace_file_read.cpp
 273     common/trace_file_write.cpp
 274     common/trace_file_zlib.cpp
 275     common/trace_file_snappy.cpp
 276     common/trace_model.cpp
 277     common/trace_parser.cpp
 278     common/trace_parser_flags.cpp
 279     common/trace_writer.cpp
 280     common/trace_writer_local.cpp
 281     common/trace_writer_model.cpp
 282     common/trace_loader.cpp
 283     common/trace_resource.cpp
 284     common/trace_tools_trace.cpp
 285     common/image.cpp
 286     common/image_bmp.cpp
 287     common/image_pnm.cpp
 288     common/image_png.cpp
 289     common/${os}
 290 )
 291
 292 set_target_properties (common PROPERTIES
 293     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 294     # Ensure it can be statically linked in shared libraries
 295     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 296 )
 297
 298 link_libraries (common)
 299
 300
 301 ##############################################################################
 302 # API tracers
 303
 304 if (WIN32)
 305     if (MINGW)
 306         # Silence warnings about @nn suffix mismatch
 307         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 308     endif (MINGW)
 309
 310     # ddraw.dll
 311     if (DirectX_D3D_INCLUDE_DIR)
 312         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 313         add_custom_command (
 314             OUTPUT ddrawtrace.cpp
 315             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 316             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 317         )
 318         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 319         set_target_properties (ddraw
 320             PROPERTIES PREFIX ""
 321             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 322             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 323         )
 324         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 325     endif (DirectX_D3D_INCLUDE_DIR)
 326
 327     # d3d8.dll
 328     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 329         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 330         add_custom_command (
 331             OUTPUT d3d8trace.cpp
 332             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 333             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 334         )
 335         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 336         set_target_properties (d3d8
 337             PROPERTIES PREFIX ""
 338             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 339             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 340         )
 341         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 342     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 343
 344     # d3d9.dll
 345     if (DirectX_D3DX9_INCLUDE_DIR)
 346         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 347         add_custom_command (
 348             OUTPUT d3d9trace.cpp
 349             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 350             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 351         )
 352         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 353         set_target_properties (d3d9
 354             PROPERTIES PREFIX ""
 355             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 356             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 357         )
 358         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 359     endif (DirectX_D3DX9_INCLUDE_DIR)
 360
 361     # d3d10.dll
 362     if (DirectX_D3D10_INCLUDE_DIR)
 363         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 364         add_custom_command (
 365             OUTPUT d3d10trace.cpp
 366             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 367             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 368         )
 369         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 370         set_target_properties (d3d10
 371             PROPERTIES PREFIX ""
 372             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 373             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 374         )
 375         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 376     endif (DirectX_D3D10_INCLUDE_DIR)
 377
 378     # opengl32.dll
 379     add_custom_command (
 380         OUTPUT wgltrace.cpp
 381         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 382         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 383     )
 384     add_library (wgltrace MODULE specs/opengl32.def
 385         wgltrace.cpp
 386         glcaps.cpp
 387         glproc_gl.cpp
 388     )
 389     add_dependencies (wgltrace glproc)
 390     set_target_properties (wgltrace PROPERTIES
 391         PREFIX ""
 392         OUTPUT_NAME opengl32
 393         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 394         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 395     )
 396     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 397
 398 elseif (APPLE)
 399     # OpenGL framework
 400     add_custom_command (
 401         OUTPUT cgltrace.cpp
 402         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 403         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 404     )
 405
 406     add_library (cgltrace SHARED
 407         cgltrace.cpp
 408         glcaps.cpp
 409         glproc_gl.cpp
 410     )
 411
 412     add_dependencies (cgltrace glproc)
 413
 414     set_target_properties (cgltrace PROPERTIES
 415         # OpenGL framework name
 416         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 417         # Specificy the version and reexport GLU symbols
 418         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 419         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 420         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 421     )
 422
 423     target_link_libraries (cgltrace dl)
 424
 425     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 426 else ()
 427     # libGL.so
 428     add_custom_command (
 429         OUTPUT glxtrace.cpp
 430         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 431         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 432     )
 433
 434     add_library (glxtrace SHARED
 435         glxtrace.cpp
 436         glcaps.cpp
 437         glproc_gl.cpp
 438     )
 439
 440     add_dependencies (glxtrace glproc)
 441
 442     set_target_properties (glxtrace PROPERTIES
 443         # avoid the default "lib" prefix
 444         PREFIX ""
 445         # Prevent symbol relocations internal to our wrapper library to be
 446         # overwritten by the application.
 447         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 448         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 449         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 450     )
 451
 452     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 453
 454     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 455 endif ()
 456
 457
 458 if (EGL_FOUND)
 459     # libEGL.so/libGL.so
 460     add_custom_command (
 461         OUTPUT egltrace.cpp
 462         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 463         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 464     )
 465
 466     add_library (egltrace SHARED
 467         egltrace.cpp
 468         glcaps.cpp
 469         glproc_egl.cpp
 470     )
 471
 472     add_dependencies (egltrace glproc)
 473
 474     set_property (
 475         TARGET egltrace
 476         APPEND
 477         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 478     )
 479
 480     set_target_properties (egltrace PROPERTIES
 481         # avoid the default "lib" prefix
 482         PREFIX ""
 483         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 484         # Prevent symbol relocations internal to our wrapper library to be
 485         # overwritten by the application.
 486         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 487         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 488     )
 489
 490     target_link_libraries (egltrace dl)
 491
 492     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 493 endif ()
 494
 495 ##############################################################################
 496 # API retracers
 497
 498 add_custom_command (
 499     OUTPUT glretrace_gl.cpp
 500     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 501     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 502 )
 503
 504 add_custom_command (
 505     OUTPUT glstate_params.cpp
 506     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 507     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 508 )
 509
 510 set (retrace_sources
 511     glretrace_gl.cpp
 512     glretrace_cgl.cpp
 513     glretrace_glx.cpp
 514     glretrace_wgl.cpp
 515     glretrace_egl.cpp
 516     glretrace_main.cpp
 517     glstate.cpp
 518     glstate_params.cpp
 519     retrace.cpp
 520     retrace_stdc.cpp
 521     glws.cpp
 522 )
 523
 524 add_executable (glretrace
 525     ${retrace_sources}
 526     ${glws_os}
 527     glproc_gl.cpp
 528 )
 529
 530 add_dependencies (glretrace glproc)
 531
 532 set_property (
 533     TARGET glretrace
 534     APPEND
 535     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 536 )
 537
 538 target_link_libraries (glretrace
 539     common
 540 )
 541
 542 if (WIN32)
 543 else ()
 544     if (APPLE)
 545         target_link_libraries (glretrace
 546             "-framework Cocoa"
 547             "-framework ApplicationServices" # CGS*
 548             ${OPENGL_gl_LIBRARY} # CGL*
 549         )
 550     else ()
 551         target_link_libraries (glretrace ${X11_X11_LIB})
 552     endif ()
 553
 554     target_link_libraries (glretrace
 555         # gdb doesn't like when pthreads is loaded through dlopen (which happens
 556         # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
 557         # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
 558         pthread
 559         dl
 560     )
 561 endif ()
 562
 563 install (TARGETS glretrace RUNTIME DESTINATION bin)
 564
 565 if (EGL_FOUND AND NOT WIN32 AND NOT APPLE)
 566     add_executable (eglretrace
 567         ${retrace_sources}
 568         glws_egl_xlib.cpp
 569         glproc_egl.cpp
 570     )
 571
 572     add_dependencies (eglretrace glproc)
 573
 574     set_property (
 575         TARGET eglretrace
 576         APPEND
 577         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 578         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 579     )
 580
 581     target_link_libraries (eglretrace
 582         common
 583         ${X11_X11_LIB}
 584         pthread
 585         dl
 586     )
 587
 588     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 589 endif ()
 590
 591 ##############################################################################
 592 # CLI
 593
 594 add_subdirectory(cli)
 595
 596 ##############################################################################
 597 # Scripts (to support the CLI)
 598
 599 install (
 600     PROGRAMS
 601         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh
 602         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 603         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 604     DESTINATION ${SCRIPTS_INSTALL_DIR}
 605 )
 606
 607 ##############################################################################
 608 # GUI
 609
 610 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 611     add_subdirectory(gui)
 612 endif ()
 613
 614
 615 ##############################################################################
 616 # Packaging
 617
 618 install (
 619     FILES
 620         BUGS.markdown
 621         LICENSE
 622         NEWS.markdown
 623         README.markdown
 624         TODO.markdown
 625     DESTINATION ${DOC_INSTALL_DIR}
 626 )
 627
 628 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 629 set (CPACK_PACKAGE_VERSION_MINOR "0")
 630
 631 # Use current date in YYYYMMDD format as patch number
 632 execute_process (
 633     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 634     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 635 )
 636
 637 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 638 if (WIN32)
 639     set (CPACK_GENERATOR "ZIP")
 640 elseif (APPLE)
 641     set (CPACK_GENERATOR "DragNDrop")
 642 else ()
 643     set (CPACK_GENERATOR "TBZ2")
 644 endif ()
 645
 646 include(CPack)