git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Find dependencies
   8
   9 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  10
  11 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  12
  13 find_package (PythonInterp REQUIRED)
  14 find_package (OpenGL REQUIRED)
  15 find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit)
  16 find_package (QJSON)
  17
  18 if (NOT WIN32)
  19     find_package (X11 REQUIRED)
  20
  21     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  22     # from the standard OpenGL framework which provides support for native Mac OS X
  23     # applications.
  24     if (APPLE)
  25         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  26         if (NOT X11_GL_INCLUDE_PATH)
  27             message (SEND_ERROR "Could not find GL/glx.h")
  28         endif (NOT X11_GL_INCLUDE_PATH)
  29         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  30
  31         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  32         if (NOT X11_GL_LIB)
  33             message (SEND_ERROR "Could not find libGL.dylib")
  34         endif (NOT X11_GL_LIB)
  35     else ()
  36         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  37         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  38     endif ()
  39
  40     include_directories (${X11_INCLUDE_DIR})
  41 endif (NOT WIN32)
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 endif (WIN32)
  46
  47
  48 ##############################################################################
  49 # Set global build options
  50
  51 include (CheckCXXCompilerFlag)
  52
  53 if (WIN32)
  54     # MSVC & MinGW only define & use APIENTRY
  55     add_definitions (-DGLAPIENTRY=__stdcall)
  56
  57     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  58     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  59 else (WIN32)
  60     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  61     if (CXX_COMPILER_FLAG_VISIBILITY)
  62         add_definitions ("-fvisibility=hidden")
  63     endif (CXX_COMPILER_FLAG_VISIBILITY)
  64 endif (WIN32)
  65
  66 if (MSVC)
  67     # C99 includes for msvc
  68     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  69
  70     # Enable math constants defines
  71     add_definitions (-D_USE_MATH_DEFINES)
  72
  73     # No min/max macros
  74     add_definitions (-DNOMINMAX)
  75
  76     # Adjust warnings
  77     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  78     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  79     add_definitions (-W4)
  80     add_definitions (-wd4063) # not a valid value for switch of enum
  81     add_definitions (-wd4127) # conditional expression is constant
  82     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  83     add_definitions (-wd4505) # unreferenced local function has been removed
  84     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  85     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  86     add_definitions (-wd4018) # signed/unsigned mismatch
  87
  88     # Use static runtime
  89     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  90     foreach (flag_var
  91         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  92         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  93     )
  94         if (${flag_var} MATCHES "/MD")
  95             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
  96         endif (${flag_var} MATCHES "/MD")
  97     endforeach (flag_var)
  98 else ()
  99     # Adjust warnings
 100     add_definitions (-Wall)
 101     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 102     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 103 endif ()
 104
 105
 106 # Put all executables into the same top level build directory, regardless of
 107 # which subdirectory they are declared
 108 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 109
 110
 111 ##############################################################################
 112 # Bundled dependencies
 113 #
 114 # We always use the bundled zlib and libpng sources:
 115 # - on Windows to make it easy to deploy the wrappers DLLs
 116 # - on unices to prevent symbol collisions when tracing applications that link
 117 # against other versions of these libraries
 118
 119 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 120 set (ZLIB_LIBRARIES z_bundled)
 121 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 122
 123 include_directories (${ZLIB_INCLUDE_DIRS})
 124 link_libraries (${ZLIB_LIBRARIES})
 125
 126 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 127 set (PNG_DEFINITIONS "")
 128 set (PNG_LIBRARIES png_bundled)
 129
 130 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 131 include_directories (${PNG_INCLUDE_DIR})
 132 add_definitions (${PNG_DEFINITIONS})
 133 link_libraries (${PNG_LIBRARIES})
 134
 135 # For glext headers
 136 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 137
 138
 139 ##############################################################################
 140 # Common libraries / utilities
 141
 142 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 143
 144 add_custom_command (
 145     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 146     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 147     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 148 )
 149
 150 if (WIN32)
 151     set (os os_win32.cpp)
 152     set (glws glws_wgl.cpp)
 153 else (WIN32)
 154     set (os os_posix.cpp)
 155     set (glws glws_glx.cpp)
 156 endif (WIN32)
 157
 158 add_library (common
 159     trace_model.cpp
 160     trace_parser.cpp
 161     trace_writer.cpp
 162     trace_model_writer.cpp
 163     image.cpp
 164     image_bmp.cpp
 165     image_png.cpp
 166     ${os}
 167 )
 168
 169 add_executable (tracedump tracedump.cpp)
 170 target_link_libraries (tracedump common)
 171 install (TARGETS tracedump RUNTIME DESTINATION bin)
 172
 173
 174 ##############################################################################
 175 # API tracers
 176
 177 if (WIN32)
 178     # ddraw.dll
 179     if (DirectX_D3D_INCLUDE_DIR)
 180         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 181         add_custom_command (
 182             OUTPUT ddraw.cpp
 183             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 184             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 185         )
 186         add_library (ddraw MODULE ddraw.def ddraw.cpp trace_writer.cpp os_win32.cpp)
 187         set_target_properties (ddraw
 188             PROPERTIES PREFIX ""
 189             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 190             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 191         )
 192         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 193     endif (DirectX_D3D_INCLUDE_DIR)
 194
 195     # d3d8.dll
 196     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 197         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 198         add_custom_command (
 199             OUTPUT d3d8.cpp
 200             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 201             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 202         )
 203         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 204         set_target_properties (d3d8
 205             PROPERTIES PREFIX ""
 206             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 207             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 208         )
 209         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 210     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 211
 212     # d3d9.dll
 213     if (DirectX_D3DX9_INCLUDE_DIR)
 214         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 215         add_custom_command (
 216             OUTPUT d3d9.cpp
 217             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 218             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 219         )
 220         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 221         set_target_properties (d3d9
 222             PROPERTIES PREFIX ""
 223             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 224             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 225         )
 226         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 227     endif (DirectX_D3DX9_INCLUDE_DIR)
 228
 229     # d3d10.dll
 230     #if (DirectX_D3D10_INCLUDE_DIR)
 231     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 232     #    add_custom_command (
 233     #        OUTPUT d3d10.cpp
 234     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 235     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 236     #    )
 237     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp trace_writer.cpp os_win32.cpp)
 238     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 239     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 240     #endif (DirectX_D3D10_INCLUDE_DIR)
 241
 242     # opengl32.dll
 243     add_custom_command (
 244         OUTPUT wgltrace.cpp
 245         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 246         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 247     )
 248     add_library (wgltrace MODULE opengl32.def wgltrace.cpp trace_writer.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 249     set_target_properties (wgltrace PROPERTIES
 250         PREFIX ""
 251         OUTPUT_NAME opengl32
 252         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 253         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 254     )
 255     if (MINGW)
 256         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 257     endif (MINGW)
 258     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 259
 260 elseif (APPLE)
 261     # OpenGL framework
 262     add_custom_command (
 263         OUTPUT cgltrace.cpp
 264         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 265         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 266     )
 267
 268     add_library (cgltrace SHARED cgltrace.cpp trace_writer.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 269
 270     set_target_properties (cgltrace PROPERTIES
 271         # OpenGL framework name
 272         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 273         # Specificy the version and reexport GLU symbols
 274         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 275         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 276         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 277     )
 278
 279     target_link_libraries (cgltrace dl)
 280
 281     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 282 else ()
 283     # libGL.so
 284     add_custom_command (
 285         OUTPUT glxtrace.cpp
 286         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 287         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 288     )
 289
 290     add_library (glxtrace SHARED
 291         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 292         glxtrace.cpp
 293         glsnapshot.cpp
 294         trace_writer.cpp
 295         image.cpp
 296         os_posix.cpp
 297     )
 298
 299     set_target_properties (glxtrace PROPERTIES
 300         # avoid the default "lib" prefix
 301         PREFIX ""
 302     )
 303
 304     # Prevent symbol relocations internal to our wrapper library to be
 305     # overwritten by the application.
 306     set_target_properties (glxtrace PROPERTIES
 307         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 308     )
 309
 310     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 311
 312     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 313 endif ()
 314
 315
 316 ##############################################################################
 317 # API retracers
 318
 319 add_custom_command (
 320     OUTPUT glretrace_gl.cpp
 321     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 322     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 323 )
 324
 325 add_custom_command (
 326     OUTPUT glstate_params.cpp
 327     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 328     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 329 )
 330
 331 include_directories (
 332     ${CMAKE_CURRENT_BINARY_DIR}
 333     ${OPENGL_INCLUDE_PATH}
 334 )
 335
 336 add_executable (glretrace
 337     glretrace_gl.cpp
 338     glretrace_cgl.cpp
 339     glretrace_glx.cpp
 340     glretrace_wgl.cpp
 341     glretrace_main.cpp
 342     glstate.cpp
 343     glstate_params.cpp
 344     retrace.cpp
 345     ${glws}
 346     image.cpp
 347     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 348 )
 349
 350 set_property (
 351     TARGET glretrace
 352     APPEND
 353     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 354 )
 355
 356 target_link_libraries (glretrace
 357     common
 358 )
 359
 360 if (WIN32)
 361     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 362 elseif (APPLE)
 363     # XXX: We use GLX on MacOSX, which is in a separate library.
 364     target_link_libraries (glretrace
 365         ${X11_GL_LIB}
 366         ${X11_X11_LIB}
 367         "-framework ApplicationServices" # CGS*
 368         ${OPENGL_gl_LIBRARY} # CGL*
 369     )
 370 else ()
 371     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 372 endif ()
 373
 374 install (TARGETS glretrace RUNTIME DESTINATION bin)
 375
 376
 377 ##############################################################################
 378 # GUI
 379
 380 if (QT4_FOUND AND QJSON_FOUND)
 381     add_subdirectory(gui)
 382 endif (QT4_FOUND AND QJSON_FOUND)
 383
 384
 385 ##############################################################################
 386 # Packaging
 387
 388 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 389
 390 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 391 set (CPACK_PACKAGE_VERSION_MINOR "0")
 392
 393 # Use current date in YYYYMMDD format as patch number
 394 execute_process (
 395     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 396     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 397 )
 398
 399 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 400 if (WIN32)
 401     set (CPACK_GENERATOR "ZIP")
 402 elseif (APPLE)
 403     set (CPACK_GENERATOR "DragNDrop")
 404 else ()
 405     set (CPACK_GENERATOR "TBZ2")
 406 endif ()
 407
 408 include(CPack)