git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20
  21 ##############################################################################
  22 # Find dependencies
  23
  24 include (FindPkgConfig)
  25
  26 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  27
  28 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  29
  30 find_package (PythonInterp REQUIRED)
  31 find_package (OpenGL REQUIRED)
  32
  33 if (ENABLE_GUI)
  34     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  35         set (REQUIRE_GUI REQUIRED)
  36     endif ()
  37     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  38     find_package (QJSON ${REQUIRE_GUI})
  39 endif ()
  40
  41 if (WIN32)
  42     find_package (DirectX)
  43 elseif (APPLE)
  44 else ()
  45     find_package (X11 REQUIRED)
  46
  47     set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  48     set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  49
  50     include_directories (${X11_INCLUDE_DIR})
  51
  52     pkg_check_modules (EGL egl)
  53     if (EGL_FOUND)
  54         include_directories (${EGL_INCLUDE_DIR})
  55         add_definitions (-DHAVE_EGL)
  56     endif ()
  57 endif ()
  58
  59
  60 ##############################################################################
  61 # Set global build options
  62
  63 include (CheckCXXCompilerFlag)
  64
  65 if (WIN32)
  66     # MSVC & MinGW only define & use APIENTRY
  67     add_definitions (-DGLAPIENTRY=__stdcall)
  68
  69     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  70     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  71 else (WIN32)
  72     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  73     if (CXX_COMPILER_FLAG_VISIBILITY)
  74         add_definitions ("-fvisibility=hidden")
  75     endif (CXX_COMPILER_FLAG_VISIBILITY)
  76 endif (WIN32)
  77
  78 if (MSVC)
  79     # C99 includes for msvc
  80     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  81
  82     # Enable math constants defines
  83     add_definitions (-D_USE_MATH_DEFINES)
  84
  85     # No min/max macros
  86     add_definitions (-DNOMINMAX)
  87
  88     # Adjust warnings
  89     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  90     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  91     add_definitions (-W4)
  92     add_definitions (-wd4063) # not a valid value for switch of enum
  93     add_definitions (-wd4127) # conditional expression is constant
  94     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  95     add_definitions (-wd4505) # unreferenced local function has been removed
  96     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  97     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  98     add_definitions (-wd4018) # signed/unsigned mismatch
  99
 100     # Use static runtime
 101     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 102     foreach (flag_var
 103         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 104         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 105     )
 106         if (${flag_var} MATCHES "/MD")
 107             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 108         endif (${flag_var} MATCHES "/MD")
 109     endforeach (flag_var)
 110 else ()
 111     # Adjust warnings
 112     add_definitions (-Wall)
 113     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 114     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 115 endif ()
 116
 117 if (MINGW)
 118     # Avoid depending on MinGW runtime DLLs
 119     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 120     if (HAVE_STATIC_LIBGCC_FLAG)
 121         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 122         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 123         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 124     endif ()
 125     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 126     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 127         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 128         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 129         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 130     endif ()
 131 endif ()
 132
 133
 134 # Put all executables into the same top level build directory, regardless of
 135 # which subdirectory they are declared
 136 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 137
 138
 139 ##############################################################################
 140 # Bundled dependencies
 141 #
 142 # We always use the bundled zlib, libpng, and snappy sources:
 143 # - on Windows to make it easy to deploy the wrappers DLLs
 144 # - on unices to prevent symbol collisions when tracing applications that link
 145 # against other versions of these libraries
 146
 147 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 148 set (ZLIB_LIBRARIES z_bundled)
 149 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 150
 151 include_directories (${ZLIB_INCLUDE_DIRS})
 152 link_libraries (${ZLIB_LIBRARIES})
 153
 154 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 155 set (SNAPPY_LIBRARIES snappy_bundled)
 156 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 157
 158 include_directories (${SNAPPY_INCLUDE_DIRS})
 159 link_libraries (${SNAPPY_LIBRARIES})
 160
 161 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 162 set (PNG_DEFINITIONS "")
 163 set (PNG_LIBRARIES png_bundled)
 164
 165 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 166 include_directories (${PNG_INCLUDE_DIR})
 167 add_definitions (${PNG_DEFINITIONS})
 168 link_libraries (${PNG_LIBRARIES})
 169
 170 # The Qt website provides binaries for Windows and MacOSX, and they are
 171 # automatically found by cmake without any manual intervention.  The situation
 172 # for QJSON is substantially different: there are no binaries for QJSON
 173 # available, and there is no standard installation directory that is detected
 174 # by cmake.
 175 #
 176 # By bundling the QJSON source, we make it much more easier to build the GUI on
 177 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 178 # AUTO.
 179 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 180     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 181     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 182     set (QJSON_LIBRARY_DIRS)
 183     set (QJSON_LIBRARIES qjson_bundled)
 184     set (QJSON_FOUND TRUE)
 185 endif ()
 186
 187 # For glext headers
 188 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 189
 190 # For EGL headers
 191 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 192
 193 ##############################################################################
 194 # Installation directories
 195
 196 if (WIN32 OR APPLE)
 197     # On Windows/MacOSX, applications are usually installed on a directory of
 198     # their own
 199     set (DOC_INSTALL_DIR doc)
 200 else ()
 201     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 202 endif ()
 203
 204 set (LIB_INSTALL_DIR lib/apitrace)
 205
 206 if (APPLE)
 207     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 208     # directories
 209     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 210 else ()
 211     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 212 endif ()
 213
 214 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 215 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 216
 217 # Expose the binary/install directories to source
 218 #
 219 # TODO: Use the same directory layout, for both build and install directories,
 220 # so that binaries can find each other using just relative paths.
 221 #
 222 add_definitions(
 223     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 224     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 225     -DAPITRACE_SCRIPTS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${SCRIPTS_INSTALL_DIR}"
 226     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 227 )
 228
 229
 230 ##############################################################################
 231 # Common libraries / utilities
 232
 233 include_directories (
 234     ${CMAKE_CURRENT_SOURCE_DIR}
 235     ${CMAKE_CURRENT_SOURCE_DIR}/common
 236 )
 237
 238 add_custom_command (
 239     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 240     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 241     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 242 )
 243
 244 if (WIN32)
 245     set (os os_win32.cpp)
 246     set (glws_os glws_wgl.cpp)
 247 else ()
 248     set (os os_posix.cpp)
 249     if (APPLE)
 250         set (glws_os glws_cocoa.mm)
 251     else ()
 252         set (glws_os glws_glx.cpp)
 253     endif ()
 254 endif ()
 255
 256 add_library (common STATIC
 257     common/trace_file.cpp
 258     common/trace_file_zlib.cpp
 259     common/trace_file_snappy.cpp
 260     common/trace_model.cpp
 261     common/trace_parser.cpp
 262     common/trace_writer.cpp
 263     common/trace_writer_local.cpp
 264     common/trace_writer_model.cpp
 265     common/trace_loader.cpp
 266     common/trace_tools_trace.cpp
 267     common/image.cpp
 268     common/image_bmp.cpp
 269     common/image_pnm.cpp
 270     common/image_png.cpp
 271     common/${os}
 272 )
 273
 274 set_target_properties (common PROPERTIES
 275     # Ensure it can be statically linked in shared libraries
 276     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 277 )
 278
 279 link_libraries (common)
 280
 281
 282 ##############################################################################
 283 # API tracers
 284
 285 if (WIN32)
 286     if (MINGW)
 287         # Silence warnings about @nn suffix mismatch
 288         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 289     endif (MINGW)
 290
 291     # ddraw.dll
 292     if (DirectX_D3D_INCLUDE_DIR)
 293         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 294         add_custom_command (
 295             OUTPUT ddrawtrace.cpp
 296             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 297             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 298         )
 299         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 300         set_target_properties (ddraw
 301             PROPERTIES PREFIX ""
 302             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 303             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 304         )
 305         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 306     endif (DirectX_D3D_INCLUDE_DIR)
 307
 308     # d3d8.dll
 309     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 310         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 311         add_custom_command (
 312             OUTPUT d3d8trace.cpp
 313             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 314             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 315         )
 316         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 317         set_target_properties (d3d8
 318             PROPERTIES PREFIX ""
 319             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 320             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 321         )
 322         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 323     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 324
 325     # d3d9.dll
 326     if (DirectX_D3DX9_INCLUDE_DIR)
 327         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 328         add_custom_command (
 329             OUTPUT d3d9trace.cpp
 330             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 331             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 332         )
 333         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 334         set_target_properties (d3d9
 335             PROPERTIES PREFIX ""
 336             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 337             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 338         )
 339         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 340     endif (DirectX_D3DX9_INCLUDE_DIR)
 341
 342     # d3d10.dll
 343     if (DirectX_D3D10_INCLUDE_DIR)
 344         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 345         add_custom_command (
 346             OUTPUT d3d10trace.cpp
 347             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 348             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 349         )
 350         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 351         set_target_properties (d3d10
 352             PROPERTIES PREFIX ""
 353             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 354             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 355         )
 356         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 357     endif (DirectX_D3D10_INCLUDE_DIR)
 358
 359     # opengl32.dll
 360     add_custom_command (
 361         OUTPUT wgltrace.cpp
 362         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 363         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 364     )
 365     add_library (wgltrace MODULE specs/opengl32.def
 366         wgltrace.cpp
 367         glcaps.cpp
 368         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 369     )
 370     set_target_properties (wgltrace PROPERTIES
 371         PREFIX ""
 372         OUTPUT_NAME opengl32
 373         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 374         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 375     )
 376     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 377
 378 elseif (APPLE)
 379     # OpenGL framework
 380     add_custom_command (
 381         OUTPUT cgltrace.cpp
 382         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 383         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 384     )
 385
 386     add_library (cgltrace SHARED
 387         cgltrace.cpp
 388         glcaps.cpp
 389         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 390     )
 391
 392     set_target_properties (cgltrace PROPERTIES
 393         # OpenGL framework name
 394         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 395         # Specificy the version and reexport GLU symbols
 396         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 397         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 398         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 399     )
 400
 401     target_link_libraries (cgltrace dl)
 402
 403     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 404 else ()
 405     # libGL.so
 406     add_custom_command (
 407         OUTPUT glxtrace.cpp
 408         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 409         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 410     )
 411
 412     add_library (glxtrace SHARED
 413         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 414         glxtrace.cpp
 415         glcaps.cpp
 416         glsnapshot.cpp
 417     )
 418
 419     set_target_properties (glxtrace PROPERTIES
 420         # avoid the default "lib" prefix
 421         PREFIX ""
 422         # Prevent symbol relocations internal to our wrapper library to be
 423         # overwritten by the application.
 424         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 425         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 426         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 427     )
 428
 429     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 430
 431     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 432 endif ()
 433
 434
 435 if (EGL_FOUND)
 436     # libEGL.so/libGL.so
 437     add_custom_command (
 438         OUTPUT egltrace.cpp
 439         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 440         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 441     )
 442
 443     add_library (egltrace SHARED
 444         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 445         egltrace.cpp
 446         glcaps.cpp
 447         glsnapshot.cpp
 448     )
 449
 450     set_property (
 451         TARGET egltrace
 452         APPEND
 453         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 454     )
 455
 456     set_target_properties (egltrace PROPERTIES
 457         # avoid the default "lib" prefix
 458         PREFIX ""
 459     )
 460
 461     # Prevent symbol relocations internal to our wrapper library to be
 462     # overwritten by the application.
 463     set_target_properties (egltrace PROPERTIES
 464         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 465     )
 466
 467     target_link_libraries (egltrace dl)
 468
 469     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 470 endif ()
 471
 472 ##############################################################################
 473 # API retracers
 474
 475 add_custom_command (
 476     OUTPUT glretrace_gl.cpp
 477     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 478     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 479 )
 480
 481 add_custom_command (
 482     OUTPUT glstate_params.cpp
 483     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 484     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 485 )
 486
 487 include_directories (
 488     ${CMAKE_CURRENT_BINARY_DIR}
 489     ${OPENGL_INCLUDE_PATH}
 490 )
 491
 492 add_executable (glretrace
 493     glretrace_gl.cpp
 494     glretrace_cgl.cpp
 495     glretrace_glx.cpp
 496     glretrace_wgl.cpp
 497     glretrace_egl.cpp
 498     glretrace_main.cpp
 499     glstate.cpp
 500     glstate_params.cpp
 501     retrace.cpp
 502     retrace_stdc.cpp
 503     glws.cpp
 504     ${glws_os}
 505     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 506 )
 507
 508 set_property (
 509     TARGET glretrace
 510     APPEND
 511     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 512 )
 513
 514 target_link_libraries (glretrace
 515     common
 516 )
 517
 518 if (WIN32)
 519     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 520 elseif (APPLE)
 521     target_link_libraries (glretrace
 522         "-framework Cocoa"
 523         "-framework ApplicationServices" # CGS*
 524         ${OPENGL_gl_LIBRARY} # CGL*
 525     )
 526 else ()
 527     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 528 endif ()
 529
 530 install (TARGETS glretrace RUNTIME DESTINATION bin)
 531
 532 ##############################################################################
 533 # CLI
 534
 535 add_subdirectory(cli)
 536
 537 ##############################################################################
 538 # Scripts (to support the CLI)
 539
 540 install (PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh DESTINATION ${LIB_INSTALL_DIR}/scripts)
 541 install (PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py DESTINATION ${LIB_INSTALL_DIR}/scripts)
 542
 543 ##############################################################################
 544 # GUI
 545
 546 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 547     add_subdirectory(gui)
 548 endif ()
 549
 550
 551 ##############################################################################
 552 # Packaging
 553
 554 install (
 555     FILES
 556         BUGS.markdown
 557         LICENSE
 558         NEWS.markdown
 559         README.markdown
 560         TODO.markdown
 561     DESTINATION ${DOC_INSTALL_DIR}
 562 )
 563
 564 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 565 set (CPACK_PACKAGE_VERSION_MINOR "0")
 566
 567 # Use current date in YYYYMMDD format as patch number
 568 execute_process (
 569     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 570     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 571 )
 572
 573 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 574 if (WIN32)
 575     set (CPACK_GENERATOR "ZIP")
 576 elseif (APPLE)
 577     set (CPACK_GENERATOR "DragNDrop")
 578 else ()
 579     set (CPACK_GENERATOR "TBZ2")
 580 endif ()
 581
 582 include(CPack)