git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_EGL "AUTO" CACHE STRING "Enable EGL support.")
  21
  22
  23 ##############################################################################
  24 # Find dependencies
  25
  26 include (FindPkgConfig)
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33 find_package (OpenGL REQUIRED)
  34
  35 if (ENABLE_GUI)
  36     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  37         set (REQUIRE_GUI REQUIRED)
  38     endif ()
  39     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  40     find_package (QJSON ${REQUIRE_GUI})
  41 endif ()
  42
  43 include_directories (${OPENGL_INCLUDE_DIR})
  44
  45 if (WIN32)
  46     find_package (DirectX)
  47 elseif (APPLE)
  48 else ()
  49     find_package (X11 REQUIRED)
  50
  51     include_directories (${X11_INCLUDE_DIR})
  52
  53     if (ENABLE_EGL)
  54         if (NOT ENABLE_EGL STREQUAL "AUTO")
  55             set (REQUIRE_EGL REQUIRED)
  56         endif ()
  57         pkg_check_modules (EGL egl glesv1_cm glesv2 ${REQUIRE_EGL})
  58         if (EGL_FOUND)
  59             include_directories (${EGL_INCLUDE_DIR})
  60             add_definitions (-DHAVE_EGL)
  61         endif ()
  62     else ()
  63         set (EGL_FOUND 0)
  64     endif ()
  65 endif ()
  66
  67
  68 ##############################################################################
  69 # Set global build options
  70
  71 include (CheckCXXCompilerFlag)
  72
  73 if (WIN32)
  74     # MSVC & MinGW only define & use APIENTRY
  75     add_definitions (-DGLAPIENTRY=__stdcall)
  76
  77     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  78     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  79 else (WIN32)
  80     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  81     if (CXX_COMPILER_FLAG_VISIBILITY)
  82         add_definitions ("-fvisibility=hidden")
  83     endif (CXX_COMPILER_FLAG_VISIBILITY)
  84 endif (WIN32)
  85
  86 if (MSVC)
  87     # C99 includes for msvc
  88     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  89
  90     # Enable math constants defines
  91     add_definitions (-D_USE_MATH_DEFINES)
  92
  93     # No min/max macros
  94     add_definitions (-DNOMINMAX)
  95
  96     # Adjust warnings
  97     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  98     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  99     add_definitions (-W4)
 100     add_definitions (-wd4063) # not a valid value for switch of enum
 101     add_definitions (-wd4127) # conditional expression is constant
 102     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
 103     add_definitions (-wd4505) # unreferenced local function has been removed
 104     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 105     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 106     add_definitions (-wd4018) # signed/unsigned mismatch
 107
 108     # Use static runtime
 109     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 110     foreach (flag_var
 111         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 112         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 113     )
 114         if (${flag_var} MATCHES "/MD")
 115             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 116         endif (${flag_var} MATCHES "/MD")
 117     endforeach (flag_var)
 118 else ()
 119     # Adjust warnings
 120     add_definitions (-Wall)
 121     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 122     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 123 endif ()
 124
 125 if (MINGW)
 126     # Avoid depending on MinGW runtime DLLs
 127     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 128     if (HAVE_STATIC_LIBGCC_FLAG)
 129         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 130         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 131         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 132     endif ()
 133     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 134     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 135         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 136         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 137         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 138     endif ()
 139 endif ()
 140
 141
 142 # Put all executables into the same top level build directory, regardless of
 143 # which subdirectory they are declared
 144 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 145
 146
 147 ##############################################################################
 148 # Bundled dependencies
 149 #
 150 # We always use the bundled zlib, libpng, and snappy sources:
 151 # - on Windows to make it easy to deploy the wrappers DLLs
 152 # - on unices to prevent symbol collisions when tracing applications that link
 153 # against other versions of these libraries
 154
 155 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 156 set (ZLIB_LIBRARIES z_bundled)
 157 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 158
 159 include_directories (${ZLIB_INCLUDE_DIRS})
 160 link_libraries (${ZLIB_LIBRARIES})
 161
 162 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 163 set (SNAPPY_LIBRARIES snappy_bundled)
 164 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 165
 166 include_directories (${SNAPPY_INCLUDE_DIRS})
 167 link_libraries (${SNAPPY_LIBRARIES})
 168
 169 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 170 set (PNG_DEFINITIONS "")
 171 set (PNG_LIBRARIES png_bundled)
 172
 173 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 174 include_directories (${PNG_INCLUDE_DIR})
 175 add_definitions (${PNG_DEFINITIONS})
 176 link_libraries (${PNG_LIBRARIES})
 177
 178 # The Qt website provides binaries for Windows and MacOSX, and they are
 179 # automatically found by cmake without any manual intervention.  The situation
 180 # for QJSON is substantially different: there are no binaries for QJSON
 181 # available, and there is no standard installation directory that is detected
 182 # by cmake.
 183 #
 184 # By bundling the QJSON source, we make it much more easier to build the GUI on
 185 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 186 # AUTO.
 187 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 188     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 189     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 190     set (QJSON_LIBRARY_DIRS)
 191     set (QJSON_LIBRARIES qjson_bundled)
 192     set (QJSON_FOUND TRUE)
 193 endif ()
 194
 195 # For glext headers
 196 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 197
 198 # For EGL headers
 199 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 200
 201 ##############################################################################
 202 # Installation directories
 203
 204 if (WIN32 OR APPLE)
 205     # On Windows/MacOSX, applications are usually installed on a directory of
 206     # their own
 207     set (DOC_INSTALL_DIR doc)
 208 else ()
 209     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 210 endif ()
 211
 212 set (LIB_INSTALL_DIR lib/apitrace)
 213
 214 if (APPLE)
 215     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 216     # directories
 217     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 218 else ()
 219     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 220 endif ()
 221
 222 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 223 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 224
 225 # Expose the binary/install directories to source
 226 #
 227 # TODO: Use the same directory layout, for both build and install directories,
 228 # so that binaries can find each other using just relative paths.
 229 #
 230 add_definitions(
 231     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 232     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 233     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 234 )
 235
 236
 237 ##############################################################################
 238 # Common libraries / utilities
 239
 240 include_directories (
 241     ${CMAKE_CURRENT_BINARY_DIR}
 242     ${CMAKE_CURRENT_SOURCE_DIR}
 243     ${CMAKE_CURRENT_SOURCE_DIR}/common
 244 )
 245
 246 add_custom_command (
 247     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 248     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 249     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 250 )
 251
 252 if (WIN32)
 253     set (os os_win32.cpp)
 254     set (glws_os glws_wgl.cpp)
 255 else ()
 256     set (os os_posix.cpp)
 257     if (APPLE)
 258         set (glws_os glws_cocoa.mm)
 259     else ()
 260         set (glws_os glws_glx.cpp)
 261     endif ()
 262 endif ()
 263
 264 add_library (common STATIC
 265     common/trace_file.cpp
 266     common/trace_file_read.cpp
 267     common/trace_file_write.cpp
 268     common/trace_file_zlib.cpp
 269     common/trace_file_snappy.cpp
 270     common/trace_model.cpp
 271     common/trace_parser.cpp
 272     common/trace_parser_flags.cpp
 273     common/trace_writer.cpp
 274     common/trace_writer_local.cpp
 275     common/trace_writer_model.cpp
 276     common/trace_loader.cpp
 277     common/trace_resource.cpp
 278     common/trace_tools_trace.cpp
 279     common/image.cpp
 280     common/image_bmp.cpp
 281     common/image_pnm.cpp
 282     common/image_png.cpp
 283     common/${os}
 284 )
 285
 286 set_target_properties (common PROPERTIES
 287     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 288     # Ensure it can be statically linked in shared libraries
 289     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 290 )
 291
 292 link_libraries (common)
 293
 294
 295 ##############################################################################
 296 # API tracers
 297
 298 if (WIN32)
 299     if (MINGW)
 300         # Silence warnings about @nn suffix mismatch
 301         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 302     endif (MINGW)
 303
 304     # ddraw.dll
 305     if (DirectX_D3D_INCLUDE_DIR)
 306         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 307         add_custom_command (
 308             OUTPUT ddrawtrace.cpp
 309             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 310             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 311         )
 312         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 313         set_target_properties (ddraw
 314             PROPERTIES PREFIX ""
 315             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 316             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 317         )
 318         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 319     endif (DirectX_D3D_INCLUDE_DIR)
 320
 321     # d3d8.dll
 322     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 323         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 324         add_custom_command (
 325             OUTPUT d3d8trace.cpp
 326             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 327             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 328         )
 329         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 330         set_target_properties (d3d8
 331             PROPERTIES PREFIX ""
 332             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 333             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 334         )
 335         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 336     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 337
 338     # d3d9.dll
 339     if (DirectX_D3DX9_INCLUDE_DIR)
 340         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 341         add_custom_command (
 342             OUTPUT d3d9trace.cpp
 343             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 344             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 345         )
 346         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 347         set_target_properties (d3d9
 348             PROPERTIES PREFIX ""
 349             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 350             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 351         )
 352         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 353     endif (DirectX_D3DX9_INCLUDE_DIR)
 354
 355     # d3d10.dll
 356     if (DirectX_D3D10_INCLUDE_DIR)
 357         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 358         add_custom_command (
 359             OUTPUT d3d10trace.cpp
 360             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 361             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 362         )
 363         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 364         set_target_properties (d3d10
 365             PROPERTIES PREFIX ""
 366             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 367             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 368         )
 369         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 370     endif (DirectX_D3D10_INCLUDE_DIR)
 371
 372     # opengl32.dll
 373     add_custom_command (
 374         OUTPUT wgltrace.cpp
 375         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 376         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 377     )
 378     add_library (wgltrace MODULE specs/opengl32.def
 379         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 380         wgltrace.cpp
 381         glcaps.cpp
 382         glproc_gl.cpp
 383     )
 384     set_target_properties (wgltrace PROPERTIES
 385         PREFIX ""
 386         OUTPUT_NAME opengl32
 387         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 388         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 389     )
 390     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 391
 392 elseif (APPLE)
 393     # OpenGL framework
 394     add_custom_command (
 395         OUTPUT cgltrace.cpp
 396         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 397         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 398     )
 399
 400     add_library (cgltrace SHARED
 401         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 402         cgltrace.cpp
 403         glcaps.cpp
 404         glproc_gl.cpp
 405     )
 406
 407     set_target_properties (cgltrace PROPERTIES
 408         # OpenGL framework name
 409         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 410         # Specificy the version and reexport GLU symbols
 411         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 412         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 413         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 414     )
 415
 416     target_link_libraries (cgltrace dl)
 417
 418     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 419 else ()
 420     # libGL.so
 421     add_custom_command (
 422         OUTPUT glxtrace.cpp
 423         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 424         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 425     )
 426
 427     add_library (glxtrace SHARED
 428         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 429         glxtrace.cpp
 430         glcaps.cpp
 431         glproc_gl.cpp
 432     )
 433
 434     set_target_properties (glxtrace PROPERTIES
 435         # avoid the default "lib" prefix
 436         PREFIX ""
 437         # Prevent symbol relocations internal to our wrapper library to be
 438         # overwritten by the application.
 439         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 440         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 441         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 442     )
 443
 444     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 445
 446     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 447 endif ()
 448
 449
 450 if (EGL_FOUND)
 451     # libEGL.so/libGL.so
 452     add_custom_command (
 453         OUTPUT egltrace.cpp
 454         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 455         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 456     )
 457
 458     add_library (egltrace SHARED
 459         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 460         egltrace.cpp
 461         glcaps.cpp
 462         glproc_egl.cpp
 463     )
 464
 465     set_property (
 466         TARGET egltrace
 467         APPEND
 468         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 469     )
 470
 471     set_target_properties (egltrace PROPERTIES
 472         # avoid the default "lib" prefix
 473         PREFIX ""
 474         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 475         # Prevent symbol relocations internal to our wrapper library to be
 476         # overwritten by the application.
 477         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 478         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 479     )
 480
 481     target_link_libraries (egltrace dl)
 482
 483     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 484 endif ()
 485
 486 ##############################################################################
 487 # API retracers
 488
 489 add_custom_command (
 490     OUTPUT glretrace_gl.cpp
 491     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 492     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 493 )
 494
 495 add_custom_command (
 496     OUTPUT glstate_params.cpp
 497     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 498     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 499 )
 500
 501 set (retrace_sources
 502     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 503     glretrace_gl.cpp
 504     glretrace_cgl.cpp
 505     glretrace_glx.cpp
 506     glretrace_wgl.cpp
 507     glretrace_egl.cpp
 508     glretrace_main.cpp
 509     glstate.cpp
 510     glstate_params.cpp
 511     retrace.cpp
 512     retrace_stdc.cpp
 513     glws.cpp
 514 )
 515
 516 add_executable (glretrace
 517     ${retrace_sources}
 518     ${glws_os}
 519     glproc_gl.cpp
 520 )
 521
 522 set_property (
 523     TARGET glretrace
 524     APPEND
 525     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 526 )
 527
 528 target_link_libraries (glretrace
 529     common
 530 )
 531
 532 if (WIN32)
 533 else ()
 534     if (APPLE)
 535         target_link_libraries (glretrace
 536             "-framework Cocoa"
 537             "-framework ApplicationServices" # CGS*
 538             ${OPENGL_gl_LIBRARY} # CGL*
 539         )
 540     else ()
 541         target_link_libraries (glretrace ${X11_X11_LIB})
 542     endif ()
 543
 544     # gdb doesn't like when pthreads is loaded through dlopen (which happens
 545     # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
 546     # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
 547     target_link_libraries (glretrace pthread)
 548 endif ()
 549
 550 install (TARGETS glretrace RUNTIME DESTINATION bin)
 551
 552 if (EGL_FOUND AND NOT WIN32 AND NOT APPLE)
 553     add_executable (eglretrace
 554         ${retrace_sources}
 555         glws_egl_xlib.cpp
 556         glproc_egl.cpp
 557     )
 558
 559     set_property (
 560         TARGET eglretrace
 561         APPEND
 562         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 563         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 564     )
 565
 566     target_link_libraries (eglretrace
 567         common
 568         ${X11_X11_LIB}
 569         pthread
 570     )
 571
 572     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 573 endif ()
 574
 575 ##############################################################################
 576 # CLI
 577
 578 add_subdirectory(cli)
 579
 580 ##############################################################################
 581 # Scripts (to support the CLI)
 582
 583 install (
 584     PROGRAMS
 585         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh
 586         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 587         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 588     DESTINATION ${SCRIPTS_INSTALL_DIR}
 589 )
 590
 591 ##############################################################################
 592 # GUI
 593
 594 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 595     add_subdirectory(gui)
 596 endif ()
 597
 598
 599 ##############################################################################
 600 # Packaging
 601
 602 install (
 603     FILES
 604         BUGS.markdown
 605         LICENSE
 606         NEWS.markdown
 607         README.markdown
 608         TODO.markdown
 609     DESTINATION ${DOC_INSTALL_DIR}
 610 )
 611
 612 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 613 set (CPACK_PACKAGE_VERSION_MINOR "0")
 614
 615 # Use current date in YYYYMMDD format as patch number
 616 execute_process (
 617     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 618     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 619 )
 620
 621 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 622 if (WIN32)
 623     set (CPACK_GENERATOR "ZIP")
 624 elseif (APPLE)
 625     set (CPACK_GENERATOR "DragNDrop")
 626 else ()
 627     set (CPACK_GENERATOR "TBZ2")
 628 endif ()
 629
 630 include(CPack)