git.cworth.org Git - tar/blob - m4/fdopendir.m4

   1 # serial 3
   2 # See if we need to provide fdopendir.
   3
   4 dnl Copyright (C) 2009-2010 Free Software Foundation, Inc.
   5 dnl This file is free software; the Free Software Foundation
   6 dnl gives unlimited permission to copy and/or distribute it,
   7 dnl with or without modifications, as long as this notice is preserved.
   8
   9 # Written by Eric Blake.
  10
  11 AC_DEFUN([gl_FUNC_FDOPENDIR],
  12 [
  13   AC_REQUIRE([gl_USE_SYSTEM_EXTENSIONS])
  14   AC_CHECK_FUNCS_ONCE([fdopendir])
  15   if test $ac_cv_func_fdopendir = no; then
  16     AC_LIBOBJ([openat-proc])
  17     AC_LIBOBJ([fdopendir])
  18     gl_REPLACE_DIRENT_H
  19     HAVE_FDOPENDIR=0
  20   else
  21     AC_CACHE_CHECK([whether fdopendir works],
  22       [gl_cv_func_fdopendir_works],
  23       [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
  24 #include <dirent.h>
  25 #include <fcntl.h>
  26 ]], [int fd = open ("conftest.c", O_RDONLY);
  27      if (fd < 0) return 2;
  28      return !!fdopendir (fd);])],
  29          [gl_cv_func_fdopendir_works=yes],
  30          [gl_cv_func_fdopendir_works=no],
  31          [gl_cv_func_fdopendir_works="guessing no"])])
  32     if test "$gl_cv_func_fdopendir_works" != yes; then
  33       REPLACE_FDOPENDIR=1
  34       gl_REPLACE_DIRENT_H
  35       AC_LIBOBJ([fdopendir])
  36     fi
  37   fi
  38 ])