git.cworth.org Git - apitrace/blob - retrace/CMakeLists.txt

   1 ##############################################################################
   2 # API retracers
   3
   4 include_directories (
   5     ${CMAKE_CURRENT_SOURCE_DIR}
   6     ${CMAKE_SOURCE_DIR}/helpers
   7     ${CMAKE_BINARY_DIR}/dispatch
   8     ${CMAKE_SOURCE_DIR}/dispatch
   9 )
  10
  11 add_definitions (-DRETRACE)
  12
  13 add_custom_command (
  14     OUTPUT glretrace_gl.cpp
  15     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glretrace.py > ${CMAKE_CURRENT_BINARY_DIR}/glretrace_gl.cpp
  16     DEPENDS
  17                 glretrace.py
  18                 retrace.py
  19                 ${CMAKE_SOURCE_DIR}/specs/glapi.py
  20                 ${CMAKE_SOURCE_DIR}/specs/gltypes.py
  21                 ${CMAKE_SOURCE_DIR}/specs/stdapi.py
  22 )
  23
  24 add_custom_command (
  25     OUTPUT glstate_params.cpp
  26     COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/glstate_params.py > ${CMAKE_CURRENT_BINARY_DIR}/glstate_params.cpp
  27     DEPENDS
  28                 glstate_params.py
  29                 ${CMAKE_SOURCE_DIR}/specs/glparams.py
  30                 ${CMAKE_SOURCE_DIR}/specs/gltypes.py
  31                 ${CMAKE_SOURCE_DIR}/specs/stdapi.py
  32 )
  33
  34 add_library (retrace_common
  35     retrace.cpp
  36     retrace_main.cpp
  37     retrace_stdc.cpp
  38     retrace_swizzle.cpp
  39 )
  40
  41 target_link_libraries (retrace_common
  42     common
  43     ${PNG_LIBRARIES}
  44     ${ZLIB_LIBRARIES}
  45     ${SNAPPY_LIBRARIES}
  46 )
  47
  48 add_library (glretrace_common
  49     glretrace_gl.cpp
  50     glretrace_cgl.cpp
  51     glretrace_glx.cpp
  52     glretrace_wgl.cpp
  53     glretrace_egl.cpp
  54     glretrace_main.cpp
  55     glretrace_ws.cpp
  56     glstate.cpp
  57     glstate_images.cpp
  58     glstate_params.cpp
  59     glstate_shaders.cpp
  60     glws.cpp
  61 )
  62
  63 add_dependencies (glretrace_common glproc)
  64
  65
  66 if (WIN32 OR APPLE OR X11_FOUND)
  67     add_executable (glretrace
  68         ${glws_os}
  69     )
  70
  71     add_dependencies (glretrace glproc)
  72
  73     target_link_libraries (glretrace
  74         retrace_common
  75         glretrace_common
  76         glproc_gl
  77     )
  78
  79     if (WIN32)
  80     else ()
  81         if (APPLE)
  82             target_link_libraries (glretrace
  83                 "-framework Cocoa"
  84                 "-framework ApplicationServices" # CGS*
  85                 #"-framework OpenGL" # CGL*
  86             )
  87         else ()
  88             target_link_libraries (glretrace ${X11_X11_LIB})
  89         endif ()
  90
  91         target_link_libraries (glretrace
  92             # gdb doesn't like when pthreads is loaded through dlopen (which happens
  93             # when dlopen'ing libGL), so link pthreads to avoid this issue.  See also
  94             # http://stackoverflow.com/questions/2702628/gdb-cannot-find-new-threads-generic-error
  95             ${CMAKE_THREAD_LIBS_INIT}
  96             dl
  97         )
  98
  99         if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 100             target_link_libraries (glretrace rt)
 101         endif ()
 102
 103     endif ()
 104
 105     install (TARGETS glretrace RUNTIME DESTINATION bin)
 106 endif ()
 107
 108 if (ENABLE_EGL AND X11_FOUND AND NOT WIN32 AND NOT APPLE)
 109     add_executable (eglretrace
 110         glws_egl_xlib.cpp
 111     )
 112
 113     add_dependencies (eglretrace glproc)
 114
 115     target_link_libraries (eglretrace
 116         retrace_common
 117         glretrace_common
 118         glproc_egl
 119         ${X11_X11_LIB}
 120         ${CMAKE_THREAD_LIBS_INIT}
 121         dl
 122     )
 123
 124     if (${CMAKE_SYSTEM_NAME} MATCHES "Linux")
 125         target_link_libraries (eglretrace rt)
 126     endif ()
 127
 128     install (TARGETS eglretrace RUNTIME DESTINATION bin)
 129 endif ()
 130
 131 if (WIN32 AND DirectX_D3DX9_INCLUDE_DIR)
 132     include_directories (SYSTEM ${DirectX_D3DX9_INCLUDE_DIR})
 133     add_custom_command (
 134         OUTPUT d3dretrace_d3d9.cpp
 135         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3d9retrace.py > ${CMAKE_CURRENT_BINARY_DIR}/d3dretrace_d3d9.cpp
 136         DEPENDS
 137                 d3d9retrace.py
 138                 dllretrace.py
 139                 retrace.py
 140                 ${CMAKE_SOURCE_DIR}/dispatch/dispatch.py
 141                 ${CMAKE_SOURCE_DIR}/specs/d3d9.py
 142                 ${CMAKE_SOURCE_DIR}/specs/d3d9types.py
 143                 ${CMAKE_SOURCE_DIR}/specs/d3d9caps.py
 144                 ${CMAKE_SOURCE_DIR}/specs/winapi.py
 145                 ${CMAKE_SOURCE_DIR}/specs/stdapi.py
 146     )
 147
 148     if (DirectX_D3D10_INCLUDE_DIR)
 149         include_directories (SYSTEM ${DirectX_D3D10_INCLUDE_DIR})
 150         set (MODULES d3d10)
 151         if (DirectX_D3D10_1_INCLUDE_DIR)
 152             include_directories (SYSTEM ${DirectX_D3D10_1_INCLUDE_DIR})
 153             set (MODULES ${MODULES} d3d10_1)
 154         endif ()
 155     endif ()
 156
 157     if (DirectX_D3D11_INCLUDE_DIR)
 158         include_directories (SYSTEM ${DirectX_D3D11_INCLUDE_DIR})
 159         set (MODULES ${MODULES} d3d11)
 160         if (DirectX_D3D11_1_INCLUDE_DIR)
 161             include_directories (SYSTEM ${DirectX_D3D11_1_INCLUDE_DIR})
 162             set (MODULES ${MODULES} d3d11_1)
 163         endif ()
 164     endif ()
 165
 166     add_custom_command (
 167         OUTPUT d3dretrace_d3d10.cpp
 168         COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/d3dcommonretrace.py ${MODULES} > ${CMAKE_CURRENT_BINARY_DIR}/d3dretrace_d3d10.cpp
 169         DEPENDS
 170                 d3dcommonretrace.py
 171                 dllretrace.py
 172                 retrace.py
 173                 ${CMAKE_SOURCE_DIR}/dispatch/dispatch.py
 174                 ${CMAKE_SOURCE_DIR}/specs/d3d11_1.py
 175                 ${CMAKE_SOURCE_DIR}/specs/d3d11.py
 176                 ${CMAKE_SOURCE_DIR}/specs/d3d11sdklayers.py
 177                 ${CMAKE_SOURCE_DIR}/specs/d3d10_1.py
 178                 ${CMAKE_SOURCE_DIR}/specs/d3d10.py
 179                 ${CMAKE_SOURCE_DIR}/specs/d3d10misc.py
 180                 ${CMAKE_SOURCE_DIR}/specs/d3d10sdklayers.py
 181                 ${CMAKE_SOURCE_DIR}/specs/d3d10shader.py
 182                 ${CMAKE_SOURCE_DIR}/specs/d3d10effect.py
 183                 ${CMAKE_SOURCE_DIR}/specs/d3dcommon.py
 184                 ${CMAKE_SOURCE_DIR}/specs/dxgi.py
 185                 ${CMAKE_SOURCE_DIR}/specs/dxgitype.py
 186                 ${CMAKE_SOURCE_DIR}/specs/dxgiformat.py
 187                 ${CMAKE_SOURCE_DIR}/specs/winapi.py
 188                 ${CMAKE_SOURCE_DIR}/specs/stdapi.py
 189     )
 190
 191     add_executable (d3dretrace
 192         d3dretrace_main.cpp
 193         d3dretrace_d3d9.cpp
 194         d3dretrace_d3d10.cpp
 195         d3dretrace_ws.cpp
 196         d3d9state.cpp
 197         d3d9state_images.cpp
 198     )
 199     target_link_libraries (d3dretrace
 200         retrace_common
 201     )
 202
 203     install (TARGETS d3dretrace RUNTIME DESTINATION bin)
 204 endif ()