git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_CLI true CACHE BOOL "Enable command Line interface.")
  21
  22 set (ENABLE_EGL true CACHE BOOL "Enable EGL support.")
  23
  24
  25 ##############################################################################
  26 # Find dependencies
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 if (ANDROID)
  33     set (ENABLE_GUI false)
  34 else ()
  35     macro (find_host_package)
  36         find_package (${ARGN})
  37     endmacro()
  38 endif ()
  39
  40 find_host_package (PythonInterp REQUIRED)
  41 find_package (Threads)
  42
  43 if (ENABLE_GUI)
  44     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  45         set (REQUIRE_GUI REQUIRED)
  46     endif ()
  47     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  48     find_package (QJSON ${REQUIRE_GUI})
  49 endif ()
  50
  51 if (WIN32)
  52     find_package (DirectX)
  53     set (ENABLE_EGL false)
  54 elseif (APPLE)
  55     set (ENABLE_EGL false)
  56 else ()
  57     find_package (X11)
  58
  59     if (X11_FOUND)
  60         include_directories (${X11_INCLUDE_DIR})
  61         add_definitions (-DHAVE_X11)
  62     endif ()
  63 endif ()
  64
  65
  66 ##############################################################################
  67 # Set global build options
  68
  69 include (CheckCXXCompilerFlag)
  70
  71 if (WIN32)
  72     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  73     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  74 else (WIN32)
  75     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  76     if (CXX_COMPILER_FLAG_VISIBILITY)
  77         add_definitions ("-fvisibility=hidden")
  78     endif ()
  79 endif ()
  80
  81 if (MSVC)
  82     # C99 includes for msvc
  83     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  84
  85     # Enable math constants defines
  86     add_definitions (-D_USE_MATH_DEFINES)
  87
  88     # No min/max macros
  89     add_definitions (-DNOMINMAX)
  90
  91     # Adjust warnings
  92     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  93     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  94     add_definitions (-W4)
  95     add_definitions (-wd4063) # not a valid value for switch of enum
  96     add_definitions (-wd4127) # conditional expression is constant
  97     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  98     add_definitions (-wd4505) # unreferenced local function has been removed
  99     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 100     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 101     add_definitions (-wd4018) # signed/unsigned mismatch
 102
 103     # Use static runtime
 104     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 105     foreach (flag_var
 106         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 107         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 108     )
 109         if (${flag_var} MATCHES "/MD")
 110             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 111         endif ()
 112     endforeach (flag_var)
 113 else ()
 114     # Adjust warnings
 115     add_definitions (-Wall)
 116     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 117     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 118 endif ()
 119
 120 if (MINGW)
 121     # Avoid depending on MinGW runtime DLLs
 122     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 123     if (HAVE_STATIC_LIBGCC_FLAG)
 124         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 125         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 126         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 127     endif ()
 128     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 129     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 130         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 131         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 132         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 133     endif ()
 134 endif ()
 135
 136
 137 # Put all executables into the same top level build directory, regardless of
 138 # which subdirectory they are declared
 139 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 140
 141
 142 ##############################################################################
 143 # Bundled dependencies
 144 #
 145 # We always use the bundled zlib, libpng, and snappy sources:
 146 # - on Windows to make it easy to deploy the wrappers DLLs
 147 # - on unices to prevent symbol collisions when tracing applications that link
 148 # against other versions of these libraries
 149
 150 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 151 set (ZLIB_LIBRARIES z_bundled)
 152 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 153
 154 include_directories (${ZLIB_INCLUDE_DIRS})
 155
 156 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 157 set (SNAPPY_LIBRARIES snappy_bundled)
 158 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 159
 160 include_directories (${SNAPPY_INCLUDE_DIRS})
 161
 162 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 163 set (PNG_DEFINITIONS "")
 164 set (PNG_LIBRARIES png_bundled)
 165
 166 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 167 include_directories (${PNG_INCLUDE_DIR})
 168 add_definitions (${PNG_DEFINITIONS})
 169
 170 if (MSVC)
 171     add_subdirectory (thirdparty/getopt EXCLUDE_FROM_ALL)
 172     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/getopt)
 173     set (GETOPT_LIBRARIES getopt_bundled)
 174 endif ()
 175
 176 if (WIN32)
 177     add_subdirectory (thirdparty/less)
 178 endif ()
 179
 180 # The Qt website provides binaries for Windows and MacOSX, and they are
 181 # automatically found by cmake without any manual intervention.  The situation
 182 # for QJSON is substantially different: there are no binaries for QJSON
 183 # available, and there is no standard installation directory that is detected
 184 # by cmake.
 185 #
 186 # By bundling the QJSON source, we make it much more easier to build the GUI on
 187 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 188 # AUTO.
 189 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 190     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 191     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 192     set (QJSON_LIBRARY_DIRS)
 193     set (QJSON_LIBRARIES qjson_bundled)
 194     set (QJSON_FOUND TRUE)
 195 endif ()
 196
 197 # We use bundled headers for all Khronos APIs, to guarantee support for both
 198 # OpenGL and OpenGL ES at build time, because the OpenGL and OpenGL ES 1 APIs
 199 # are so intertwined that conditional compilation extremely difficult. This
 200 # also avoids missing/inconsistent declarations in system headers.
 201 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khronos)
 202
 203 ##############################################################################
 204 # Installation directories
 205
 206 if (WIN32 OR APPLE)
 207     # On Windows/MacOSX, applications are usually installed on a directory of
 208     # their own
 209     set (DOC_INSTALL_DIR doc)
 210     set (LIB_INSTALL_DIR lib)
 211 else ()
 212     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 213     set (LIB_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 214 endif ()
 215
 216 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 217 set(WRAPPER_INSTALL_DIR ${LIB_INSTALL_DIR}/wrappers)
 218
 219 # Expose the binary/install directories to source
 220 #
 221 # TODO: Use the same directory layout, for both build and install directories,
 222 # so that binaries can find each other using just relative paths.
 223 #
 224 add_definitions(
 225     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 226     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 227     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 228 )
 229
 230
 231 ##############################################################################
 232 # Common libraries / utilities
 233
 234 include_directories (
 235     ${CMAKE_CURRENT_BINARY_DIR}
 236     ${CMAKE_CURRENT_SOURCE_DIR}
 237     ${CMAKE_CURRENT_SOURCE_DIR}/common
 238 )
 239
 240 add_custom_command (
 241     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 242     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 243     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 244 )
 245
 246 # Wrap glproc.hpp as a target to prevent the command from being executed
 247 # multiple times simulatenously, when the targets that depend on it are built
 248 # in parallel.
 249 add_custom_target (glproc DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 250
 251 if (WIN32)
 252     set (os os_win32.cpp)
 253     set (glws_os glws_wgl.cpp)
 254 else ()
 255     set (os os_posix.cpp)
 256     if (APPLE)
 257         set (glws_os glws_cocoa.mm)
 258     else ()
 259         set (glws_os glws_glx.cpp)
 260     endif ()
 261 endif ()
 262
 263 add_library (common STATIC
 264     common/trace_callset.cpp
 265     common/trace_dump.cpp
 266     common/trace_file.cpp
 267     common/trace_file_read.cpp
 268     common/trace_file_write.cpp
 269     common/trace_file_zlib.cpp
 270     common/trace_file_snappy.cpp
 271     common/trace_model.cpp
 272     common/trace_parser.cpp
 273     common/trace_parser_flags.cpp
 274     common/trace_writer.cpp
 275     common/trace_writer_local.cpp
 276     common/trace_writer_model.cpp
 277     common/trace_loader.cpp
 278     common/trace_resource.cpp
 279     common/trace_tools_trace.cpp
 280     common/image.cpp
 281     common/image_bmp.cpp
 282     common/image_pnm.cpp
 283     common/image_png.cpp
 284     common/${os}
 285 )
 286
 287 set_target_properties (common PROPERTIES
 288     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 289     # Ensure it can be statically linked in shared libraries
 290     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 291 )
 292
 293 if (ANDROID)
 294     target_link_libraries (common log)
 295 endif ()
 296
 297
 298 ##############################################################################
 299 # API tracers
 300
 301 add_subdirectory (wrappers)
 302
 303
 304 ##############################################################################
 305 # API retracers
 306
 307 add_subdirectory (retrace)
 308
 309
 310 ##############################################################################
 311 # CLI
 312
 313 if (ENABLE_CLI)
 314     add_subdirectory(cli)
 315 endif ()
 316
 317 ##############################################################################
 318 # Scripts (to support the CLI)
 319
 320 install (
 321     PROGRAMS
 322         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.py
 323         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 324         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 325     DESTINATION ${SCRIPTS_INSTALL_DIR}
 326 )
 327
 328 ##############################################################################
 329 # GUI
 330
 331 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 332     add_subdirectory(gui)
 333 endif ()
 334
 335
 336 ##############################################################################
 337 # Packaging
 338
 339 install (
 340     FILES
 341         BUGS.markdown
 342         LICENSE
 343         NEWS.markdown
 344         README.markdown
 345     DESTINATION ${DOC_INSTALL_DIR}
 346 )
 347
 348 set (CPACK_PACKAGE_VERSION_MAJOR "3")
 349 set (CPACK_PACKAGE_VERSION_MINOR "0")
 350
 351 # Use current date in YYYYMMDD format as patch number
 352 execute_process (
 353     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 354     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 355 )
 356
 357 # cpack mistakenly detects Mingw-w64 as win32
 358 if (MINGW)
 359     if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 360         set (CPACK_SYSTEM_NAME win64)
 361     endif ()
 362 endif ()
 363
 364 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 365 if (WIN32)
 366     set (CPACK_GENERATOR "ZIP")
 367 elseif (APPLE)
 368     set (CPACK_GENERATOR "DragNDrop")
 369 else ()
 370     set (CPACK_GENERATOR "TBZ2")
 371 endif ()
 372
 373 include(CPack)