git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Options
   8
   9 # On Mac OS X build fat binaries with i386 and x86_64 architectures by default.
  10 if (APPLE AND NOT CMAKE_OSX_ARCHITECTURES)
  11     set (CMAKE_OSX_ARCHITECTURES "i386;x86_64" CACHE STRING "Build architectures for OSX" FORCE)
  12 endif ()
  13
  14 # We use a cached string variable instead of the standard (boolean) OPTION
  15 # command so that we can default to auto-detecting optional depencies, while
  16 # still providing a mechanism to force/disable these optional dependencies, as
  17 # prescribed in http://www.gentoo.org/proj/en/qa/automagic.xml
  18 set (ENABLE_GUI "AUTO" CACHE STRING "Enable Qt GUI.")
  19
  20
  21 ##############################################################################
  22 # Find dependencies
  23
  24 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  25
  26 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  27
  28 find_package (PythonInterp REQUIRED)
  29 find_package (OpenGL REQUIRED)
  30
  31 if (ENABLE_GUI)
  32     if (NOT (ENABLE_GUI STREQUAL "AUTO"))
  33         set (REQUIRE_GUI REQUIRED)
  34     endif ()
  35     find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit ${REQUIRE_GUI})
  36     find_package (QJSON ${REQUIRE_GUI})
  37 endif ()
  38
  39 if (WIN32)
  40     find_package (DirectX)
  41 elseif (APPLE)
  42 else ()
  43     find_package (X11 REQUIRED)
  44
  45     set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  46     set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  47
  48     include_directories (${X11_INCLUDE_DIR})
  49 endif ()
  50
  51
  52 ##############################################################################
  53 # Set global build options
  54
  55 include (CheckCXXCompilerFlag)
  56
  57 if (WIN32)
  58     # MSVC & MinGW only define & use APIENTRY
  59     add_definitions (-DGLAPIENTRY=__stdcall)
  60
  61     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  62     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  63 else (WIN32)
  64     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  65     if (CXX_COMPILER_FLAG_VISIBILITY)
  66         add_definitions ("-fvisibility=hidden")
  67     endif (CXX_COMPILER_FLAG_VISIBILITY)
  68 endif (WIN32)
  69
  70 if (MSVC)
  71     # C99 includes for msvc
  72     include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/msvc)
  73
  74     # Enable math constants defines
  75     add_definitions (-D_USE_MATH_DEFINES)
  76
  77     # No min/max macros
  78     add_definitions (-DNOMINMAX)
  79
  80     # Adjust warnings
  81     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  82     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  83     add_definitions (-W4)
  84     add_definitions (-wd4063) # not a valid value for switch of enum
  85     add_definitions (-wd4127) # conditional expression is constant
  86     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  87     add_definitions (-wd4505) # unreferenced local function has been removed
  88     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  89     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  90     add_definitions (-wd4018) # signed/unsigned mismatch
  91
  92     # Use static runtime
  93     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  94     foreach (flag_var
  95         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  96         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
  97     )
  98         if (${flag_var} MATCHES "/MD")
  99             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 100         endif (${flag_var} MATCHES "/MD")
 101     endforeach (flag_var)
 102 else ()
 103     # Adjust warnings
 104     add_definitions (-Wall)
 105     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 106     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 107 endif ()
 108
 109 if (MINGW)
 110     # Avoid depending on MinGW runtime DLLs
 111     check_cxx_compiler_flag (-static-libgcc HAVE_STATIC_LIBGCC_FLAG)
 112     if (HAVE_STATIC_LIBGCC_FLAG)
 113         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libgcc")
 114         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libgcc")
 115         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libgcc")
 116     endif ()
 117     check_cxx_compiler_flag (-static-libstdc++ HAVE_STATIC_LIBSTDCXX_FLAG)
 118     if (HAVE_STATIC_LIBSTDCXX_FLAG)
 119         set (CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static-libstdc++")
 120         set (CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -static-libstdc++")
 121         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -static-libstdc++")
 122     endif ()
 123 endif ()
 124
 125
 126 # Put all executables into the same top level build directory, regardless of
 127 # which subdirectory they are declared
 128 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 129
 130
 131 ##############################################################################
 132 # Bundled dependencies
 133 #
 134 # We always use the bundled zlib, libpng, and snappy sources:
 135 # - on Windows to make it easy to deploy the wrappers DLLs
 136 # - on unices to prevent symbol collisions when tracing applications that link
 137 # against other versions of these libraries
 138
 139 set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/zlib)
 140 set (ZLIB_LIBRARIES z_bundled)
 141 add_subdirectory (thirdparty/zlib EXCLUDE_FROM_ALL)
 142
 143 include_directories (${ZLIB_INCLUDE_DIRS})
 144 link_libraries (${ZLIB_LIBRARIES})
 145
 146 set (SNAPPY_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/snappy)
 147 set (SNAPPY_LIBRARIES snappy_bundled)
 148 add_subdirectory (thirdparty/snappy EXCLUDE_FROM_ALL)
 149
 150 include_directories (${SNAPPY_INCLUDE_DIRS})
 151 link_libraries (${SNAPPY_LIBRARIES})
 152
 153 set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/libpng)
 154 set (PNG_DEFINITIONS "")
 155 set (PNG_LIBRARIES png_bundled)
 156
 157 add_subdirectory (thirdparty/libpng EXCLUDE_FROM_ALL)
 158 include_directories (${PNG_INCLUDE_DIR})
 159 add_definitions (${PNG_DEFINITIONS})
 160 link_libraries (${PNG_LIBRARIES})
 161
 162 # The Qt website provides binaries for Windows and MacOSX, and they are
 163 # automatically found by cmake without any manual intervention.  The situation
 164 # for QJSON is substantially different: there are no binaries for QJSON
 165 # available, and there is no standard installation directory that is detected
 166 # by cmake.
 167 #
 168 # By bundling the QJSON source, we make it much more easier to build the GUI on
 169 # Windows and MacOSX.  But we only use the bundled sources when ENABLE_GUI is
 170 # AUTO.
 171 if (QT4_FOUND AND NOT QJSON_FOUND AND (ENABLE_GUI STREQUAL "AUTO"))
 172     add_subdirectory (thirdparty/qjson EXCLUDE_FROM_ALL)
 173     set (QJSON_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/qjson)
 174     set (QJSON_LIBRARY_DIRS)
 175     set (QJSON_LIBRARIES qjson_bundled)
 176     set (QJSON_FOUND TRUE)
 177 endif ()
 178
 179 # For glext headers
 180 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty)
 181
 182 # For EGL headers
 183 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/thirdparty/khr)
 184
 185 ##############################################################################
 186 # Installation directories
 187
 188 if (WIN32 OR APPLE)
 189     # On Windows/MacOSX, applications are usually installed on a directory of
 190     # their own
 191     set (DOC_INSTALL_DIR doc)
 192 else ()
 193     set (DOC_INSTALL_DIR share/doc/${CMAKE_PROJECT_NAME})
 194 endif ()
 195
 196 set (LIB_INSTALL_DIR lib/apitrace)
 197
 198 if (APPLE)
 199     # MacOSX uses fat binaries, so no need to have per-architecture wrapper
 200     # directories
 201     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR})
 202 else ()
 203     set (LIB_ARCH_INSTALL_DIR ${LIB_INSTALL_DIR}/${CMAKE_SYSTEM_PROCESSOR})
 204 endif ()
 205
 206 set(SCRIPTS_INSTALL_DIR ${LIB_INSTALL_DIR}/scripts)
 207 set(WRAPPER_INSTALL_DIR ${LIB_ARCH_INSTALL_DIR}/wrappers)
 208
 209 # Expose the binary/install directories to source
 210 #
 211 # TODO: Use the same directory layout, for both build and install directories,
 212 # so that binaries can find each other using just relative paths.
 213 #
 214 add_definitions(
 215     -DAPITRACE_BINARY_DIR="${CMAKE_BINARY_DIR}"
 216     -DAPITRACE_INSTALL_PREFIX="${CMAKE_INSTALL_PREFIX}"
 217     -DAPITRACE_SCRIPTS_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${SCRIPTS_INSTALL_DIR}"
 218     -DAPITRACE_WRAPPER_INSTALL_DIR="${CMAKE_INSTALL_PREFIX}/${WRAPPER_INSTALL_DIR}"
 219 )
 220
 221
 222 ##############################################################################
 223 # Common libraries / utilities
 224
 225 include_directories (
 226     ${CMAKE_CURRENT_SOURCE_DIR}
 227     ${CMAKE_CURRENT_SOURCE_DIR}/common
 228 )
 229
 230 add_custom_command (
 231     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 232     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 233     DEPENDS glproc.py dispatch.py specs/wglapi.py specs/glxapi.py specs/cglapi.py specs/eglapi.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 234 )
 235
 236 if (WIN32)
 237     set (os os_win32.cpp)
 238     set (glws_os glws_wgl.cpp)
 239 else ()
 240     set (os os_posix.cpp)
 241     if (APPLE)
 242         set (glws_os glws_cocoa.mm)
 243     else ()
 244         set (glws_os glws_glx.cpp)
 245     endif ()
 246 endif ()
 247
 248 add_library (common STATIC
 249     common/trace_file.cpp
 250     common/trace_file_zlib.cpp
 251     common/trace_file_snappy.cpp
 252     common/trace_model.cpp
 253     common/trace_parser.cpp
 254     common/trace_writer.cpp
 255     common/trace_writer_local.cpp
 256     common/trace_writer_model.cpp
 257     common/trace_loader.cpp
 258     common/trace_tools_trace.cpp
 259     common/image.cpp
 260     common/image_bmp.cpp
 261     common/image_pnm.cpp
 262     common/image_png.cpp
 263     common/${os}
 264 )
 265
 266 set_target_properties (common PROPERTIES
 267     # Ensure it can be statically linked in shared libraries
 268     COMPILE_FLAGS "${CMAKE_SHARED_LIBRARY_CXX_FLAGS}"
 269 )
 270
 271 link_libraries (common)
 272
 273
 274 ##############################################################################
 275 # API tracers
 276
 277 if (WIN32)
 278     if (MINGW)
 279         # Silence warnings about @nn suffix mismatch
 280         set (CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--enable-stdcall-fixup")
 281     endif (MINGW)
 282
 283     # ddraw.dll
 284     if (DirectX_D3D_INCLUDE_DIR)
 285         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 286         add_custom_command (
 287             OUTPUT ddrawtrace.cpp
 288             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/ddrawtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/ddrawtrace.cpp
 289             DEPENDS ddrawtrace.py trace.py specs/d3d.py specs/d3dtypes.py specs/d3dcaps.py specs/ddraw.py specs/winapi.py specs/stdapi.py
 290         )
 291         add_library (ddraw MODULE specs/ddraw.def ddrawtrace.cpp)
 292         set_target_properties (ddraw
 293             PROPERTIES PREFIX ""
 294             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 295             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 296         )
 297         install (TARGETS ddraw LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 298     endif (DirectX_D3D_INCLUDE_DIR)
 299
 300     # d3d8.dll
 301     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 302         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 303         add_custom_command (
 304             OUTPUT d3d8trace.cpp
 305             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8trace.cpp
 306             DEPENDS d3d8trace.py trace.py specs/d3d8.py specs/d3d8types.py specs/d3d8caps.py specs/winapi.py specs/stdapi.py
 307         )
 308         add_library (d3d8 MODULE specs/d3d8.def d3d8trace.cpp d3dshader.cpp)
 309         set_target_properties (d3d8
 310             PROPERTIES PREFIX ""
 311             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 312             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 313         )
 314         install (TARGETS d3d8 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 315     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 316
 317     # d3d9.dll
 318     if (DirectX_D3DX9_INCLUDE_DIR)
 319         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 320         add_custom_command (
 321             OUTPUT d3d9trace.cpp
 322             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9trace.cpp
 323             DEPENDS d3d9trace.py trace.py specs/d3d9.py specs/d3d9types.py specs/d3d9caps.py specs/winapi.py specs/stdapi.py
 324         )
 325         add_library (d3d9 MODULE specs/d3d9.def d3d9trace.cpp d3dshader.cpp)
 326         set_target_properties (d3d9
 327             PROPERTIES PREFIX ""
 328             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 329             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 330         )
 331         install (TARGETS d3d9 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 332     endif (DirectX_D3DX9_INCLUDE_DIR)
 333
 334     # d3d10.dll
 335     if (DirectX_D3D10_INCLUDE_DIR)
 336         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 337         add_custom_command (
 338             OUTPUT d3d10trace.cpp
 339             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10trace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10trace.cpp
 340             DEPENDS d3d10trace.py trace.py specs/d3d10misc.py specs/d3d10.py specs/dxgi.py specs/dxgitype.py specs/dxgiformat.py specs/winapi.py specs/stdapi.py
 341         )
 342         add_library (d3d10 MODULE specs/d3d10.def d3d10trace.cpp)
 343         set_target_properties (d3d10
 344             PROPERTIES PREFIX ""
 345             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 346             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 347         )
 348         install (TARGETS d3d10 LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 349     endif (DirectX_D3D10_INCLUDE_DIR)
 350
 351     # opengl32.dll
 352     add_custom_command (
 353         OUTPUT wgltrace.cpp
 354         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 355         DEPENDS wgltrace.py gltrace.py trace.py specs/wglapi.py specs/wglenum.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/winapi.py specs/stdapi.py
 356     )
 357     add_library (wgltrace MODULE specs/opengl32.def
 358         wgltrace.cpp
 359         glcaps.cpp
 360         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 361     )
 362     set_target_properties (wgltrace PROPERTIES
 363         PREFIX ""
 364         OUTPUT_NAME opengl32
 365         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 366         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 367     )
 368     install (TARGETS wgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 369
 370 elseif (APPLE)
 371     # OpenGL framework
 372     add_custom_command (
 373         OUTPUT cgltrace.cpp
 374         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 375         DEPENDS cgltrace.py gltrace.py trace.py specs/cglapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 376     )
 377
 378     add_library (cgltrace SHARED
 379         cgltrace.cpp
 380         glcaps.cpp
 381         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 382     )
 383
 384     set_target_properties (cgltrace PROPERTIES
 385         # OpenGL framework name
 386         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 387         # Specificy the version and reexport GLU symbols
 388         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 389         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 390         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 391     )
 392
 393     target_link_libraries (cgltrace dl)
 394
 395     install (TARGETS cgltrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 396 else ()
 397     # libGL.so
 398     add_custom_command (
 399         OUTPUT glxtrace.cpp
 400         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 401         DEPENDS glxtrace.py gltrace.py trace.py specs/glxapi.py specs/glapi.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 402     )
 403
 404     add_library (glxtrace SHARED
 405         ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 406         glxtrace.cpp
 407         glcaps.cpp
 408         glsnapshot.cpp
 409     )
 410
 411     set_target_properties (glxtrace PROPERTIES
 412         # avoid the default "lib" prefix
 413         PREFIX ""
 414         # Prevent symbol relocations internal to our wrapper library to be
 415         # overwritten by the application.
 416         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 417         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 418         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 419     )
 420
 421     target_link_libraries (glxtrace dl ${X11_X11_LIB})
 422
 423     install (TARGETS glxtrace LIBRARY DESTINATION ${WRAPPER_INSTALL_DIR})
 424 endif ()
 425
 426
 427 ##############################################################################
 428 # API retracers
 429
 430 add_custom_command (
 431     OUTPUT glretrace_gl.cpp
 432     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 433     DEPENDS glretrace.py retrace.py specs/glapi.py specs/gltypes.py specs/stdapi.py
 434 )
 435
 436 add_custom_command (
 437     OUTPUT glstate_params.cpp
 438     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 439     DEPENDS glstate.py specs/glparams.py specs/gltypes.py specs/stdapi.py
 440 )
 441
 442 include_directories (
 443     ${CMAKE_CURRENT_BINARY_DIR}
 444     ${OPENGL_INCLUDE_PATH}
 445 )
 446
 447 add_executable (glretrace
 448     glretrace_gl.cpp
 449     glretrace_cgl.cpp
 450     glretrace_glx.cpp
 451     glretrace_wgl.cpp
 452     glretrace_main.cpp
 453     glstate.cpp
 454     glstate_params.cpp
 455     retrace.cpp
 456     retrace_stdc.cpp
 457     glws.cpp
 458     ${glws_os}
 459     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 460 )
 461
 462 set_property (
 463     TARGET glretrace
 464     APPEND
 465     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 466 )
 467
 468 target_link_libraries (glretrace
 469     common
 470 )
 471
 472 if (WIN32)
 473     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 474 elseif (APPLE)
 475     target_link_libraries (glretrace
 476         "-framework Cocoa"
 477         "-framework ApplicationServices" # CGS*
 478         ${OPENGL_gl_LIBRARY} # CGL*
 479     )
 480 else ()
 481     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 482 endif ()
 483
 484 install (TARGETS glretrace RUNTIME DESTINATION bin)
 485
 486 ##############################################################################
 487 # CLI
 488
 489 add_subdirectory(cli)
 490
 491 ##############################################################################
 492 # Scripts (to support the CLI)
 493
 494 install (PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/scripts/tracediff.sh DESTINATION ${LIB_INSTALL_DIR}/scripts)
 495 install (PROGRAMS ${CMAKE_CURRENT_SOURCE_DIR}/scripts/jsondiff.py DESTINATION ${LIB_INSTALL_DIR}/scripts)
 496
 497 ##############################################################################
 498 # GUI
 499
 500 if (ENABLE_GUI AND QT4_FOUND AND QJSON_FOUND)
 501     add_subdirectory(gui)
 502 endif ()
 503
 504
 505 ##############################################################################
 506 # Packaging
 507
 508 install (
 509     FILES
 510         BUGS.markdown
 511         LICENSE
 512         NEWS.markdown
 513         README.markdown
 514         TODO.markdown
 515     DESTINATION ${DOC_INSTALL_DIR}
 516 )
 517
 518 set (CPACK_PACKAGE_VERSION_MAJOR "2")
 519 set (CPACK_PACKAGE_VERSION_MINOR "0")
 520
 521 # Use current date in YYYYMMDD format as patch number
 522 execute_process (
 523     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 524     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 525 )
 526
 527 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 528 if (WIN32)
 529     set (CPACK_GENERATOR "ZIP")
 530 elseif (APPLE)
 531     set (CPACK_GENERATOR "DragNDrop")
 532 else ()
 533     set (CPACK_GENERATOR "TBZ2")
 534 endif ()
 535
 536 include(CPack)