git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 include_directories (${OPENGL_INCLUDE_DIR})
  44
  45 if (WIN32)
  46     find_package (DirectX)
  47 elseif (APPLE)
  48 else ()
  49     find_package (X11)
  50
  51     if (X11_FOUND)
  52         include_directories (${X11_INCLUDE_DIR})
  53         add_definitions (-DHAVE_X11)
  54     endif ()
  55
  56     if (ENABLE_EGL)
  57         if (NOT ENABLE_EGL STREQUAL "AUTO")
  58             set (REQUIRE_EGL REQUIRED)
  59         endif ()
  60         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  61         if (EGL_FOUND)
  62             include_directories (${EGL_INCLUDE_DIR})
  63             add_definitions (-DHAVE_EGL)
  64         endif ()
  65     else ()
  66         set (EGL_FOUND 0)
  67     endif ()
  68 endif ()
  69
  70
  71 ##############################################################################
  72 # Set global build options
  73
  74 include (CheckCXXCompilerFlag)
  75
  76 if (WIN32)
  77     # MSVC & MinGW only define & use APIENTRY
  78     add_definitions (-DGLAPIENTRY=__stdcall)
  79
  80     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  81     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  82 else (WIN32)
  83     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  84     if (CXX_COMPILER_FLAG_VISIBILITY)
  85         add_definitions ("-fvisibility=hidden")
  86     endif (CXX_COMPILER_FLAG_VISIBILITY)
  87 endif (WIN32)
  88
  89 if (MSVC)
  90     # C99 includes for msvc
  91     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  92
  93     # Enable math constants defines
  94     add_definitions (-D_USE_MATH_DEFINES)
  95
  96     # No min/max macros
  97     add_definitions (-DNOMINMAX)
  98
  99     # Adjust warnings
 100     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 101     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 102     add_definitions (-W4)
 103     add_definitions (-wd4063) # not a valid value for switch of enum
 104     add_definitions (-wd4127) # conditional expression is constant
 105     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 106     add_definitions (-wd4505) # unreferenced local function has been removed
 107     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 108     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 109     add_definitions (-wd4018) # signed/unsigned mismatch
 110
 111     # Use static runtime
 112     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 113     foreach (flag_var
 114         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 115         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 116     )
 117         if (${flag_var} MATCHES "/MD")
 118             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 119         endif (${flag_var} MATCHES "/MD")
 120     endforeach (flag_var)
 121 else ()
 122     # Adjust warnings
 123     add_definitions (-Wall)
 124     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 125     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 126 endif ()
 127
 128 if (MINGW)
 129     # Avoid depending on MinGW runtime DLLs
 130     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 131     if (HAVE_STATIC_LIBGCC_FLAG)
 132         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 133         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 134         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 135     endif ()
 136     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 137     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 138         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 139         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 140         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 141     endif ()
 142 endif ()
 143
 144
 145 # Put all executables into the same top level build directory, regardless of
 146 # which subdirectory they are declared
 147 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 148
 149
 150 ##############################################################################
 151 # Bundled dependencies
 152 #
 153 # We always use the bundled zlib, libpng, and snappy sources:
 154 # - on Windows to make it easy to deploy the wrappers DLLs
 155 # - on unices to prevent symbol collisions when tracing applications that link
 156 # against other versions of these libraries
 157
 158 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 159 set (ZLIB_LIBRARIES z_bundled)
 160 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 161
 162 include_directories (${ZLIB_INCLUDE_DIRS})
 163 link_libraries (${ZLIB_LIBRARIES})
 164
 165 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 166 set (SNAPPY_LIBRARIES snappy_bundled)
 167 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 168
 169 include_directories (${SNAPPY_INCLUDE_DIRS})
 170 link_libraries (${SNAPPY_LIBRARIES})
 171
 172 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 173 set (PNG_DEFINITIONS "")
 174 set (PNG_LIBRARIES png_bundled)
 175
 176 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 177 include_directories (${PNG_INCLUDE_DIR})
 178 add_definitions (${PNG_DEFINITIONS})
 179 link_libraries (${PNG_LIBRARIES})
 180
 181 # The Qt website provides binaries for Windows and MacOSX, and they are
 182 # automatically found by cmake without any manual intervention.  The situation
 183 # for QJSON is substantially different: there are no binaries for QJSON
 184 # available, and there is no standard installation directory that is detected
 185 # by cmake.
 186 #
 187 # By bundling the QJSON source, we make it much more easier to build the GUI on
 188 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 189 # AUTO.
 190 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 191     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 192     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 193     set (QJSON_LIBRARY_DIRS)
 194     set (QJSON_LIBRARIES qjson_bundled)
 195     set (QJSON_FOUND TRUE)
 196 endif ()
 197
 198 # For glext headers
 199 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 200
 201 # For EGL headers
 202 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 203
 204 ##############################################################################
 205 # Installation directories
 206
 207 if (WIN32 OR APPLE)
 208     # On Windows/MacOSX, applications are usually installed on a directory of
 209     # their own
 210     set (DOC_INSTALL_DIR doc)
 211 else ()
 212     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 213 endif ()
 214
 215 set (LIB_INSTALL_DIR lib/apitrace)
 216
 217 if (APPLE)
 218     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 219     # directories
 220     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 221 else ()
 222     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 223 endif ()
 224
 225 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 226 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 227
 228 # Expose the binary/install directories to source
 229 #
 230 # TODO: Use the same directory layout, for both build and install directories,
 231 # so that binaries can find each other using just relative paths.
 232 #
 233 add_definitions(
 234     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 235     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 236     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 237 )
 238
 239
 240 ##############################################################################
 241 # Common libraries / utilities
 242
 243 include_directories (
 244     ${CMAKE_CURRENT_BINARY_DIR}
 245     ${CMAKE_CURRENT_SOURCE_DIR}
 246     ${CMAKE_CURRENT_SOURCE_DIR}/common
 247 )
 248
 249 add_custom_command (
 250     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 251     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 252     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 253 )
 254
 255 # Wrap glproc.hpp as a target to prevent the command from being executed
 256 # multiple times simulatenously, when the targets that depend on it are built
 257 # in parallel.
 258 add_custom_target (glproc DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 259
 260 if (WIN32)
 261     set (os os_win32.cpp)
 262     set (glws_os glws_wgl.cpp)
 263 else ()
 264     set (os os_posix.cpp)
 265     if (APPLE)
 266         set (glws_os glws_cocoa.mm)
 267     else ()
 268         set (glws_os glws_glx.cpp)
 269     endif ()
 270 endif ()
 271
 272 add_library (common STATIC
 273     common/trace_dump.cpp
 274     common/trace_file.cpp
 275     common/trace_file_read.cpp
 276     common/trace_file_write.cpp
 277     common/trace_file_zlib.cpp
 278     common/trace_file_snappy.cpp
 279     common/trace_model.cpp
 280     common/trace_parser.cpp
 281     common/trace_parser_flags.cpp
 282     common/trace_writer.cpp
 283     common/trace_writer_local.cpp
 284     common/trace_writer_model.cpp
 285     common/trace_loader.cpp
 286     common/trace_resource.cpp
 287     common/trace_tools_trace.cpp
 288     common/image.cpp
 289     common/image_bmp.cpp
 290     common/image_pnm.cpp
 291     common/image_png.cpp
 292     common/${os}
 293 )
 294
 295 set_target_properties (common PROPERTIES
 296     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 297     # Ensure it can be statically linked in shared libraries
 298     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 299 )
 300
 301 link_libraries (common)
 302
 303
 304 ##############################################################################
 305 # API tracers
 306
 307 if (WIN32)
 308     if (MINGW)
 309         # Silence warnings about @nn suffix mismatch
 310         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 311     endif (MINGW)
 312
 313     # ddraw.dll
 314     if (DirectX_D3D_INCLUDE_DIR)
 315         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 316         add_custom_command (
 317             OUTPUT ddrawtrace.cpp
 318             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 319             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 320         )
 321         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 322         set_target_properties (ddraw
 323             PROPERTIES PREFIX ""
 324             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 325             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 326         )
 327         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 328     endif (DirectX_D3D_INCLUDE_DIR)
 329
 330     # d3d8.dll
 331     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 332         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 333         add_custom_command (
 334             OUTPUT d3d8trace.cpp
 335             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 336             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 337         )
 338         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 339         set_target_properties (d3d8
 340             PROPERTIES PREFIX ""
 341             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 342             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 343         )
 344         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 345     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 346
 347     # d3d9.dll
 348     if (DirectX_D3DX9_INCLUDE_DIR)
 349         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 350         add_custom_command (
 351             OUTPUT d3d9trace.cpp
 352             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 353             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 354         )
 355         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 356         set_target_properties (d3d9
 357             PROPERTIES PREFIX ""
 358             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 359             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 360         )
 361         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 362     endif (DirectX_D3DX9_INCLUDE_DIR)
 363
 364     # d3d10.dll
 365     if (DirectX_D3D10_INCLUDE_DIR)
 366         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 367         add_custom_command (
 368             OUTPUT d3d10trace.cpp
 369             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 370             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 371         )
 372         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 373         set_target_properties (d3d10
 374             PROPERTIES PREFIX ""
 375             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 376             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 377         )
 378         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 379     endif (DirectX_D3D10_INCLUDE_DIR)
 380
 381     # opengl32.dll
 382     add_custom_command (
 383         OUTPUT wgltrace.cpp
 384         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 385         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 386     )
 387     add_library (wgltrace MODULE specs/opengl32.def
 388         wgltrace.cpp
 389         glcaps.cpp
 390         glproc_gl.cpp
 391     )
 392     add_dependencies (wgltrace glproc)
 393     set_target_properties (wgltrace PROPERTIES
 394         PREFIX ""
 395         OUTPUT_NAME opengl32
 396         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 397         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 398     )
 399     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 400
 401 elseif (APPLE)
 402     # OpenGL framework
 403     add_custom_command (
 404         OUTPUT cgltrace.cpp
 405         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 406         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 407     )
 408
 409     add_library (cgltrace SHARED
 410         cgltrace.cpp
 411         glcaps.cpp
 412         glproc_gl.cpp
 413     )
 414
 415     add_dependencies (cgltrace glproc)
 416
 417     set_target_properties (cgltrace PROPERTIES
 418         # OpenGL framework name
 419         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 420         # Specificy the version and reexport GLU symbols
 421         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 422         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 423         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 424     )
 425
 426     target_link_libraries (cgltrace
 427         pthread
 428         dl
 429     )
 430
 431     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 432 elseif (X11_FOUND)
 433     # libGL.so
 434     add_custom_command (
 435         OUTPUT glxtrace.cpp
 436         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 437         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 438     )
 439
 440     add_library (glxtrace SHARED
 441         glxtrace.cpp
 442         glcaps.cpp
 443         glproc_gl.cpp
 444     )
 445
 446     add_dependencies (glxtrace glproc)
 447
 448     set_target_properties (glxtrace PROPERTIES
 449         # avoid the default "lib" prefix
 450         PREFIX ""
 451         # Prevent symbol relocations internal to our wrapper library to be
 452         # overwritten by the application.
 453         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 454         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 455         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 456     )
 457
 458     target_link_libraries (glxtrace
 459         ${X11_X11_LIB}
 460         pthread
 461         dl
 462     )
 463
 464     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 465 endif ()
 466
 467
 468 if (EGL_FOUND)
 469     # libEGL.so/libGL.so
 470     add_custom_command (
 471         OUTPUT egltrace.cpp
 472         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 473         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 474     )
 475
 476     add_library (egltrace SHARED
 477         egltrace.cpp
 478         glcaps.cpp
 479         glproc_egl.cpp
 480     )
 481
 482     add_dependencies (egltrace glproc)
 483
 484     set_property (
 485         TARGET egltrace
 486         APPEND
 487         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 488     )
 489
 490     set_target_properties (egltrace PROPERTIES
 491         # avoid the default "lib" prefix
 492         PREFIX ""
 493         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 494         # Prevent symbol relocations internal to our wrapper library to be
 495         # overwritten by the application.
 496         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 497         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 498     )
 499
 500     target_link_libraries (egltrace
 501         pthread
 502         dl
 503     )
 504
 505     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 506 endif ()
 507
 508 ##############################################################################
 509 # API retracers
 510
 511 add_custom_command (
 512     OUTPUT glretrace_gl.cpp
 513     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 514     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 515 )
 516
 517 add_custom_command (
 518     OUTPUT glstate_params.cpp
 519     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 520     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 521 )
 522
 523 set (retrace_sources
 524     glretrace_gl.cpp
 525     glretrace_cgl.cpp
 526     glretrace_glx.cpp
 527     glretrace_wgl.cpp
 528     glretrace_egl.cpp
 529     glretrace_main.cpp
 530     glstate.cpp
 531     glstate_params.cpp
 532     retrace.cpp
 533     retrace_stdc.cpp
 534     glws.cpp
 535 )
 536
 537 if (WIN32 OR APPLE OR X11_FOUND)
 538     add_executable (glretrace
 539         ${retrace_sources}
 540         ${glws_os}
 541         glproc_gl.cpp
 542     )
 543
 544     add_dependencies (glretrace glproc)
 545
 546     set_property (
 547         TARGET glretrace
 548         APPEND
 549         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 550     )
 551
 552     target_link_libraries (glretrace
 553         common
 554     )
 555
 556     if (WIN32)
 557     else ()
 558         if (APPLE)
 559             target_link_libraries (glretrace
 560                 "-framework Cocoa"
 561                 "-framework ApplicationServices" # CGS*
 562                 ${OPENGL_gl_LIBRARY} # CGL*
 563             )
 564         else ()
 565             target_link_libraries (glretrace ${X11_X11_LIB})
 566         endif ()
 567
 568         target_link_libraries (glretrace
 569             # gdb doesn't like when pthreads is loaded through dlopen (which happens
 570             # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
 571             # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
 572             pthread
 573             dl
 574         )
 575     endif ()
 576
 577     install (TARGETS glretrace RUNTIME DESTINATION bin)
 578 endif ()
 579
 580 if (EGL_FOUND AND X11_FOUND AND NOT WIN32 AND NOT APPLE)
 581     add_executable (eglretrace
 582         ${retrace_sources}
 583         glws_egl_xlib.cpp
 584         glproc_egl.cpp
 585     )
 586
 587     add_dependencies (eglretrace glproc)
 588
 589     set_property (
 590         TARGET eglretrace
 591         APPEND
 592         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 593         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 594     )
 595
 596     target_link_libraries (eglretrace
 597         common
 598         ${X11_X11_LIB}
 599         pthread
 600         dl
 601     )
 602
 603     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 604 endif ()
 605
 606 ##############################################################################
 607 # CLI
 608
 609 add_subdirectory(cli)
 610
 611 ##############################################################################
 612 # Scripts (to support the CLI)
 613
 614 install (
 615     PROGRAMS
 616         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh
 617         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 618         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 619     DESTINATION ${SCRIPTS_INSTALL_DIR}
 620 )
 621
 622 ##############################################################################
 623 # GUI
 624
 625 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 626     add_subdirectory(gui)
 627 endif ()
 628
 629
 630 ##############################################################################
 631 # Packaging
 632
 633 install (
 634     FILES
 635         BUGS.markdown
 636         LICENSE
 637         NEWS.markdown
 638         README.markdown
 639         TODO.markdown
 640     DESTINATION ${DOC_INSTALL_DIR}
 641 )
 642
 643 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 644 set (CPACK_PACKAGE_VERSION_MINOR "0")
 645
 646 # Use current date in YYYYMMDD format as patch number
 647 execute_process (
 648     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 649     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 650 )
 651
 652 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 653 if (WIN32)
 654     set (CPACK_GENERATOR "ZIP")
 655 elseif (APPLE)
 656     set (CPACK_GENERATOR "DragNDrop")
 657 else ()
 658     set (CPACK_GENERATOR "TBZ2")
 659 endif ()
 660
 661 include(CPack)