git.cworth.org Git - apitrace/blob - glws_cocoa.mm

   1 /**************************************************************************
   2  *
   3  * Copyright 2011 VMware, Inc.
   4  * All Rights Reserved.
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining a copy
   7  * of this software and associated documentation files (the "Software"), to deal
   8  * in the Software without restriction, including without limitation the rights
   9  * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
  10  * copies of the Software, and to permit persons to whom the Software is
  11  * furnished to do so, subject to the following conditions:
  12  *
  13  * The above copyright notice and this permission notice shall be included in
  14  * all copies or substantial portions of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  19  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  21  * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
  22  * THE SOFTWARE.
  23  *
  24  **************************************************************************/
  25
  26
  27 /**
  28  * Minimal Cocoa integration.
  29  *
  30  * See also:
  31  * - http://developer.apple.com/library/mac/#samplecode/CocoaGL/Introduction/Intro.html
  32  * - http://developer.apple.com/library/mac/#samplecode/Cocoa_With_Carbon_or_CPP/Introduction/Intro.html
  33  * - http://developer.apple.com/library/mac/#samplecode/glut/Introduction/Intro.html
  34  * - http://developer.apple.com/library/mac/#samplecode/GLEssentials/Introduction/Intro.html
  35  * - http://www.glfw.org/
  36  */
  37
  38
  39 #include <stdlib.h>
  40 #include <iostream>
  41
  42 #include <Cocoa/Cocoa.h>
  43
  44 #include "glws.hpp"
  45
  46
  47 namespace glws {
  48
  49
  50 NSAutoreleasePool *autoreleasePool = nil;
  51
  52
  53 class CocoaVisual : public Visual
  54 {
  55 public:
  56     NSOpenGLPixelFormat *pixelFormat;
  57
  58     CocoaVisual(NSOpenGLPixelFormat *pf) :
  59         pixelFormat(pf)
  60     {}
  61
  62     ~CocoaVisual() {
  63         [pixelFormat release];
  64     }
  65 };
  66
  67
  68 class CocoaDrawable : public Drawable
  69 {
  70 public:
  71     NSWindow *window;
  72     NSOpenGLContext *currentContext;
  73
  74     CocoaDrawable(const Visual *vis, int w, int h) :
  75         Drawable(vis, w, h),
  76         currentContext(nil)
  77     {
  78         NSOpenGLPixelFormat *pixelFormat = dynamic_cast<const CocoaVisual *>(visual)->pixelFormat;
  79
  80         NSRect winRect = NSMakeRect(0, 0, w, h);
  81
  82         window = [[NSWindow alloc]
  83                          initWithContentRect:winRect
  84                                    styleMask:NSTitledWindowMask |
  85                                              NSClosableWindowMask |
  86                                              NSMiniaturizableWindowMask
  87                                      backing:NSBackingStoreRetained
  88                                        defer:NO];
  89         assert(window != nil);
  90
  91         NSOpenGLView *view = [[NSOpenGLView alloc]
  92                               initWithFrame:winRect
  93                                 pixelFormat:pixelFormat];
  94         assert(view != nil);
  95
  96         [window setContentView:view];
  97         [window setTitle:@"glretrace"];
  98
  99     }
 100
 101     ~CocoaDrawable() {
 102         [window release];
 103     }
 104
 105     void
 106     resize(int w, int h) {
 107         if (w == width && h == height) {
 108             return;
 109         }
 110
 111         [window setContentSize:NSMakeSize(w, h)];
 112
 113         if (currentContext != nil) {
 114             [currentContext update];
 115             [window makeKeyAndOrderFront:nil];
 116             [currentContext setView:[window contentView]];
 117             [currentContext makeCurrentContext];
 118         }
 119
 120         Drawable::resize(w, h);
 121     }
 122
 123     void show(void) {
 124         if (visible) {
 125             return;
 126         }
 127
 128         // TODO
 129
 130         Drawable::show();
 131     }
 132
 133     void swapBuffers(void) {
 134         if (currentContext != nil) {
 135             [currentContext flushBuffer];
 136         }
 137     }
 138 };
 139
 140
 141 class CocoaContext : public Context
 142 {
 143 public:
 144     NSOpenGLContext *context;
 145
 146     CocoaContext(const Visual *vis, NSOpenGLContext *ctx) :
 147         Context(vis),
 148         context(ctx)
 149     {}
 150
 151     ~CocoaContext() {
 152         [context release];
 153     }
 154 };
 155
 156
 157 void
 158 init(void) {
 159     [NSApplication sharedApplication];
 160
 161     autoreleasePool = [[NSAutoreleasePool alloc] init];
 162
 163     [NSApp finishLaunching];
 164 }
 165
 166
 167 void
 168 cleanup(void) {
 169     [autoreleasePool release];
 170 }
 171
 172
 173 Visual *
 174 createVisual(bool doubleBuffer) {
 175     NSOpenGLPixelFormatAttribute single_attribs[] = {
 176         NSOpenGLPFAAlphaSize, (NSOpenGLPixelFormatAttribute)1,
 177         NSOpenGLPFAColorSize, (NSOpenGLPixelFormatAttribute)24,
 178         NSOpenGLPFADepthSize, (NSOpenGLPixelFormatAttribute)1,
 179         NSOpenGLPFAStencilSize, (NSOpenGLPixelFormatAttribute)1,
 180         (NSOpenGLPixelFormatAttribute)0
 181     };
 182
 183     NSOpenGLPixelFormatAttribute double_attribs[] = {
 184         NSOpenGLPFAAlphaSize, (NSOpenGLPixelFormatAttribute)1,
 185         NSOpenGLPFAColorSize, (NSOpenGLPixelFormatAttribute)24,
 186         NSOpenGLPFADoubleBuffer,
 187         NSOpenGLPFADepthSize, (NSOpenGLPixelFormatAttribute)1,
 188         NSOpenGLPFAStencilSize, (NSOpenGLPixelFormatAttribute)1,
 189         (NSOpenGLPixelFormatAttribute)0
 190     };
 191
 192     NSOpenGLPixelFormatAttribute *attribs = doubleBuffer ? double_attribs : single_attribs;
 193
 194     NSOpenGLPixelFormat *pixelFormat = [[NSOpenGLPixelFormat alloc]
 195                                      initWithAttributes:attribs];
 196
 197     return new CocoaVisual(pixelFormat);
 198 }
 199
 200 Drawable *
 201 createDrawable(const Visual *visual, int width, int height)
 202 {
 203     return new CocoaDrawable(visual, width, height);
 204 }
 205
 206 Context *
 207 createContext(const Visual *visual, Context *shareContext)
 208 {
 209     NSOpenGLPixelFormat *pixelFormat = dynamic_cast<const CocoaVisual *>(visual)->pixelFormat;
 210     NSOpenGLContext *share_context = nil;
 211     NSOpenGLContext *context;
 212
 213     if (shareContext) {
 214         share_context = dynamic_cast<CocoaContext*>(shareContext)->context;
 215     }
 216
 217     context = [[NSOpenGLContext alloc]
 218                initWithFormat:pixelFormat
 219                shareContext:share_context];
 220     assert(context != nil);
 221
 222     return new CocoaContext(visual, context);
 223 }
 224
 225 bool
 226 makeCurrent(Drawable *drawable, Context *context)
 227 {
 228     if (!drawable || !context) {
 229         [NSOpenGLContext clearCurrentContext];
 230     } else {
 231         CocoaDrawable *cocoaDrawable = dynamic_cast<CocoaDrawable *>(drawable);
 232         CocoaContext *cocoaContext = dynamic_cast<CocoaContext *>(context);
 233
 234         [cocoaDrawable->window makeKeyAndOrderFront:nil];
 235         [cocoaContext->context setView:[cocoaDrawable->window contentView]];
 236         [cocoaContext->context makeCurrentContext];
 237
 238         cocoaDrawable->currentContext = cocoaContext->context;
 239     }
 240
 241     return TRUE;
 242 }
 243
 244 bool
 245 processEvents(void) {
 246    NSEvent* event;
 247
 248     do {
 249         event = [NSApp nextEventMatchingMask:NSAnyEventMask
 250                                    untilDate:[NSDate distantPast]
 251                                       inMode:NSDefaultRunLoopMode
 252                                      dequeue:YES];
 253         if (event)
 254             [NSApp sendEvent:event];
 255     } while (event);
 256
 257     return true;
 258 }
 259
 260
 261 } /* namespace glws */