git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8 #
   9 # We use a cached string variable instead of the standard (boolean) OPTION
  10 # command so that we can default to auto-detecting optional depencies, while
  11 # still providing a mechanism to force/disable these optional dependencies, as
  12 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  13
  14 set (ENABLE_GUI "AUTO" CACHE STRING "Enable QT GUI.")
  15
  16
  17 ##############################################################################
  18 # Find dependencies
  19
  20 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  21
  22 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  23
  24 find_package (PythonInterp REQUIRED)
  25 find_package (OpenGL REQUIRED)
  26
  27 if (ENABLE_GUI)
  28     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  29         set (REQUIRE_GUI REQUIRED)
  30     endif ()
  31     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  32     find_package (QJSON ${REQUIRE_GUI})
  33 endif ()
  34
  35 if (NOT WIN32)
  36     find_package (X11 REQUIRED)
  37
  38     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  39     # from the standard OpenGL framework which provides support for native Mac OS X
  40     # applications.
  41     if (APPLE)
  42         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  43         if (NOT X11_GL_INCLUDE_PATH)
  44             message (SEND_ERROR "Could not find GL/glx.h")
  45         endif (NOT X11_GL_INCLUDE_PATH)
  46         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  47
  48         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  49         if (NOT X11_GL_LIB)
  50             message (SEND_ERROR "Could not find libGL.dylib")
  51         endif (NOT X11_GL_LIB)
  52     else ()
  53         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  54         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  55     endif ()
  56
  57     include_directories (${X11_INCLUDE_DIR})
  58 endif (NOT WIN32)
  59
  60 if (WIN32)
  61     find_package (DirectX)
  62 endif (WIN32)
  63
  64
  65 ##############################################################################
  66 # Set global build options
  67
  68 include (CheckCXXCompilerFlag)
  69
  70 if (WIN32)
  71     # MSVC & MinGW only define & use APIENTRY
  72     add_definitions (-DGLAPIENTRY=__stdcall)
  73
  74     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  75     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  76 else (WIN32)
  77     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  78     if (CXX_COMPILER_FLAG_VISIBILITY)
  79         add_definitions ("-fvisibility=hidden")
  80     endif (CXX_COMPILER_FLAG_VISIBILITY)
  81 endif (WIN32)
  82
  83 if (MSVC)
  84     # C99 includes for msvc
  85     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  86
  87     # Enable math constants defines
  88     add_definitions (-D_USE_MATH_DEFINES)
  89
  90     # No min/max macros
  91     add_definitions (-DNOMINMAX)
  92
  93     # Adjust warnings
  94     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  95     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  96     add_definitions (-W4)
  97     add_definitions (-wd4063) # not a valid value for switch of enum
  98     add_definitions (-wd4127) # conditional expression is constant
  99     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 100     add_definitions (-wd4505) # unreferenced local function has been removed
 101     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 102     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 103     add_definitions (-wd4018) # signed/unsigned mismatch
 104
 105     # Use static runtime
 106     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 107     foreach (flag_var
 108         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 109         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 110     )
 111         if (${flag_var} MATCHES "/MD")
 112             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 113         endif (${flag_var} MATCHES "/MD")
 114     endforeach (flag_var)
 115 else ()
 116     # Adjust warnings
 117     add_definitions (-Wall)
 118     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 119     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 120 endif ()
 121
 122
 123 # Put all executables into the same top level build directory, regardless of
 124 # which subdirectory they are declared
 125 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 126
 127
 128 ##############################################################################
 129 # Bundled dependencies
 130 #
 131 # We always use the bundled zlib and libpng sources:
 132 # - on Windows to make it easy to deploy the wrappers DLLs
 133 # - on unices to prevent symbol collisions when tracing applications that link
 134 # against other versions of these libraries
 135
 136 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 137 set (ZLIB_LIBRARIES z_bundled)
 138 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 139
 140 include_directories (${ZLIB_INCLUDE_DIRS})
 141 link_libraries (${ZLIB_LIBRARIES})
 142
 143 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 144 set (PNG_DEFINITIONS "")
 145 set (PNG_LIBRARIES png_bundled)
 146
 147 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 148 include_directories (${PNG_INCLUDE_DIR})
 149 add_definitions (${PNG_DEFINITIONS})
 150 link_libraries (${PNG_LIBRARIES})
 151
 152 # For glext headers
 153 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 154
 155
 156 ##############################################################################
 157 # Common libraries / utilities
 158
 159 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 160
 161 add_custom_command (
 162     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 163     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 164     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 165 )
 166
 167 if (WIN32)
 168     set (os os_win32.cpp)
 169     set (glws glws_wgl.cpp)
 170 else (WIN32)
 171     set (os os_posix.cpp)
 172     set (glws glws_glx.cpp)
 173 endif (WIN32)
 174
 175 add_library (common
 176     trace_model.cpp
 177     trace_parser.cpp
 178     trace_writer.cpp
 179     trace_model_writer.cpp
 180     image.cpp
 181     image_bmp.cpp
 182     image_pnm.cpp
 183     image_png.cpp
 184     ${os}
 185 )
 186
 187 set_target_properties (common PROPERTIES
 188     # Ensure it can be statically linked in shared libraries
 189     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_C_FLAGS}"
 190 )
 191
 192 link_libraries (common)
 193
 194 add_executable (tracedump tracedump.cpp)
 195 install (TARGETS tracedump RUNTIME DESTINATION bin)
 196
 197
 198 ##############################################################################
 199 # API tracers
 200
 201 if (WIN32)
 202     # ddraw.dll
 203     if (DirectX_D3D_INCLUDE_DIR)
 204         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 205         add_custom_command (
 206             OUTPUT ddraw.cpp
 207             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 208             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 209         )
 210         add_library (ddraw MODULE ddraw.def ddraw.cpp)
 211         set_target_properties (ddraw
 212             PROPERTIES PREFIX ""
 213             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 214             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 215         )
 216         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 217     endif (DirectX_D3D_INCLUDE_DIR)
 218
 219     # d3d8.dll
 220     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 221         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 222         add_custom_command (
 223             OUTPUT d3d8.cpp
 224             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 225             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 226         )
 227         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp)
 228         set_target_properties (d3d8
 229             PROPERTIES PREFIX ""
 230             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 231             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 232         )
 233         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 234     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 235
 236     # d3d9.dll
 237     if (DirectX_D3DX9_INCLUDE_DIR)
 238         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 239         add_custom_command (
 240             OUTPUT d3d9.cpp
 241             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 242             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 243         )
 244         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp)
 245         set_target_properties (d3d9
 246             PROPERTIES PREFIX ""
 247             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 248             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 249         )
 250         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 251     endif (DirectX_D3DX9_INCLUDE_DIR)
 252
 253     # d3d10.dll
 254     #if (DirectX_D3D10_INCLUDE_DIR)
 255     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 256     #    add_custom_command (
 257     #        OUTPUT d3d10.cpp
 258     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 259     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 260     #    )
 261     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp)
 262     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 263     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 264     #endif (DirectX_D3D10_INCLUDE_DIR)
 265
 266     # opengl32.dll
 267     add_custom_command (
 268         OUTPUT wgltrace.cpp
 269         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 270         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 271     )
 272     add_library (wgltrace MODULE opengl32.def
 273         wgltrace.cpp
 274         glcaps.cpp
 275         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 276     )
 277     set_target_properties (wgltrace PROPERTIES
 278         PREFIX ""
 279         OUTPUT_NAME opengl32
 280         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 281         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 282     )
 283     if (MINGW)
 284         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 285     endif (MINGW)
 286     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 287
 288 elseif (APPLE)
 289     # OpenGL framework
 290     add_custom_command (
 291         OUTPUT cgltrace.cpp
 292         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 293         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 294     )
 295
 296     add_library (cgltrace SHARED
 297         cgltrace.cpp
 298         glcaps.cpp
 299         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 300     )
 301
 302     set_target_properties (cgltrace PROPERTIES
 303         # OpenGL framework name
 304         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 305         # Specificy the version and reexport GLU symbols
 306         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 307         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 308         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 309     )
 310
 311     target_link_libraries (cgltrace dl)
 312
 313     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 314 else ()
 315     # libGL.so
 316     add_custom_command (
 317         OUTPUT glxtrace.cpp
 318         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 319         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 320     )
 321
 322     add_library (glxtrace SHARED
 323         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 324         glxtrace.cpp
 325         glcaps.cpp
 326         glsnapshot.cpp
 327     )
 328
 329     set_target_properties (glxtrace PROPERTIES
 330         # avoid the default "lib" prefix
 331         PREFIX ""
 332     )
 333
 334     # Prevent symbol relocations internal to our wrapper library to be
 335     # overwritten by the application.
 336     set_target_properties (glxtrace PROPERTIES
 337         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 338     )
 339
 340     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 341
 342     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 343 endif ()
 344
 345
 346 ##############################################################################
 347 # API retracers
 348
 349 add_custom_command (
 350     OUTPUT glretrace_gl.cpp
 351     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 352     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 353 )
 354
 355 add_custom_command (
 356     OUTPUT glstate_params.cpp
 357     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 358     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 359 )
 360
 361 include_directories (
 362     ${CMAKE_CURRENT_BINARY_DIR}
 363     ${OPENGL_INCLUDE_PATH}
 364 )
 365
 366 add_executable (glretrace
 367     glretrace_gl.cpp
 368     glretrace_cgl.cpp
 369     glretrace_glx.cpp
 370     glretrace_wgl.cpp
 371     glretrace_main.cpp
 372     glstate.cpp
 373     glstate_params.cpp
 374     retrace.cpp
 375     ${glws}
 376     image.cpp
 377     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 378 )
 379
 380 set_property (
 381     TARGET glretrace
 382     APPEND
 383     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 384 )
 385
 386 target_link_libraries (glretrace
 387     common
 388 )
 389
 390 if (WIN32)
 391     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 392 elseif (APPLE)
 393     # XXX: We use GLX on MacOSX, which is in a separate library.
 394     target_link_libraries (glretrace
 395         ${X11_GL_LIB}
 396         ${X11_X11_LIB}
 397         "-framework ApplicationServices" # CGS*
 398         ${OPENGL_gl_LIBRARY} # CGL*
 399     )
 400 else ()
 401     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 402 endif ()
 403
 404 install (TARGETS glretrace RUNTIME DESTINATION bin)
 405
 406
 407 ##############################################################################
 408 # GUI
 409
 410 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 411     add_subdirectory(gui)
 412 endif ()
 413
 414
 415 ##############################################################################
 416 # Packaging
 417
 418 install (FILES LICENSE README.markdown TODO.markdown DESTINATION doc)
 419
 420 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 421 set (CPACK_PACKAGE_VERSION_MINOR "0")
 422
 423 # Use current date in YYYYMMDD format as patch number
 424 execute_process (
 425     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 426     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 427 )
 428
 429 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 430 if (WIN32)
 431     set (CPACK_GENERATOR "ZIP")
 432 elseif (APPLE)
 433     set (CPACK_GENERATOR "DragNDrop")
 434 else ()
 435     set (CPACK_GENERATOR "TBZ2")
 436 endif ()
 437
 438 include(CPack)