git.cworth.org Git - tar/blob - m4/gnulib-common.m4

   1 # gnulib-common.m4 serial 13
   2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 # gl_COMMON
   8 # is expanded unconditionally through gnulib-tool magic.
   9 AC_DEFUN([gl_COMMON], [
  10   dnl Use AC_REQUIRE here, so that the code is expanded once only.
  11   AC_REQUIRE([gl_00GNULIB])
  12   AC_REQUIRE([gl_COMMON_BODY])
  13 ])
  14 AC_DEFUN([gl_COMMON_BODY], [
  15   AH_VERBATIM([isoc99_inline],
  16 [/* Work around a bug in Apple GCC 4.0.1 build 5465: In C99 mode, it supports
  17    the ISO C 99 semantics of 'extern inline' (unlike the GNU C semantics of
  18    earlier versions), but does not display it by setting __GNUC_STDC_INLINE__.
  19    __APPLE__ && __MACH__ test for MacOS X.
  20    __APPLE_CC__ tests for the Apple compiler and its version.
  21    __STDC_VERSION__ tests for the C99 mode.  */
  22 #if defined __APPLE__ && defined __MACH__ && __APPLE_CC__ >= 5465 && !defined __cplusplus && __STDC_VERSION__ >= 199901L && !defined __GNUC_STDC_INLINE__
  23 # define __GNUC_STDC_INLINE__ 1
  24 #endif])
  25   AH_VERBATIM([unused_parameter],
  26 [/* Define as a marker that can be attached to declarations that might not
  27     be used.  This helps to reduce warnings, such as from
  28     GCC -Wunused-parameter.  */
  29 #if __GNUC__ >= 3 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
  30 # define _GL_UNUSED __attribute__ ((__unused__))
  31 #else
  32 # define _GL_UNUSED
  33 #endif
  34 /* The name _UNUSED_PARAMETER_ is an earlier spelling, although the name
  35    is a misnomer outside of parameter lists.  */
  36 #define _UNUSED_PARAMETER_ _GL_UNUSED
  37 ])
  38 ])
  39
  40 # gl_MODULE_INDICATOR([modulename])
  41 # defines a C macro indicating the presence of the given module.
  42 AC_DEFUN([gl_MODULE_INDICATOR],
  43 [
  44   AC_DEFINE([GNULIB_]translit([$1],[abcdefghijklmnopqrstuvwxyz./-],[ABCDEFGHIJKLMNOPQRSTUVWXYZ___]), [1],
  45     [Define to 1 when using the gnulib module ]$1[.])
  46 ])
  47
  48 # m4_foreach_w
  49 # is a backport of autoconf-2.59c's m4_foreach_w.
  50 # Remove this macro when we can assume autoconf >= 2.60.
  51 m4_ifndef([m4_foreach_w],
  52   [m4_define([m4_foreach_w],
  53     [m4_foreach([$1], m4_split(m4_normalize([$2]), [ ]), [$3])])])
  54
  55 # AS_VAR_IF(VAR, VALUE, [IF-MATCH], [IF-NOT-MATCH])
  56 # ----------------------------------------------------
  57 # Backport of autoconf-2.63b's macro.
  58 # Remove this macro when we can assume autoconf >= 2.64.
  59 m4_ifndef([AS_VAR_IF],
  60 [m4_define([AS_VAR_IF],
  61 [AS_IF([test x"AS_VAR_GET([$1])" = x""$2], [$3], [$4])])])
  62
  63 # AC_PROG_MKDIR_P
  64 # is a backport of autoconf-2.60's AC_PROG_MKDIR_P, with a fix
  65 # for interoperability with automake-1.9.6 from autoconf-2.62.
  66 # Remove this macro when we can assume autoconf >= 2.62 or
  67 # autoconf >= 2.60 && automake >= 1.10.
  68 m4_ifdef([AC_PROG_MKDIR_P], [
  69   dnl For automake-1.9.6 && autoconf < 2.62: Ensure MKDIR_P is AC_SUBSTed.
  70   m4_define([AC_PROG_MKDIR_P],
  71     m4_defn([AC_PROG_MKDIR_P])[
  72     AC_SUBST([MKDIR_P])])], [
  73   dnl For autoconf < 2.60: Backport of AC_PROG_MKDIR_P.
  74   AC_DEFUN_ONCE([AC_PROG_MKDIR_P],
  75     [AC_REQUIRE([AM_PROG_MKDIR_P])dnl defined by automake
  76      MKDIR_P='$(mkdir_p)'
  77      AC_SUBST([MKDIR_P])])])
  78
  79 # AC_C_RESTRICT
  80 # This definition overrides the AC_C_RESTRICT macro from autoconf 2.60..2.61,
  81 # so that mixed use of GNU C and GNU C++ and mixed use of Sun C and Sun C++
  82 # works.
  83 # This definition can be removed once autoconf >= 2.62 can be assumed.
  84 AC_DEFUN([AC_C_RESTRICT],
  85 [AC_CACHE_CHECK([for C/C++ restrict keyword], [ac_cv_c_restrict],
  86   [ac_cv_c_restrict=no
  87    # The order here caters to the fact that C++ does not require restrict.
  88    for ac_kw in __restrict __restrict__ _Restrict restrict; do
  89      AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
  90       [[typedef int * int_ptr;
  91         int foo (int_ptr $ac_kw ip) {
  92         return ip[0];
  93        }]],
  94       [[int s[1];
  95         int * $ac_kw t = s;
  96         t[0] = 0;
  97         return foo(t)]])],
  98       [ac_cv_c_restrict=$ac_kw])
  99      test "$ac_cv_c_restrict" != no && break
 100    done
 101   ])
 102  AH_VERBATIM([restrict],
 103 [/* Define to the equivalent of the C99 'restrict' keyword, or to
 104    nothing if this is not supported.  Do not define if restrict is
 105    supported directly.  */
 106 #undef restrict
 107 /* Work around a bug in Sun C++: it does not support _Restrict, even
 108    though the corresponding Sun C compiler does, which causes
 109    "#define restrict _Restrict" in the previous line.  Perhaps some future
 110    version of Sun C++ will work with _Restrict; if so, it'll probably
 111    define __RESTRICT, just as Sun C does.  */
 112 #if defined __SUNPRO_CC && !defined __RESTRICT
 113 # define _Restrict
 114 #endif])
 115  case $ac_cv_c_restrict in
 116    restrict) ;;
 117    no) AC_DEFINE([restrict], []) ;;
 118    *)  AC_DEFINE_UNQUOTED([restrict], [$ac_cv_c_restrict]) ;;
 119  esac
 120 ])
 121
 122 # gl_BIGENDIAN
 123 # is like AC_C_BIGENDIAN, except that it can be AC_REQUIREd.
 124 # Note that AC_REQUIRE([AC_C_BIGENDIAN]) does not work reliably because some
 125 # macros invoke AC_C_BIGENDIAN with arguments.
 126 AC_DEFUN([gl_BIGENDIAN],
 127 [
 128   AC_C_BIGENDIAN
 129 ])
 130
 131 # gl_CACHE_VAL_SILENT(cache-id, command-to-set-it)
 132 # is like AC_CACHE_VAL(cache-id, command-to-set-it), except that it does not
 133 # output a spurious "(cached)" mark in the midst of other configure output.
 134 # This macro should be used instead of AC_CACHE_VAL when it is not surrounded
 135 # by an AC_MSG_CHECKING/AC_MSG_RESULT pair.
 136 AC_DEFUN([gl_CACHE_VAL_SILENT],
 137 [
 138   saved_as_echo_n="$as_echo_n"
 139   as_echo_n=':'
 140   AC_CACHE_VAL([$1], [$2])
 141   as_echo_n="$saved_as_echo_n"
 142 ])