git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20 set (ENABLE_CLI true CACHE BOOL "Enable command Line interface.")
  21
  22 set (ENABLE_EGL true CACHE BOOL "Enable EGL support.")
  23
  24
  25 ##############################################################################
  26 # Find dependencies
  27
  28 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  29
  30 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  31
  32 find_package (PythonInterp REQUIRED)
  33
  34 find_package (Threads)
  35
  36 if (ENABLE_GUI)
  37     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  38         set (REQUIRE_GUI REQUIRED)
  39     endif ()
  40     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  41     find_package (QJSON ${REQUIRE_GUI})
  42 endif ()
  43
  44 if (WIN32)
  45     find_package (DirectX)
  46     set (ENABLE_EGL false)
  47 elseif (APPLE)
  48     set (ENABLE_EGL false)
  49 else ()
  50     find_package (X11)
  51
  52     if (X11_FOUND)
  53         include_directories (${X11_INCLUDE_DIR})
  54         add_definitions (-DHAVE_X11)
  55     endif ()
  56
  57     if (ENABLE_EGL)
  58         add_definitions (-DHAVE_EGL)
  59     endif ()
  60 endif ()
  61
  62
  63 ##############################################################################
  64 # Set global build options
  65
  66 include (CheckCXXCompilerFlag)
  67
  68 if (WIN32)
  69     # MSVC & MinGW only define & use APIENTRY
  70     add_definitions (-DGLAPIENTRY=__stdcall)
  71
  72     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  73     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  74 else (WIN32)
  75     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  76     if (CXX_COMPILER_FLAG_VISIBILITY)
  77         add_definitions ("-fvisibility=hidden")
  78     endif (CXX_COMPILER_FLAG_VISIBILITY)
  79 endif (WIN32)
  80
  81 if (MSVC)
  82     # C99 includes for msvc
  83     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  84
  85     # Enable math constants defines
  86     add_definitions (-D_USE_MATH_DEFINES)
  87
  88     # No min/max macros
  89     add_definitions (-DNOMINMAX)
  90
  91     # Adjust warnings
  92     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  93     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  94     add_definitions (-W4)
  95     add_definitions (-wd4063) # not a valid value for switch of enum
  96     add_definitions (-wd4127) # conditional expression is constant
  97     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  98     add_definitions (-wd4505) # unreferenced local function has been removed
  99     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
 100     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 101     add_definitions (-wd4018) # signed/unsigned mismatch
 102
 103     # Use static runtime
 104     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
 105     foreach (flag_var
 106         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 107         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 108     )
 109         if (${flag_var} MATCHES "/MD")
 110             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 111         endif (${flag_var} MATCHES "/MD")
 112     endforeach (flag_var)
 113 else ()
 114     # Adjust warnings
 115     add_definitions (-Wall)
 116     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 117     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 118 endif ()
 119
 120 if (MINGW)
 121     # Avoid depending on MinGW runtime DLLs
 122     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 123     if (HAVE_STATIC_LIBGCC_FLAG)
 124         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 125         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 126         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 127     endif ()
 128     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 129     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 130         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 131         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 132         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 133     endif ()
 134 endif ()
 135
 136
 137 # Put all executables into the same top level build directory, regardless of
 138 # which subdirectory they are declared
 139 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 140
 141
 142 ##############################################################################
 143 # Bundled dependencies
 144 #
 145 # We always use the bundled zlib, libpng, and snappy sources:
 146 # - on Windows to make it easy to deploy the wrappers DLLs
 147 # - on unices to prevent symbol collisions when tracing applications that link
 148 # against other versions of these libraries
 149
 150 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 151 set (ZLIB_LIBRARIES z_bundled)
 152 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 153
 154 include_directories (${ZLIB_INCLUDE_DIRS})
 155 link_libraries (${ZLIB_LIBRARIES})
 156
 157 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 158 set (SNAPPY_LIBRARIES snappy_bundled)
 159 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 160
 161 include_directories (${SNAPPY_INCLUDE_DIRS})
 162 link_libraries (${SNAPPY_LIBRARIES})
 163
 164 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 165 set (PNG_DEFINITIONS "")
 166 set (PNG_LIBRARIES png_bundled)
 167
 168 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 169 include_directories (${PNG_INCLUDE_DIR})
 170 add_definitions (${PNG_DEFINITIONS})
 171 link_libraries (${PNG_LIBRARIES})
 172
 173 if (MSVC)
 174     add_subdirectory (thirdparty/getopt EXCLUDE_FROM_ALL)
 175     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/getopt)
 176     set (GETOPT_LIBRARIES getopt_bundled)
 177 endif ()
 178
 179 # The Qt website provides binaries for Windows and MacOSX, and they are
 180 # automatically found by cmake without any manual intervention.  The situation
 181 # for QJSON is substantially different: there are no binaries for QJSON
 182 # available, and there is no standard installation directory that is detected
 183 # by cmake.
 184 #
 185 # By bundling the QJSON source, we make it much more easier to build the GUI on
 186 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 187 # AUTO.
 188 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 189     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 190     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 191     set (QJSON_LIBRARY_DIRS)
 192     set (QJSON_LIBRARIES qjson_bundled)
 193     set (QJSON_FOUND TRUE)
 194 endif ()
 195
 196 # We use bundled headers for all Khronos APIs, to guarantee support for both
 197 # OpenGL and OpenGL ES at build time, because the OpenGL and OpenGL ES 1 APIs
 198 # are so intertwined that conditional compilation extremely difficult. This
 199 # also avoids missing/inconsistent declarations in system headers.
 200 include_directories (BEFORE ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khronos)
 201
 202 ##############################################################################
 203 # Installation directories
 204
 205 if (WIN32 OR APPLE)
 206     # On Windows/MacOSX, applications are usually installed on a directory of
 207     # their own
 208     set (DOC_INSTALL_DIR doc)
 209     set (LIB_INSTALL_DIR lib)
 210 else ()
 211     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 212     set (LIB_INSTALL_DIR lib/${CMAKE_PROJECT_NAME})
 213 endif ()
 214
 215 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 216 set(WRAPPER_INSTALL_DIR ${LIB_INSTALL_DIR}/wrappers)
 217
 218 # Expose the binary/install directories to source
 219 #
 220 # TODO: Use the same directory layout, for both build and install directories,
 221 # so that binaries can find each other using just relative paths.
 222 #
 223 add_definitions(
 224     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 225     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 226     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 227 )
 228
 229
 230 ##############################################################################
 231 # Common libraries / utilities
 232
 233 include_directories (
 234     ${CMAKE_CURRENT_BINARY_DIR}
 235     ${CMAKE_CURRENT_SOURCE_DIR}
 236     ${CMAKE_CURRENT_SOURCE_DIR}/common
 237 )
 238
 239 add_custom_command (
 240     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 241     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 242     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 243 )
 244
 245 # Wrap glproc.hpp as a target to prevent the command from being executed
 246 # multiple times simulatenously, when the targets that depend on it are built
 247 # in parallel.
 248 add_custom_target (glproc DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 249
 250 if (WIN32)
 251     set (os os_win32.cpp)
 252     set (glws_os glws_wgl.cpp)
 253 else ()
 254     set (os os_posix.cpp)
 255     if (APPLE)
 256         set (glws_os glws_cocoa.mm)
 257     else ()
 258         set (glws_os glws_glx.cpp)
 259     endif ()
 260 endif ()
 261
 262 add_library (common STATIC
 263     common/trace_callset.cpp
 264     common/trace_dump.cpp
 265     common/trace_file.cpp
 266     common/trace_file_read.cpp
 267     common/trace_file_write.cpp
 268     common/trace_file_zlib.cpp
 269     common/trace_file_snappy.cpp
 270     common/trace_model.cpp
 271     common/trace_parser.cpp
 272     common/trace_parser_flags.cpp
 273     common/trace_writer.cpp
 274     common/trace_writer_local.cpp
 275     common/trace_writer_model.cpp
 276     common/trace_loader.cpp
 277     common/trace_resource.cpp
 278     common/trace_tools_trace.cpp
 279     common/image.cpp
 280     common/image_bmp.cpp
 281     common/image_pnm.cpp
 282     common/image_png.cpp
 283     common/${os}
 284 )
 285
 286 set_target_properties (common PROPERTIES
 287     COMPILE_DEFINITIONS APITRACE_SOURCE_DIR="${CMAKE_SOURCE_DIR}"
 288     # Ensure it can be statically linked in shared libraries
 289     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 290 )
 291
 292 link_libraries (common)
 293
 294
 295 ##############################################################################
 296 # API tracers
 297
 298 if (WIN32)
 299     if (MINGW)
 300         # Silence warnings about @nn suffix mismatch
 301         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 302     endif (MINGW)
 303
 304     # ddraw.dll
 305     if (DirectX_D3D_INCLUDE_DIR)
 306         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 307         add_custom_command (
 308             OUTPUT ddrawtrace.cpp
 309             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 310             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 311         )
 312         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 313         set_target_properties (ddraw
 314             PROPERTIES PREFIX ""
 315             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 316             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 317         )
 318         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 319     endif (DirectX_D3D_INCLUDE_DIR)
 320
 321     # d3d8.dll
 322     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 323         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 324         add_custom_command (
 325             OUTPUT d3d8trace.cpp
 326             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 327             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 328         )
 329         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 330         set_target_properties (d3d8
 331             PROPERTIES PREFIX ""
 332             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 333             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 334         )
 335         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 336     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 337
 338     # d3d9.dll
 339     if (DirectX_D3DX9_INCLUDE_DIR)
 340         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 341         add_custom_command (
 342             OUTPUT d3d9trace.cpp
 343             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 344             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 345         )
 346         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 347         set_target_properties (d3d9
 348             PROPERTIES PREFIX ""
 349             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 350             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 351         )
 352         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 353     endif (DirectX_D3DX9_INCLUDE_DIR)
 354
 355     # d3d10.dll
 356     if (DirectX_D3D10_INCLUDE_DIR)
 357         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 358         add_custom_command (
 359             OUTPUT d3d10trace.cpp
 360             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 361             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 362         )
 363         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 364         set_target_properties (d3d10
 365             PROPERTIES PREFIX ""
 366             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 367             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 368         )
 369         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 370     endif (DirectX_D3D10_INCLUDE_DIR)
 371
 372     # opengl32.dll
 373     add_custom_command (
 374         OUTPUT wgltrace.cpp
 375         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 376         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 377     )
 378     add_library (wgltrace MODULE specs/opengl32.def
 379         wgltrace.cpp
 380         glcaps.cpp
 381         glproc_gl.cpp
 382     )
 383     add_dependencies (wgltrace glproc)
 384     set_target_properties (wgltrace PROPERTIES
 385         PREFIX ""
 386         OUTPUT_NAME opengl32
 387         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 388         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 389     )
 390     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 391
 392 elseif (APPLE)
 393     # OpenGL framework
 394     add_custom_command (
 395         OUTPUT cgltrace.cpp
 396         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 397         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 398     )
 399
 400     add_library (cgltrace SHARED
 401         cgltrace.cpp
 402         glcaps.cpp
 403         glproc_gl.cpp
 404     )
 405
 406     add_dependencies (cgltrace glproc)
 407
 408     set_target_properties (cgltrace PROPERTIES
 409         # OpenGL framework name
 410         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 411         # Specificy the version and reexport GLU symbols
 412         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 413         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 414         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 415     )
 416
 417     target_link_libraries (cgltrace
 418         ${CMAKE_THREAD_LIBS_INIT}
 419         dl
 420     )
 421
 422     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 423 elseif (X11_FOUND)
 424     # libGL.so
 425     add_custom_command (
 426         OUTPUT glxtrace.cpp
 427         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 428         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 429     )
 430
 431     add_library (glxtrace SHARED
 432         glxtrace.cpp
 433         glcaps.cpp
 434         glproc_gl.cpp
 435     )
 436
 437     add_dependencies (glxtrace glproc)
 438
 439     set_target_properties (glxtrace PROPERTIES
 440         # avoid the default "lib" prefix
 441         PREFIX ""
 442         # Prevent symbol relocations internal to our wrapper library to be
 443         # overwritten by the application.
 444         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 445         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 446         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 447     )
 448
 449     target_link_libraries (glxtrace
 450         ${X11_X11_LIB}
 451         ${CMAKE_THREAD_LIBS_INIT}
 452         dl
 453     )
 454
 455     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 456 endif ()
 457
 458
 459 if (ENABLE_EGL AND NOT WIN32 AND NOT APPLE)
 460     # libEGL.so/libGL.so
 461     add_custom_command (
 462         OUTPUT egltrace.cpp
 463         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/egltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/egltrace.cpp
 464         DEPENDS egltrace.py gltrace.py trace.py specs/eglapi.py specs/glesapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 465     )
 466
 467     add_library (egltrace SHARED
 468         egltrace.cpp
 469         glcaps.cpp
 470         glproc_egl.cpp
 471     )
 472
 473     add_dependencies (egltrace glproc)
 474
 475     set_property (
 476         TARGET egltrace
 477         APPEND
 478         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 479     )
 480
 481     set_target_properties (egltrace PROPERTIES
 482         # avoid the default "lib" prefix
 483         PREFIX ""
 484         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 485         # Prevent symbol relocations internal to our wrapper library to be
 486         # overwritten by the application.
 487         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 488         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 489     )
 490
 491     target_link_libraries (egltrace
 492         ${CMAKE_THREAD_LIBS_INIT}
 493         dl
 494     )
 495
 496     install (TARGETS egltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 497 endif ()
 498
 499 ##############################################################################
 500 # API retracers
 501
 502 add_custom_command (
 503     OUTPUT glretrace_gl.cpp
 504     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 505     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 506 )
 507
 508 add_custom_command (
 509     OUTPUT glstate_params.cpp
 510     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 511     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 512 )
 513
 514 set (retrace_sources
 515     glretrace_gl.cpp
 516     glretrace_cgl.cpp
 517     glretrace_glx.cpp
 518     glretrace_wgl.cpp
 519     glretrace_egl.cpp
 520     glretrace_main.cpp
 521     glstate.cpp
 522     glstate_params.cpp
 523     retrace.cpp
 524     retrace_stdc.cpp
 525     glws.cpp
 526 )
 527
 528 if (WIN32 OR APPLE OR X11_FOUND)
 529     add_executable (glretrace
 530         ${retrace_sources}
 531         ${glws_os}
 532         glproc_gl.cpp
 533     )
 534
 535     add_dependencies (glretrace glproc)
 536
 537     set_property (
 538         TARGET glretrace
 539         APPEND
 540         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 541     )
 542
 543     target_link_libraries (glretrace
 544         common
 545     )
 546
 547     if (WIN32)
 548     else ()
 549         if (APPLE)
 550             target_link_libraries (glretrace
 551                 "-framework Cocoa"
 552                 "-framework ApplicationServices" # CGS*
 553                 #"-framework OpenGL" # CGL*
 554             )
 555         else ()
 556             target_link_libraries (glretrace ${X11_X11_LIB})
 557         endif ()
 558
 559         target_link_libraries (glretrace
 560             # gdb doesn't like when pthreads is loaded through dlopen (which happens
 561             # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
 562             # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
 563             ${CMAKE_THREAD_LIBS_INIT}
 564             dl
 565         )
 566
 567         if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 568             target_link_libraries (glretrace rt)
 569         endif ()
 570
 571     endif ()
 572
 573     install (TARGETS glretrace RUNTIME DESTINATION bin)
 574 endif ()
 575
 576 if (ENABLE_EGL AND X11_FOUND AND NOT WIN32 AND NOT APPLE)
 577     add_executable (eglretrace
 578         ${retrace_sources}
 579         glws_egl_xlib.cpp
 580         glproc_egl.cpp
 581     )
 582
 583     add_dependencies (eglretrace glproc)
 584
 585     set_property (
 586         TARGET eglretrace
 587         APPEND
 588         PROPERTY COMPILE_DEFINITIONS "RETRACE"
 589         PROPERTY COMPILE_DEFINITIONS "TRACE_EGL"
 590     )
 591
 592     target_link_libraries (eglretrace
 593         common
 594         ${X11_X11_LIB}
 595         ${CMAKE_THREAD_LIBS_INIT}
 596         dl
 597     )
 598
 599     if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 600         target_link_libraries (eglretrace rt)
 601     endif ()
 602
 603     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 604 endif ()
 605
 606 ##############################################################################
 607 # CLI
 608
 609 if (ENABLE_CLI)
 610     add_subdirectory(cli)
 611 endif ()
 612
 613 ##############################################################################
 614 # Scripts (to support the CLI)
 615
 616 install (
 617     PROGRAMS
 618         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.py
 619         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py
 620         ${CMAKE_CURRENT_SOURCE_DIR}/scripts/snapdiff.py
 621     DESTINATION ${SCRIPTS_INSTALL_DIR}
 622 )
 623
 624 ##############################################################################
 625 # GUI
 626
 627 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 628     add_subdirectory(gui)
 629 endif ()
 630
 631
 632 ##############################################################################
 633 # Packaging
 634
 635 install (
 636     FILES
 637         BUGS.markdown
 638         LICENSE
 639         NEWS.markdown
 640         README.markdown
 641     DESTINATION ${DOC_INSTALL_DIR}
 642 )
 643
 644 set (CPACK_PACKAGE_VERSION_MAJOR "3")
 645 set (CPACK_PACKAGE_VERSION_MINOR "0")
 646
 647 # Use current date in YYYYMMDD format as patch number
 648 execute_process (
 649     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 650     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 651 )
 652
 653 # cpack mistakenly detects Mingw-w64 as win32
 654 if (MINGW)
 655     if (CMAKE_SIZEOF_VOID_P EQUAL 8)
 656         set (CPACK_SYSTEM_NAME win64)
 657     endif ()
 658 endif ()
 659
 660 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 661 if (WIN32)
 662     set (CPACK_GENERATOR "ZIP")
 663 elseif (APPLE)
 664     set (CPACK_GENERATOR "DragNDrop")
 665 else ()
 666     set (CPACK_GENERATOR "TBZ2")
 667 endif ()
 668
 669 include(CPack)