git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20
  21 ##############################################################################
  22 # Find dependencies
  23
  24 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  25
  26 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  27
  28 find_package (PythonInterp REQUIRED)
  29 find_package (OpenGL REQUIRED)
  30
  31 if (ENABLE_GUI)
  32     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  33         set (REQUIRE_GUI REQUIRED)
  34     endif ()
  35     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  36     find_package (QJSON ${REQUIRE_GUI})
  37 endif ()
  38
  39 if (WIN32)
  40     find_package (DirectX)
  41 elseif (APPLE)
  42 else ()
  43     find_package (X11 REQUIRED)
  44
  45     set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  46     set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  47
  48     include_directories (${X11_INCLUDE_DIR})
  49 endif ()
  50
  51
  52 ##############################################################################
  53 # Set global build options
  54
  55 include (CheckCXXCompilerFlag)
  56
  57 if (WIN32)
  58     # MSVC & MinGW only define & use APIENTRY
  59     add_definitions (-DGLAPIENTRY=__stdcall)
  60
  61     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  62     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  63 else (WIN32)
  64     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  65     if (CXX_COMPILER_FLAG_VISIBILITY)
  66         add_definitions ("-fvisibility=hidden")
  67     endif (CXX_COMPILER_FLAG_VISIBILITY)
  68 endif (WIN32)
  69
  70 if (MSVC)
  71     # C99 includes for msvc
  72     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  73
  74     # Enable math constants defines
  75     add_definitions (-D_USE_MATH_DEFINES)
  76
  77     # No min/max macros
  78     add_definitions (-DNOMINMAX)
  79
  80     # Adjust warnings
  81     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  82     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  83     add_definitions (-W4)
  84     add_definitions (-wd4063) # not a valid value for switch of enum
  85     add_definitions (-wd4127) # conditional expression is constant
  86     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  87     add_definitions (-wd4505) # unreferenced local function has been removed
  88     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  89     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  90     add_definitions (-wd4018) # signed/unsigned mismatch
  91
  92     # Use static runtime
  93     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  94     foreach (flag_var
  95         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  96         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  97     )
  98         if (${flag_var} MATCHES "/MD")
  99             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 100         endif (${flag_var} MATCHES "/MD")
 101     endforeach (flag_var)
 102 else ()
 103     # Adjust warnings
 104     add_definitions (-Wall)
 105     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 106     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 107 endif ()
 108
 109 if (MINGW)
 110     # Avoid depending on MinGW runtime DLLs
 111     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 112     if (HAVE_STATIC_LIBGCC_FLAG)
 113         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 114         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 115         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 116     endif ()
 117     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 118     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 119         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 120         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 121         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 122     endif ()
 123 endif ()
 124
 125
 126 # Put all executables into the same top level build directory, regardless of
 127 # which subdirectory they are declared
 128 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 129
 130
 131 ##############################################################################
 132 # Bundled dependencies
 133 #
 134 # We always use the bundled zlib, libpng, and snappy sources:
 135 # - on Windows to make it easy to deploy the wrappers DLLs
 136 # - on unices to prevent symbol collisions when tracing applications that link
 137 # against other versions of these libraries
 138
 139 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 140 set (ZLIB_LIBRARIES z_bundled)
 141 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 142
 143 include_directories (${ZLIB_INCLUDE_DIRS})
 144 link_libraries (${ZLIB_LIBRARIES})
 145
 146 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 147 set (SNAPPY_LIBRARIES snappy_bundled)
 148 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 149
 150 include_directories (${SNAPPY_INCLUDE_DIRS})
 151 link_libraries (${SNAPPY_LIBRARIES})
 152
 153 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 154 set (PNG_DEFINITIONS "")
 155 set (PNG_LIBRARIES png_bundled)
 156
 157 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 158 include_directories (${PNG_INCLUDE_DIR})
 159 add_definitions (${PNG_DEFINITIONS})
 160 link_libraries (${PNG_LIBRARIES})
 161
 162 # The Qt website provides binaries for Windows and MacOSX, and they are
 163 # automatically found by cmake without any manual intervention.  The situation
 164 # for QJSON is substantially different: there are no binaries for QJSON
 165 # available, and there is no standard installation directory that is detected
 166 # by cmake.
 167 #
 168 # By bundling the QJSON source, we make it much more easier to build the GUI on
 169 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 170 # AUTO.
 171 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 172     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 173     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 174     set (QJSON_LIBRARY_DIRS)
 175     set (QJSON_LIBRARIES qjson_bundled)
 176     set (QJSON_FOUND TRUE)
 177 endif ()
 178
 179 # For glext headers
 180 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 181
 182
 183 ##############################################################################
 184 # Common libraries / utilities
 185
 186 include_directories (
 187     ${CMAKE_CURRENT_SOURCE_DIR}
 188     ${CMAKE_CURRENT_SOURCE_DIR}/common
 189 )
 190
 191 add_custom_command (
 192     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 193     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 194     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 195 )
 196
 197 if (WIN32)
 198     set (os os_win32.cpp)
 199     set (glws_os glws_wgl.cpp)
 200 else ()
 201     set (os os_posix.cpp)
 202     if (APPLE)
 203         set (glws_os glws_cocoa.mm)
 204     else ()
 205         set (glws_os glws_glx.cpp)
 206     endif ()
 207 endif ()
 208
 209 add_library (common STATIC
 210     common/trace_file.cpp
 211     common/trace_snappyfile.cpp
 212     common/trace_model.cpp
 213     common/trace_parser.cpp
 214     common/trace_writer.cpp
 215     common/trace_local_writer.cpp
 216     common/trace_model_writer.cpp
 217     common/trace_loader.cpp
 218     common/image.cpp
 219     common/image_bmp.cpp
 220     common/image_pnm.cpp
 221     common/image_png.cpp
 222     common/${os}
 223 )
 224
 225 set_target_properties (common PROPERTIES
 226     # Ensure it can be statically linked in shared libraries
 227     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 228 )
 229
 230 link_libraries (common)
 231
 232 add_executable (tracedump tracedump.cpp)
 233 install (TARGETS tracedump RUNTIME DESTINATION bin)
 234
 235
 236 ##############################################################################
 237 # API tracers
 238
 239 if (WIN32)
 240     if (MINGW)
 241         # Silence warnings about @nn suffix mismatch
 242         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 243     endif (MINGW)
 244
 245     # ddraw.dll
 246     if (DirectX_D3D_INCLUDE_DIR)
 247         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 248         add_custom_command (
 249             OUTPUT ddrawtrace.cpp
 250             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 251             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 252         )
 253         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 254         set_target_properties (ddraw
 255             PROPERTIES PREFIX ""
 256             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 257             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 258         )
 259         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 260     endif (DirectX_D3D_INCLUDE_DIR)
 261
 262     # d3d8.dll
 263     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 264         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 265         add_custom_command (
 266             OUTPUT d3d8trace.cpp
 267             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 268             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 269         )
 270         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 271         set_target_properties (d3d8
 272             PROPERTIES PREFIX ""
 273             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 274             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 275         )
 276         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 277     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 278
 279     # d3d9.dll
 280     if (DirectX_D3DX9_INCLUDE_DIR)
 281         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 282         add_custom_command (
 283             OUTPUT d3d9trace.cpp
 284             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 285             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 286         )
 287         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 288         set_target_properties (d3d9
 289             PROPERTIES PREFIX ""
 290             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 291             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 292         )
 293         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 294     endif (DirectX_D3DX9_INCLUDE_DIR)
 295
 296     # d3d10.dll
 297     if (DirectX_D3D10_INCLUDE_DIR)
 298         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 299         add_custom_command (
 300             OUTPUT d3d10trace.cpp
 301             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 302             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 303         )
 304         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 305         set_target_properties (d3d10
 306             PROPERTIES PREFIX ""
 307             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 308             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 309         )
 310         install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 311     endif (DirectX_D3D10_INCLUDE_DIR)
 312
 313     # opengl32.dll
 314     add_custom_command (
 315         OUTPUT wgltrace.cpp
 316         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 317         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 318     )
 319     add_library (wgltrace MODULE specs/opengl32.def
 320         wgltrace.cpp
 321         glcaps.cpp
 322         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 323     )
 324     set_target_properties (wgltrace PROPERTIES
 325         PREFIX ""
 326         OUTPUT_NAME opengl32
 327         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 328         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 329     )
 330     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 331
 332 elseif (APPLE)
 333     # OpenGL framework
 334     add_custom_command (
 335         OUTPUT cgltrace.cpp
 336         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 337         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 338     )
 339
 340     add_library (cgltrace SHARED
 341         cgltrace.cpp
 342         glcaps.cpp
 343         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 344     )
 345
 346     set_target_properties (cgltrace PROPERTIES
 347         # OpenGL framework name
 348         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 349         # Specificy the version and reexport GLU symbols
 350         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 351         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 352         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 353     )
 354
 355     target_link_libraries (cgltrace dl)
 356
 357     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 358 else ()
 359     # libGL.so
 360     add_custom_command (
 361         OUTPUT glxtrace.cpp
 362         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 363         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 364     )
 365
 366     add_library (glxtrace SHARED
 367         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 368         glxtrace.cpp
 369         glcaps.cpp
 370         glsnapshot.cpp
 371     )
 372
 373     set_target_properties (glxtrace PROPERTIES
 374         # avoid the default "lib" prefix
 375         PREFIX ""
 376     )
 377
 378     # Prevent symbol relocations internal to our wrapper library to be
 379     # overwritten by the application.
 380     set_target_properties (glxtrace PROPERTIES
 381         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 382     )
 383
 384     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 385
 386     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 387 endif ()
 388
 389
 390 ##############################################################################
 391 # API retracers
 392
 393 add_custom_command (
 394     OUTPUT glretrace_gl.cpp
 395     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 396     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 397 )
 398
 399 add_custom_command (
 400     OUTPUT glstate_params.cpp
 401     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 402     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 403 )
 404
 405 include_directories (
 406     ${CMAKE_CURRENT_BINARY_DIR}
 407     ${OPENGL_INCLUDE_PATH}
 408 )
 409
 410 add_executable (glretrace
 411     glretrace_gl.cpp
 412     glretrace_cgl.cpp
 413     glretrace_glx.cpp
 414     glretrace_wgl.cpp
 415     glretrace_main.cpp
 416     glstate.cpp
 417     glstate_params.cpp
 418     retrace.cpp
 419     glws.cpp
 420     ${glws_os}
 421     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 422 )
 423
 424 set_property (
 425     TARGET glretrace
 426     APPEND
 427     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 428 )
 429
 430 target_link_libraries (glretrace
 431     common
 432 )
 433
 434 if (WIN32)
 435     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 436 elseif (APPLE)
 437     target_link_libraries (glretrace
 438         "-framework Cocoa"
 439         "-framework ApplicationServices" # CGS*
 440         ${OPENGL_gl_LIBRARY} # CGL*
 441     )
 442 else ()
 443     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 444 endif ()
 445
 446 install (TARGETS glretrace RUNTIME DESTINATION bin)
 447
 448
 449 ##############################################################################
 450 # GUI
 451
 452 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 453     add_subdirectory(gui)
 454 endif ()
 455
 456
 457 ##############################################################################
 458 # Packaging
 459
 460 install (
 461     FILES
 462         BUGS.markdown
 463         LICENSE
 464         NEWS.markdown
 465         README.markdown
 466         TODO.markdown
 467     DESTINATION doc)
 468
 469 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 470 set (CPACK_PACKAGE_VERSION_MINOR "0")
 471
 472 # Use current date in YYYYMMDD format as patch number
 473 execute_process (
 474     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 475     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 476 )
 477
 478 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 479 if (WIN32)
 480     set (CPACK_GENERATOR "ZIP")
 481 elseif (APPLE)
 482     set (CPACK_GENERATOR "DragNDrop")
 483 else ()
 484     set (CPACK_GENERATOR "TBZ2")
 485 endif ()
 486
 487 include(CPack)