git.cworth.org Git - apitrace/blob - retrace/CMakeLists.txt

   1 ##############################################################################
   2 # API retracers
   3
   4 include_directories (
   5     ${CMAKE_CURRENT_SOURCE_DIR}
   6     ${CMAKE_SOURCE_DIR}/helpers
   7     ${CMAKE_BINARY_DIR}/dispatch
   8     ${CMAKE_SOURCE_DIR}/dispatch
   9 )
  10
  11 add_definitions (-DRETRACE)
  12
  13 add_custom_command (
  14     OUTPUT glretrace_gl.cpp
  15     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
  16     DEPENDS
  17                 glretrace.py
  18                 retrace.py
  19                 ${CMAKE_SOURCE_DIR}/specs/glapi.py
  20                 ${CMAKE_SOURCE_DIR}/specs/gltypes.py
  21                 ${CMAKE_SOURCE_DIR}/specs/stdapi.py
  22 )
  23
  24 add_custom_command (
  25     OUTPUT glstate_params.cpp
  26     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate_params.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
  27     DEPENDS
  28                 glstate_params.py
  29                 ${CMAKE_SOURCE_DIR}/specs/glparams.py
  30                 ${CMAKE_SOURCE_DIR}/specs/gltypes.py
  31                 ${CMAKE_SOURCE_DIR}/specs/stdapi.py
  32 )
  33
  34 add_library (retrace_common
  35     retrace.cpp
  36     retrace_main.cpp
  37     retrace_stdc.cpp
  38     retrace_swizzle.cpp
  39 )
  40
  41 target_link_libraries (retrace_common
  42     common
  43     ${PNG_LIBRARIES}
  44     ${ZLIB_LIBRARIES}
  45     ${SNAPPY_LIBRARIES}
  46     ${GETOPT_LIBRARIES}
  47 )
  48
  49 add_library (glretrace_common
  50     glretrace_gl.cpp
  51     glretrace_cgl.cpp
  52     glretrace_glx.cpp
  53     glretrace_wgl.cpp
  54     glretrace_egl.cpp
  55     glretrace_main.cpp
  56     glretrace_ws.cpp
  57     glstate.cpp
  58     glstate_images.cpp
  59     glstate_params.cpp
  60     glstate_shaders.cpp
  61     glws.cpp
  62 )
  63
  64 add_dependencies (glretrace_common glproc)
  65
  66
  67 if (WIN32 OR APPLE OR X11_FOUND)
  68     add_executable (glretrace
  69         ${glws_os}
  70     )
  71
  72     add_dependencies (glretrace glproc)
  73
  74     target_link_libraries (glretrace
  75         retrace_common
  76         glretrace_common
  77         glproc_gl
  78     )
  79
  80     if (WIN32)
  81     else ()
  82         if (APPLE)
  83             target_link_libraries (glretrace
  84                 "-framework Cocoa"
  85                 "-framework ApplicationServices" # CGS*
  86                 #"-framework OpenGL" # CGL*
  87             )
  88         else ()
  89             target_link_libraries (glretrace ${X11_X11_LIB})
  90         endif ()
  91
  92         target_link_libraries (glretrace
  93             # gdb doesn't like when pthreads is loaded through dlopen (which happens
  94             # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
  95             # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
  96             ${CMAKE_THREAD_LIBS_INIT}
  97             dl
  98         )
  99
 100         if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 101             target_link_libraries (glretrace rt)
 102         endif ()
 103
 104     endif ()
 105
 106     install (TARGETS glretrace RUNTIME DESTINATION bin)
 107 endif ()
 108
 109 if (ENABLE_EGL AND X11_FOUND AND NOT WIN32 AND NOT APPLE)
 110     add_executable (eglretrace
 111         glws_egl_xlib.cpp
 112     )
 113
 114     add_dependencies (eglretrace glproc)
 115
 116     target_link_libraries (eglretrace
 117         retrace_common
 118         glretrace_common
 119         glproc_egl
 120         ${X11_X11_LIB}
 121         ${CMAKE_THREAD_LIBS_INIT}
 122         dl
 123     )
 124
 125     if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 126         target_link_libraries (eglretrace rt)
 127     endif ()
 128
 129     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 130 endif ()
 131
 132 if (WIN32 AND DirectX_D3DX9_INCLUDE_DIR)
 133     include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 134     add_custom_command (
 135         OUTPUT d3dretrace_d3d9.cpp
 136         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9retrace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3dretrace_d3d9.cpp
 137         DEPENDS
 138                 d3d9retrace.py
 139                 dllretrace.py
 140                 retrace.py
 141                 ${CMAKE_SOURCE_DIR}/dispatch/dispatch.py
 142                 ${CMAKE_SOURCE_DIR}/specs/d3d9.py
 143                 ${CMAKE_SOURCE_DIR}/specs/d3d9types.py
 144                 ${CMAKE_SOURCE_DIR}/specs/d3d9caps.py
 145                 ${CMAKE_SOURCE_DIR}/specs/winapi.py
 146                 ${CMAKE_SOURCE_DIR}/specs/stdapi.py
 147     )
 148
 149     if (DirectX_D3D10_INCLUDE_DIR)
 150         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 151         set (D3D10_MODULES d3d10)
 152         if (DirectX_D3D10_1_INCLUDE_DIR)
 153             include_directories (SYSTEM ${DirectX_D3D10_1_INCLUDE_DIR})
 154             set (D3D10_MODULES ${D3D10_MODULES} d3d10_1)
 155         endif ()
 156         set (D3DSTATE_SOURCES ${D3DSTATE_SOURCES}
 157             d3d10state.cpp
 158             d3d10state_images.cpp
 159         )
 160     endif ()
 161
 162     if (DirectX_D3D11_INCLUDE_DIR)
 163         include_directories (SYSTEM ${DirectX_D3D11_INCLUDE_DIR})
 164         set (D3D10_MODULES ${D3D10_MODULES} d3d11)
 165         if (DirectX_D3D11_1_INCLUDE_DIR)
 166             include_directories (SYSTEM ${DirectX_D3D11_1_INCLUDE_DIR})
 167             set (D3D10_MODULES ${D3D10_MODULES} d3d11_1)
 168         endif ()
 169         set (D3DSTATE_SOURCES ${D3DSTATE_SOURCES}
 170             d3d11state.cpp
 171             d3d11state_images.cpp
 172         )
 173     endif ()
 174
 175     add_custom_command (
 176         OUTPUT d3dretrace_d3d10.cpp
 177         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3dcommonretrace.py ${D3D10_MODULES} > ${CMAKE_CURRENT_BINARY_DIR}/d3dretrace_d3d10.cpp
 178         DEPENDS
 179                 d3dcommonretrace.py
 180                 dllretrace.py
 181                 retrace.py
 182                 ${CMAKE_SOURCE_DIR}/dispatch/dispatch.py
 183                 ${CMAKE_SOURCE_DIR}/specs/d3d11_1.py
 184                 ${CMAKE_SOURCE_DIR}/specs/d3d11.py
 185                 ${CMAKE_SOURCE_DIR}/specs/d3d11sdklayers.py
 186                 ${CMAKE_SOURCE_DIR}/specs/d3d10_1.py
 187                 ${CMAKE_SOURCE_DIR}/specs/d3d10.py
 188                 ${CMAKE_SOURCE_DIR}/specs/d3d10misc.py
 189                 ${CMAKE_SOURCE_DIR}/specs/d3d10sdklayers.py
 190                 ${CMAKE_SOURCE_DIR}/specs/d3d10shader.py
 191                 ${CMAKE_SOURCE_DIR}/specs/d3d10effect.py
 192                 ${CMAKE_SOURCE_DIR}/specs/d3dcommon.py
 193                 ${CMAKE_SOURCE_DIR}/specs/dxgi.py
 194                 ${CMAKE_SOURCE_DIR}/specs/dxgitype.py
 195                 ${CMAKE_SOURCE_DIR}/specs/dxgiformat.py
 196                 ${CMAKE_SOURCE_DIR}/specs/winapi.py
 197                 ${CMAKE_SOURCE_DIR}/specs/stdapi.py
 198     )
 199
 200     add_executable (d3dretrace
 201         d3dretrace_main.cpp
 202         d3dretrace_d3d9.cpp
 203         d3dretrace_d3d10.cpp
 204         d3dretrace_ws.cpp
 205         d3d9state.cpp
 206         d3d9state_images.cpp
 207         ${D3DSTATE_SOURCES}
 208     )
 209     target_link_libraries (d3dretrace
 210         retrace_common
 211     )
 212
 213     install (TARGETS d3dretrace RUNTIME DESTINATION bin)
 214 endif ()