git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 if (WIN32)
  44     find_package (DirectX)
  45 elseif (APPLE)
  46 else ()
  47     find_package (X11 REQUIRED)
  48
  49     set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  50     set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  51
  52     include_directories (${X11_INCLUDE_DIR})
  53
  54     if (ENABLE_EGL)
  55         if (NOT ENABLE_EGL STREQUAL "AUTO")
  56             set (REQUIRE_EGL REQUIRED)
  57         endif ()
  58         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  59         if (EGL_FOUND)
  60             include_directories (${EGL_INCLUDE_DIR})
  61             add_definitions (-DHAVE_EGL)
  62         endif ()
  63     else ()
  64         set (EGL_FOUND 0)
  65     endif ()
  66 endif ()
  67
  68
  69 ##############################################################################
  70 # Set global build options
  71
  72 include (CheckCXXCompilerFlag)
  73
  74 if (WIN32)
  75     # MSVC & MinGW only define & use APIENTRY
  76     add_definitions (-DGLAPIENTRY=__stdcall)
  77
  78     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  79     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  80 else (WIN32)
  81     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  82     if (CXX_COMPILER_FLAG_VISIBILITY)
  83         add_definitions ("-fvisibility=hidden")
  84     endif (CXX_COMPILER_FLAG_VISIBILITY)
  85 endif (WIN32)
  86
  87 if (MSVC)
  88     # C99 includes for msvc
  89     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  90
  91     # Enable math constants defines
  92     add_definitions (-D_USE_MATH_DEFINES)
  93
  94     # No min/max macros
  95     add_definitions (-DNOMINMAX)
  96
  97     # Adjust warnings
  98     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  99     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 100     add_definitions (-W4)
 101     add_definitions (-wd4063) # not a valid value for switch of enum
 102     add_definitions (-wd4127) # conditional expression is constant
 103     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 104     add_definitions (-wd4505) # unreferenced local function has been removed
 105     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 106     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 107     add_definitions (-wd4018) # signed/unsigned mismatch
 108
 109     # Use static runtime
 110     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 111     foreach (flag_var
 112         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 113         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 114     )
 115         if (${flag_var} MATCHES "/MD")
 116             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 117         endif (${flag_var} MATCHES "/MD")
 118     endforeach (flag_var)
 119 else ()
 120     # Adjust warnings
 121     add_definitions (-Wall)
 122     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 123     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 124 endif ()
 125
 126 if (MINGW)
 127     # Avoid depending on MinGW runtime DLLs
 128     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 129     if (HAVE_STATIC_LIBGCC_FLAG)
 130         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 131         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 132         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 133     endif ()
 134     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 135     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 136         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 137         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 138         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 139     endif ()
 140 endif ()
 141
 142
 143 # Put all executables into the same top level build directory, regardless of
 144 # which subdirectory they are declared
 145 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 146
 147
 148 ##############################################################################
 149 # Bundled dependencies
 150 #
 151 # We always use the bundled zlib, libpng, and snappy sources:
 152 # - on Windows to make it easy to deploy the wrappers DLLs
 153 # - on unices to prevent symbol collisions when tracing applications that link
 154 # against other versions of these libraries
 155
 156 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 157 set (ZLIB_LIBRARIES z_bundled)
 158 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 159
 160 include_directories (${ZLIB_INCLUDE_DIRS})
 161 link_libraries (${ZLIB_LIBRARIES})
 162
 163 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 164 set (SNAPPY_LIBRARIES snappy_bundled)
 165 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 166
 167 include_directories (${SNAPPY_INCLUDE_DIRS})
 168 link_libraries (${SNAPPY_LIBRARIES})
 169
 170 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 171 set (PNG_DEFINITIONS "")
 172 set (PNG_LIBRARIES png_bundled)
 173
 174 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 175 include_directories (${PNG_INCLUDE_DIR})
 176 add_definitions (${PNG_DEFINITIONS})
 177 link_libraries (${PNG_LIBRARIES})
 178
 179 # The Qt website provides binaries for Windows and MacOSX, and they are
 180 # automatically found by cmake without any manual intervention.  The situation
 181 # for QJSON is substantially different: there are no binaries for QJSON
 182 # available, and there is no standard installation directory that is detected
 183 # by cmake.
 184 #
 185 # By bundling the QJSON source, we make it much more easier to build the GUI on
 186 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 187 # AUTO.
 188 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 189     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 190     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 191     set (QJSON_LIBRARY_DIRS)
 192     set (QJSON_LIBRARIES qjson_bundled)
 193     set (QJSON_FOUND TRUE)
 194 endif ()
 195
 196 # For glext headers
 197 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 198
 199 # For EGL headers
 200 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 201
 202 ##############################################################################
 203 # Installation directories
 204
 205 if (WIN32 OR APPLE)
 206     # On Windows/MacOSX, applications are usually installed on a directory of
 207     # their own
 208     set (DOC_INSTALL_DIR doc)
 209 else ()
 210     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 211 endif ()
 212
 213 set (LIB_INSTALL_DIR lib/apitrace)
 214
 215 if (APPLE)
 216     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 217     # directories
 218     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 219 else ()
 220     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 221 endif ()
 222
 223 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 224 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 225
 226 # Expose the binary/install directories to source
 227 #
 228 # TODO: Use the same directory layout, for both build and install directories,
 229 # so that binaries can find each other using just relative paths.
 230 #
 231 add_definitions(
 232     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 233     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 234     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 235 )
 236
 237
 238 ##############################################################################
 239 # Common libraries / utilities
 240
 241 include_directories (
 242     ${CMAKE_CURRENT_SOURCE_DIR}
 243     ${CMAKE_CURRENT_SOURCE_DIR}/common
 244 )
 245
 246 add_custom_command (
 247     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 248     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 249     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 250 )
 251
 252 if (WIN32)
 253     set (os os_win32.cpp)
 254     set (glws_os glws_wgl.cpp)
 255 else ()
 256     set (os os_posix.cpp)
 257     if (APPLE)
 258         set (glws_os glws_cocoa.mm)
 259     else ()
 260         set (glws_os glws_glx.cpp)
 261     endif ()
 262 endif ()
 263
 264 add_library (common STATIC
 265     common/trace_file.cpp
 266     common/trace_file_read.cpp
 267     common/trace_file_write.cpp
 268     common/trace_file_zlib.cpp
 269     common/trace_file_snappy.cpp
 270     common/trace_model.cpp
 271     common/trace_parser.cpp
 272     common/trace_writer.cpp
 273     common/trace_writer_local.cpp
 274     common/trace_writer_model.cpp
 275     common/trace_loader.cpp
 276     common/trace_resource.cpp
 277     common/trace_tools_trace.cpp
 278     common/image.cpp
 279     common/image_bmp.cpp
 280     common/image_pnm.cpp
 281     common/image_png.cpp
 282     common/${os}
 283 )
 284
 285 set_target_properties (common PROPERTIES
 286     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 287     # Ensure it can be statically linked in shared libraries
 288     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 289 )
 290
 291 link_libraries (common)
 292
 293
 294 ##############################################################################
 295 # API tracers
 296
 297 if (WIN32)
 298     if (MINGW)
 299         # Silence warnings about @nn suffix mismatch
 300         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 301     endif (MINGW)
 302
 303     # ddraw.dll
 304     if (DirectX_D3D_INCLUDE_DIR)
 305         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 306         add_custom_command (
 307             OUTPUT ddrawtrace.cpp
 308             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 309             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 310         )
 311         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 312         set_target_properties (ddraw
 313             PROPERTIES PREFIX ""
 314             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 315             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 316         )
 317         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 318     endif (DirectX_D3D_INCLUDE_DIR)
 319
 320     # d3d8.dll
 321     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 322         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 323         add_custom_command (
 324             OUTPUT d3d8trace.cpp
 325             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 326             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 327         )
 328         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 329         set_target_properties (d3d8
 330             PROPERTIES PREFIX ""
 331             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 332             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 333         )
 334         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 335     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 336
 337     # d3d9.dll
 338     if (DirectX_D3DX9_INCLUDE_DIR)
 339         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 340         add_custom_command (
 341             OUTPUT d3d9trace.cpp
 342             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 343             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 344         )
 345         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 346         set_target_properties (d3d9
 347             PROPERTIES PREFIX ""
 348             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 349             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 350         )
 351         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 352     endif (DirectX_D3DX9_INCLUDE_DIR)
 353
 354     # d3d10.dll
 355     if (DirectX_D3D10_INCLUDE_DIR)
 356         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 357         add_custom_command (
 358             OUTPUT d3d10trace.cpp
 359             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 360             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 361         )
 362         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 363         set_target_properties (d3d10
 364             PROPERTIES PREFIX ""
 365             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 366             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 367         )
 368         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 369     endif (DirectX_D3D10_INCLUDE_DIR)
 370
 371     # opengl32.dll
 372     add_custom_command (
 373         OUTPUT wgltrace.cpp
 374         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 375         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 376     )
 377     add_library (wgltrace MODULE specs/opengl32.def
 378         wgltrace.cpp
 379         glcaps.cpp
 380         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 381     )
 382     set_target_properties (wgltrace PROPERTIES
 383         PREFIX ""
 384         OUTPUT_NAME opengl32
 385         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 386         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 387     )
 388     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 389
 390 elseif (APPLE)
 391     # OpenGL framework
 392     add_custom_command (
 393         OUTPUT cgltrace.cpp
 394         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 395         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 396     )
 397
 398     add_library (cgltrace SHARED
 399         cgltrace.cpp
 400         glcaps.cpp
 401         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 402     )
 403
 404     set_target_properties (cgltrace PROPERTIES
 405         # OpenGL framework name
 406         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 407         # Specificy the version and reexport GLU symbols
 408         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 409         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 410         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 411     )
 412
 413     target_link_libraries (cgltrace dl)
 414
 415     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 416 else ()
 417     # libGL.so
 418     add_custom_command (
 419         OUTPUT glxtrace.cpp
 420         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 421         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 422     )
 423
 424     add_library (glxtrace SHARED
 425         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 426         glxtrace.cpp
 427         glcaps.cpp
 428     )
 429
 430     set_target_properties (glxtrace PROPERTIES
 431         # avoid the default "lib" prefix
 432         PREFIX ""
 433         # Prevent symbol relocations internal to our wrapper library to be
 434         # overwritten by the application.
 435         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 436         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 437         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 438     )
 439
 440     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 441
 442     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 443 endif ()
 444
 445
 446 if (EGL_FOUND)
 447     # libEGL.so/libGL.so
 448     add_custom_command (
 449         OUTPUT egltrace.cpp
 450         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 451         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 452     )
 453
 454     add_library (egltrace SHARED
 455         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 456         egltrace.cpp
 457         glcaps.cpp
 458     )
 459
 460     set_property (
 461         TARGET egltrace
 462         APPEND
 463         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 464     )
 465
 466     set_target_properties (egltrace PROPERTIES
 467         # avoid the default "lib" prefix
 468         PREFIX ""
 469         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 470         # Prevent symbol relocations internal to our wrapper library to be
 471         # overwritten by the application.
 472         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 473         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 474     )
 475
 476     target_link_libraries (egltrace dl)
 477
 478     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 479 endif ()
 480
 481 ##############################################################################
 482 # API retracers
 483
 484 add_custom_command (
 485     OUTPUT glretrace_gl.cpp
 486     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 487     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 488 )
 489
 490 add_custom_command (
 491     OUTPUT glstate_params.cpp
 492     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 493     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 494 )
 495
 496 include_directories (
 497     ${CMAKE_CURRENT_BINARY_DIR}
 498     ${OPENGL_INCLUDE_PATH}
 499 )
 500
 501 set (retrace_sources
 502     glretrace_gl.cpp
 503     glretrace_cgl.cpp
 504     glretrace_glx.cpp
 505     glretrace_wgl.cpp
 506     glretrace_egl.cpp
 507     glretrace_main.cpp
 508     glstate.cpp
 509     glstate_params.cpp
 510     retrace.cpp
 511     retrace_stdc.cpp
 512     glws.cpp
 513     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 514 )
 515
 516 add_executable (glretrace
 517     ${retrace_sources}
 518     ${glws_os}
 519 )
 520
 521 set_property (
 522     TARGET glretrace
 523     APPEND
 524     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 525 )
 526
 527 target_link_libraries (glretrace
 528     common
 529 )
 530
 531 if (WIN32)
 532     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 533 elseif (APPLE)
 534     target_link_libraries (glretrace
 535         "-framework Cocoa"
 536         "-framework ApplicationServices" # CGS*
 537         ${OPENGL_gl_LIBRARY} # CGL*
 538     )
 539 else ()
 540     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 541 endif ()
 542
 543 install (TARGETS glretrace RUNTIME DESTINATION bin)
 544
 545 if (EGL_FOUND AND NOT WIN32 AND NOT APPLE)
 546     add_executable (eglretrace
 547         ${retrace_sources}
 548         glws_egl_xlib.cpp
 549     )
 550
 551     set_property (
 552         TARGET eglretrace
 553         APPEND
 554         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 555         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 556     )
 557
 558     target_link_libraries (eglretrace
 559         common
 560     )
 561
 562     target_link_libraries (eglretrace
 563         ${EGL_LIBRARIES}
 564         ${OPENGL_gl_LIBRARY}
 565         ${X11_X11_LIB}
 566     )
 567
 568     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 569 endif ()
 570
 571 ##############################################################################
 572 # CLI
 573
 574 add_subdirectory(cli)
 575
 576 ##############################################################################
 577 # Scripts (to support the CLI)
 578
 579 install (
 580     PROGRAMS
 581         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh
 582         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 583         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 584     DESTINATION ${SCRIPTS_INSTALL_DIR}
 585 )
 586
 587 ##############################################################################
 588 # GUI
 589
 590 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 591     add_subdirectory(gui)
 592 endif ()
 593
 594
 595 ##############################################################################
 596 # Packaging
 597
 598 install (
 599     FILES
 600         BUGS.markdown
 601         LICENSE
 602         NEWS.markdown
 603         README.markdown
 604         TODO.markdown
 605     DESTINATION ${DOC_INSTALL_DIR}
 606 )
 607
 608 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 609 set (CPACK_PACKAGE_VERSION_MINOR "0")
 610
 611 # Use current date in YYYYMMDD format as patch number
 612 execute_process (
 613     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 614     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 615 )
 616
 617 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 618 if (WIN32)
 619     set (CPACK_GENERATOR "ZIP")
 620 elseif (APPLE)
 621     set (CPACK_GENERATOR "DragNDrop")
 622 else ()
 623     set (CPACK_GENERATOR "TBZ2")
 624 endif ()
 625
 626 include(CPack)