git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3
   4 # Use clang on MacOSX. gcc doesn't support __thread key, and Apple has
   5 # abandoned it for clang.  This must be done before the project is defined.
   6 if (APPLE)
   7     set (CMAKE_C_COMPILER "clang")
   8     set (CMAKE_CXX_COMPILER "clang++")
   9 endif ()
  10
  11
  12 project (apitrace)
  13
  14
  15 ##############################################################################
  16 # Options
  17
  18 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  19 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  20     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  21 endif ()
  22
  23 # We use a cached string variable instead of the standard (boolean) OPTION
  24 # command so that we can default to auto-detecting optional depencies, while
  25 # still providing a mechanism to force/disable these optional dependencies, as
  26 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  27 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  28
  29 set (ENABLE_CLI true CACHE BOOL "Enable command Line interface.")
  30
  31 set (ENABLE_EGL true CACHE BOOL "Enable EGL support.")
  32
  33
  34 ##############################################################################
  35 # Find dependencies
  36
  37 # Ensure __thread is support
  38 if (NOT MSVC)
  39     include (CheckCXXSourceCompiles)
  40     check_cxx_source_compiles("__thread int i; int main() { return 0; }" HAVE_COMPILER_TLS)
  41     if (NOT HAVE_COMPILER_TLS)
  42         if (APPLE)
  43             message (FATAL_ERROR "C++ compiler does not support __thread keyword. Please install XCode 4.5 or higher.")
  44         else (MINGW32)
  45             message (FATAL_ERROR "C++ compiler does not support __thread keyword. Please use MinGW g++ version 4.4 or higher")
  46         else ()
  47             message (FATAL_ERROR "C++ compiler does not support __thread keyword.")
  48         endif ()
  49     endif ()
  50 endif ()
  51
  52 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  53
  54 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  55
  56 if (ANDROID)
  57     set (ENABLE_GUI false)
  58 else ()
  59     macro (find_host_package)
  60         find_package (${ARGN})
  61     endmacro()
  62 endif ()
  63
  64 find_host_package (PythonInterp REQUIRED)
  65 find_package (Threads)
  66
  67 if (ENABLE_GUI)
  68     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  69         set (REQUIRE_GUI REQUIRED)
  70     endif ()
  71     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  72 endif ()
  73
  74 if (WIN32)
  75     find_package (DirectX)
  76     set (ENABLE_EGL false)
  77 elseif (APPLE)
  78     set (ENABLE_EGL false)
  79 else ()
  80     find_package (X11)
  81
  82     if (X11_FOUND)
  83         include_directories (${X11_INCLUDE_DIR})
  84         add_definitions (-DHAVE_X11)
  85     endif ()
  86 endif ()
  87
  88
  89 ##############################################################################
  90 # Set global build options
  91
  92 include (CheckCXXCompilerFlag)
  93
  94 if (WIN32)
  95     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  96     add_definitions (-D_WIN32_WINNT=0x0601 -DWINVER=0x0601)
  97 else (WIN32)
  98     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  99     if (CXX_COMPILER_FLAG_VISIBILITY)
 100         add_definitions ("-fvisibility=hidden")
 101     endif ()
 102 endif ()
 103
 104 if (MSVC)
 105     # C99 includes for msvc
 106     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
 107
 108     # Enable math constants defines
 109     add_definitions (-D_USE_MATH_DEFINES)
 110
 111     # No min/max macros
 112     add_definitions (-DNOMINMAX)
 113
 114     # Adjust warnings
 115     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 116     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
 117     add_definitions (-W4)
 118     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 119     add_definitions (-wd4018) # signed/unsigned mismatch
 120     add_definitions (-wd4063) # not a valid value for switch of enum
 121     add_definitions (-wd4100) # unreferenced formal parameter
 122     add_definitions (-wd4127) # conditional expression is constant
 123     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 124     add_definitions (-wd4505) # unreferenced local function has been removed
 125     add_definitions (-wd4512) # assignment operator could not be generated
 126     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 127
 128     # Use static runtime
 129     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 130     foreach (flag_var
 131         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 132         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 133     )
 134         if (${flag_var} MATCHES "/MD")
 135             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 136         endif ()
 137     endforeach (flag_var)
 138 else ()
 139     # Adjust warnings
 140     add_definitions (-Wall)
 141     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 142     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 143
 144     # Use GDB extensions if available
 145     if (CMAKE_COMPILER_IS_GNUC)
 146         set (CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG} -ggdb -O0")
 147         set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO} -ggdb")
 148     endif ()
 149     if (CMAKE_COMPILER_IS_GNUCXX)
 150         set (CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -ggdb -O0")
 151         set (CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO} -ggdb")
 152     endif ()
 153
 154     # Be nice to Eclipse
 155     add_definitions (-fmessage-length=0)
 156 endif ()
 157
 158 if (MINGW)
 159     # Avoid depending on MinGW runtime DLLs
 160     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 161     if (HAVE_STATIC_LIBGCC_FLAG)
 162         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 163         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 164         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 165     endif ()
 166     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 167     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 168         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 169         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 170         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 171     endif ()
 172 endif ()
 173
 174
 175 # Put all executables into the same top level build directory, regardless of
 176 # which subdirectory they are declared
 177 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 178
 179
 180 ##############################################################################
 181 # Bundled dependencies
 182 #
 183 # We always use the bundled zlib, libpng, and snappy sources:
 184 # - on Windows to make it easy to deploy the wrappers DLLs
 185 # - on unices to prevent symbol collisions when tracing applications that link
 186 # against other versions of these libraries
 187
 188 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 189 set (ZLIB_LIBRARIES z_bundled)
 190 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 191
 192 include_directories (${ZLIB_INCLUDE_DIRS})
 193
 194 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 195 set (SNAPPY_LIBRARIES snappy_bundled)
 196 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 197
 198 include_directories (${SNAPPY_INCLUDE_DIRS})
 199
 200 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 201 set (PNG_DEFINITIONS "")
 202 set (PNG_LIBRARIES png_bundled)
 203
 204 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 205 include_directories (${PNG_INCLUDE_DIR})
 206 add_definitions (${PNG_DEFINITIONS})
 207
 208 if (MSVC)
 209     add_subdirectory (thirdparty/getopt EXCLUDE_FROM_ALL)
 210     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/getopt)
 211     set (GETOPT_LIBRARIES getopt_bundled)
 212 endif ()
 213
 214 if (WIN32)
 215     add_subdirectory (thirdparty/less)
 216 endif ()
 217
 218 # Always use bundled QJSon.
 219 # - The packaged versions QJson are very old, and do not support NaN/Infinity.
 220 # - To make it easier to build the GUI on Windows and MacOSX, as there are no
 221 # binaries at all.
 222 if (QT4_FOUND)
 223     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 224     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 225     set (QJSON_LIBRARY_DIRS)
 226     set (QJSON_LIBRARIES qjson_bundled)
 227     set (QJSON_FOUND TRUE)
 228 endif ()
 229
 230 # We use bundled headers for all Khronos APIs, to guarantee support for both
 231 # OpenGL and OpenGL ES at build time, because the OpenGL and OpenGL ES 1 APIs
 232 # are so intertwined that conditional compilation extremely difficult. This
 233 # also avoids missing/inconsistent declarations in system headers.
 234 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khronos)
 235
 236
 237 ##############################################################################
 238 # Installation directories
 239
 240 if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 241     # Debian multiarch support
 242     execute_process(COMMAND dpkg-architecture -qDEB_HOST_MULTIARCH
 243         OUTPUT_VARIABLE ARCH_SUBDIR
 244         ERROR_QUIET
 245         OUTPUT_STRIP_TRAILING_WHITESPACE
 246     )
 247 endif()
 248
 249 if (WIN32 OR APPLE)
 250     # On Windows/MacOSX, applications are usually installed on a directory of
 251     # their own
 252     set (DOC_INSTALL_DIR doc)
 253     set (LIB_INSTALL_DIR lib)
 254     set (LIB_ARCH_INSTALL_DIR lib)
 255 else ()
 256     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 257     set (LIB_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 258     if (ARCH_SUBDIR)
 259         set (LIB_ARCH_INSTALL_DIR lib/${ARCH_SUBDIR}/${CMAKE_PROJECT_NAME})
 260     else ()
 261         set (LIB_ARCH_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 262     endif ()
 263 endif ()
 264
 265 set (SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 266 set (WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 267
 268 # Expose the binary/install directories to source
 269 #
 270 # TODO: Use the same directory layout, for both build and install directories,
 271 # so that binaries can find each other using just relative paths.
 272 #
 273 add_definitions(
 274     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 275     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 276     -DAPITRACE_SCRIPTS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${SCRIPTS_INSTALL_DIR}"
 277     -DAPITRACE_WRAPPERS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 278 )
 279
 280
 281 ##############################################################################
 282 # Common libraries / utilities
 283
 284 include_directories (
 285     ${CMAKE_CURRENT_BINARY_DIR}
 286     ${CMAKE_CURRENT_SOURCE_DIR}
 287     ${CMAKE_CURRENT_SOURCE_DIR}/common
 288 )
 289
 290 if (WIN32)
 291     set (os os_win32.cpp)
 292     set (glws_os glws_wgl.cpp)
 293 else ()
 294     set (os os_posix.cpp)
 295     if (APPLE)
 296         set (glws_os glws_cocoa.mm)
 297     else ()
 298         set (glws_os glws_glx.cpp)
 299     endif ()
 300 endif ()
 301
 302 add_library (common STATIC
 303     common/trace_callset.cpp
 304     common/trace_dump.cpp
 305     common/trace_file.cpp
 306     common/trace_file_read.cpp
 307     common/trace_file_write.cpp
 308     common/trace_file_zlib.cpp
 309     common/trace_file_snappy.cpp
 310     common/trace_model.cpp
 311     common/trace_parser.cpp
 312     common/trace_parser_flags.cpp
 313     common/trace_writer.cpp
 314     common/trace_writer_local.cpp
 315     common/trace_writer_model.cpp
 316     common/trace_loader.cpp
 317     common/trace_resource.cpp
 318     common/trace_tools_trace.cpp
 319     common/trace_profiler.cpp
 320     common/image.cpp
 321     common/image_bmp.cpp
 322     common/image_pnm.cpp
 323     common/image_png.cpp
 324     common/${os}
 325 )
 326
 327 set_target_properties (common PROPERTIES
 328     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 329     # Ensure it can be statically linked in shared libraries
 330     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 331 )
 332
 333 if (ANDROID)
 334     target_link_libraries (common log)
 335 endif ()
 336
 337
 338 ##############################################################################
 339 # Sub-directories
 340
 341 add_subdirectory (dispatch)
 342 add_subdirectory (wrappers)
 343 add_subdirectory (retrace)
 344
 345
 346 ##############################################################################
 347 # CLI
 348
 349 if (ENABLE_CLI)
 350     add_subdirectory(cli)
 351 endif ()
 352
 353 ##############################################################################
 354 # Scripts (to support the CLI)
 355
 356 install (
 357     PROGRAMS
 358         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.py
 359         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 360         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 361     DESTINATION ${SCRIPTS_INSTALL_DIR}
 362 )
 363
 364 ##############################################################################
 365 # GUI
 366
 367 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 368     add_subdirectory(gui)
 369 endif ()
 370
 371
 372 ##############################################################################
 373 # Packaging
 374
 375 install (
 376     FILES
 377         BUGS.markdown
 378         LICENSE
 379         NEWS.markdown
 380         README.markdown
 381     DESTINATION ${DOC_INSTALL_DIR}
 382 )
 383
 384 set (CPACK_PACKAGE_VERSION_MAJOR "3")
 385 set (CPACK_PACKAGE_VERSION_MINOR "0")
 386
 387 # Use current date in YYYYMMDD format as patch number
 388 execute_process (
 389     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 390     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 391 )
 392
 393 # cpack mistakenly detects Mingw-w64 as win32
 394 if (MINGW)
 395     if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 396         set (CPACK_SYSTEM_NAME win64)
 397     endif ()
 398 endif ()
 399
 400 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 401 if (WIN32)
 402     set (CPACK_GENERATOR "ZIP")
 403 elseif (APPLE)
 404     set (CPACK_GENERATOR "DragNDrop")
 405 else ()
 406     set (CPACK_GENERATOR "TBZ2")
 407 endif ()
 408
 409 include(CPack)