git.cworth.org Git - apitrace/blob - CMakeLists.txt

   1 cmake_minimum_required (VERSION 2.8)
   2
   3 project (apitrace)
   4
   5
   6 ##############################################################################
   7 # Find dependencies
   8
   9 set (CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake)
  10
  11 set (CMAKE_USE_PYTHON_VERSION 2.7 2.6)
  12
  13 find_package (PythonInterp REQUIRED)
  14 find_package (OpenGL REQUIRED)
  15 find_package (Qt4 4.7 COMPONENTS QtCore QtGui QtWebKit)
  16 find_package (QJSON)
  17
  18 if (NOT WIN32)
  19     # Always use the bundled zlib and libpng sources on Windows to make it easy
  20     # to deploy the wrappers DLLs
  21     find_package (ZLIB)
  22     find_package (PNG)
  23 endif (NOT WIN32)
  24
  25 if (NOT WIN32)
  26     find_package (X11 REQUIRED)
  27
  28     # On Mac OS X, GLX is provided as a separate OpenGL implementation, different
  29     # from the standard OpenGL framework which provides support for native Mac OS X
  30     # applications.
  31     if (APPLE)
  32         find_path (X11_GL_INCLUDE_PATH GL/glx.h ${X11_INC_SEARCH_PATH})
  33         if (NOT X11_GL_INCLUDE_PATH)
  34             message (SEND_ERROR "Could not find GL/glx.h")
  35         endif (NOT X11_GL_INCLUDE_PATH)
  36         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${X11_GL_INCLUDE_PATH})
  37
  38         find_library (X11_GL_LIB GL ${X11_LIB_SEARCH_PATH})
  39         if (NOT X11_GL_LIB)
  40             message (SEND_ERROR "Could not find libGL.dylib")
  41         endif (NOT X11_GL_LIB)
  42     else ()
  43         set (X11_INCLUDE_DIR ${X11_INCLUDE_DIR} ${OPENGL_INCLUDE_DIR})
  44         set (X11_GL_LIB ${OPENGL_gl_LIBRARY})
  45     endif ()
  46
  47     include_directories (${X11_INCLUDE_DIR})
  48 endif (NOT WIN32)
  49
  50 if (WIN32)
  51     find_package (DirectX)
  52 endif (WIN32)
  53
  54
  55 ##############################################################################
  56 # Set global build options
  57
  58 include (CheckCXXCompilerFlag)
  59
  60 if (WIN32)
  61     # MSVC & MinGW only define & use APIENTRY
  62     add_definitions (-DGLAPIENTRY=__stdcall)
  63
  64     # http://msdn.microsoft.com/en-us/library/aa383745.aspx
  65     add_definitions (-D_WIN32_WINNT=0x0500 -DWINVER=0x0500)
  66 else (WIN32)
  67     CHECK_CXX_COMPILER_FLAG("-fvisibility=hidden" CXX_COMPILER_FLAG_VISIBILITY)
  68     if (CXX_COMPILER_FLAG_VISIBILITY)
  69         add_definitions ("-fvisibility=hidden")
  70     endif (CXX_COMPILER_FLAG_VISIBILITY)
  71 endif (WIN32)
  72
  73 if (MSVC)
  74     # C99 includes for msvc
  75     include_directories (msvc)
  76
  77     # Enable math constants defines
  78     add_definitions (-D_USE_MATH_DEFINES)
  79
  80     # No min/max macros
  81     add_definitions (-DNOMINMAX)
  82
  83     # Adjust warnings
  84     add_definitions (-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
  85     add_definitions (-D_SCL_SECURE_NO_DEPRECATE -D_SCL_SECURE_NO_WARNINGS)
  86     add_definitions (-W4)
  87     add_definitions (-wd4063) # not a valid value for switch of enum
  88     add_definitions (-wd4127) # conditional expression is constant
  89     add_definitions (-wd4244) # conversion from 'type1' to 'type2', possible loss of data
  90     add_definitions (-wd4505) # unreferenced local function has been removed
  91     add_definitions (-wd4800) # forcing value to bool 'true' or 'false' (performance warning)
  92     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
  93     add_definitions (-wd4018) # signed/unsigned mismatch
  94
  95     # Use static runtime
  96     # http://www.cmake.org/Wiki/CMake_FAQ#How_can_I_build_my_MSVC_application_with_a_static_runtime.3F
  97     foreach (flag_var
  98         CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
  99         CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO
 100     )
 101         if (${flag_var} MATCHES "/MD")
 102             string (REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 103         endif (${flag_var} MATCHES "/MD")
 104     endforeach (flag_var)
 105 else ()
 106     # Adjust warnings
 107     add_definitions (-Wall)
 108     # XXX: it's safer to use ssize_t everywhere instead of disabling warning
 109     add_definitions (-Wno-sign-compare) # comparison between signed and unsigned integer expressions
 110 endif ()
 111
 112
 113 # Put all executables into the same top level build directory, regardless of
 114 # which subdirectory they are declared
 115 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR})
 116
 117 include_directories (${CMAKE_CURRENT_SOURCE_DIR})
 118
 119
 120 ##############################################################################
 121 # Bundled dependencies
 122
 123 # Use bundled ZLIB if system one can't be found
 124 if (NOT ZLIB_FOUND)
 125     set (ZLIB_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/zlib)
 126     set (ZLIB_LIBRARIES zlib)
 127     add_subdirectory (zlib EXCLUDE_FROM_ALL)
 128 endif (NOT ZLIB_FOUND)
 129
 130 include_directories (${ZLIB_INCLUDE_DIRS})
 131 link_libraries (${ZLIB_LIBRARIES})
 132
 133 # Use bundled LIBPNG if system one can't be found
 134 if (PNG_FOUND)
 135 else (PNG_FOUND)
 136     set (PNG_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/libpng)
 137     set (PNG_DEFINITIONS "")
 138     set (PNG_LIBRARIES png)
 139     add_subdirectory (libpng EXCLUDE_FROM_ALL)
 140 endif (PNG_FOUND)
 141 include_directories (${PNG_INCLUDE_DIR})
 142 add_definitions (${PNG_DEFINITIONS})
 143 link_libraries (${PNG_LIBRARIES})
 144
 145
 146 ##############################################################################
 147 # Common libraries / utilities
 148
 149 add_custom_command (
 150     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 151     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glproc.py > ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 152     DEPENDS glproc.py dispatch.py wglapi.py glxapi.py cglapi.py glapi.py gltypes.py stdapi.py
 153 )
 154
 155 if (WIN32)
 156     set (os os_win32.cpp)
 157     set (glws glws_wgl.cpp)
 158 else (WIN32)
 159     set (os os_posix.cpp)
 160     set (glws glws_glx.cpp)
 161 endif (WIN32)
 162
 163 add_library (trace trace_model.cpp trace_parser.cpp trace_writer.cpp trace_model_writer.cpp ${os})
 164
 165 add_executable (tracedump tracedump.cpp)
 166 target_link_libraries (tracedump trace)
 167 install (TARGETS tracedump RUNTIME DESTINATION bin)
 168
 169
 170 ##############################################################################
 171 # API tracers
 172
 173 if (WIN32)
 174     # ddraw.dll
 175     if (DirectX_D3D_INCLUDE_DIR)
 176         include_directories (SYSTEM ${DirectX_D3D_INCLUDE_DIR})
 177         add_custom_command (
 178             OUTPUT ddraw.cpp
 179             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d.py > ${CMAKE_CURRENT_BINARY_DIR}/ddraw.cpp
 180             DEPENDS d3d.py d3dtypes.py d3dcaps.py ddraw.py trace.py winapi.py stdapi.py
 181         )
 182         add_library (ddraw MODULE ddraw.def ddraw.cpp trace_writer.cpp os_win32.cpp)
 183         set_target_properties (ddraw
 184             PROPERTIES PREFIX ""
 185             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 186             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 187         )
 188         install (TARGETS ddraw LIBRARY DESTINATION wrappers)
 189     endif (DirectX_D3D_INCLUDE_DIR)
 190
 191     # d3d8.dll
 192     if (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 193         include_directories (SYSTEM ${DirectX_D3D8_INCLUDE_DIR} ${DirectX_D3DX9_INCLUDE_DIR})
 194         add_custom_command (
 195             OUTPUT d3d8.cpp
 196             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d8.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d8.cpp
 197             DEPENDS d3d8.py trace.py d3d8types.py d3d8caps.py winapi.py stdapi.py
 198         )
 199         add_library (d3d8 MODULE d3d8.def d3d8.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 200         set_target_properties (d3d8
 201             PROPERTIES PREFIX ""
 202             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 203             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 204         )
 205         install (TARGETS d3d8 LIBRARY DESTINATION wrappers)
 206     endif (DirectX_D3D8_INCLUDE_DIR AND DirectX_D3DX9_INCLUDE_DIR)
 207
 208     # d3d9.dll
 209     if (DirectX_D3DX9_INCLUDE_DIR)
 210         include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 211         add_custom_command (
 212             OUTPUT d3d9.cpp
 213             COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d9.cpp
 214             DEPENDS d3d9.py trace.py d3d9types.py d3d9caps.py winapi.py stdapi.py
 215         )
 216         add_library (d3d9 MODULE d3d9.def d3d9.cpp d3dshader.cpp trace_writer.cpp os_win32.cpp)
 217         set_target_properties (d3d9
 218             PROPERTIES PREFIX ""
 219             RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 220             LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 221         )
 222         install (TARGETS d3d9 LIBRARY DESTINATION wrappers)
 223     endif (DirectX_D3DX9_INCLUDE_DIR)
 224
 225     # d3d10.dll
 226     #if (DirectX_D3D10_INCLUDE_DIR)
 227     #    include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 228     #    add_custom_command (
 229     #        OUTPUT d3d10.cpp
 230     #        COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d10misc.py > ${CMAKE_CURRENT_BINARY_DIR}/d3d10.cpp
 231     #        DEPENDS d3d10misc.py winapi.py stdapi.py
 232     #    )
 233     #    add_library (d3d10 MODULE d3d10.def d3d10.cpp trace_writer.cpp os_win32.cpp)
 234     #    set_target_properties (d3d10 PROPERTIES PREFIX "")
 235     #    install (TARGETS d3d10 LIBRARY DESTINATION wrappers)
 236     #endif (DirectX_D3D10_INCLUDE_DIR)
 237
 238     # opengl32.dll
 239     add_custom_command (
 240         OUTPUT wgltrace.cpp
 241         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/wgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/wgltrace.cpp
 242         DEPENDS wgltrace.py gltrace.py trace.py wglapi.py wglenum.py glapi.py glparams.py gltypes.py winapi.py stdapi.py
 243     )
 244     add_library (wgltrace MODULE opengl32.def wgltrace.cpp trace_writer.cpp os_win32.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 245     set_target_properties (wgltrace PROPERTIES
 246         PREFIX ""
 247         OUTPUT_NAME opengl32
 248         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 249         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 250     )
 251     if (MINGW)
 252         set_target_properties(wgltrace PROPERTIES LINK_FLAGS "-Wl,--enable-stdcall-fixup ${CMAKE_CURRENT_SOURCE_DIR}/opengl32.def")
 253     endif (MINGW)
 254     install (TARGETS wgltrace LIBRARY DESTINATION wrappers)
 255
 256 elseif (APPLE)
 257     # OpenGL framework
 258     add_custom_command (
 259         OUTPUT cgltrace.cpp
 260         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/cgltrace.py > ${CMAKE_CURRENT_BINARY_DIR}/cgltrace.cpp
 261         DEPENDS cgltrace.py gltrace.py trace.py cglapi.py glapi.py glparams.py gltypes.py stdapi.py
 262     )
 263
 264     add_library (cgltrace SHARED cgltrace.cpp trace_writer.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 265
 266     set_target_properties (cgltrace PROPERTIES
 267         # OpenGL framework name
 268         PREFIX "" OUTPUT_NAME "OpenGL" SUFFIX ""
 269         # Specificy the version and reexport GLU symbols
 270         LINK_FLAGS "-compatibility_version 1 -current_version 1.0.0 -Wl,-reexport_library,/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGLU.dylib"
 271         RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 272         LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/wrappers
 273     )
 274
 275     target_link_libraries (cgltrace dl)
 276
 277     install (TARGETS cgltrace LIBRARY DESTINATION wrappers)
 278 else ()
 279     # libGL.so
 280     add_custom_command (
 281         OUTPUT glxtrace.cpp
 282         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glxtrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glxtrace.cpp
 283         DEPENDS glxtrace.py gltrace.py trace.py glxapi.py glapi.py glparams.py gltypes.py stdapi.py
 284     )
 285
 286     add_library (glxtrace SHARED glxtrace.cpp trace_writer.cpp os_posix.cpp ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp)
 287
 288     set_target_properties (glxtrace PROPERTIES
 289         # avoid the default "lib" prefix
 290         PREFIX ""
 291     )
 292
 293     # Prevent symbol relocations internal to our wrapper library to be
 294     # overwritten by the application.
 295     set_target_properties (glxtrace PROPERTIES
 296         LINK_FLAGS "-Wl,-Bsymbolic -Wl,-Bsymbolic-functions"
 297     )
 298
 299     target_link_libraries (glxtrace dl)
 300
 301     install (TARGETS glxtrace LIBRARY DESTINATION lib)
 302 endif ()
 303
 304
 305 ##############################################################################
 306 # API retracers
 307
 308 add_custom_command (
 309     OUTPUT glretrace_gl.cpp
 310     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
 311     DEPENDS glretrace.py retrace.py codegen.py glapi.py gltypes.py stdapi.py
 312 )
 313
 314 add_custom_command (
 315     OUTPUT glstate_params.cpp
 316     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
 317     DEPENDS glstate.py glparams.py gltypes.py stdapi.py
 318 )
 319
 320 include_directories (
 321     ${CMAKE_CURRENT_BINARY_DIR}
 322     ${OPENGL_INCLUDE_PATH}
 323 )
 324
 325 add_executable (glretrace
 326     glretrace_gl.cpp
 327     glretrace_cgl.cpp
 328     glretrace_glx.cpp
 329     glretrace_wgl.cpp
 330     glretrace_main.cpp
 331     glstate.cpp
 332     glstate_params.cpp
 333     retrace.cpp
 334     ${glws}
 335     image.cpp
 336     ${CMAKE_CURRENT_BINARY_DIR}/glproc.hpp
 337 )
 338
 339 set_property (
 340     TARGET glretrace
 341     APPEND
 342     PROPERTY COMPILE_DEFINITIONS "RETRACE"
 343 )
 344
 345 target_link_libraries (glretrace
 346     trace
 347 )
 348
 349 if (WIN32)
 350     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY})
 351 elseif (APPLE)
 352     # XXX: We use GLX on MacOSX, which is in a separate library.
 353     target_link_libraries (glretrace
 354         ${X11_GL_LIB}
 355         ${X11_X11_LIB}
 356         "-framework ApplicationServices" # CGS*
 357         ${OPENGL_gl_LIBRARY} # CGL*
 358     )
 359 else ()
 360     target_link_libraries (glretrace ${OPENGL_gl_LIBRARY} ${X11_X11_LIB})
 361 endif ()
 362
 363 install (TARGETS glretrace RUNTIME DESTINATION bin)
 364
 365
 366 ##############################################################################
 367 # GUI
 368
 369 if (QT4_FOUND AND QJSON_FOUND)
 370     add_subdirectory(gui)
 371 endif (QT4_FOUND AND QJSON_FOUND)
 372
 373
 374 ##############################################################################
 375 # Packaging
 376
 377 install (FILES LICENSE README TODO DESTINATION doc)
 378
 379 set (CPACK_PACKAGE_VERSION_MAJOR "1")
 380 set (CPACK_PACKAGE_VERSION_MINOR "0")
 381
 382 # Use current date in YYYYMMDD format as patch number
 383 execute_process (
 384     COMMAND ${PYTHON_EXECUTABLE} -c "import time, sys; sys.stdout.write(time.strftime('%Y%m%d'))"
 385     OUTPUT_VARIABLE CPACK_PACKAGE_VERSION_PATCH
 386 )
 387
 388 # See http://www.vtk.org/Wiki/CMake:CPackPackageGenerators
 389 if (WIN32)
 390     set (CPACK_GENERATOR "ZIP")
 391 elseif (APPLE)
 392     set (CPACK_GENERATOR "DragNDrop")
 393 else ()
 394     set (CPACK_GENERATOR "TBZ2")
 395 endif ()
 396
 397 include(CPack)